Wolfram Language & System Documentation Center

CosDegrees

CosDegrees[θ]

gives the cosine of degrees.

Details

CosDegrees and other trigonometric functions are studied in high-school geometry courses and are also used in many scientific disciplines.
The argument of CosDegrees is assumed to be in degrees.
CosDegrees is automatically evaluated when its argument is a simple rational multiple of ; for more complicated rational multiples, FunctionExpand can sometimes be used.
CosDegrees of angle is the ratio of the adjacent side to the hypotenuse of a right triangle:

CosDegrees is related to SinDegrees by the Pythagorean identity $TemplateBox[{theta}, SinDegrees]^2+TemplateBox[{theta}, CosDegrees]^2=1$ .
For certain special arguments, CosDegrees automatically evaluates to exact values.
CosDegrees can be evaluated to arbitrary numerical precision.
CosDegrees automatically threads over lists.
CosDegrees can be used with Interval, CenteredInterval and Around objects.
Mathematical function, suitable for both symbolic and numerical manipulation.

Examples

open all close all

Basic Examples (6)

The argument is given in degrees:

Wolfram Language code: CosDegrees[60]

Calculate CosDegrees of 45 degrees for a right triangle with unit sides:

Calculate the cosine by hand:

Wolfram Language code: Cos45deg = (1/Sqrt[1 + 1])

Verify the result:

Wolfram Language code: Cos45deg == CosDegrees[45]

Solve a trigonometric equation:

Wolfram Language code: Solve[CosDegrees[x] == 1 / 2 && 0 < x < 90, x]

Solve a trigonometric inequality:

Wolfram Language code: Reduce[CosDegrees[x] > 1 / 2 && 0 <= x <= 360, x]

Plot over two periods:

Wolfram Language code: Plot[CosDegrees[x], {x, -360, 360}]

Series expansion at 0:

Wolfram Language code: Series[CosDegrees[x], {x, 0, 7}]

Scope (47)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: CosDegrees[11.2]

Evaluate to high precision:

