Wolfram Language & System Documentation Center

WeightedData

WeightedData[{x₁,x₂,…},{w₁,w₂,…}]

represents observations x_i with weights w_i.

WeightedData[{x₁,x₂,…},fn]

represents observations x_i with weighting function fn.

Details

WeightedData augments data with weights for each data point.
The data {x₁,x₂,…} and weights {w₁,w₂,…} should be lists of equal length.
The weight function fn is applied to the list {x₁,x₂,…} and should return an explicit list of weights {w₁,w₂,…}.
WeightedData can be used in statistics functions including:

	Mean,Variance,…	descriptive statistics functions
	EmpiricalDistribution,…	nonparametric distribution estimation
	EstimatedDistribution,…	parametric distribution estimation

WeightedData[{x₁,x₂,…}] gives data with equal weights.
Properties of WeightedData can be obtained by specifying WeightedData[…]["property"].
A list of available properties can be obtained using WeightedData[…]["Properties"].
WeightedData has the following properties:

	"EmpiricalPDF"	data values and estimated weights
	"InputData"	unweighted input data values
	"MetaInformation"	a list containing meta-information rules
	"Weights"	a list containing the data weights

Examples

open all close all

Basic Examples (1)

Create data with weights:

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
w = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: 𝒜 = WeightedData[data, w]

Compute a weighted Mean and StandardDeviation:

Wolfram Language code: Mean[𝒜]

Wolfram Language code: StandardDeviation[𝒜]

Scope (10)

Create weighted univariate data:

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
w = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: 𝒜 = WeightedData[data, w];

Some weighted descriptive statistics:

Wolfram Language code: Table[{i, i[𝒜]}, {i, {Mean, Median, Variance, StandardDeviation, Kurtosis, Skewness, InterquartileRange}}]//Grid

Add weights to a set of multivariate values:

Wolfram Language code:

x = {{1, 2}, {4, 5}, {5, 6}, {7, 3}};
w = {.5, .25, .1, 1};

Wolfram Language code: 𝒜 = WeightedData[x, w]

A set of weighted multivariate descriptive statistics:

Wolfram Language code: Mean[𝒜]

Wolfram Language code: Covariance[𝒜]

Wolfram Language code: Correlation[𝒜]

Use a pure function to create weighted data values:

Wolfram Language code: x = RandomInteger[{1, 25}, 5000];

Wolfram Language code: 𝒜 = Table[WeightedData[x, Function@@{t, t^i}], {i, Range[0, 4]}];

Weighted means and variances:

Wolfram Language code: N[Mean /@ 𝒜]

Wolfram Language code: N[Variance /@ 𝒜]

Visualize the impact of the various weighting schemes:

Wolfram Language code:

Plot[Evaluate@Table[PDF[SmoothKernelDistribution[w], a], {w, 𝒜}], {a, -3, 30}, PlotRange -> All, PlotLegends -> Map[Row[{"t --> ", #}]&, t ^ Range[0, 4]]]

Fit nonparametric distributions to weighted data:

Wolfram Language code:

data = RandomVariate[NormalDistribution[0, 1], 50];
w = data ^ 2;

Wolfram Language code: 𝒜 = WeightedData[data, w]

Wolfram Language code: dists = Table[𝒟[𝒜], {𝒟, {EmpiricalDistribution, HistogramDistribution, SmoothKernelDistribution}}];

Wolfram Language code: Table[Plot[CDF[i, x], {x, -3, 3}, PlotLabel -> Row[{"Mean: ", Mean[i]}], Exclusions -> None], {i, dists}]

Fit parametric distributions to weighted data:

Wolfram Language code:

data = RandomReal[{0, 100}, 1000];
w = PDF[ExponentialDistribution[1 / 20], #]&;

Wolfram Language code: 𝒜 = WeightedData[data, w]

Wolfram Language code: 𝒟1 = EstimatedDistribution[𝒜, ExponentialDistribution[a]]

Compare the estimated and empirical distributions:

Wolfram Language code: 𝒟2 = EmpiricalDistribution[𝒜];

Wolfram Language code:

Plot[{CDF[𝒟1, x], CDF[𝒟2, x]}, {x, 0, 50}, Exclusions -> None, PlotStyle -> {Thick, Automatic}, PlotLegends -> {"𝒟1", "𝒟2"}]

Extract the input data from a WeightedData object:

Wolfram Language code:

𝒜 = WeightedData[Automatic, {{4.3424867371049345, 84.95915906432668, 54.62083275189872, 
   60.351715598529864, 74.13571604649297, 60.94262726482822, 66.51118636065769, 64.48764263803247, 
   71.21344855673459, 82.3471338515244, 99.98746459746363, 17.1 ... 584268284, 0.004700837378501972, 
   0.008097966826215594, 0.0027249292830005016, 0.029142913216900736, 0.005685347349364164, 
   0.02694522380487357, 0.013049595682933283, 0.0005752644284236291, 0.0013256312483065082, 
   0.0004190555990108067}}];

Wolfram Language code: d = 𝒜["InputData"];

Compare the distributions of the unweighted and weighted data:

Wolfram Language code: 𝒟1 = HistogramDistribution[d];

Wolfram Language code: 𝒟2 = HistogramDistribution[𝒜];

Wolfram Language code:

Table[Plot[PDF[𝒟, x], {x, 0, 100}, Filling -> Axis, Exclusions -> None, PlotRange -> {0, .04}], {𝒟, {𝒟1, 𝒟2}}]

Obtain the weights from a WeightedData object:

Wolfram Language code:

𝒜 = WeightedData[Automatic, {{4.3424867371049345, 84.95915906432668, 54.62083275189872, 
   60.351715598529864, 74.13571604649297, 60.94262726482822, 66.51118636065769, 64.48764263803247, 
   71.21344855673459, 82.3471338515244, 99.98746459746363, 17.1 ... 584268284, 0.004700837378501972, 
   0.008097966826215594, 0.0027249292830005016, 0.029142913216900736, 0.005685347349364164, 
   0.02694522380487357, 0.013049595682933283, 0.0005752644284236291, 0.0013256312483065082, 
   0.0004190555990108067}}];

Wolfram Language code: w = 𝒜["Weights"];

Visually inspect the effect of the weights on the data values:

Wolfram Language code: ListLinePlot[Sort@Transpose[{𝒜["InputData"], w}]]

Compute a weighted mean from the empirical PDF:

Wolfram Language code:

𝒜 = WeightedData[Automatic, {{4.3424867371049345, 84.95915906432668, 54.62083275189872, 
   60.351715598529864, 74.13571604649297, 60.94262726482822, 66.51118636065769, 64.48764263803247, 
   71.21344855673459, 82.3471338515244, 99.98746459746363, 17.1 ... 584268284, 0.004700837378501972, 
   0.008097966826215594, 0.0027249292830005016, 0.029142913216900736, 0.005685347349364164, 
   0.02694522380487357, 0.013049595682933283, 0.0005752644284236291, 0.0013256312483065082, 
   0.0004190555990108067}}];

Wolfram Language code: {d, pdf} = 𝒜["EmpiricalPDF"];

Wolfram Language code: d.pdf

The weighted mean can be computed directly using Mean:

Wolfram Language code: Mean[𝒜]

Find the weighted average of an irregularly sampled TimeSeries:

Wolfram Language code: ts = TimeSeries[Table[{t, 2t + RandomVariate[NormalDistribution[0, 0.3]]}, {t, {0., 0.15, 0.2, 0.5, 0.75, 1., 1.5, 2}}]]

Wolfram Language code: wm = Mean[WeightedData[ts]]

Compare with the average of values:

Wolfram Language code: vm = Mean[ts]

Wolfram Language code:

ListLinePlot[ts, Frame -> True, PlotMarkers -> {Automatic, Tiny}, 
	GridLines -> {None, {{vm, Dashed}, {wm, Dotted}}}, 
	FrameTicks -> {{Automatic, {{vm, " value mean"}, {wm, " weighted mean"}}}, {Automatic, Automatic}}]

Create weighted data involving quantities:

Wolfram Language code:

data = Quantity[{7, 3, 5, 4, 9, 0, 4, 2, 2, 3}, "Meters"];
w = {0.12, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: 𝒜 = WeightedData[data, w];

Some weighted descriptive statistics:

Wolfram Language code: Table[{i, i[𝒜]}, {i, {Mean, Median, Variance, StandardDeviation, Kurtosis, Skewness, InterquartileRange}}]//TableForm

Applications (2)

Create a weighted histogram:

Wolfram Language code: data = RandomReal[{-5, 5}, 10 ^ 4];

Wolfram Language code: 𝒜 = WeightedData[data, PDF[NormalDistribution[], #]&];

Wolfram Language code: 𝒟 = HistogramDistribution[𝒜, 50];

Wolfram Language code:

m = Mean[𝒜];
sd = StandardDeviation[𝒜];
Plot[PDF[𝒟, x], {x, -4, 4}, Exclusions -> None, Filling -> Axis, Epilog -> Inset[TableForm[{{"Mean:", m}, {"SD:", sd}}], {Right, Top}, {Right, Top}]]

Estimate confidence interval for maximum likelihood estimates of distribution parameters:

Wolfram Language code:

BlockRandom[SeedRandom[40];
	data = RandomVariate[WeibullDistribution[2.3, 0.8], 30]];

Wolfram Language code: mleP = {α, β} /. FindDistributionParameters[data, WeibullDistribution[α, β]]

Apply fractional random weight bootstrap to estimate confidence interval, by repeating weighted estimation with weights sampled from a DirichletDistribution with unit parameters:

Wolfram Language code: weightSample[n_Integer] := RandomVariate[DirichletDistribution[ConstantArray[1, n + 1]]]

Wolfram Language code: frwData[data_] := WeightedData[data, weightSample[Length[data]]]

Generate one thousand estimates of the distribution parameters:

Wolfram Language code: frwPs = Table[{α, β} /. FindDistributionParameters[frwData[data], WeibullDistribution[α, β]], 1000];

Visualize bootstrap estimates:

Wolfram Language code: ListPlot[frwPs, Epilog -> {Directive[PointSize[Large], Orange], Point[mleP]}]

Fit joint Gaussian distribution to the bootstrapped parameters:

Wolfram Language code: EstimatedDistribution[frwPs, BinormalDistribution[{αμ, βm}, {αv, βv}, ρ]]

Properties & Relations (3)

WeightedData with equal weights:

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
wd = WeightedData[data]

The underlying empirical distributions are the same:

Wolfram Language code: EmpiricalDistribution[data] === EmpiricalDistribution[wd]

Descriptive statistics are based on the underlying EmpiricalDistribution:

Wolfram Language code: 𝒜 = WeightedData[{{-30, -30}, {10, 10}, {20, 20}}, {1, 7, 2}];

Wolfram Language code: 𝒟 = EmpiricalDistribution[𝒜];

Wolfram Language code: {Mean[𝒜], Mean[𝒟]}

Sample estimates are given when they differ from population estimates:

Wolfram Language code: {Variance[𝒜], Variance[𝒟]}

WeightedData works for TimeSeries objects:

Wolfram Language code:

ts = TimeSeries[vals = {x1, x2, x3, x4}, {times = {0, 1 / 3, 1 / 2, 1}}];
wm = Mean[WeightedData[ts]]

For , the weights are proportional to :

Wolfram Language code: weights = MovingAverage[ArrayPad[Differences[times], {1, 1}, "Fixed"], 2]

Wolfram Language code: Normalize[weights, Total].vals

Compare with bin‐sampled time average:

Wolfram Language code: evals = ArrayPad[vals, {1, 1}, "Fixed"]

Wolfram Language code: etimes = ArrayPad[times, {1, 1}, "ReflectedDifferences"]

Wolfram Language code: if = Interpolation[Transpose[{etimes, evals}], InterpolationOrder -> 1];

Compute integration limits:

Wolfram Language code: {tmin, tmax} = {Mean[Take[etimes, 2]], Mean[Take[etimes, -2]]}

Wolfram Language code: (1/tmax - tmin)Integrate[if[t], {t, tmin, tmax}]//Expand

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

WeightedData

Details

Examples

Basic Examples (1)

Scope (10)

Applications (2)

Properties & Relations (3)

Text

CMS

APA

BibTeX

BibLaTeX

WeightedData

Details

Examples

Basic Examples (1)

Scope (10)

Applications (2)

Properties & Relations (3)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX