Wolfram Language & System Documentation Center

SinDegrees

SinDegrees[θ]

gives the sine of degrees.

Details

SinDegrees and other trigonometric functions are studied in high-school geometry courses and are also used in many scientific disciplines.
The argument of SinDegrees is assumed to be in degrees.
SinDegrees is automatically evaluated when its argument is a simple rational multiple of ; for more complicated rational multiples, FunctionExpand can sometimes be used.
SinDegrees of angle is the ratio of the opposite side to the hypotenuse of a right triangle:

SinDegrees is related to CosDegrees by the Pythagorean identity $TemplateBox[{theta}, SinDegrees]^2+TemplateBox[{theta}, CosDegrees]^2=1$ .
For certain special arguments, SinDegrees automatically evaluates to exact values.
SinDegrees can be evaluated to arbitrary numerical precision.
SinDegrees automatically threads over lists.
SinDegrees can be used with Interval, CenteredInterval and Around objects.
Mathematical function, suitable for both symbolic and numerical manipulation.

Examples

open all close all

Basic Examples (6)

The argument is given in degrees:

Wolfram Language code: SinDegrees[60]

Calculate SinDegrees of 45 degrees for a right triangle with unit sides:

Calculate the sine by hand:

Wolfram Language code: Sin45deg = (1/Sqrt[1 + 1])

Verify the result:

Wolfram Language code: Sin45deg == SinDegrees[45]

Solve a trigonometric equation:

Wolfram Language code: Solve[SinDegrees[x] == 1 / 2 && 0 < x < 90, x]

Solve a trigonometric inequality:

Wolfram Language code: Reduce[SinDegrees[x] > 1 / 2 && 0 <= x <= 360, x]

Plot over two periods:

Wolfram Language code: Plot[SinDegrees[x], {x, -360, 360}]

Series expansion at 0:

Wolfram Language code: Series[SinDegrees[x], {x, 0, 7}]

Scope (47)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: SinDegrees[1.2]

Evaluate to high precision:

Wolfram Language code: SinDegrees[12 / 10`30]

The precision of the output tracks the precision of the input:

Wolfram Language code: SinDegrees[1.20000000000000000000000]

SinDegrees can take complex number inputs:

Wolfram Language code: SinDegrees[2.5 + I]

Evaluate SinDegrees efficiently at high precision:

Wolfram Language code: SinDegrees[1.2`500]//Timing

Wolfram Language code: SinDegrees[1.2`100000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: SinDegrees[Interval[{-30, 30}]]

Wolfram Language code: SinDegrees[Interval[{-Infinity, Infinity}]]

Wolfram Language code: SinDegrees[CenteredInterval[1, 1 / 100]]

Wolfram Language code: SinDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: SinDegrees[Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: SinDegrees[{{60, 180}, {30, -90}}]

Or compute the matrix SinDegrees function using MatrixFunction:

Wolfram Language code: MatrixFunction[SinDegrees[#]&, {{60, 180}, {30, -90}}]

Specific Values (6)

Values of SinDegrees at fixed points:

Wolfram Language code: SinDegrees[{0, 30, 45, 60, 90, 180}]

SinDegrees has exact values at rational multiples of 30 degrees:

Wolfram Language code: Table[SinDegrees[30 n], {n, 0, 6}]

Values at infinity:

Wolfram Language code: SinDegrees[Infinity]

Wolfram Language code: SinDegrees[ComplexInfinity]

Simple exact values are generated automatically:

Wolfram Language code: SinDegrees[180 / 5]

More complicated cases require explicit use of FunctionExpand:

Wolfram Language code: SinDegrees[180 / 24]

Wolfram Language code: FunctionExpand[%]

Zeros of SinDegrees:

Wolfram Language code: Assuming[m∈Integers, Refine[SinDegrees[180 m]]]

Extrema of SinDegrees:

Wolfram Language code: Assuming[m∈Integers, FullSimplify[SinDegrees[180 ((1/2) + m)]]]

Find the first positive maximum as a root of :

Wolfram Language code: sol = Solve[D[SinDegrees[x], x] == 0 && 0 < x < 180, x]

Substitute in the result:

Wolfram Language code: xmax = x /. First[sol]

Visualize the result:

Wolfram Language code: Plot[SinDegrees[x], {x, 0, 360}, Rule[...]]

Visualization (4)

Plot the SinDegrees function:

Wolfram Language code: Plot[SinDegrees[x], {x, 0, 360}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[SinDegrees[z], {z, -360 - (360/π) I, 360 + (360/π) I}, Rule[...]]

Plot the real part of SinDegrees:

Wolfram Language code: ComplexContourPlot[Re[SinDegrees[z]], {z, -360 - (360/π) I, 360 + (360/π) I}, ...]

Plot the imaginary part of SinDegrees:

Wolfram Language code: ComplexContourPlot[Im[SinDegrees[z]], {z, -360 - (360/π) I, 360 + (360/π) I}, ...]

Polar plot with SinDegrees:

Wolfram Language code: Table[PolarPlot[SinDegrees[k ϕ * 180 / Pi], {ϕ, 0, 2π}, ...], {k, 1, 8}]

Function Properties (13)

SinDegrees is a periodic function with a period of 360 degrees:

Wolfram Language code: SinDegrees[30] == SinDegrees[30 + 360]

Check this with FunctionPeriod:

Wolfram Language code: FunctionPeriod[SinDegrees[x], x]

SinDegrees is defined for all real and complex values:

Wolfram Language code: FunctionDomain[SinDegrees[x], x]

Wolfram Language code: FunctionDomain[SinDegrees[z], z, Complexes]

SinDegrees achieves all real values between and :

Wolfram Language code: FunctionRange[SinDegrees[x], x, y]

The range for complex values is the whole plane:

Wolfram Language code: FunctionRange[SinDegrees[z], z, y, Complexes]

SinDegrees is an odd function:

Wolfram Language code: SinDegrees[-x]

SinDegrees has the mirror property :

Wolfram Language code: FullSimplify[SinDegrees[Conjugate[z]] == Conjugate[SinDegrees[z]]]

SinDegrees is an analytic function of x:

Wolfram Language code: FunctionAnalytic[SinDegrees[x], x]

SinDegrees is monotonic in a specific range:

Wolfram Language code: FunctionMonotonicity[SinDegrees[x], x]

Wolfram Language code: FunctionMonotonicity[{SinDegrees[x], 0 < x < 90}, x]

SinDegrees is not injective:

Wolfram Language code: FunctionInjective[SinDegrees[x], x]

Wolfram Language code: Plot[{SinDegrees[x], 1 / 2}, {x, -360, 360}]

SinDegrees is not surjective:

Wolfram Language code: FunctionSurjective[SinDegrees[x], x]

Wolfram Language code: Plot[{SinDegrees[x], 1.5}, {x, -360, 360}]

SinDegrees is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[SinDegrees[x], x]

SinDegrees has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[SinDegrees[x], x]

Wolfram Language code: FunctionDiscontinuities[SinDegrees[x], x]

SinDegrees is neither convex nor concave:

Wolfram Language code: FunctionConvexity[SinDegrees[x], x]

SinDegrees is concave for x in [0,180]:

Wolfram Language code: FunctionConvexity[{SinDegrees[x], 0 < x < 180}, x]

Wolfram Language code: Plot[SinDegrees[x], {x, 0, 180}]

TraditionalForm formatting:

Wolfram Language code: SinDegrees[α]//TraditionalForm

Differentiation (3)

First derivative:

Wolfram Language code: D[SinDegrees[x], x]

Higher derivatives:

Wolfram Language code: Table[D[SinDegrees[x], {x, n}], {n, 1, 4}]

Formula for the derivative:

Wolfram Language code: D[SinDegrees[x], {x, n}]

Integration (3)

Compute the indefinite integral of SinDegrees via Integrate:

Wolfram Language code: Integrate[SinDegrees[x], x]

Definite integral of SinDegrees over a period is 0:

Wolfram Language code: Integrate[SinDegrees[x], {x, 0, 360}]

More integrals:

Wolfram Language code: Integrate[SinDegrees[x]CosDegrees[x], x]

Wolfram Language code: Integrate[SinDegrees[z] ^ a, z]

Series Expansions (3)

Find the Taylor expansion using Series:

Wolfram Language code: Series[SinDegrees[x], {x, 0, 7}]

Plots of the first three approximations for SinDegrees around :

Wolfram Language code:

terms = Normal@Table[Series[SinDegrees[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{SinDegrees[x], terms}, {x, -360, 360}, PlotRange -> {-1.5, 1.5}]

Fourier series:

Wolfram Language code: FourierSeries[SinDegrees[z], z, 1]

SinDegrees can be applied to power series:

Wolfram Language code: SinDegrees[90 + x + (x^2/2) + (x^3/3) + O[x]^4]

Function Identities and Simplifications (5)

Double-angle formula using TrigExpand:

Wolfram Language code: TrigExpand[SinDegrees[2x]]

Angle sum formula:

Wolfram Language code: TrigExpand[SinDegrees[x + y]]

Multiple‐angle expressions:

Wolfram Language code: TrigExpand[SinDegrees[4x]]

Recover the original expression using TrigReduce:

Wolfram Language code: TrigReduce[%]

Convert sums to products using TrigFactor:

Wolfram Language code: TrigFactor[SinDegrees[x] + SinDegrees[y]]

Convert to exponentials using TrigToExp:

Wolfram Language code: TrigToExp[SinDegrees[z]]

Function Representations (4)

Representation through CosDegrees:

Wolfram Language code: CosDegrees[90 - x]

The Pythagorean identity:

Wolfram Language code: 1 - CosDegrees[x]^2//Simplify

Representations through CosDegrees, TanDegrees and CotDegrees:

Wolfram Language code: Simplify[CosDegrees[x] TanDegrees[x]]

Wolfram Language code: Simplify[CosDegrees[x] / CotDegrees[x]]

Representation through CscDegrees:

Wolfram Language code: Simplify[1 / CscDegrees[x]]

Applications (22)

Basic Trigonometric Applications (3)

Given , find the SinDegrees of the angle :

Wolfram Language code: Solve[x^2 + (5/9) == 1, x]

Find the missing opposite side length of a right triangle with hypotenuse 5 given the angle is 30 degrees:

Wolfram Language code: Solve[SinDegrees[30] == x / 5, x]

Draw a circle:

Wolfram Language code: ParametricPlot[{SinDegrees[t], CosDegrees[t]}, {t, 0, 360}]

Trigonometric Identities (7)

Calculate the SinDegrees value of 105 degrees using the sum and difference formulas:

Wolfram Language code: SinDegrees[α + β]//TrigExpand

Wolfram Language code: % /. {α -> 60, β -> 45}//Simplify

Compare with the result of direct calculation:

Wolfram Language code: % == SinDegrees[105]

Calculate the SinDegrees value of 15 degrees using the half-angle formula :

Wolfram Language code: (±Sqrt[(1 - CosDegrees[α]/2)] /. α -> 30)//Simplify

Compare this result with directly calculated SinDegrees:

Wolfram Language code: %[[1]] == SinDegrees[15]

Calculate the product of two SinDegrees using the trigonometric product to sum formula :

Wolfram Language code: ((1/2)(SinDegrees[α + β] + SinDegrees[α - β]) /. {α -> 30, β -> 45})//FullSimplify

Compare this result with directly calculated product of two SinDegrees instances:

Wolfram Language code: % == SinDegrees[30]SinDegrees[45]

Simplify trigonometric expressions:

Wolfram Language code: Simplify[(SinDegrees[x]/1 + CosDegrees[x]) + (1 + CosDegrees[x]/SinDegrees[x])]

Wolfram Language code: Simplify[(SinDegrees[x]CosDegrees[x]/TanDegrees[x]) - 1]

Verify trigonometric identities:

Wolfram Language code: Simplify[SinDegrees[2x]^2 + (1 - 2SinDegrees[x]^2)^2 == 1]

Use the law of sines to find the length of the side opposite to the angle angle, given the length of the side and :

This could be calculated via the formula :

Wolfram Language code: Solve[(SinDegrees[28]/x) == (SinDegrees[49]/7), x]

The numerical value of :

Wolfram Language code: %//N

Calculate the base length of an isosceles triangle given the leg length and the vertex angle :

Calculate the base:

Wolfram Language code: base = 2a SinDegrees[α / 2] /. {a -> 2, α -> 30}

Get the numerical value of the base:

Wolfram Language code: %//N

Trigonometric Equations (2)

Solve a basic trigonometric equation:

Wolfram Language code: Solve[SinDegrees[5x] == 1 / 2, x]

Solve trigonometric equations including other trigonometric functions:

Wolfram Language code: Solve[SinDegrees[5x] == CosDegrees[x], x]//FullSimplify

Solve trigonometric equations with conditions:

Wolfram Language code: Reduce[2Sqrt[2SinDegrees[x]] + 3CosDegrees[x] == 9 / 2 && 0 < x < 90, x]

Trigonometric Inequalities (2)

Solve this trigonometric inequality:

Wolfram Language code: Reduce[SinDegrees[x - 60] > SinDegrees[x] && 0 <= x <= 360, x]

Solve this trigonometric inequality including other trigonometric functions:

Wolfram Language code: Reduce[(SinDegrees[x] - 1/TanDegrees[x]) > 0, x, Reals]

Advanced Applications (8)

Lissajous figure:

Wolfram Language code: ParametricPlot[{SinDegrees[t], SinDegrees[2t]}, {t, 0, 360}]

Equiangular (logarithmic) spiral:

Wolfram Language code: ParametricPlot[Exp[t / 10 * π / 180]{SinDegrees[t], CosDegrees[t]}, {t, 0, 5 * 360}, PlotRange -> All]

Plot a sphere:

Wolfram Language code:

ParametricPlot3D[{CosDegrees[ϕ] SinDegrees[θ], SinDegrees[θ] SinDegrees[ϕ], CosDegrees[θ]}, {ϕ, -180, 180}, {θ, 0, 180}]

Plot a torus:

Wolfram Language code:

ParametricPlot3D[{CosDegrees[ϕ] + 1 / 2 CosDegrees[θ] CosDegrees[ϕ], SinDegrees[ϕ] + 1 / 2 CosDegrees[θ] SinDegrees[ϕ], SinDegrees[θ] / 2}, {ϕ, -180, 180}, {θ, 0, 360}]

Plot waves:

Wolfram Language code: Plot3D[SinDegrees[x]SinDegrees[y], {x, 0, 720}, {y, 0, 720}]

Approximate the almost nowhere differentiable Riemann–Weierstrass function:

Wolfram Language code: Plot[Sum[N[SinDegrees[j ^ 2 x] / j ^ 2], {j, 1, 12}], {x, 0, 360}]

Intensity of the Fraunhofer diffraction pattern of a circular aperture versus diffraction angle:

Wolfram Language code: Plot[2(BesselJ[2, 10SinDegrees[θ]] / (10SinDegrees[θ])) ^ 2, {θ, 0, 90}]

Find a point on a unit circle using CosDegrees and SinDegrees functions:

Wolfram Language code: ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1.5, 1.5}, {y, -1.5, 1.5}, ...]

Properties & Relations (11)

Check that 1 degree is radians:

Wolfram Language code: SinDegrees[60] == Sin[π / 3]

Basic parity and periodicity properties are automatically applied:

Wolfram Language code: SinDegrees[x + 360]

Wolfram Language code: SinDegrees[-x]

Wolfram Language code: SinDegrees[I x]

Wolfram Language code: 1 / SinDegrees[x]//Simplify

Complicated expressions containing trigonometric functions do not simplify automatically:

Wolfram Language code: SinDegrees[3z]^2 + (2 CosDegrees[z] CosDegrees[2 z] - CosDegrees[z])^2

Wolfram Language code: Simplify[%]

Another example:

Wolfram Language code: SinDegrees[x] - SinDegrees[y] - 2CosDegrees[(x + y/2)]SinDegrees[(x - y/2)]

Wolfram Language code: FullSimplify[%]

Use FunctionExpand to express SinDegrees in terms of radicals:

Wolfram Language code: {SinDegrees[180 / 8], SinDegrees[180 / 12], SinDegrees[180 / 15]}

Wolfram Language code: FunctionExpand[%]

Compositions with the inverse trigonometric functions:

Wolfram Language code: {SinDegrees[ArcSinDegrees[z]], SinDegrees[2ArcSinDegrees[z]], SinDegrees[3ArcSinDegrees[z]]}

Wolfram Language code: FunctionExpand[%]

Solve a trigonometric equation:

Wolfram Language code: Reduce[SinDegrees[z]^2 + 3 SinDegrees[z + 30] == 4, z]

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[SinDegrees[z]^2 + 15 SinDegrees[z + 30] == z, {z, 0, 15}]

Plot the function to check if the solution is correct:

Wolfram Language code: Plot[SinDegrees[z]^2 + 15 SinDegrees[z + 30] - z, {z, 0, 15}]

The zeros of SinDegrees:

Wolfram Language code: Reduce[SinDegrees[α x + β] == 0, x]

FunctionExpand applied to SinDegrees generates expressions in trigonometric functions in radians:

Wolfram Language code: FunctionExpand[SinDegrees[x]]

Wolfram Language code: FunctionExpand[SinDegrees[x ^ 2]SinDegrees[120 - x / 2]]

ExpToTrig applied to the outputs of TrigToExp will generate trigonometric functions in radians:

Wolfram Language code: TrigToExp[SinDegrees[z]]

Wolfram Language code: ExpToTrig[%]

Wolfram Language code:

TrigToExp[SinDegrees[2z]SinDegrees[z]];
ExpToTrig[%]

SinDegrees is a numeric function:

Wolfram Language code: NumericQ[SinDegrees[2 + E]]

Possible Issues (1)

Machine-precision input is insufficient to get a correct answer:

Wolfram Language code: SinDegrees[10. ^ 30]

With exact input, the answer is correct:

Wolfram Language code: N[SinDegrees[10 ^ 30], 20]

Neat Examples (5)

Trigonometric functions are ratios that relate the angle measures of a right triangle to the lengths of its sides:

Wolfram Language code:

Trigfunclist = {SinDegrees[θ], CosDegrees[θ], TanDegrees[θ], CotDegrees[θ], SecDegrees[θ], CscDegrees[θ]};
ratioslist = {a / c, b / c, a / b, b / a, c / b, c / a};

Wolfram Language code: Grid[...]//TraditionalForm

Solve a trigonometric equation:

Wolfram Language code: Solve[SinDegrees[x] == CosDegrees[2x], x]//Simplify

Add some condition to the solution:

Wolfram Language code: Reduce[SinDegrees[x] == CosDegrees[2x] && 0 < x < 45, x]

Some arguments can be expressed as a finite sequence of nested radicals:

Wolfram Language code: SinDegrees[(180/2^12)]//FunctionExpand

Indefinite integral of :

Wolfram Language code: Integrate[SinDegrees[x ^ n], x]

Noncommensurate waves (quasiperiodic function):

Wolfram Language code: Plot[SinDegrees[x] + SinDegrees[Sqrt[2]x], {x, 0, 20 * 360}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

SinDegrees

Details

Examples

Basic Examples (6)

Scope (47)

Numerical Evaluation (6)

Specific Values (6)

Visualization (4)

Function Properties (13)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (5)

Function Representations (4)

Applications (22)

Basic Trigonometric Applications (3)

Trigonometric Identities (7)

Trigonometric Equations (2)

Trigonometric Inequalities (2)

Advanced Applications (8)

Properties & Relations (11)

Possible Issues (1)

Neat Examples (5)

Text

CMS

APA

BibTeX

BibLaTeX

SinDegrees

Details

Examples

Basic Examples (6)

Scope (47)

Numerical Evaluation (6)

Specific Values (6)

Visualization (4)

Function Properties (13)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (5)

Function Representations (4)

Applications (22)

Basic Trigonometric Applications (3)

Trigonometric Identities (7)

Trigonometric Equations (2)

Trigonometric Inequalities (2)

Advanced Applications (8)

Properties & Relations (11)

Possible Issues (1)

Neat Examples (5)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX