WOLFRAM

Wolfram Language & System Documentation Center

NearestMeshCells[mr,pt]

gives the indices for the cells to which the point pt is nearest in the mesh region mr.

NearestMeshCells[mr,pt,n]

gives the n nearest cell indices to pt.

NearestMeshCells[mr,pt,{n,r}]

gives the n or fewer nearest cell indices to pt that are within radius r of pt.

NearestMeshCells[{mr,d},…]

gives the indices for the cells of dimension d.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Mesh Regions  
Polygons & Polyhedra  
Applications  
Interactive Examples  
Neat Examples  
See Also
Related Guides
History
Cite this Page

NearestMeshCells

NearestMeshCells[mr,pt]

gives the indices for the cells to which the point pt is nearest in the mesh region mr.

NearestMeshCells[mr,pt,n]

gives the n nearest cell indices to pt.

NearestMeshCells[mr,pt,{n,r}]

gives the n or fewer nearest cell indices to pt that are within radius r of pt.

NearestMeshCells[{mr,d},…]

gives the indices for the cells of dimension d.

Details

  • NearestMeshCells is also known as nearest point or nearest region.
  • NearestMeshCells is typically used to find the closest cells in mesh from a given point.
  • The distance to a cell in a mesh is the distance to the closest point in that cell. The nearest cell is the one with the smallest distance.
  • NearestMeshCells returns a list of cell indexes of the form {d,{i1,i2,…}}.

Examples

open all close all

Basic Examples  (2)

Find the nearest line in the triangle:

Wolfram Language code: NearestMeshCells[{Triangle[], 1}, {1, 1}]

Highlight the cell:

Wolfram Language code: Show[HighlightMesh[Triangle[], %], Graphics[{Red, Point[{1, 1}]}]]

Find the nearest cell in the mesh region:

Wolfram Language code: ℛ = MeshRegion[{{0, 0, 0}, {1, 0, 0}, {2, 0, 0}, {3, 0, -1 / 2}, {3, 0, 1 / 2}, {4, -1 / 2, 0}, {4, 1 / 2, 0}}, {Point[1], Line[{2, 3}], Triangle[{3, 4, 5}], Tetrahedron[{4, 6, 5, 7}]}];
Wolfram Language code: NearestMeshCells[ℛ, {2, 1, 1}]

Highlight the cell:

Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics3D[{Red, Point[{2, 1, 1}]}]]

Scope  (8)

Basic Uses  (2)

Find the cell nearest to {2,1}:

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, 1 / 2}, {2, -1 / 2}}, {Line[{1, 2}], Triangle[{2, 3, 4}]}];
Wolfram Language code: NearestMeshCells[ℛ, {2, 1}]

The point:

Wolfram Language code: NearestMeshCells[{ℛ, 0}, {2, 1}]

The line:

Wolfram Language code: NearestMeshCells[{ℛ, 1}, {2, 1}]

Find the 5 cells nearest to {1.5,.5}:

Wolfram Language code: ℛ = VoronoiMesh[RandomReal[1, {50, 2}]];
Wolfram Language code: NearestMeshCells[ℛ, {1.5, .5}, 5]

At most 10 cells within radius 0.5:

Wolfram Language code: NearestMeshCells[ℛ, {1.5, .5}, {10, .5}]

Mesh Regions  (2)

Find the nearest cell in a MeshRegion:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {50, 3}]]
Wolfram Language code: NearestMeshCells[ℛ, {1, 0, 1}]

Highlight it:

Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics3D[{Red, Point[{1, 0, 1}]}]]

Find the nearest line in a BoundaryMeshRegion:

Wolfram Language code: ℛ = BoundaryMeshRegion[{{0, 0}, {3, 0}, {3, 3}, {0, 3}, {1, 1}, {2, 1}, {2, 2}, {1, 2}}, Line[{1, 2, 3, 4, 1}], Line[{5, 6, 7, 8, 5}]]
Wolfram Language code: NearestMeshCells[{ℛ, 1}, {5, 1.5}]

Highlight it:

Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics[{Red, Point[{5, 1.5}]}]]

Polygons & Polyhedra  (4)

Polyhedron:

Wolfram Language code: ℛ = Polyhedron[{{-0.85065080835204, 0., 1.1135163644116066}, {-0.2628655560595668, 0.8090169943749475, 1.1135163644116066}, {-0.42532540417602, 1.3090169943749475, 0.2628655560595668}, {-1.1135163644116066, 0.8090169943749475, -0.262865556059566 ... {{1, 2, 3, 4, 5}, {6, 7, 1, 5, 8}, {9, 10, 6, 8, 11}, {12, 13, 9, 11, 14}, {4, 14, 11, 8, 5}, {3, 15, 12, 14, 4}, {16, 17, 10, 9, 13}, {18, 16, 13, 12, 15}, {19, 18, 15, 3, 2}, {20, 19, 2, 1, 7}, {17, 20, 7, 6, 10}, {16, 18, 19, 20, 17}}];
Wolfram Language code: NearestMeshCells[ℛ, {1.5, 1, 1}]
Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics3D[{Red, Point[{1.5, 1, 1}]}]]

Polygon:

Wolfram Language code: ℛ = Polygon[{{{0, 0}, {1, 0}, {0, 1}}, {{1, 1}, {2, 1}, {1, 2}}}];
Wolfram Language code: NearestMeshCells[ℛ, {1, .8}]
Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics[{Red, Point[{1, .8}]}]]

Line:

Wolfram Language code: ℛ = Line[{{1, 0}, {2, 1}, {3, 0}, {4, 1}}];
Wolfram Language code: NearestMeshCells[Line[{{1, 0}, {2, 1}, {3, 0}, {4, 1}}], {1, 1}]
Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics[{Red, Point[{1, 1}]}]]

Point:

Wolfram Language code: ℛ = Point[Table[{t, Sin[t]}, {t, 0, 2π, 2π / 10}]];
Wolfram Language code: NearestMeshCells[ℛ, {1.2, .5}]
Wolfram Language code: Show[HighlightMesh[ℛ, %], Graphics[{Red, Point[{1.2, .5}]}]]

Applications  (1)

Find a Voronoi cell that corresponds to the given point:

Wolfram Language code: pts = RandomReal[{-1, 1}, {25, 2}];
Wolfram Language code: vmesh = VoronoiMesh[pts]
Wolfram Language code: NearestMeshCells[vmesh, pts[[1]]]

Highlight a Voronoi cell:

Wolfram Language code: Show[HighlightMesh[vmesh, %], Graphics[{Orange, Point[pts[[1]]]}]]

Interactive Examples  (1)

Nearest cells around the Voronoi mesh:

Wolfram Language code: Manipulate[HighlightMesh[vm, NearestMeshCells[vm, pt, 40]], {{pt, {0.5, 0.5}}, Locator}, RuleDelayed[...]]

Neat Examples  (1)

Nearest cells around the space shuttle:

Wolfram Language code: Manipulate[Module[{pt}, pt = Append[xy, z];Show[{HighlightMesh[ℛ, NearestMeshCells[ℛ, pt, n]], Graphics3D[{Red, Sphere[pt, .2]}]}, PlotRange -> {{-8.2, 8.2}, {-5.2, 5.2}, {-2.2, 5.2}}, ImageSize -> 280]], ...]
Wolfram Research (2020), NearestMeshCells, Wolfram Language function, https://reference.wolfram.com/language/ref/NearestMeshCells.html.

Text

Wolfram Research (2020), NearestMeshCells, Wolfram Language function, https://reference.wolfram.com/language/ref/NearestMeshCells.html.

CMS

Wolfram Language. 2020. "NearestMeshCells." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NearestMeshCells.html.

APA

Wolfram Language. (2020). NearestMeshCells. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NearestMeshCells.html

BibTeX

@misc{reference.wolfram_2026_nearestmeshcells, author="Wolfram Research", title="{NearestMeshCells}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/NearestMeshCells.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_nearestmeshcells, organization={Wolfram Research}, title={NearestMeshCells}, year={2020}, url={https://reference.wolfram.com/language/ref/NearestMeshCells.html}, note=[Accessed: 15-June-2026]}