Wolfram Language code: N[CosDegrees[12 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: CosDegrees[1.20000000000000000000000]

CosDegrees can take complex number inputs:

Wolfram Language code: CosDegrees[22.5 + I]

Evaluate CosDegrees efficiently at high precision:

Wolfram Language code: CosDegrees[12.2`500]//Timing

Wolfram Language code: Cos[12.2`100000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: CosDegrees[Interval[{90, 60}]]

Wolfram Language code: CosDegrees[CenteredInterval[67, 1 / 100]]

Wolfram Language code: CosDegrees[CenteredInterval[10 + 31I, (1 + I) / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: CosDegrees[Around[40, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: CosDegrees[{{60, 180}, {30, -90}}]

Or compute the matrix CosDegrees function using MatrixFunction:

Wolfram Language code: MatrixFunction[CosDegrees[#]&, {{60, 180}, {30, -90}}]

Specific Values (6)

Values of CosDegrees at fixed points:

Wolfram Language code: CosDegrees[{0, 30, 45, 60, 90, 180}]

CosDegrees has exact values at rational multiples of 30 degrees:

Wolfram Language code: Table[CosDegrees[30 n], {n, 0, 6}]

Values at infinity:

Wolfram Language code: CosDegrees[Infinity]

Wolfram Language code: CosDegrees[ComplexInfinity]

Simple exact values are generated automatically:

Wolfram Language code: CosDegrees[180 / 5]

More complicated cases require explicit use of FunctionExpand:

Wolfram Language code: CosDegrees[180 / 24]

Wolfram Language code: FunctionExpand[%]

Zeros of CosDegrees:

Wolfram Language code: Assuming[m∈Integers, Refine[CosDegrees[180 ((1/2) + m)]]]

Extrema of CosDegrees:

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[CosDegrees[180 m]]]]

Find a minimum of CosDegrees as the root of in the minimum's neighborhood:

Wolfram Language code: sol = Solve[D[CosDegrees[x], x] == 0 && 0 < x < 360, x]

Substitute in the result:

Wolfram Language code: xmin = x /. First[sol]

Visualize the result:

Wolfram Language code: Plot[CosDegrees[x], {x, 0, 360}, Rule[...]]

Visualization (4)

Plot the CosDegrees function:

Wolfram Language code: Plot[CosDegrees[x], {x, -360, 360}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[CosDegrees[z], {z, -360 - 100 I, 360 + 100 I}, Rule[...]]

Plot the real part of CosDegrees:

Wolfram Language code: ComplexContourPlot[Re[CosDegrees[z]], {z, -360 - (360/π) I, 360 + (360/π) I}, ...]

Plot the imaginary part of CosDegrees:

Wolfram Language code: ComplexContourPlot[Im[CosDegrees[z]], {z, -360 - (360/π) I, 360 + (360/π) I}, ...]

Polar plot with CosDegrees:

Wolfram Language code: Table[PolarPlot[CosDegrees[k ϕ * 180 / Pi], {ϕ, 0, 2π}, ...], {k, 1, 8}]

Function Properties (13)

CosDegrees is a periodic function with a period of degrees:

Wolfram Language code: CosDegrees[30] == CosDegrees[30 + 360]

Check this with FunctionPeriod:

Wolfram Language code: FunctionPeriod[CosDegrees[x], x]

CosDegrees is defined for all real and complex values:

Wolfram Language code: FunctionDomain[CosDegrees[x], x]

Wolfram Language code: FunctionDomain[CosDegrees[z], z, Complexes]

CosDegrees achieves all real values between and :

Wolfram Language code: FunctionRange[CosDegrees[x], x, y]

The range for complex values is the whole plane:

Wolfram Language code: FunctionRange[CosDegrees[z], z, y, Complexes]

CosDegrees is an even function:

Wolfram Language code: CosDegrees[-x]

CosDegrees has the mirror property :

Wolfram Language code: FullSimplify[CosDegrees[Conjugate[z]] == Conjugate[CosDegrees[z]]]

CosDegrees is an analytic function of x:

Wolfram Language code: FunctionAnalytic[CosDegrees[x], x]

CosDegrees is monotonic in a specific range:

Wolfram Language code: FunctionMonotonicity[CosDegrees[x], x]

Wolfram Language code: FunctionMonotonicity[{CosDegrees[x], -90 < x < 0}, x]

CosDegrees is not injective:

Wolfram Language code: FunctionInjective[CosDegrees[x], x]

Wolfram Language code: Plot[{CosDegrees[x], 1 / 2}, {x, -360, 360}]

CosDegrees is not surjective:

Wolfram Language code: FunctionSurjective[CosDegrees[x], x]

Wolfram Language code: Plot[{CosDegrees[x], 1.5}, {x, -360, 360}]

CosDegrees is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[CosDegrees[x], x]

CosDegrees has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[CosDegrees[x], x]

Wolfram Language code: FunctionDiscontinuities[CosDegrees[x], x]

CosDegrees is neither convex nor concave:

Wolfram Language code: FunctionConvexity[CosDegrees[x], x]

It is concave for x in [-90,90]:

Wolfram Language code: FunctionConvexity[{CosDegrees[x], -90 < x < 90}, x]

Wolfram Language code: Plot[CosDegrees[x], {x, -90, 90}]

TraditionalForm formatting:

Wolfram Language code: CosDegrees[α]//TraditionalForm

Differentiation (3)

First derivative:

Wolfram Language code: D[CosDegrees[x], x]

Higher derivatives:

Wolfram Language code: Table[D[CosDegrees[x], {x, n}], {n, 1, 4}]

Formula for the derivative:

Wolfram Language code: D[CosDegrees[x], {x, n}]

Integration (3)

Compute the indefinite integral of CosDegrees via Integrate:

Wolfram Language code: Integrate[CosDegrees[x], x]

Definite integral of CosDegrees over a period is 0:

Wolfram Language code: Integrate[CosDegrees[x], {x, 0, 360}]

More integrals:

Wolfram Language code: Integrate[CosDegrees[x]SinDegrees[x], x]

Wolfram Language code: Integrate[CosDegrees[x] ^ a, x]

Series Expansions (3)

Find the Taylor expansion using Series:

Wolfram Language code: Series[CosDegrees[x], {x, 0, 8}]

Plot the first three approximations for CosDegrees around :

Wolfram Language code:

terms = Normal@Table[Series[CosDegrees[x], {x, 0, m}], {m, 2, 6, 2}];
Plot[{CosDegrees[x], terms}, {x, -360, 360}, PlotRange -> {-1.5, 1.5}]

Fourier series:

Wolfram Language code: FourierSeries[CosDegrees[z], z, 1]

CosDegrees can be applied to power series:

Wolfram Language code: CosDegrees[180 + x + (x^2/2) + (x^3/3) + O[x]^4]

Function Identities and Simplifications (5)

Double-angle formula using TrigExpand:

Wolfram Language code: TrigExpand[CosDegrees[2x]]

Angle sum formula:

Wolfram Language code: TrigExpand[CosDegrees[x + y]]

Multiple‐angle expressions:

Wolfram Language code: TrigExpand[CosDegrees[4x]]

Recover the original expression using TrigReduce:

Wolfram Language code: TrigReduce[%]

Convert sums to products using TrigFactor:

Wolfram Language code: TrigFactor[CosDegrees[x] + CosDegrees[y]]

Convert to exponentials using TrigToExp:

Wolfram Language code: TrigToExp[CosDegrees[z]]

Function Representations (4)

Representation through SinDegrees:

Wolfram Language code: SinDegrees[90 - x]

The Pythagorean identity:

Wolfram Language code: 1 - SinDegrees[x]^2//Simplify

Representations through SinDegrees, TanDegrees and CotDegrees:

Wolfram Language code: Simplify[SinDegrees[x] / TanDegrees[x]]

Wolfram Language code: Simplify[SinDegrees[x]CotDegrees[x]]

Representation through SecDegrees:

Wolfram Language code: Simplify[1 / SecDegrees[x]]

Applications (21)

Basic Trigonometric Applications (3)

Given , find the CosDegrees of the angle :

Wolfram Language code: Solve[(5/9) + x^2 == 1, x]

Find the missing adjacent side length of a right triangle with hypotenuse 5, given the angle is 30 degrees:

Wolfram Language code: Solve[CosDegrees[30] == x / 5, x]

Draw a circle:

Wolfram Language code: ParametricPlot[{CosDegrees[t], SinDegrees[t]}, {t, 0, 360}]

Trigonometric Identities (7)

Calculate the CosDegrees value of 105 degrees using the sum and difference formulas:

Wolfram Language code: CosDegrees[α + β]//TrigExpand

Wolfram Language code: % /. {α -> 60, β -> 45}//Simplify

Compare with the result of direct calculation:

Wolfram Language code: % == CosDegrees[105]

Calculate the CosDegrees value of 15 degrees using the half-angle formula :

Wolfram Language code: (±Sqrt[(1 + CosDegrees[α]/2)] /. α -> 30)//Simplify

Wolfram Language code: %[[1]] == CosDegrees[15]//N

Calculate the product of two CosDegrees using the trigonometric product to sum formula :

Wolfram Language code: ((1/2)(CosDegrees[α + β] + CosDegrees[α - β]) /. {α -> 30, β -> 45})//Simplify

Compare this result with directly calculated product of two CosDegrees instances:

Wolfram Language code: % == CosDegrees[30]CosDegrees[45]

Simplify trigonometric expressions:

Wolfram Language code: Simplify[(SinDegrees[x]/1 + CosDegrees[x]) + (1 + CosDegrees[x]/SinDegrees[x])]

Wolfram Language code: Simplify[(SinDegrees[x]CosDegrees[x]/TanDegrees[x]) - 1]

Verify trigonometric identities:

Wolfram Language code: Simplify[CosDegrees[2x]^2 - (1 - 2CosDegrees[x]^2)^2 == 0]

Use the law of cosines to find the length of the side of the following triangle if the angle and the lengths of two other sides are , :

This could be calculated via the formula :

Wolfram Language code: BClength = Sqrt[7 ^ 2 + 12 ^ 2 - 2 * 7 * 12 * CosDegrees[30]]

The numerical value of :

Wolfram Language code: BClength//N

Calculate the base length of an isosceles triangle, given the leg length and the base angles :

Calculate the base:

Wolfram Language code: base = 2a CosDegrees[α] /. {a -> 2, α -> 30}

Get the numerical value of the base:

Wolfram Language code: %//N

Trigonometric Equations (2)

Solve a basic trigonometric equation:

Wolfram Language code: Solve[CosDegrees[5x] == 1 / 2, x]

Solve trigonometric equations including other trigonometric functions:

Wolfram Language code: Solve[CosDegrees[5x] == SinDegrees[x], x]//FullSimplify

Solve trigonometric equations with conditions:

Wolfram Language code: Reduce[3CosDegrees[x] + 2Sqrt[2SinDegrees[x]] == 9 / 2 && 0 < x < 90, x]

Trigonometric Inequalities (2)

Solve this trigonometric inequality:

Wolfram Language code: Reduce[CosDegrees[x - 60] > CosDegrees[x] && 0 <= x <= 360, x]

Solve this trigonometric inequality including other trigonometric functions:

Wolfram Language code: Reduce[(CosDegrees[x] - 1/TanDegrees[x]) > 0, x, Reals]

Advanced Applications (7)

Lissajous figure:

Wolfram Language code: ParametricPlot[{CosDegrees[2t], CosDegrees[5t]}, {t, 0, 360}]

Equiangular (logarithmic) spiral:

Wolfram Language code: ParametricPlot[Exp[t / 10 * π / 180]{CosDegrees[t], SinDegrees[t]}, {t, 0, 5 * 360}, PlotRange -> All]

Plot a sphere:

Wolfram Language code:

ParametricPlot3D[{CosDegrees[ϕ] SinDegrees[θ], SinDegrees[θ] SinDegrees[ϕ], CosDegrees[θ]}, {ϕ, -180, 180}, {θ, 0, 180}]

Plot a torus:

Wolfram Language code:

ParametricPlot3D[{CosDegrees[ϕ] + 1 / 2 CosDegrees[θ] CosDegrees[ϕ], SinDegrees[ϕ] + 1 / 2 CosDegrees[θ] SinDegrees[ϕ], SinDegrees[θ] / 2}, {ϕ, -180, 180}, {θ, 0, 360}]

Plot 2D waves:

Wolfram Language code: Plot3D[CosDegrees[x]CosDegrees[y], {x, 0, 720}, {y, 0, 720}]

Approximate the almost nowhere differentiable Riemann–Weierstrass function:

Wolfram Language code: Plot[Sum[N[CosDegrees[j ^ 2 x] / j ^ 2], {j, 12}], {x, 0, 360}]

Find a point in the circle using CosDegrees and SinDegrees functions:

Wolfram Language code: ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1.5, 1.5}, {y, -1.5, 1.5}, ...]

Properties & Relations (11)

Check that 1 degree is radians:

Wolfram Language code: CosDegrees[60] == Cos[π / 3]

Basic parity and periodicity properties are automatically applied:

Wolfram Language code: CosDegrees[x + 360]

Wolfram Language code: CosDegrees[-x]

Wolfram Language code: CosDegrees[I x]

Wolfram Language code: 1 / CosDegrees[x]//Simplify

Complicated expressions containing trigonometric functions do not simplify automatically:

Wolfram Language code: CosDegrees[3z]^2 - (CosDegrees[z]^3 - 3 CosDegrees[z] SinDegrees[z]^2)^2

Wolfram Language code: Simplify[%]

Another example:

Wolfram Language code:

CosDegrees[(x + y/2)]CosDegrees[(x - y/2)] + ((1/2) CosDegrees[(x/2)]^2 + (1/2) CosDegrees[(y/2)]^2 - (1/2) SinDegrees[(x/2)]^2 - (1/2) SinDegrees[(y/2)]^2)

Wolfram Language code: FullSimplify[%]

Use FunctionExpand to express CosDegrees in terms of radicals:

Wolfram Language code: {CosDegrees[180 / 8], CosDegrees[180 / 12], CosDegrees[180 / 15]}

Wolfram Language code: FunctionExpand[%]

Compositions with the inverse trigonometric functions:

Wolfram Language code: {CosDegrees[ArcCosDegrees[z]], CosDegrees[2ArcCosDegrees[z]], CosDegrees[3ArcCosDegrees[z]]}

Wolfram Language code: FunctionExpand[%]

Solve a trigonometric equation:

Wolfram Language code: Reduce[CosDegrees[z]^2 + 3 CosDegrees[z + 30] == 4, z]

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[CosDegrees[z]^2 - 13 CosDegrees[z + 30] + z == 4, {z, 0, 15}]

Plot the function to check if the solution is correct:

Wolfram Language code: Plot[CosDegrees[z]^2 - 13 CosDegrees[z + 30] + z - 4, {z, 0, 15}]

The zeros of CosDegrees:

Wolfram Language code: Reduce[CosDegrees[α x + β] == 0, x]

FunctionExpand applied to CosDegrees generates expressions in trigonometric functions in radians:

Wolfram Language code: FunctionExpand[CosDegrees[x]]

Wolfram Language code: FunctionExpand[CosDegrees[x ^ 2]CosDegrees[120 - x / 2]]

ExpToTrig applied to the outputs of TrigToExp will generate trigonometric functions in radians:

Wolfram Language code: TrigToExp[CosDegrees[z]]

Wolfram Language code: ExpToTrig[%]

Wolfram Language code:

TrigToExp[CosDegrees[2z]CosDegrees[z]];
ExpToTrig[%]

CosDegrees is a numeric function:

Wolfram Language code: NumericQ[CosDegrees[2 + E]]

Possible Issues (1)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: CosDegrees[10. ^ 45]

With exact input, the answer is correct:

Wolfram Language code: N[CosDegrees[10 ^ 45], 20]

Neat Examples (5)

Trigonometric functions are ratios that relate the angle measures of a right triangle to the length of its sides:

Wolfram Language code:

Trigfunclist = {SinDegrees[θ], CosDegrees[θ], TanDegrees[θ], CotDegrees[θ], SecDegrees[θ], CscDegrees[θ]};
ratioslist = {a / c, b / c, a / b, b / a, c / b, c / a};

Wolfram Language code: Grid[...]//TraditionalForm

Solve a trigonometric equation:

Wolfram Language code: Solve[CosDegrees[x] == SinDegrees[2x], x]//Simplify

Add some condition on the solution:

Wolfram Language code: Reduce[CosDegrees[x] == SinDegrees[2x] && 0 < x < 45, x]

Some arguments can be expressed as a finite sequence of nested radicals:

Wolfram Language code: CosDegrees[(180/2^12)]//FunctionExpand

Indefinite integral of :

Wolfram Language code: Integrate[CosDegrees[x ^ n], x]

Non-commensurate waves (quasiperiodic function):

Wolfram Language code: Plot[CosDegrees[x] + CosDegrees[Sqrt[2]x], {x, 0, 20 * 360}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

CosDegrees

Details

Examples

Basic Examples (6)

Scope (47)

Numerical Evaluation (6)

Specific Values (6)

Visualization (4)

Function Properties (13)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (5)

Function Representations (4)

Applications (21)

Basic Trigonometric Applications (3)

Trigonometric Identities (7)

Trigonometric Equations (2)

Trigonometric Inequalities (2)

Advanced Applications (7)

Properties & Relations (11)

Possible Issues (1)

Neat Examples (5)

Text

CMS

APA

BibTeX

BibLaTeX

CosDegrees

Details

Examples

Basic Examples (6)

Scope (47)

Numerical Evaluation (6)

Specific Values (6)

Visualization (4)

Function Properties (13)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (5)

Function Representations (4)

Applications (21)

Basic Trigonometric Applications (3)

Trigonometric Identities (7)

Trigonometric Equations (2)

Trigonometric Inequalities (2)

Advanced Applications (7)

Properties & Relations (11)

Possible Issues (1)

Neat Examples (5)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX