Wolfram Language & System Documentation Center

FunctionAnalytic

tests whether is an analytic function for x∈Reals.

tests whether is an analytic function for x∈dom.

FunctionAnalytic[{f₁,f₂,…},{x₁,x₂,…},dom]

tests whether are analytic functions for x₁,x₂,…∈dom.

tests whether are analytic functions for xvars in an open set containing the solutions of the constraints cons over the domain dom.

FunctionAnalytic

FunctionAnalytic[f,x]

tests whether is an analytic function for x∈Reals.

FunctionAnalytic[f,x,dom]

tests whether is an analytic function for x∈dom.

FunctionAnalytic[{f₁,f₂,…},{x₁,x₂,…},dom]

tests whether are analytic functions for x₁,x₂,…∈dom.

FunctionAnalytic[{funs,cons},xvars,dom]

tests whether are analytic functions for xvars in an open set containing the solutions of the constraints cons over the domain dom.

Details and Options

Complex analytic functions are also known as holomorphic functions.
A function is analytic in an open set if for all y∈ℛ there is an and a sequence such that for all , .
A function is analytic in an open set if for all there is an and a sequence such that for all $TemplateBox[{{{, {{{x, _, 1}, -, {y, _, 1}}, ,, ..., ,, {{x, _, n}, -, {y, _, n}}}, }}}, Norm]<r(y_1,...,y_n)$ , $f(x_1,...,x_n)=sum_(k in TemplateBox[{}, NonNegativeIntegers]^n)a_k(y_1,...,y_n)(x_1-y_1)^(k_1) ... (x_n-y_n)^(k_n)$ .
If funs contains parameters other than xvars, the result is typically a ConditionalExpression.
Possible values for dom are Reals and Complexes. The default is Reals.
If dom is Reals, then all variables, parameters, constants and function values are restricted to be real.
cons can contain inequalities or logical combinations of these.
The following options can be given:

Assumptions	$Assumptions	assumptions on parameters
GenerateConditions	True	whether to generate conditions on parameters
PerformanceGoal	$PerformanceGoal	whether to prioritize speed or quality

Possible settings for GenerateConditions include:
Automatic nongeneric conditions only

True all conditions

False no conditions

None return unevaluated if conditions are needed
Possible settings for PerformanceGoal are "Speed" and "Quality".

Examples

open all close all

Basic Examples (4)

Test analyticity of real functions:

Wolfram Language code: FunctionAnalytic[Sin[x], x]

Wolfram Language code: FunctionAnalytic[Tan[x], x]

Test analyticity of complex functions:

Wolfram Language code: FunctionAnalytic[E ^ x + x, x, Complexes]

Wolfram Language code: FunctionAnalytic[Sqrt[x], x, Complexes]

Test analyticity over restricted domains:

Wolfram Language code: FunctionAnalytic[{Tan[x], -Pi / 2 < x < Pi / 2}, x]

Wolfram Language code: FunctionAnalytic[{Sqrt[x], Re[x] > 0}, x, Complexes]

Test analyticity of multivariate functions:

Wolfram Language code: FunctionAnalytic[Gamma[x ^ 2 + y ^ 2 + 1, E ^ (x y)], {x, y}]

Scope (6)

Real univariate functions:

Wolfram Language code: FunctionAnalytic[Tanh[x], x]

Wolfram Language code: FunctionAnalytic[Floor[x], x]

Wolfram Language code: Plot[{Tanh[x], Floor[x]}, {x, -3, 3}]

Complex univariate functions:

Wolfram Language code: FunctionAnalytic[Exp[z], z, Complexes]

Wolfram Language code: FunctionAnalytic[Log[z], z, Complexes]

Wolfram Language code: GraphicsRow[ComplexPlot[#, {z, -2 - 2I, 2 + 2I}]& /@ {Exp[z], Log[z]}, ImageSize -> Medium]

Functions with restricted domains:

Wolfram Language code: FunctionAnalytic[{ArcSin[x], -1 < x < 1}, x]

Wolfram Language code: FunctionAnalytic[{Log[z], Im[z] ≠ 0}, z, Complexes]

Real multivariate functions:

Wolfram Language code: FunctionAnalytic[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], {x, y}]

Wolfram Language code: FunctionAnalytic[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 - 1)], {x, y}]

Wolfram Language code: GraphicsRow[Plot3D[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + #)], {x, -2, 2}, {y, -2, 2}]& /@ {1, -1}, ImageSize -> Medium]

Complex multivariate functions:

Wolfram Language code: FunctionAnalytic[LaguerreL[E ^ (x + z), Sin[y z]], {x, y, z}, Complexes]

Wolfram Language code: FunctionAnalytic[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], {x, y}, Complexes]

Wolfram Language code: FunctionAnalytic[{Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], x ^ 2 + y ^ 2 ≠ -1}, {x, y}, Complexes]

Functions with symbolic parameters:

Wolfram Language code: FunctionAnalytic[Gamma[x ^ 2 + a], x]

Wolfram Language code: FunctionAnalytic[Sin[x y] / (x ^ 2 + a x y + y ^ 2 + b), {x, y}]

Options (4)

Assumptions (1)

FunctionAnalytic cannot find the answer for arbitrary values of the parameter :

Wolfram Language code: FunctionAnalytic[Sin[x + y] / (Exp[x y] + a), {x, y}]

With the assumption that , FunctionAnalytic succeeds:

Wolfram Language code: FunctionAnalytic[Sin[x + y] / (Exp[x y] + a), {x, y}, Assumptions -> a > 0]

GenerateConditions (2)

By default, FunctionAnalytic may generate conditions on symbolic parameters:

Wolfram Language code: FunctionAnalytic[Log[x ^ 2 + a], x]

With GenerateConditions->None, FunctionAnalytic fails instead of giving a conditional result:

Wolfram Language code: FunctionAnalytic[Log[x ^ 2 + a], x, GenerateConditions -> None]

This returns a conditionally valid result without stating the condition:

Wolfram Language code: FunctionAnalytic[Log[x ^ 2 + a], x, GenerateConditions -> False]

By default, all conditions are reported:

Wolfram Language code: FunctionAnalytic[Cos[x y] / a, {x, y}]

With GenerateConditions->Automatic, conditions that are generically true are not reported:

Wolfram Language code: FunctionAnalytic[Cos[x y] / a, {x, y}, GenerateConditions -> Automatic]

PerformanceGoal (1)

Use PerformanceGoal to avoid potentially expensive computations:

Wolfram Language code: FunctionAnalytic[1 / (x ^ 4 + a x ^ 3 y + b x y ^ 3 + y ^ 4 + c), {x, y}, PerformanceGoal -> "Speed"]

The default setting uses all available techniques to try to produce a result:

Wolfram Language code: FunctionAnalytic[1 / (x ^ 4 + a x ^ 3 y + b x y ^ 3 + y ^ 4 + c), {x, y}]

Applications (11)

Classes of Analytic Functions (6)

Polynomials are analytic:

Wolfram Language code: {FunctionAnalytic[x, x], FunctionAnalytic[x^2 + 1, x], FunctionAnalytic[x^3 - 2 x^2 - 5 x + 6, x]}

Sin, Cos and Exp are analytic:

Wolfram Language code: {FunctionAnalytic[Sin[x], x], FunctionAnalytic[Cos[x], x], FunctionAnalytic[Exp[x], x]}

Visualize these functions:

Wolfram Language code: Grid[Partition[Table[Plot[f, {x, -5, 5}], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}], 3]]

These functions are analytic in the complex plane as well:

Wolfram Language code: Table[FunctionAnalytic[f, x, Complexes], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}]

Visualize these functions over :

Wolfram Language code: Grid[Partition[Table[ComplexPlot3D[f, {x, 5}], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}], 3]]

Functions that are analytic in the plane are called entire functions and can be considered infinite-degree polynomials:

Wolfram Language code: Exp[x] == Sum[(x^k/k!), {k, 0, ∞}]

Wolfram Language code: Cos[x] == Sum[((-1)^kx^2k/(2k)!), {k, 0, ∞}]

Wolfram Language code: Sin[x] == Sum[((-1)^kx^2k + 1/(2k + 1)!), {k, 0, ∞}]

No discontinuous function is analytic:

Wolfram Language code:

TableForm[Table[{f, FunctionContinuous[f[x], x], FunctionAnalytic[f[x], x]}, {f, {UnitStep, RealSign, Floor, SquareWave, SawtoothWave}}], TableHeadings -> {None, {f, "Continuous?", "Analytic?"}}]

Visualize some of the preceding functions:

Wolfram Language code: Grid[{Table[Plot[f[x], {x, -3, 3}, PlotLabel -> f], {f, {UnitStep, Floor, SawtoothWave}}]}]

Some continuous functions are not analytic, like the real absolute value function RealAbs:

Wolfram Language code: {FunctionContinuous[RealAbs[x], x], FunctionAnalytic[RealAbs[x], x]}

The problem with RealAbs is the "kink" at the origin:

Wolfram Language code: FunctionAnalytic[{RealAbs[x], x ≠ 0}, x]

Wolfram Language code: Plot[RealAbs[x], {x, -1, 1}]

The complex absolute value function Abs is analytic nowhere in the complex plane:

Wolfram Language code: {FunctionContinuous[Abs[x], x, ℂ], FunctionAnalytic[Abs[x], x, ℂ]}

It suffers from a different problem than RealAbs, namely it is nowhere differentiable:

Wolfram Language code: {RealAbs'[x], Abs'[x]}

The reciprocal of an analytic function is analytic wherever :

Wolfram Language code: FunctionAnalytic[{(1/x), x ≠ 0}, x]

Thus, rational functions may or may not be continuous over the reals:

Wolfram Language code: FunctionAnalytic[(4/x^2 + 4), x]

Wolfram Language code: FunctionAnalytic[(1/x^2 - 4), x]

Wolfram Language code: Plot[{(4/x^2 + 4), (1/x^2 - 4)}, {x, -4, 4}, PlotTheme -> {"DashedLines", "Detailed"}]

However, as every nonconstant polynomial has a root in the plane, rational functions are never analytic on :

Wolfram Language code: FunctionAnalytic[(4/x^2 + 4), x, Complexes]

Instead, rational functions are the prototype of the larger class of meromorphic functions in the complex plane:

Wolfram Language code: FunctionMeromorphic[(4/x^2 + 4), x]

Visualizing the function in the complex plane shows the blowup at :

Wolfram Language code: ComplexPlot3D[(4/x^2 + 4), {x, 4}, ClippingStyle -> None]

As Cot and Csc are rational functions of Sin and Cos, they are analytic when sine is nonzero:

Wolfram Language code: {FunctionAnalytic[{Cot[x], (x/π)∉ℤ}, x], FunctionAnalytic[{Csc[x], (x/π)∉ℤ}, x]}

Visualize the functions along with sine:

