TanDegrees
TanDegrees[θ]
gives the tangent of 
degrees.
Details
- TanDegrees and other trigonometric functions are studied in high-school geometry courses and are also used in many scientific disciplines.
- The argument of TanDegrees is assumed to be in degrees.
- TanDegrees is automatically evaluated when its argument is a simple rational multiple of
; for more complicated rational multiples, FunctionExpand can sometimes be used. - TanDegrees of angle
is the ratio of the opposite side to the adjacent side of a right triangle: - TanDegrees is related to SinDegrees and CosDegrees by the identity
![TemplateBox[{x}, TanDegrees]=(TemplateBox[{x}, SinDegrees])/(TemplateBox[{x}, CosDegrees])](Files/TanDegrees.en/4.png "TemplateBox[{x}, TanDegrees]=(TemplateBox[{x}, SinDegrees])/(TemplateBox[{x}, CosDegrees])")
. - For certain special arguments, TanDegrees automatically evaluates to exact values.
- TanDegrees can be evaluated to arbitrary numerical precision.
- TanDegrees automatically threads over lists.
- TanDegrees can be used with Interval, CenteredInterval and Around objects.
- Mathematical function, suitable for both symbolic and numerical manipulation.
Examples
open all close allBasic Examples (6)
The argument is given in degrees:
TanDegrees[60]Calculate TanDegrees of 45 Degree for a right triangle with unit sides:
Calculate the tangent by hand:
Tan45deg = (1/1)Tan45deg == TanDegrees[45]Solve a trigonometric equation:
Solve[TanDegrees[x] == Sqrt[3] && 0 < x < 90, x]Solve a trigonometric inequality:
Reduce[TanDegrees[x] > Sqrt[3] && 0 <= x <= 180, x]Plot[TanDegrees[x], {x, -90, 270}]Series[TanDegrees[x], {x, 0, 7}]Scope (46)
Numerical Evaluation (6)
TanDegrees[51.2]N[TanDegrees[122 / 10], 50]The precision of the output tracks the precision of the input:
TanDegrees[12.20000000000000000000000]TanDegrees can take complex number inputs:
TanDegrees[2.5 + I]Evaluate TanDegrees efficiently at high precision:
TanDegrees[12.2`500]//TimingTanDegrees[12.2`100000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
TanDegrees[Interval[{0, 30}]]TanDegrees[CenteredInterval[60, 1 / 100]]TanDegrees[CenteredInterval[20 + 3I, (1 + I) / 100]]Or compute average-case statistical intervals using Around:
TanDegrees[Around[20, 0.02]]Compute the elementwise values of an array:
TanDegrees[{{30, 60}, {180, -45}}]Or compute the matrix TanDegrees function using MatrixFunction:
MatrixFunction[TanDegrees[#]&, {{30, 60}, {180, -45}}]//NSpecific Values (6)
Values of TanDegrees at fixed points:
TanDegrees[{0, 30, 45, 60, 90, 180}]TanDegrees has exact values at rational multiples of 60 degrees:
Table[TanDegrees[60n], {n, -3, 3}]TanDegrees[Infinity]TanDegrees[ComplexInfinity]Simple exact values are generated automatically:
TanDegrees[180 / 5]More complicated cases require explicit use of FunctionExpand:
TanDegrees[180 / 8]FunctionExpand[%]Zeros of TanDegrees:
Assuming[m∈Integers, Refine[TanDegrees[180 m]]]Find one zero using Solve:
sol = Solve[TanDegrees[x] == 0 && -90 < x < 90, x]xzero = x /. First[sol]Plot[TanDegrees[x], {x, -90, 90}, Rule[...]]Singular points of TanDegrees:
Assuming[m∈Integers, FullSimplify[Refine[TanDegrees[180((1/2) + m)]]]]Visualization (4)
Plot the TanDegrees function:
Plot[TanDegrees[x], {x, -90, 270}]Plot over a subset of the complexes:
ComplexPlot3D[TanDegrees[z], {z, -180 - 100 I, 180 + 100 I}, ...]Plot the real part of TanDegrees:
ComplexContourPlot[Re[TanDegrees[z]], {z, -180 - 60I, 180 + 60I}, ...]Plot the imaginary part of TanDegrees:
ComplexContourPlot[Im[TanDegrees[z]], {z, -180 - 60I, 180 + 60I}, ...]Polar plot with TanDegrees:
Table[PolarPlot[TanDegrees[k ϕ * 180 / Pi], {ϕ, -π, π}, ...], {k, 1, 4}]Function Properties (13)
TanDegrees is a periodic function with a period of 
:
TanDegrees[30] == TanDegrees[30 + 180]Check this with FunctionPeriod:
FunctionPeriod[TanDegrees[x], x]Real domain of TanDegrees:
FunctionDomain[TanDegrees[x], x]FunctionDomain[TanDegrees[z], z, Complexes]TanDegrees achieves all real values:
FunctionRange[TanDegrees[x], x, y]FunctionRange[TanDegrees[x], x, y, Complexes]TanDegrees is an odd function:
TanDegrees[-x]TanDegrees has the mirror property ![tan(TemplateBox[{z}, Conjugate])=TemplateBox[{{tan, (, z, )}}, Conjugate]](Files/TanDegrees.en/7.png "tan(TemplateBox[{z}, Conjugate])=TemplateBox[{{tan, (, z, )}}, Conjugate]"){kind=small}
:
FullSimplify[TanDegrees[Conjugate[z]] == Conjugate[TanDegrees[z]]]TanDegrees is not an analytic function:
FunctionAnalytic[TanDegrees[x], x]FunctionMeromorphic[TanDegrees[x], x]TanDegrees is monotonic in a specific range:
FunctionMonotonicity[TanDegrees[x], x]FunctionMonotonicity[{TanDegrees[x], 0 < x < 90}, x]TanDegrees is not injective:
FunctionInjective[TanDegrees[x], x]Plot[{TanDegrees[x], 1}, {x, -360, 360}]TanDegrees is surjective:
FunctionSurjective[TanDegrees[x], x]Plot[{TanDegrees[x], 20}, {x, -360, 360}]TanDegrees is neither non-negative nor non-positive:
FunctionSign[TanDegrees[x], x]TanDegrees has both singularities and discontinuities in points multiple to 90:
FunctionSingularities[TanDegrees[x], x]FunctionDiscontinuities[TanDegrees[x], x]TanDegrees is neither convex nor concave:
FunctionConvexity[TanDegrees[x], x]TanDegrees is convex for x in [0,90]:
FunctionConvexity[{TanDegrees[x], 0 < x < 90}, x]Plot[TanDegrees[x], {x, 0, 90}]TraditionalForm formatting:
TanDegrees[α]//TraditionalFormDifferentiation (3)
derivative:Integration (3)
Compute the indefinite integrals of TanDegrees via Integrate:
Integrate[TanDegrees[x], x]Integrate[TanDegrees[ArcCotDegrees[z]], z]Definite integral of TanDegrees over a period is 0:
Integrate[TanDegrees[x], {x, 0, 180}, PrincipalValue -> True]Integrate[TanDegrees[x]CosDegrees[x], x]Integrate[TanDegrees[z] ^ a, z]Series Expansions (3)
Find the Taylor expansion using Series:
Series[TanDegrees[x], {x, 0, 7}]Plot the first three approximations for TanDegrees around 
:
terms = Normal@Table[Series[TanDegrees[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{TanDegrees[x], terms}, {x, -90, 90}, PlotRange -> {{-5, 5}}]Asymptotic expansion at a singular point:
Series[TanDegrees[x], {x, 90, 5}]TanDegrees can be applied to power series:
TanDegrees[x + (x^2/2) + (x^3/3) + O[x]^4]Function Identities and Simplifications (5)
Double-angle formula using TrigExpand:
TrigExpand[TanDegrees[2x]]TrigExpand[TanDegrees[x + y]]TrigExpand[TanDegrees[4x]]Recover the original expression using TrigReduce:
TrigReduce[%]Convert sums to products using TrigFactor:
TrigFactor[TanDegrees[x] + TanDegrees[y]]Convert to exponentials using TrigToExp:
TrigToExp[TanDegrees[z]]Function Representations (3)
Representation through CotDegrees:
CotDegrees[90 - x]Representation through SinDegrees and CosDegrees:
Simplify[SinDegrees[x] / CosDegrees[x]]Representation through SecDegrees and CscDegrees:
Simplify[SecDegrees[x] / CscDegrees[x]]Applications (12)
Basic Trigonometric Applications (2)
Given 
, find the TanDegrees of the angle 
using the identity 
:
Solve[x == (Sqrt[1 - y^2]/y) /. y -> (Sqrt[5]/3), x]Find the missing opposite side length of a right triangle if the adjacent side is 5 and the angle is 30 degrees:
Solve[TanDegrees[30] == x / 5, x]Trigonometric Identities (4)
Calculate the TanDegrees value of 105 degrees using the sum and difference formulas:
TanDegrees[α + β]//TrigExpand% /. {α -> 60, β -> 45}//SimplifyCompare with the result of direct calculation:
% == TanDegrees[105]Calculate the TanDegrees value of 15 degrees using the half-angle formula 
:
(±Sqrt[(1 - CosDegrees[α]/1 + CosDegrees[α])] /. α -> 30)//SimplifyCompare this result with directly calculated TanDegrees:
%[[1]] == TanDegrees[15]//NSimplify trigonometric expressions:
Simplify[(TanDegrees[x]/1 + CosDegrees[x])]Simplify[(SinDegrees[x]CosDegrees[x]/TanDegrees[x]) - 1]Verify trigonometric identities:
Simplify[TanDegrees[x]^2(1 - SinDegrees[x]^2) == (1 - CosDegrees[2x]/2)]Trigonometric Equations (2)
Solve a basic trigonometric equation:
Solve[TanDegrees[5x] == 1 / 2, x]Solve trigonometric equations including other trigonometric functions:
Solve[TanDegrees[2x] == CosDegrees[x], x]//FullSimplifySolve trigonometric equations with conditions:
Reduce[2Sqrt[2TanDegrees[x]] + 3CosDegrees[x] == 9 / 2 && 0 < x < 90, x]Trigonometric Inequalities (2)
Advanced Applications (2)
Generate a plot over the complex argument plane:
Plot3D[Re[TanDegrees[x + I y]], {x, 0, 360}, {y, 0, 180}]The function 
has the limit zero as 
approaches 
:
g[x_] := CosDegrees[x]CosDegrees[TanDegrees[x]]Limit[g[x], x -> 90]MaxLimit[g[x], x -> 90]Properties & Relations (13)
Check that 1 degree is 
radians:
TanDegrees[60] == Tan[π / 3]Basic parity and periodicity properties of the tangent function get automatically applied:
TanDegrees[x + 180]TanDegrees[-x]TanDegrees[I x]1 / TanDegrees[x]//SimplifySimplify under assumptions on parameters:
TanDegrees[-x + 180k]Simplify[%, k∈Integers]Complicated expressions containing trigonometric functions do not simplify automatically:
(2 CosDegrees[x] SinDegrees[x]/CosDegrees[x]^2 - SinDegrees[x]^2)Simplify[%]Use FunctionExpand to express TanDegrees in terms of radicals:
{TanDegrees[180 / 8], TanDegrees[180 / 12], TanDegrees[180 / 15]}FunctionExpand[%]//SimplifyCompositions with the inverse trigonometric functions:
{TanDegrees[ArcTanDegrees[z]], TanDegrees[2ArcTanDegrees[z]], TanDegrees[3ArcTanDegrees[z]]}FunctionExpand[%]Solve a trigonometric equation:
Reduce[TanDegrees[z]^2 - 2 TanDegrees[z + 45] == 4, z]Numerically find a root of a transcendental equation:
FindRoot[TanDegrees[z]^2 + 3TanDegrees[z + 30] + z == 4, {z, 0, 4}]Plot the function to check if the solution is correct:
Plot[TanDegrees[z]^2 + 3TanDegrees[z + 30] + z - 4, {z, 0, 5}]The zeros of TanDegrees:
Reduce[TanDegrees[α x + β] == 0, x]The poles of TanDegrees:
Reduce[1 / TanDegrees[α x + β] == 0, x]Calculate residue symbolically and numerically:
Table[Residue[TanDegrees[z]^k, {z, 90}], {k, 5}](1/2π I)NIntegrate[TanDegrees[z], {z, 90 - (1/4), 90 - (I/4), 90 + (1/4), 90 + (I/4), 90 - (1/4)}]FunctionExpand applied to TanDegrees generates expressions in trigonometric functions in radians:
FunctionExpand[TanDegrees[x]]FunctionExpand[TanDegrees[x ^ 2]TanDegrees[120 - x / 2]]ExpToTrig applied to the outputs of TrigToExp will generate trigonometric functions in radians:
TrigToExp[TanDegrees[z]]ExpToTrig[%]TrigToExp[TanDegrees[2z]TanDegrees[z]];
ExpToTrig[%]TanDegrees is a numeric function:
NumericQ[TanDegrees[2 + E]]Possible Issues (1)
Neat Examples (4)
Trigonometric functions are ratios that relate the angle measures of a right triangle to the length of its sides:
Trigfunclist = {SinDegrees[θ], CosDegrees[θ], TanDegrees[θ], CotDegrees[θ], SecDegrees[θ], CscDegrees[θ]};
ratioslist = {a / c, b / c, a / b, b / a, c / b, c / a};Grid[...]//TraditionalFormSolve trigonometric equations:
Solve[TanDegrees[x] == SinDegrees[2x], x]//SimplifyAdd some condition on the solution:
Reduce[TanDegrees[x] == SinDegrees[2x] && 0 < x < 90, x]//SimplifySome arguments can be expressed as a finite sequence of nested radicals:
TanDegrees[(180/2^12)]//FunctionExpand
∫TanDegrees[x]^nⅆxText
Wolfram Research (2024), TanDegrees, Wolfram Language function, https://reference.wolfram.com/language/ref/TanDegrees.html.
CMS
Wolfram Language. 2024. "TanDegrees." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TanDegrees.html.
APA
Wolfram Language. (2024). TanDegrees. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TanDegrees.html