WOLFRAM

Wolfram Language & System Documentation Center

RegionHausdorffDistance[reg1,reg2]

gives the Hausdorff distance between the regions reg1 and reg2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Special Regions  
Mesh Regions  
Options  
WorkingPrecision  
Applications  
Region Reconstruction  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

RegionHausdorffDistance

RegionHausdorffDistance[reg1,reg2]

gives the Hausdorff distance between the regions reg1 and reg2.

Details and Options

  • RegionHausdorffDistance is also known as Hausdorff metric and Pompeiu–Hausdorff distance.
  • The Hausdorff distance measures how different two regions are from each other.
  • RegionHausdorffDistance is the greatest of all distances from a point in one region to the closest point in the other region.
  • The distance between points p and q is taken to be Norm[p-q].
  • RegionHausdorffDistance is effectively given by the maximum of MaxValue[MinValue[Norm[p-q],q∈reg2],p∈reg1] and MaxValue[MinValue[Norm[p-q],q∈reg1],p∈reg2].
  • Unless the regions are closed, the Hausdorff distance may not be attained by points in the region but in the closure of the regions.
  • The Hausdorff distance between two regions reg1 and reg2 is ϵ if reg1⊆RegionDilation[reg2,ϵ] and reg2⊆RegionDilation[reg1,ϵ].

Examples

open all close all

Basic Examples  (4)

Find the Hausdorff distance between two disks:

Wolfram Language code: RegionHausdorffDistance[Disk[], Disk[{0, 0}, 3]]

Show the disks:

Wolfram Language code: Graphics[{Opacity[1 / 3], Disk[], Disk[{0, 0}, 3]}, Axes -> True]

Find the Hausdorff distance between the unit disk and a regular polygon:

Wolfram Language code: RegionHausdorffDistance[Disk[], RegularPolygon[6]]

Show the regions:

Wolfram Language code: Graphics[{Opacity[1 / 3], Disk[], RegularPolygon[6]}, Axes -> True]

Plot the Hausdorff distance as the number of sides increases:

Wolfram Language code: ListPlot[Table[{n, RegionHausdorffDistance[Disk[], RegularPolygon[n]]}, {n, 3, 10}], Joined -> True]

Find the Hausdorff distance between two point clouds:

Wolfram Language code: RegionHausdorffDistance[RandomReal[1, {1000, 2}], RandomReal[1, {1000, 2}]]

Find the Hausdorff distance between a MeshRegion and its convex hull:

Wolfram Language code: Subscript[ℛ, 1] = ResourceData["Stanford Bunny"]; Subscript[ℛ, 2] = ConvexHullMesh[Subscript[ℛ, 1]];
Wolfram Language code: RegionHausdorffDistance[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Show the hull:

Wolfram Language code: Graphics3D[{EdgeForm[], Opacity[0.5], Subscript[ℛ, 1], Subscript[ℛ, 2]}]

Scope  (9)

Special Regions  (8)

Points:

Wolfram Language code: RegionHausdorffDistance[Point[{{1, 1}, {1, 2}}], Point[{3, 4}]]

RegionHausdorffDistance accepts coordinate lists:

Wolfram Language code: RegionHausdorffDistance[{{1, 1}, {1, 2}}, {3, 4}]

Lines:

Wolfram Language code: RegionHausdorffDistance[Line[{{0, 0}, {1, 1}}], Line[{{-1, 1}, {2, 0}}]]
Wolfram Language code: RegionHausdorffDistance[Line[{{0, -1, 2}, {2, -1, -3}}], Line[{{-1, 1, 3}, {2, -1, 0}}]]

Polygons:

Wolfram Language code: RegionHausdorffDistance[Polygon[{{0, 0}, {2, 1}, {1, 3}}], Polygon[{{2, 0}, {0, 3}, {-1, 1}}]]
Wolfram Language code: RegionHausdorffDistance[Triangle[], Rectangle[]]

Simplices:

Wolfram Language code: RegionHausdorffDistance[Simplex[{{0}, {1}}], Simplex[{{2}, {3}}]]
Wolfram Language code: RegionHausdorffDistance[Simplex[{{0, 0}, {2, 0}, {0, 2}}], Simplex[{{1, -1}, {1, 1}, {2, -1}}]]
Wolfram Language code: RegionHausdorffDistance[Simplex[{{0, 0, 0}, {2, 0, 0}, {0, 2, 0}, {0, 0, 2}}], Simplex[{{-1, 0, 1}, {2, 0, 1}, {3, 2, 0}, {2, 0, 2}}]]

Boxes:

Wolfram Language code: RegionHausdorffDistance[Rectangle[], Rectangle[{2, 1}]]
Wolfram Language code: RegionHausdorffDistance[Cuboid[], Cuboid[{3, 2, 1}]]
Wolfram Language code: RegionHausdorffDistance[Cube[], Cube[2]]

Balls:

Wolfram Language code: RegionHausdorffDistance[Disk[], Disk[{1, 1}]]
Wolfram Language code: RegionHausdorffDistance[Ball[], Ball[{1, 2, 3}]]

Spheres:

Wolfram Language code: RegionHausdorffDistance[Circle[], Circle[{1, 2}]]
Wolfram Language code: RegionHausdorffDistance[Sphere[], Sphere[{4, 5, 6}]]

Regions in n:

Wolfram Language code: RegionHausdorffDistance[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}], {1, 2, 3, 4}]
Wolfram Language code: RegionHausdorffDistance[Point[{1, 2, 3, 4, 5}], {6, 7, 8, 9, 10}]
Wolfram Language code: RegionHausdorffDistance[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}], {11, 12, 13, 14, 15}]
Wolfram Language code: RegionHausdorffDistance[Ball[{1, 2, 3, 4, 5, 6, 7}, 8], {9, 10, 11, 12, 13, 14, 15}]

Mesh Regions  (1)

The Hausdorff distance between two 1D meshes:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {10, 1}]]; 𝒮 = ConvexHullMesh[RandomReal[1, {10, 1}]];
Wolfram Language code: RegionHausdorffDistance[ℛ, 𝒮]

2D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {10, 2}]]; 𝒮 = ConvexHullMesh[RandomReal[{1 / 2, 3 / 2}, {10, 2}]];
Wolfram Language code: Show[ℛ, HighlightMesh[𝒮, 2]]
Wolfram Language code: RegionHausdorffDistance[ℛ, 𝒮]

3D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {20, 3}]]; 𝒮 = ConvexHullMesh[RandomReal[{1 / 2, 3 / 2}, {20, 3}]];
Wolfram Language code: Show[ℛ, HighlightMesh[𝒮, 2]]
Wolfram Language code: RegionHausdorffDistance[ℛ, 𝒮]

Options  (2)

WorkingPrecision  (2)

RegionHausdorffDistance will try to compute the distance using the same precision as its inputs:

Wolfram Language code: RegionHausdorffDistance[Disk[], Point[{4, 4}]]

Compute the distance using machine arithmetic:

Wolfram Language code: RegionHausdorffDistance[Disk[], Point[{4, 4}], WorkingPrecision -> MachinePrecision]

In some cases, the exact answer cannot be computed:

Wolfram Language code: RegionHausdorffDistance[ImplicitRegion[x ^ 6 + y ^ 6 - x y <= 1, {x, y}], Point[{2, 3}]]

Find the RegionHausdorffDistance using 30 digits of precision:

Wolfram Language code: RegionHausdorffDistance[Disk[], Point[{4, 4}], WorkingPrecision -> 30]

Applications  (1)

Region Reconstruction  (1)

Reconstruct a mesh from random point samples:

Wolfram Language code: ℛ = ResourceData["Horse"]; 𝒮 = ReconstructionMesh[RandomPoint[ℛ, 10000]];

Determine the Hausdorff distance between the ground truth and reconstructed mesh:

Wolfram Language code: RegionHausdorffDistance[ℛ, 𝒮]

Plot how the Hausdorff distance decreases with larger sample counts:

Wolfram Language code: ListPlot[Table[{n, RegionHausdorffDistance[ℛ, ReconstructionMesh[RandomPoint[ℛ, n]]]}, {n, {100, 500, 1000, 2000, 3000, 4000}}], Joined -> True]

Properties & Relations  (4)

The Hausdorff distance between two points is equivalent to the EuclideanDistance:

Wolfram Language code: RegionHausdorffDistance[{1, 2}, {3, 4}]
Wolfram Language code: EuclideanDistance[{1, 2}, {3, 4}]

The Hausdorff distance between two point sets is the maximum EuclideanDistance from any point to the other set:

Wolfram Language code: 𝒜 = {{0, 0}, {1, 2}, {4, 3}}; ℬ = {{4, 2}, {3, 0}};
Wolfram Language code: RegionHausdorffDistance[𝒜, ℬ] === Max[Min /@ Table[EuclideanDistance[a, b], {a, 𝒜}, {b, ℬ}]]

The Hausdorff distance between a region and a single point is the furthest distance of the point to any point in the region:

Wolfram Language code: RegionHausdorffDistance[Disk[], Point[{3, 5}]] === RegionFarthestDistance[Disk[], Point[{3, 5}]]

RegionDistance can be used to find the nearest distance from a point to a region:

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: RegionDistance[ℛ, {3, 5}]
Wolfram Research (2023), RegionHausdorffDistance, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionHausdorffDistance.html.

Text

Wolfram Research (2023), RegionHausdorffDistance, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionHausdorffDistance.html.

CMS

Wolfram Language. 2023. "RegionHausdorffDistance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RegionHausdorffDistance.html.

APA

Wolfram Language. (2023). RegionHausdorffDistance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionHausdorffDistance.html

BibTeX

@misc{reference.wolfram_2026_regionhausdorffdistance, author="Wolfram Research", title="{RegionHausdorffDistance}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/RegionHausdorffDistance.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_regionhausdorffdistance, organization={Wolfram Research}, title={RegionHausdorffDistance}, year={2023}, url={https://reference.wolfram.com/language/ref/RegionHausdorffDistance.html}, note=[Accessed: 12-June-2026]}