Wolfram Language code: Plot[{Cot[x], Csc[x], Sin[x]}, {x, -3π, 3π}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

Since sine's only zeros are on the real line, this means the Cot and Csc are analytic except on the multiples of :

Wolfram Language code: {FunctionAnalytic[{Cot[x], (x/π)∉ℤ}, x, ℂ], FunctionAnalytic[{Csc[x], (x/π)∉ℤ}, x, ℂ]}

Similarly, Tan and Sec are continuous when cosine is nonzero:

Wolfram Language code: {FunctionAnalytic[{Tan[x], (x/π) - (1/2)∉ℤ}, x, ℂ], FunctionAnalytic[{Sec[x], (x/π) - (1/2)∉ℤ}, x, ℂ]}

Wolfram Language code:

Grid[Partition[Table[ComplexPlot3D[f[x], {x, 3π}, PlotRange -> {0, 2}, ImageSize -> Small, ClippingStyle -> None], {f, {Cot, Csc, Tan, Sec}}], 2]]

This same principle applies to the hyperbolic trigonometric functions Coth and Csch:

Wolfram Language code: {FunctionAnalytic[{Coth[x], x ≠ 0}, x], FunctionAnalytic[{Csch[x], x ≠ 0}, x]}

As well as Tanh and Sech:

Wolfram Language code: {FunctionAnalytic[Tanh[x], x], FunctionAnalytic[Sech[x], x]}

But as the zeros of Cosh and Sinh lie on the imaginary axis, more exclusions are needed for analyticity over :

Wolfram Language code: {FunctionAnalytic[{Coth[x], (x/I π)∉ℤ}, x, ℂ], FunctionAnalytic[{Csch[x], (x/I π)∉ℤ}, x, ℂ]}

Wolfram Language code:

{FunctionAnalytic[{Tanh[x], (x/I π) - (1/2)∉ℤ}, x, ℂ], FunctionAnalytic[{Sech[x], (x/I π) - (1/2)∉ℤ}, x, ℂ]}

Plots of the hyperbolic functions are just rotations by along with a phase shift by the same amount:

Wolfram Language code:

Grid[Partition[Table[ComplexPlot3D[f[x], {x, 3π}, PlotRange -> {0, 2}, ImageSize -> Small, ClippingStyle -> None], {f, {Coth, Csch, Tanh, Sech}}], 2]]

The compositions of analytic functions are analytic:

Wolfram Language code: FunctionAnalytic[Sin[x ^ 2 + 3x + 2], x]

Wolfram Language code: FunctionAnalytic[Exp[Sin[x]], x]

Wolfram Language code: FunctionAnalytic[Cos[Sin[x]]^2 + Sin[x]Cos[x] + Exp[-x], x]

Multivariate polynomials are analytic over the reals and complexes:

Wolfram Language code: {FunctionAnalytic[x ^ 2 + 3x y - 7y ^ 2, {x, y}], FunctionAnalytic[x ^ 2 + 3x y - 7y ^ 2, {x, y}, ℂ]}

So are multivariate polynomials in entire functions:

Wolfram Language code: FunctionAnalytic[Cos[x] ^ 2 + Cos[x]Sin[ y] - Sin[y] ^ 3, {x, y}]

Rational multivariate functions may or may not be analytic over the reals:

Wolfram Language code: {FunctionAnalytic[(x^2 - y^2/x^2 + y^2 + 1), {x, y}], FunctionAnalytic[(x^2 - y^2 + 1/x^2 - y), {x, y}]}

They are always nonanalytic over the complexes:

Wolfram Language code: FunctionAnalytic[(x^2 - y^2/x^2 + y^2 + 1), {x, y}, ℂ]

By composing with analytic univariate functions, many more analytic functions can be generated:

Wolfram Language code:

{FunctionAnalytic[ArcTan[x ^ 2 + 3x y - 7y ^ 2], {x, y}], FunctionAnalytic[Cos[(x^2 - y^2/x^2 + y^2 + 1)], {x, y}], FunctionAnalytic[Sin[(x^2 - y^2/Exp[x^2 - y])], {x, y}]}

Visualize the analytic functions:

Wolfram Language code:

Grid[Partition[Table[Plot3D[f, {x, -5, 5}, {y, -5, 5}, PlotRange -> All, ImageSize -> 165], {f, {x^2 + 3 x y + 7 y^2, Cos[x]^2 + Cos[x] Sin[y] - Sin[y]^3, (x^2 - y^2/x^2 + y^2 + 1), ArcTan[x^2 + 3 x y - 7 y^2], Cos[(x^2 - y^2/x^2 + y^2 + 1)], Sin[(x^2 - y^2 + 1/Exp[x^2 - y])]}}], 3]]

Calculus (5)

Analytic functions can be represented by power series:

Wolfram Language code: Exp[z] == Sum[(z^k/k!), {k, 0, ∞}]

In this case, the sum converges for all values of :

Wolfram Language code: SumConvergence[(z^k/k!), k]

Consider the following function:

Wolfram Language code: f[z_] := (z ^ 2 + 4z + 17/z ^ 2 - 25)

It is analytic on the open disk of radius 5:

Wolfram Language code: FunctionAnalytic[{f[z], Abs[z] < 5}, z, ℂ]

Therefore it can be expressed as a power series about any point in the disk, say :

Wolfram Language code: coeff[n_] = SeriesCoefficient[f[z], {z, 2, n}]

Wolfram Language code: Sum[coeff[n](z - 2) ^ n, {n, 0, ∞}]

However, this sum does not converge for all values of :

Wolfram Language code: SumConvergence[coeff[n](z - 2) ^ n, n]

Substituting a value of outside this range produces a divergent sum:

Wolfram Language code: Sum[coeff[n](-4 - 2) ^ n, {n, 0, ∞}]

Visualize the function along with the domains of analyticity and convergence:

Wolfram Language code: ComplexPlot[f[z], {z, 6}, PlotLegends -> Automatic, Epilog -> {Circle[{0, 0}, 5], Dashed, Circle[{2, 0}, 3]}]

The integral of an analytic function around a close contour is zero:

Wolfram Language code: Integrate[Exp[z], {z, 1, E^(I π/3), E^(2 I π/3), -1, E^-(2 I π/3), E^-(I π/3), 1}]

The following integral is nonzero, so Log cannot be analytic:

Wolfram Language code: Integrate[Log[z], {z, 1, E^(I π/3), E^(2 I π/3), -1, E^-(2 I π/3), E^-(I π/3), 1}]//Simplify

Wolfram Language code: FunctionAnalytic[Log[z], z, ℂ]

Visualize the functions and the contour:

Wolfram Language code:

Grid[{Table[ComplexPlot[f[z], {z, 1.2}, PlotLegends -> Automatic, Epilog -> {Arrowheads[Medium], Arrow[ReIm /@ Exp[2π I / 6 Range[0, 6]]]}, ImageSize -> Small], {f, {Exp, Log}}]}]

If and are analytic in a region in the complex plane, only has simple zeros and is nonzero. A sum over the zeros of can be computed as . Consider :

Wolfram Language code: f[z_] := ((z^3 + 10 z^2 + 23 z + 14) E^(1/z + 8)/z - 6)

This function is analytic in a disk of radius 4:

Wolfram Language code: FunctionAnalytic[{f[z], Abs[z] ≤ 4}, z, ℂ]

Let . It is analytic and nonzero in the disk of radius 4:

Wolfram Language code: ϕ[z_] := (z + 7/z^2 + 25);

Wolfram Language code: FunctionAnalytic[{ϕ[z], Abs[z] ≤ 4}, z, ℂ]

Wolfram Language code: Solve[ϕ[z] == 0 && Abs[z] ≤ 4, z]

The function has two simple roots within the disk, at and :

Wolfram Language code: Reduce[f[z] == 0, z]

Thus, the sum is easy to compute:

Wolfram Language code: Sum[ϕ[z], {z, {-1, -2}}]

The integral gives the same answer:

Wolfram Language code: (1/2π I)Subsuperscript[∫, 0, 2π]ϕ[4E^I ω](f'[4E^I ω]/f[4E^I ω])(4 I E^ I ω )ⅆω

Differential equations with analytic coefficients have solutions that are analytic at most points, which makes series solutions a viable method of approach. Consider the following differential equation:

Wolfram Language code: de = {y''[x] + 2y'[x] ^ 2 + 7 Sin[x] ^ 2 y[x] == Cos[2x], y[0] == 1, y'[0] == 5};

There is no closed-form solution to this equation:

Wolfram Language code: DSolveValue[de, y[x], x]

However, all coefficients are analytic:

Wolfram Language code: Table[FunctionAnalytic[coeff, x], {coeff, {1, 2, 7Sin[x]^2, Cos[2x]}}]

Thus, a series solution can be found using AsymptoticDSolveValue:

Wolfram Language code: AsymptoticDSolveValue[de, y[x], {x, 0, 5}]

The function is continuous:

Wolfram Language code: h[x_] := Piecewise[{{x*Sin[1/x], x != 0}, {0, x == 0}}]

Wolfram Language code: FunctionContinuous[h[x], x]

However, its first derivative is not continuous:

Wolfram Language code: FunctionContinuous[h'[x], x]

Therefore is not analytic:

Wolfram Language code: FunctionAnalytic[h[x], x]

While goes smoothly to zero, its derivative oscillates wildly at the origin:

Wolfram Language code: {MinLimit[h'[x], x -> 0], MaxLimit[h'[x], x -> 0]}

Visualize and its first derivative:

Wolfram Language code: Plot[{h[x], h'[x]}, {x, -1, 1}, PlotRange -> {-4, 4}, PlotTheme -> "DashedLines"]

Properties & Relations (7)

An analytic function is differentiable arbitrarily many times:

Wolfram Language code: f = Sin[Exp[x]];

Wolfram Language code: FunctionAnalytic[f, x]

Use D to compute derivatives:

Wolfram Language code: NestList[D[#, x]&, f, 5]//Column

An analytic function can be expressed as a Taylor series at each point of its domain:

Wolfram Language code: f = x Cos[2 ^ Sin[x ^ 2] + 2x];

Wolfram Language code: FunctionAnalytic[f, x]

Use Series to compute initial terms of Taylor series:

Wolfram Language code: s = Series[f, {x, 0, 3}]

The resulting polynomial approximates near :

Wolfram Language code: Plot@@{{f, Normal[s]}, {x, -2, 2}}

Zeros of an analytic function cannot have an accumulation point in the domain:

Wolfram Language code: f = Piecewise[{{x Sin[1 / x], x ≠ 0}}]

Zeros of have an accumulation point at :

Wolfram Language code: Plot[f, {x, -1, 1}]

is continuous, but not analytic:

Wolfram Language code: FunctionContinuous[f, x]

Wolfram Language code: FunctionAnalytic[f, x]

is analytic if is excluded from the domain:

Wolfram Language code: FunctionAnalytic[{f, x ≠ 0}, x]

An analytic function can have only finitely many zeros in a closed and bounded region:

Wolfram Language code: f = Sin[3x ^ 3] - 2x + 1;

Wolfram Language code: FunctionAnalytic[f, x, Complexes]

Use Solve to find the roots of in the unit disk:

Wolfram Language code: Solve[f == 0 && Abs[x] ≤ 1, x]

Wolfram Language code:

ComplexPlot[f, {x, -1 - I, 1 + I}, RegionFunction -> (Abs[#] ≤ 1&), Epilog -> {PointSize[Medium], Blue, Point[{Re[x], Im[x]}] /. %}]

Use FunctionContinuous to check whether a function is continuous:

Wolfram Language code: FunctionContinuous[Abs[x], x]

Continuous functions may not be analytic:

Wolfram Language code: FunctionAnalytic[Abs[x], x]

Analytic functions are continuous:

Wolfram Language code: f = 2 ^ Sin[x ^ 2 + 7] - x;

Wolfram Language code: FunctionAnalytic[f, x]

Wolfram Language code: FunctionContinuous[f, x]

Use FunctionMeromorphic to check whether a function is meromorphic:

Wolfram Language code: FunctionMeromorphic[Tan[x], x]

Meromorphic functions may not be complex analytic:

Wolfram Language code: FunctionAnalytic[Tan[x], x, Complexes]

A quotient of complex analytic functions is meromorphic:

Wolfram Language code:

f = 2 ^ Sin[x ^ 2 + 7] - x;
g = Cos[x ^ 3 + 7x - 4] - 3 ^ x;

Wolfram Language code: FunctionAnalytic[#, x, Complexes]& /@ {f, g}

Wolfram Language code: FunctionMeromorphic[#, x]& /@ {f / g, g / f}

Sum of residues of an analytic function is zero:

Wolfram Language code: FunctionAnalytic[Sin[Cosh[x ^ 3 - E ^ x]], x]

Use ResidueSum to verify this property:

Wolfram Language code: ResidueSum[Sin[Cosh[x ^ 3 - E ^ x]], x]

Possible Issues (3)

A function needs to be defined everywhere to be analytic:

Wolfram Language code: FunctionAnalytic[Sin[x] / x, x]

Wolfram Language code: FunctionAnalytic[{Sin[x] / x, x ≠ 0}, x]

Wolfram Language code: FunctionAnalytic[Sinc[x], x]

A function needs to be real valued to be analytic over the real domain:

Wolfram Language code: FunctionAnalytic[E ^ (I x), x]

Wolfram Language code: FunctionAnalytic[E ^ (I x), x, Complexes]

All subexpressions of need to be real valued for a point to belong to the real domain of :

Wolfram Language code: FunctionAnalytic[Cos[Sqrt[x]], x]

Negative reals are not in the real domain of because is not real valued:

Wolfram Language code: FunctionDomain[Cos[Sqrt[x]], x]

is real valued for all real :

Wolfram Language code: Plot[Cos[Sqrt[x]], {x, -10, 10}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FunctionAnalytic

Details and Options

Examples

Basic Examples (4)

Scope (6)

Options (4)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

Applications (11)

Classes of Analytic Functions (6)

Calculus (5)

Properties & Relations (7)

Possible Issues (3)

Text

CMS

APA

BibTeX

BibLaTeX

FunctionAnalytic

Details and Options

Examples

Basic Examples (4)

Scope (6)

Options (4)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

Applications (11)

Classes of Analytic Functions (6)

Calculus (5)

Properties & Relations (7)

Possible Issues (3)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX