WOLFRAM

Wolfram Language & System Documentation Center

Tube[{{x1,y1,z1},{x2,y2,z2},…}]

represents a 3D tube around the line joining a sequence of points.

Tube[{pt1,pt2,…},r]

represents a tube of radius r.

Tube[{{pt11,pt12,…},{pt21,…},…},…]

represents a collection of tubes.

Tube[curve,…]

represents a tube around the specified 3D curve.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Tube Specification  
Tube Styling  
Coordinate Specification  
Options  
VertexColors  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

Tube

Tube[{{x1,y1,z1},{x2,y2,z2},…}]

represents a 3D tube around the line joining a sequence of points.

Tube[{pt1,pt2,…},r]

represents a tube of radius r.

Tube[{{pt11,pt12,…},{pt21,…},…},…]

represents a collection of tubes.

Tube[curve,…]

represents a tube around the specified 3D curve.

Details and Options

  • Tube renders as a circular 3D tube in Graphics3D.
  • The radius of the tube can be specified either in absolute coordinates, or as Scaled[s].
  • If no explicit radius is specified, Tube uses a small scaled radius.
  • Tube[{pt1,pt2,…},{r1,r2,…}] specifies a different tube radius at the position of each of the points pti.
  • Tube[{pt1,pt2,…},…] gives a tube consisting of a sequence of straight segments. It is equivalent to Tube[Line[{pt1,…}],…].
  • The following curve specifications can be used:
  • Line[…]piecewise line segments
    BezierCurve[…]composite Bezier curve
    BSplineCurve[…]B-spline curve
  • By default, the joins between tube segments are rounded.
  • Different forms of joining between tube segments can be specified using JoinForm.
  • By default, the ends of the tube are rounded.
  • Different caps for the tube can be specified using CapForm.
  • CapForm[None] specifies that the end of the tube should be left open.
  • In Tube[curve,…], curve can have head BezierCurve, BSplineCurve, or Line.
  • Colors and other material properties of tubes can be specified using color directives as well as Specularity and Glow.
  • Tubes can be specified as transparent using Opacity directives.
  • Individual coordinates and lists of coordinates in tubes can be Dynamic objects.

Examples

open all close all

Basic Examples  (4)

A tube primitive:

Wolfram Language code: Graphics3D[Tube[{{0, 0, 0}, {1, 1, 1}}]]

A tube along a curve:

Wolfram Language code: Graphics3D[Tube[BSplineCurve[{{1, 1, -1}, {2, 2, 1}, {3, 3, -1}, {3, 4, 1}}]]]

A tube with radius .1:

Wolfram Language code: Graphics3D[Tube[{{0, 0, 0}, {1, 1, 1}}, .1]]

Differently styled tubes:

Wolfram Language code: t = Tube[{{-1, -1, -1}, {0, 0, 1}, {1, 1, -1}}, 0.4];
Wolfram Language code: {Graphics3D[{Red, t}], Graphics3D[{CapForm["Round"], t}], Graphics3D[{JoinForm["Miter"], t}]}

Scope  (16)

Tube Specification  (7)

Single tube segment:

Wolfram Language code: Graphics3D[Tube[{{0, 0, 0}, {2, 1, 1}}]]

Multiple connected tube segments:

Wolfram Language code: Graphics3D[Tube[{{0, 0, 0}, {2, 1, 1}, {4, 0, 0}}]]

Multiple disconnected tube segments:

Wolfram Language code: s = {{0, 0, 0}, {2, 1, 1}, {4, 0, 0}};
Wolfram Language code: {Graphics3D[Tube[{s, s + 1}]], Graphics3D[Tube[BSplineCurve[{s, s + 1}]]]}

Tubes with different radii:

Wolfram Language code: s = {{-1, -1, -1}, {1, 1, 1}};
Wolfram Language code: Table[Graphics3D[Tube[s, i]], {i, {.05, .1, .2}}]

Radii can also be specified at vertices:

Wolfram Language code: {Graphics3D[{CapForm[None], Tube[{{0, 0, 0}, {1, 1, 1}}, {1, 2}]}], Graphics3D[{CapForm["Round"], Tube[{{0, 0, 0}, {-6, 4, 10}}, {2, 1}]}]}

Tubes with scaled radii:

Wolfram Language code: s = {{-1, -1, -1}, {1, 1, 1}};
Wolfram Language code: Table[Graphics3D[Tube[s, Scaled[i]], PlotRange -> 1.5], {i, {.01, .02, .04}}]

Tube can take a line or curve argument:

Wolfram Language code: {Graphics3D[Tube[Line[{{0, 0, 0}, {1, 1, 0}, {2, 0, 0}}], .1]], Graphics3D[{Tube[BezierCurve[{{0, 0, 0}, {1, 1, 0}, {2, 0, 0}}], .1]}]}

Tube Styling  (8)

Colored tubes:

Wolfram Language code: l = Tube[{{1, 1, -1}, {2, 2, 1}, {3, 3, -1}, {4, 4, 1}}, 0.1];
Wolfram Language code: Table[Graphics3D[{c, CapForm[None], JoinForm[None], l}], {c, {Red, Green, Blue, Yellow}}]

Different properties can be specified for the front and back faces using FaceForm:

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], Tube[{{0, 0, -1}, {0, 0, 1}}, 1]}, PlotRange -> {{-1, 1}, {-.8, 1}, {-1, 1}}]

Tubes with different specular exponents:

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[GrayLevel[1], n], CapForm["Round"], Tube[{{0, 0, -1}, {0, 0, 1}}, 1]}, Lighting -> {{"Point", White, Scaled[{2, -1, 1.2}]}}], {n, {5, 20, 100}}]

White tube that glows red:

Wolfram Language code: Graphics3D[{Glow[Red], Black, CapForm["Round"], Tube[{{0, 0, -1}, {0, 0, 1}}, 1]}]

Opacity specifies the face opacity:

Wolfram Language code: Table[Graphics3D[{CapForm["Round"], Opacity[o], Tube[{{0, 0, -1}, {0, 0, 1}}, 1]}, PlotLabel -> o], {o, {0.3, 0.5, 0.9}}]

Tube caps can be specified using CapForm:

Wolfram Language code: Table[Graphics3D[{CapForm[cap], Tube[{{-1, 1, -1}, {1, -1 / 2, 1}}, 0.7]}, PlotRange -> 2, PlotLabel -> Row[{cap}], Boxed -> False], {cap, {None, "Butt", "Round", "Square"}}]

Joining of tube segments can be specified using JoinForm:

Wolfram Language code: Table[Graphics3D[{JoinForm[j], Tube[{{-1, -1, -1}, {0, 0, 1}, {1, 1, -1}}, 0.4]}, PlotRange -> 2, PlotLabel -> Row[{j}], Boxed -> False], {j, {None, "Bevel", "Round", "Miter"}}]

Colors can be specified at vertices using VertexColors:

Wolfram Language code: Graphics3D[{Tube[{{0, 0, 0}, {2, 1, 1}}, 0.1, VertexColors -> {Red, Green}]}]

Coordinate Specification  (1)

Use Scaled coordinates:

Wolfram Language code: Graphics3D[Tube[{Scaled[{0, .2, 0}], Scaled[{1, .8, 1}]}], Axes -> True]

Options  (1)

VertexColors  (1)

Use VertexColors to vary the colors along the tube:

Wolfram Language code: Graphics3D[{Tube[{{0, 0, 0}, {2, 1, 1}}, 0.1, VertexColors -> {Red, Green}]}]

Applications  (4)

PieChart3D uses Tube to produce donut charts:

Wolfram Language code: PieChart3D[{1, 2, 3, 4}, ChartElementFunction -> "TorusSector3D", SectorOrigin -> {Automatic, 1}, BoxRatios -> Automatic]

Plot a parametric space curve and replace the curve with a tube:

Wolfram Language code: ParametricPlot3D[{Sin[u], Cos[u], u / 10}, {u, 0, 20}, PlotStyle -> Orange, PlotRange -> All] /. Line[pts_, rest___] :> Tube[pts, 0.1, rest]

Tube can be used with Arrow for full 3D arrows:

Wolfram Language code: Graphics3D[{Arrowheads[.4], Blue, Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.1, VertexColors -> {Red, Blue}]]}]

A random 3D walk:

Wolfram Language code: randomWalk = Accumulate[RandomChoice[Join[IdentityMatrix[3], -IdentityMatrix[3]], 40]];
Wolfram Language code: Graphics3D[{Red, CapForm[None], JoinForm[None], Arrowheads[RandomChoice[{{0.04}}, 50]], Arrow[Tube[randomWalk]]}]

Use Tube for 3D edges in GraphPlot3D:

Wolfram Language code: GraphPlot3D[{1 -> 2, 2 -> 3, 3 -> 4, 4 -> 1, 4 -> 5, 5 -> 1, 2 -> 5, 3 -> 5}, EdgeShapeFunction -> (Tube[#1, .05]&), VertexShapeFunction -> ({ColorData["Atoms"][RandomInteger[{1, 117}]], Sphere[#1, .15]}&), PlotStyle -> Directive[Specularity[White, 20]]]

Obtain directed edges using Arrow:

Wolfram Language code: GraphPlot3D[{1 -> 2, 2 -> 3, 3 -> 4, 4 -> 1, 4 -> 5, 5 -> 1, 2 -> 5, 3 -> 5}, EdgeShapeFunction -> (Arrow@Tube[#1, .03]&), VertexShapeFunction -> ({ColorData["Atoms"][RandomInteger[{1, 117}]], Sphere[#1, .15]}&), PlotStyle -> Directive[Specularity[White, 20], Arrowheads[{{0.1, 0.7}}]]]

Properties & Relations  (6)

Use Scale to get an elliptical tube:

Wolfram Language code: Graphics3D[Scale[Tube[{{0, 0, -1}, {0, 0, 1}}, 1], {2, 4, 3}, {0, 0, 0}], Axes -> True]

Use Arrow with Tube to get a full 3D arrow:

Wolfram Language code: Graphics3D[{Arrowheads[.1], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.02]]}]

Cone is a special case of Tube:

Wolfram Language code: {Graphics3D[Cone[{{0, 0, 0}, {1, 1, 1}}, 1]], Graphics3D[{CapForm["Butt"], Tube[{{0, 0, 0}, {1, 1, 1}}, {1, 0}]}]}

Get a truncated cone by specifying different radii in Tube:

Wolfram Language code: Graphics3D[{CapForm["Butt"], Tube[{{0, 0, 0}, {1, 1, 1}}, {1, 1 / 2}]}]

Cylinder is a special case of Tube:

Wolfram Language code: {Graphics3D[Cylinder[{{0, 0, 0}, {1, 1, 1}}, 1]], Graphics3D[{CapForm["Butt"], Tube[{{0, 0, 0}, {1, 1, 1}}, {1, 1}]}]}

Get curved cylinder by using additional points:

Wolfram Language code: Graphics3D[{CapForm["Butt"], Tube[{{0, 0, 0}, {1, 1, 1}, {1, 1, 3}}, {1, 1, 1}]}]

A parametric specification of a tube generated using ParametricPlot3D:

Wolfram Language code: ParametricPlot3D[{Cos[θ], Sin[θ], z}, {θ, 0, 2 π}, {z, -1, 1}, Mesh -> None]

An implicit specification of a tube generated by ContourPlot3D:

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None]

Possible Issues  (1)

Tube objects can only use machine-number coordinates:

Wolfram Language code: Graphics3D[Tube[{{0, 0, 0}, {10. ^ 500, 10. ^ 500, 10. ^ 500}}]]
Wolfram Language code: MachineNumberQ[10. ^ 500]

Neat Examples  (4)

A random collection of tube curves:

Wolfram Language code: Graphics3D[Tube[BSplineCurve[RandomReal[.1, {20, 3, 3}]]]]

Tubes with interpolated colors:

Wolfram Language code: ParametricPlot3D[{Cos[2 t], Sin[2 t], Cos[t]}, {t, 0, 2 Pi}, PlotStyle -> Directive[Opacity[0.7], CapForm[None], JoinForm["Miter"], Red], PlotRange -> All, ColorFunction -> Hue, Boxed -> False, MaxRecursion -> 0, PlotPoints -> 100, Axes -> None, Method -> {"TubePoints" -> 30}] /. Line[pts_, rest___] :> Tube[pts, 0.2, rest]

Tube curves with interpolated radii:

Wolfram Language code: Graphics3D[{Red, CapForm["Round"], Tube[BSplineCurve[{{0, 0, 0}, {1, 1, 0}, {1.2, 2, 0}, {.6, 1.8, 0}, {0, 1.3, 0}, {-.6, 1.8, 0}, {-1.2, 2, 0}, {-1, 1, 0}, {0, 0, 0}}], {.1, .1, .1, .1, .3, .1, .1, .1, .1}]}]
Wolfram Language code: Graphics3D[{CapForm[None], Tube[BSplineCurve[{{0, 0, -1}, {0, 0, -.5}, {0, 0, 0}, {0, 0, 1}, {0, 0, 15}, {0, 0, 20}, {0, 0, 25}, {0, 0, 32}, {0, 0, 35}}], {6, 6.5, 6, 3.2, 12, 4, 2, 2.4, 3.5}]}]

Using random radii:

Wolfram Language code: pts = N[Table[10{u, 5 Cos[u u], 5 Sin[u u]}, {u, 1, 10, .3}]];
Wolfram Language code: Graphics3D[{Red, Tube[BSplineCurve[pts, SplineDegree -> 3], 5RandomReal[1, 34]], Green, Tube[BSplineCurve[pts, SplineDegree -> 8], 5RandomReal[1, 34]]}, PlotRange -> All]
Wolfram Research (2008), Tube, Wolfram Language function, https://reference.wolfram.com/language/ref/Tube.html (updated 2010).

Text

Wolfram Research (2008), Tube, Wolfram Language function, https://reference.wolfram.com/language/ref/Tube.html (updated 2010).

CMS

Wolfram Language. 2008. "Tube." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2010. https://reference.wolfram.com/language/ref/Tube.html.

APA

Wolfram Language. (2008). Tube. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Tube.html

BibTeX

@misc{reference.wolfram_2026_tube, author="Wolfram Research", title="{Tube}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/Tube.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tube, organization={Wolfram Research}, title={Tube}, year={2010}, url={https://reference.wolfram.com/language/ref/Tube.html}, note=[Accessed: 12-June-2026]}