WOLFRAM

Wolfram Language & System Documentation Center

HalfLine[{p1,p2}]

represents the half-line from the point p1 through p2.

HalfLine[p,v]

represents the half-line from the point p in the direction v.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

HalfLine

HalfLine[{p1,p2}]

represents the half-line from the point p1 through p2.

HalfLine[p,v]

represents the half-line from the point p in the direction v.

Details

Examples

open all close all

Basic Examples  (3)

A HalfLine in 2D:

Wolfram Language code: Graphics[HalfLine[{{0, 0}, {1, 0}}], Frame -> True]

And in 3D:

Wolfram Language code: Graphics3D[HalfLine[{0, 0, 0}, {1, 2, 3}]]

Different styles applied to a half-line:

Wolfram Language code: ℛ = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: {Graphics[{Red, ℛ}], Graphics[{Thick, Red, ℛ}], Graphics[{Thick, Red, Dashed, ℛ}]}

The arc length of a half-line is infinite:

Wolfram Language code: ArcLength[HalfLine[{0, 0}, {1, 1}]]

Scope  (18)

Graphics  (9)

Specification  (3)

Define a HalfLine starting at in the direction :

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];
Wolfram Language code: Show[ill, Graphics[HalfLine[{1, 1}, {2, 1}]]]

Define the same half-line starting at and passing through :

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];
Wolfram Language code: Show[ill, Graphics[HalfLine[{{1, 1}, {3, 2}}]]]

Define a 3D half-line starting at and going in the direction :

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> {{0, 5}, {0, 5}, {0, 5}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[HalfLine[{1, 1, 1}, {1, 2, 3}]]]

Define the same half-line using the points and :

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> {{0, 5}, {0, 5}, {0, 5}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[HalfLine[{{1, 1, 1}, {2, 3, 4}}]]]

A half-line with symbolic direction:

Wolfram Language code: Table[Graphics[HalfLine[{0, 0}, {Cos[θ], Sin[θ]}], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

Styling  (5)

A HalfLine with varying thickness:

Wolfram Language code: Table[Graphics[{Thickness[i], HalfLine[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{t, HalfLine[{{0, 0}, {2, 1}}]}], {t, {Thin, Thick}}]

Thickness in scaled size:

Wolfram Language code: Table[Graphics[{Thickness[i], HalfLine[{{0, 0}, {2, 1}}]}], {i, {.005, .05, .1}}]

Thickness in printer's points:

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], HalfLine[{{0, 0}, {2, 1}}]}], {i, {1, 5, 10}}]

Half-lines can be rendered in dashed or dotted styles:

Wolfram Language code: Table[Graphics[{Dashing[i], HalfLine[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, HalfLine[{{0, 0}, {2, 1}}]}], {d, {Dotted, Dashed, DotDashed}}]

Color directives can be used to specify the color of a half-line:

Wolfram Language code: Table[Graphics[{c, HalfLine[{{0, 0}, {2, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

Combine various directives to style a half-line:

Wolfram Language code: Graphics[{Thick, Blue, Dashed, HalfLine[{{0, 0}, {2, 1}}]}]

Coordinates  (1)

Points and vectors can be Dynamic:

Wolfram Language code: DynamicModule[{θ = 0}, {Slider[Dynamic[θ], {0, 2Pi}], Graphics[HalfLine[{0, 0}, Dynamic[{Cos[θ], Sin[θ]}]]]}]

Regions  (9)

Embedding dimension is the dimensionality of the vertices:

Wolfram Language code: RegionEmbeddingDimension[HalfLine[{-1, -1}, {1, 1}]]
Wolfram Language code: RegionEmbeddingDimension[HalfLine[{0, 0, 0}, {1, 1, 1}]]

Geometric dimension is the dimension of the region itself:

Wolfram Language code: RegionDimension[HalfLine[{-1, 1}, {1, 1}]]

Point membership testing:

Wolfram Language code: ℛ = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: {RegionMember[ℛ, {2, 2}], RegionMember[ℛ, {3, 4}]}

Get conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

A half-line has infinite measure and undefined centroid:

Wolfram Language code: ℛ = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: RegionMeasure[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

Computing distance to a half-line:

Wolfram Language code: ℛ = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: RegionDistance[ℛ, {1, 2}]

Plot it:

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 1}, {y, -1, 1}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate[RegionDistance[ℛ, {x, y}]], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Nearest points:

Wolfram Language code: ℛ = HalfLine[{0, 0}, {1, 2}];
Wolfram Language code: RegionNearest[ℛ, {1, 1}]

Visualize it:

Wolfram Language code: pts = Table[{0, 0} + {Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0, 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A half-line is unbounded:

Wolfram Language code: ℛ = HalfLine[{0, 0, 0}, {1, 1, 0}];
Wolfram Language code: BoundedRegionQ[ℛ]

But its range is not necessarily unbounded in all dimensions:

Wolfram Language code: RegionBounds[ℛ]

Integrate over a half-line:

Wolfram Language code: ℛ = HalfLine[{1, 1}, {1, 1}];
Wolfram Language code: Integrate[(1 / (x y))^2, {x, y}∈ℛ]

Optimize over a half-line:

Wolfram Language code: ℛ = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: Minimize[{(x y - 1)^2 + 3, {x, y}∈ℛ}, {x, y}]

Solve equations on a half-line:

Wolfram Language code: ℛ = HalfLine[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && {x, y, z}∈ℛ, {x, y, z}]

Applications  (4)

Create parallel rays aligned to :

Wolfram Language code: rays = Table[HalfLine[{0, y}, {1, 1}], {y, 5}];
Wolfram Language code: Graphics[rays, PlotRange -> {{-6, 6}, {0, 6}}]

Create rays perpendicular to the unit circle:

Wolfram Language code: rays = Table[HalfLine[{Cos[ϕ], Sin[ϕ]}, {Cos[ϕ], Sin[ϕ]}], {ϕ, 0, 2Pi, 2Pi / 100}];
Wolfram Language code: Graphics[rays]

Illustrate asymptotes:

Wolfram Language code: asym = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: Plot[(1/x) + Abs[x], {x, -2, 7}, Epilog -> {Red, Dashed, asym}]

Add drop lines to plots:

Wolfram Language code: pt = {0.7, 0.7 ^ 2};
Wolfram Language code: Plot[x ^ 2, {x, -1, 1}, Epilog -> {Red, HalfLine[pt, {-1, 0}], HalfLine[pt, {0, -1}]}]

Properties & Relations  (4)

Any InfiniteLine is a union of two half-lines:

Wolfram Language code: Subscript[ℛ, 1] = InfiniteLine[{1, 0}, {1, 2}];
Wolfram Language code: Subscript[ℛ, 2] = RegionUnion[HalfLine[{1, 0}, {1, 2}], HalfLine[{1, 0}, {-1, -2}]];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion can represent any HalfLine:

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{t + 1, 2t}, {{t, 0, ∞}}];
Wolfram Language code: Subscript[ℛ, 2] = HalfLine[{1, 0}, {1, 2}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion can represent any HalfLine:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[1 - x ≤ 0 && 1 + x - y == 0, {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = HalfLine[{{1, 2}, {3, 4}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfLine is a special case of ConicHullRegion:

Wolfram Language code: chr = ConicHullRegion[{{0, 0}}, {{1, 1}}];
Wolfram Language code: hline = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[chr, hline]

Neat Examples  (3)

A random collection of half-lines:

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], HalfLine[RandomReal[1, 2], RandomReal[{-1, 1}, 2]]}, {100}]]

An organized collection of half-lines:

Wolfram Language code: Graphics[Table[HalfLine[{Cos[θ], Sin[θ]}, {-Sin[θ], Cos[θ]}], {θ, 0, 2π, π / 20}], PlotRange -> 2]

Create moiré patterns:

Wolfram Language code: Graphics[Table[HalfLine[{Cos[ϕ], Sin[ϕ]}, {Sin[ϕ], Cos[ϕ]}], {ϕ, 0, 2Pi, 2Pi / 200}], PlotRange -> 3]
Wolfram Research (2014), HalfLine, Wolfram Language function, https://reference.wolfram.com/language/ref/HalfLine.html.

Text

Wolfram Research (2014), HalfLine, Wolfram Language function, https://reference.wolfram.com/language/ref/HalfLine.html.

CMS

Wolfram Language. 2014. "HalfLine." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HalfLine.html.

APA

Wolfram Language. (2014). HalfLine. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HalfLine.html

BibTeX

@misc{reference.wolfram_2026_halfline, author="Wolfram Research", title="{HalfLine}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/HalfLine.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_halfline, organization={Wolfram Research}, title={HalfLine}, year={2014}, url={https://reference.wolfram.com/language/ref/HalfLine.html}, note=[Accessed: 12-June-2026]}