SecDegrees
SecDegrees[θ]
gives the secant of 
degrees.
Details
- SecDegrees and other trigonometric functions are studied in high-school geometry courses and are also used in many scientific disciplines.
- The argument of SecDegrees is assumed to be in degrees.
- SecDegrees of angle
is the ratio of the hypotenuse to the adjacent side of a right triangle: - SecDegrees is related to CosDegrees by the identity
![TemplateBox[{x}, SecDegrees]=1/(TemplateBox[{x}, CosDegrees])](Files/SecDegrees.en/3.png "TemplateBox[{x}, SecDegrees]=1/(TemplateBox[{x}, CosDegrees])")
. - For certain special arguments, SecDegrees automatically evaluates to exact values.
- SecDegrees can be evaluated to arbitrary numerical precision.
- SecDegrees automatically threads over lists.
- SecDegrees can be used with Interval, CenteredInterval and Around objects.
- Mathematical function, suitable for both symbolic and numerical manipulation.
Examples
open all close allBasic Examples (6)
The argument is given in degrees:
SecDegrees[30]Calculate SecDegrees of 45 Degree for a right triangle with unit sides:
Sec45deg = (Sqrt[1 + 1]/1)Sec45deg == SecDegrees[45]Solve a trigonometric equation:
Solve[SecDegrees[x] == 2 && 0 < x < 90, x]Solve a trigonometric inequality:
Reduce[SecDegrees[x] > 2 && 0 <= x <= 180, x]Plot[SecDegrees[x], {x, -270, 450}]Series[SecDegrees[x], {x, 0, 7}]Scope (45)
Numerical Evaluation (5)
N[SecDegrees[112 / 10], 50]The precision of the output tracks the precision of the input:
SecDegrees[11.20000000000000000000000]Evaluate for complex arguments:
SecDegrees[22.5 + 3I]Evaluate SecDegrees efficiently at high precision:
SecDegrees[11.2`500]//TimingSecDegrees[11.2`100000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
SecDegrees[Interval[{30, 60}]]SecDegrees[CenteredInterval[60, 1 / 100]]SecDegrees[CenteredInterval[60 + 30I, (10 + 2I) / 100]]Or compute average-case statistical intervals using Around:
SecDegrees[Around[56, 0.1]]Compute the elementwise values of an array:
SecDegrees[{{150, 0}, {30, -45}}]Or compute the matrix SecDegrees function using MatrixFunction:
MatrixFunction[SecDegrees[#]&, {{150, 0}, {30, -45}}]Specific Values (6)
Values of SecDegrees at fixed points:
SecDegrees[{0, 30, 45, 60, 90, 180}]SecDegrees has exact values at rational multiples of 30 degrees:
Table[SecDegrees[30 n], {n, -2, 2}]SecDegrees[Infinity]SecDegrees[ComplexInfinity]Simple exact values are generated automatically:
SecDegrees[180 / 5]More complicated cases require explicit use of FunctionExpand:
SecDegrees[180 / 24]FunctionExpand[%]//FullSimplifySingular points of SecDegrees:
Assuming[m∈Integers, Refine[SecDegrees[180((1/2) + m)]]]Local extrema of SecDegrees:
Assuming[m∈Integers, FullSimplify[Refine[SecDegrees[180 m]]]]Find a local minimum of SecDegrees as the root of ![(dTemplateBox[{x}, SecDegrees])/(d x)=0](Files/SecDegrees.en/5.png "(dTemplateBox[{x}, SecDegrees])/(d x)=0"){kind=small}
in the minimum's neighborhood:
sol = Solve[D[SecDegrees[x], x] == 0 && -90 < x < 90, x]xmin = x /. First[sol]Plot[Sec[x], {x, -π / 2, π / 2}, Rule[...]]Visualization (4)
Plot the SecDegrees function:
Plot[SecDegrees[x], {x, -270, 450}]Plot over a subset of the complexes:
ComplexPlot3D[SecDegrees[z], {z, -180 - 60I, 180 + 60I}, Rule[...]]Plot the real part of SecDegrees:
ComplexContourPlot[Re[SecDegrees[z]], {z, -360 - 180 I, 360 + 180 I}, ...]Plot the imaginary part of SecDegrees:
ComplexContourPlot[Im[SecDegrees[z]], {z, -360 - 180 I, 360 + 180 I}, ...]Polar plot with SecDegrees:
Table[PolarPlot[SecDegrees[k ϕ * 180 / Pi], {ϕ, -π, π}, ...], {k, 1, 6}]Function Properties (13)
SecDegrees is a periodic function with a period of 
:
SecDegrees[30] == SecDegrees[30 + 360]Check this with FunctionPeriod:
FunctionPeriod[SecDegrees[x], x]The real domain of SecDegrees:
FunctionDomain[SecDegrees[x], x]FunctionDomain[SecDegrees[z], z, Complexes]SecDegrees achieves all real values except the open interval 
:
FunctionRange[SecDegrees[x], x, y]FunctionRange[SecDegrees[x], x, y, Complexes]SecDegrees is an even function:
SecDegrees[-x]SecDegrees has the mirror property ![sec(TemplateBox[{z}, Conjugate])=TemplateBox[{{sec, (, z, )}}, Conjugate]](Files/SecDegrees.en/8.png "sec(TemplateBox[{z}, Conjugate])=TemplateBox[{{sec, (, z, )}}, Conjugate]"){kind=small}
:
FullSimplify[SecDegrees[Conjugate[z]] == Conjugate[SecDegrees[z]]]SecDegrees is not an analytic function:
FunctionAnalytic[SecDegrees[x], x]FunctionMeromorphic[SecDegrees[x], x]SecDegrees is monotonic in a specific range:
FunctionMonotonicity[SecDegrees[x], x]FunctionMonotonicity[{SecDegrees[x], 0 < x < 90}, x]SecDegrees is not injective:
FunctionInjective[SecDegrees[x], x]Plot[{SecDegrees[x], 2}, {x, -360, 360}]SecDegrees is not surjective:
FunctionSurjective[SecDegrees[x], x]Plot[{SecDegrees[x], .5}, {x, -360, 360}]SecDegrees is neither non-negative nor non-positive:
FunctionSign[SecDegrees[x], x]It has both singularity and discontinuity when x is a multiple of 90:
FunctionSingularities[SecDegrees[x], x]FunctionDiscontinuities[SecDegrees[x], x]FunctionConvexity[SecDegrees[x], x]It is convex for x in [-90,90]:
FunctionConvexity[{SecDegrees[x], -90 < x < 90}, x]Plot[SecDegrees[x], {x, -90, 90}]TraditionalForm formatting:
SecDegrees[α]//TraditionalFormDifferentiation (3)
derivative:Integration (3)
Compute the indefinite integral of SecDegrees via Integrate:
Integrate[SecDegrees[x], x]//SimplifyDefinite integral of SecDegrees over a period is 0:
Integrate[SecDegrees[x], {x, -150, 180 + 30}, PrincipalValue -> True]Integrate[SecDegrees[x]SinDegrees[x], x]Integrate[SecDegrees[z]^a, z]Integrate[SinDegrees[b z] SecDegrees[c z], z]Series Expansions (3)
Find the Taylor expansion using Series:
Series[SecDegrees[x], {x, 0, 6}]Plot the first three approximations for SecDegrees around 
:
terms = Normal@Table[Series[SecDegrees[x], {x, 0, m}], {m, 2, 6, 2}];
Plot[{SecDegrees[x], terms}, {x, -90, 90}, PlotRange -> {0, 4}]Asymptotic expansion at a singular point:
Series[SecDegrees[x], {x, 270, 5}]SecDegrees can be applied to power series:
SecDegrees[90 + x + (x^2/2) + (x^3/3) + O[x]^4]Function Identities and Simplifications (5)
Double-angle formula using TrigExpand:
TrigExpand[SecDegrees[2x]]TrigExpand[SecDegrees[x + y]]TrigExpand[SecDegrees[4x]]TrigReduce[%]Convert sums to products using TrigFactor:
TrigFactor[SecDegrees[x] + SecDegrees[y]]Convert to complex exponentials:
TrigToExp[SecDegrees[z]]Function Representations (3)
Representation through CosDegrees:
Simplify[1 / CosDegrees[x]]Representation through SinDegrees:
Simplify[1 / SinDegrees[90 - x]]Representations through SinDegrees and TanDegrees:
Simplify[TanDegrees[x] / SinDegrees[x]]Applications (11)
Basic Trigonometric Applications (2)
Given 
, find the SecDegrees of the angle 
using the formula 
:
Solve[x^2 == 1 + (5/9), x]Find the missing adjacent side length of a right triangle with hypotenuse 5 given the angle is 30 degrees:
Solve[SecDegrees[30] == 5 / x, x]Trigonometric Identities (3)
Calculate the SecDegrees value of 105 degrees using the sum and difference formulas:
SecDegrees[α + β]//TrigExpand% /. {α -> 60, β -> 45}//SimplifyCompare with the result of direct calculation:
% == SecDegrees[105]Simplify trigonometric expressions:
Simplify[(SinDegrees[x]/1 + 1 / SecDegrees[x])]Verify trigonometric identities:
Simplify[(SinDegrees[x]/SecDegrees[x]TanDegrees[x]) == 1 - SinDegrees[x]^2]Trigonometric Equations (2)
Solve a basic trigonometric equation:
Solve[SecDegrees[5x] == 1 / 2, x]Solve trigonometric equations including other trigonometric functions:
Solve[SecDegrees[5x] == CosDegrees[x], x, Reals]Solve trigonometric equations with conditions:
Reduce[3SecDegrees[x] + 2Sqrt[2SinDegrees[x]] == 9 / 2 && x < 60, x]Trigonometric Inequalities (2)
Advanced Applications (2)
Generate a plot over the complex argument plane:
Plot3D[Re[SecDegrees[x + I y]], {x, 0, 360}, {y, -60, 60}]Automatically label different trigonometric functions:
Table[Plot[Evaluate[f[x]], {x, -180, 180}, PlotLabel -> f[x]], {f, {SinDegrees, CosDegrees, SecDegrees, CscDegrees}}]Properties & Relations (13)
Check that 1 degree is 
radians:
SecDegrees[60] == Sec[π / 3]Basic parity and periodicity properties are automatically applied:
SecDegrees[x + 180]SecDegrees[-x]SecDegrees[I x]1 / SecDegrees[x]//SimplifySimplify under assumptions on parameters:
SecDegrees[-x + 180k]Refine[%, k∈Integers]Complicated expressions containing trigonometric functions do not simplify automatically:
SecDegrees[z - 60] SecDegrees[60 + z] + SecDegrees[z - 60] SecDegrees[z] + SecDegrees[z] SecDegrees[60 + z]FullSimplify[%]SecDegrees[Conjugate[z]] - Conjugate[SecDegrees[z]]FullSimplify[%]Use FunctionExpand to express SecDegrees in terms of radicals:
{SecDegrees[180 / 8], SecDegrees[180 / 12], SecDegrees[180 / 15]}FunctionExpand[%]Compositions with the inverse trigonometric functions:
{SecDegrees[ArcSecDegrees[z]], SecDegrees[2ArcSecDegrees[z]], SecDegrees[3ArcSecDegrees[z]]}FunctionExpand[%]//TogetherSolve a trigonometric equation:
Reduce[SecDegrees[z]^2 - SecDegrees[z + 45] == 1, z]Numerically solve a transcendental equation:
FindRoot[SecDegrees[z]^2 + 3 SecDegrees[z + 30] + z == 14, {z, 0, 15}]Plot the function to check if the solution is correct:
Plot[SecDegrees[z]^2 + 3 SecDegrees[z + 30] + z - 14, {z, 0, 15}]The zeros of SecDegrees:
Reduce[SecDegrees[α x + β] == 0, x]The poles of SecDegrees:
Reduce[1 / SecDegrees[α x + β] == 0, x]Calculate residue symbolically and numerically:
Table[Residue[SecDegrees[z]^k, {z, 90}], {k, 10}](1/2π I)NIntegrate[SecDegrees[z], {z, 90 - (1/4), 90 - (I/4), 90 + (1/4), 90 + (I/4), 90 - (1/4)}]FunctionExpand applied to SecDegrees generates expressions in trigonometric functions in radians:
FunctionExpand[SecDegrees[x]]FunctionExpand[SecDegrees[x ^ 2]SecDegrees[120 - x / 2]]ExpToTrig applied to the outputs of TrigToExp will generate trigonometric functions in radians:
TrigToExp[SecDegrees[z]]ExpToTrig[%]TrigToExp[SecDegrees[2z]SecDegrees[z]];
ExpToTrig[%]SecDegrees is a numeric function:
NumericQ[SecDegrees[2 + E]]Possible Issues (1)
Neat Examples (5)
Trigonometric functions are ratios that relate the angle measures of a right triangle to the length of its sides:
Trigfunclist = {SinDegrees[θ], CosDegrees[θ], TanDegrees[θ], CotDegrees[θ], SecDegrees[θ], CscDegrees[θ]};
ratioslist = {a / c, b / c, a / b, b / a, c / b, c / a};Grid[...]//TraditionalFormSolve trigonometric equations:
Solve[SecDegrees[x] == CotDegrees[x], x]//SimplifyAdd some condition on the solution:
Reduce[SecDegrees[x] == CotDegrees[x] && 0 < x < 90, x]//SimplifySome arguments can be expressed as a finite sequence of nested radicals:
SecDegrees[(180/2^12)]//FunctionExpand
∫SecDegrees[x]^nⅆxPlot SecDegrees at integer points:
ArrayPlot[Table[ArcTanDegrees[Abs[SecDegrees[x y]]], {x, -120, 120}, {y, -120, 120}]]Text
Wolfram Research (2024), SecDegrees, Wolfram Language function, https://reference.wolfram.com/language/ref/SecDegrees.html.
CMS
Wolfram Language. 2024. "SecDegrees." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SecDegrees.html.
APA
Wolfram Language. (2024). SecDegrees. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SecDegrees.html