WOLFRAM

Wolfram Language & System Documentation Center

HalfSpace[n,p]

represents the half-space of points such that .

HalfSpace[n,c]

represents the half-space of points such that .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

HalfSpace

HalfSpace[n,p]

represents the half-space of points such that .

HalfSpace[n,c]

represents the half-space of points such that .

Details

Examples

open all close all

Basic Examples  (3)

A HalfSpace in 2D:

Wolfram Language code: Graphics[HalfSpace[{2, 1}, {0, 0}]]

And in 3D:

Wolfram Language code: Graphics3D[HalfSpace[{-1, -1, 1}, {0, 0, 0}]]

Different styles applied to a half-space region:

Wolfram Language code: ℛ = HalfSpace[{-1, -1, 1}, {0, 0, 0}];
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], Pink, ℛ}], Graphics3D[{EdgeForm[Dashed], Pink, ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Determine if points belong to a given half-space region:

Wolfram Language code: ℛ = HalfSpace[{-1, -1, 1}, {0, 0, 0}];
Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {-1, 0, 0}]}

Scope  (15)

Graphics  (5)

Specification  (2)

A half-space in 2D defined by a normal vector and a point:

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {-1, 1}}]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[Graphics[{Blue, HalfSpace[{-1, 1}, {0, 0}]}], ill, PlotRange -> 2]

The same half-space defined by a normal vector and a constant:

Wolfram Language code: ill = Graphics[{Arrowheads[Medium], Thick, Arrow[{{0, 0}, {-1, 1}}]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[Graphics[{Blue, HalfSpace[{-1, 1}, 0]}], ill, PlotRange -> 2]

Define a half-space in 3D using a normal vector and a point:

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{1, 0, 2}], Arrowheads[Medium], Thick, Arrow[{{1, 0, 2}, {-1, 0, 2}}]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[HalfSpace[{-1, 0, 0}, {1, 0, 2}]]]

Define the same half-space using a normal vector and a constant:

Wolfram Language code: ill = Graphics3D[{Arrowheads[Medium], Thick, Arrow[{{1, 0, 2}, {-1, 0, 2}}]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[HalfSpace[{-1, 0, 0}, -1]]]

Half-spaces varying in direction of the normal:

Wolfram Language code: Table[Graphics3D[HalfSpace[{0, Cos[θ], Sin[θ]}, 0], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

Styling  (2)

Color directives specify the color of the half-space:

Wolfram Language code: Table[Graphics3D[{c, HalfSpace[{1, -1, 1}, 0]}], {c, {Red, Green, Yellow, Blue}}]

FaceForm and EdgeForm can be used to specify the styles of the faces and edges:

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], HalfSpace[{1, -1, 1}, 0]}]

Coordinates  (1)

Points and vectors can be Dynamic:

Wolfram Language code: DynamicModule[{θ = 0}, {Slider[Dynamic[θ], {0, Pi}], Graphics3D[HalfSpace[Dynamic[{1, Cos[θ], Sin[θ]}], 0]]}]

Regions  (10)

Embedding dimension is the dimension of the coordinates:

Wolfram Language code: RegionEmbeddingDimension[HalfSpace[{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, c]]
Wolfram Language code: RegionEmbeddingDimension[HalfSpace[{Subscript[x, 0], Subscript[y, 0]}, c]]

Geometric dimension is the dimension of the region itself:

Wolfram Language code: RegionDimension[HalfSpace[{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, c]]
Wolfram Language code: RegionDimension[HalfSpace[{Subscript[x, 0], Subscript[y, 0]}, c]]

Point membership test:

Wolfram Language code: ℛ = HalfSpace[{1, 0, 0}, 0];
Wolfram Language code: {RegionMember[ℛ, {2, 2, 0}], RegionMember[ℛ, {0, 0, 1}]}

Get the conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

A half-space has infinite measure and undefined centroid:

Wolfram Language code: ℛ = HalfSpace[{1, 1}, 0];
Wolfram Language code: RegionMeasure[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

Distance from a point:

Wolfram Language code: ℛ = HalfSpace[{1, 0}, -1];
Wolfram Language code: RegionDistance[ℛ, {-5, -3}]

Signed distance from a point:

Wolfram Language code: SignedRegionDistance[ℛ, {-5, -3}]

Nearest point in the region:

Wolfram Language code: ℛ = HalfSpace[{1, 1, 1}, 0];
Wolfram Language code: RegionNearest[ℛ, {1, 2, 3}]

Nearest points:

Wolfram Language code: pts = Flatten[Table[{Cos[k 2 π / 8]Cos[j π / 8], Sin[k 2 π / 8]Cos[j π / 8], Sin[j π / 8]}, {k, 0, 7}, {j, -3, 3}], 1]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics3D[{{Opacity[0.5], ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}, Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A half-space is unbounded:

Wolfram Language code: ℛ = HalfSpace[{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, c];
Wolfram Language code: BoundedRegionQ[ℛ]

Find the region range:

Wolfram Language code: RegionBounds[ℛ]

In the axis-aligned case:

Wolfram Language code: ℛ = HalfSpace[{1, 0, 0}, 1];
Wolfram Language code: BoundedRegionQ[ℛ]
Wolfram Language code: RegionBounds[ℛ]

Integrate over a half-space:

Wolfram Language code: ℛ = HalfSpace[{1, 0}, 0];
Wolfram Language code: Integrate[Exp[-x^2 - y^2], {x, y}∈ℛ]

Optimize over a half-space:

Wolfram Language code: ℛ = HalfSpace[{1, 1, 1}, -4];
Wolfram Language code: Minimize[{x^2 + y^2 + z^2 + 1, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations over a half-space:

Wolfram Language code: ℛ = HalfSpace[{1, 0, 0}, 0];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && {x, y, z}∈ℛ, {x, y, z}]

Applications  (5)

Visualize 2D half-planes:

Wolfram Language code: showHalfPlane[ahs_HalfSpace] := Graphics[{Opacity[0.3], ahs}, PlotRange -> {{-2, 2}, {-2, 2}}, Frame -> True]

The upper half-plane:

Wolfram Language code: HalfSpace[{0, -1}, 0]//showHalfPlane

The lower half-plane:

Wolfram Language code: HalfSpace[{0, 1}, 0]//showHalfPlane

The left half-plane:

Wolfram Language code: HalfSpace[{1, 0}, 0]//showHalfPlane

The right half-plane:

Wolfram Language code: HalfSpace[{-1, 0}, 0]//showHalfPlane

Visualize 3D half-spaces:

Wolfram Language code: showHalfSpace[ahs_HalfSpace] := Graphics3D[{EdgeForm[White], Opacity[0.3], ahs}, PlotRange -> {{-2, 2}, {-2, 2}, {-2, 2}}]

The upper half-space:

Wolfram Language code: HalfSpace[{0, 0, -1}, 0]//showHalfSpace

The lower half-space:

Wolfram Language code: HalfSpace[{0, 0, 1}, 0]//showHalfSpace

The left half-space:

Wolfram Language code: HalfSpace[{1, 0, 0}, 0]//showHalfSpace

The right half-space:

Wolfram Language code: HalfSpace[{-1, 0, 0}, 0]//showHalfSpace

The front half-space:

Wolfram Language code: HalfSpace[{0, 1, 0}, 0]//showHalfSpace

The back half-space:

Wolfram Language code: HalfSpace[{0, -1, 0}, 0]//showHalfSpace

Partition space in a BubbleChart:

Wolfram Language code: b = BubbleChart3D[RandomReal[1, {20, 4}]];
Wolfram Language code: hs = HalfSpace[{1, 0, 1}, {0.5, 0, 0.5}];

Combine the graphics:

Wolfram Language code: Show[b, Graphics3D[{Opacity[0.5], hs}]]

Any convex polygon in 2D can be represented as an intersection of half-spaces:

Wolfram Language code: Region[RegionIntersection@@(HalfSpace[#, 1]& /@ CirclePoints[6])]

Any convex polyhedron in 3D can be represented as an intersection of half-spaces:

Wolfram Language code: Region[RegionIntersection@@(HalfSpace[#, #]& /@ Tuples[{{-1, 1}, {-1, 1}, {-1, 1}}])]

Properties & Relations  (7)

ClipPlanes, for a given , results in a graphic that does not render anything within the :

Wolfram Language code: {Graphics3D[HalfSpace[{1, 1, 1}, 1], PlotRange -> 1], Graphics3D[Cuboid[{-1, -1, -1}, {1, 1, 1}], ClipPlanes -> {1, 1, 1, -1}, PlotRange -> 1]}

HalfSpace is a special case of ConicHullRegion:

Wolfram Language code: p = {1, 2, 1};n = {-2, 3, 1}; v = NullSpace[{n}];
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = ConicHullRegion[p, v, {-n}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfSpace is a special case of AffineHalfSpace:

Wolfram Language code: p = {1, 2, 1};n = {-2, 3, 1}; v = NullSpace[{n}];
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = AffineHalfSpace[p, v, -n];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfLine is a special case of HalfSpace:

Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[{-1}, {1}]; Subscript[ℛ, 2] = HalfLine[{1}, {1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfPlane is a special case of HalfSpace:

Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[{-1, -1}, {1, 1}]; Subscript[ℛ, 2] = HalfPlane[{1, 1}, {1, -1}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion can represent any HalfSpace in :

Wolfram Language code: p = {1};n = {-1}; eqns = n.{x} ≤ n.p
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = ImplicitRegion[eqns, {x}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

In :

Wolfram Language code: p = {1, 1};n = {-1, 1}; eqns = n.{x, y} ≤ n.p
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = ImplicitRegion[eqns, {x, y}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

In :

Wolfram Language code: p = {5, 4, 3, 2, 1};n = {1, 2, 3, 2, 1}; eqns = n.{x1, x2, x3, x4, x5} ≤ n.p
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = ImplicitRegion[eqns, {x1, x2, x3, x4, x5}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion can represent any HalfSpace in :

Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[{-1}, {1}]; Subscript[ℛ, 2] = ParametricRegion[{a}, {{a, 1, Infinity}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

In :

Wolfram Language code: p = {1, 1};n = {-1, 1}; {v} = NullSpace[{n}];
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = ParametricRegion[{1, 1} - a n + b v, {{a, 0, Infinity}, b}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

In :

Wolfram Language code: p = {5, 4, 3, 2, 1};n = {1, 2, 3, 2, 1}; {v1, v2, v3, v4} = NullSpace[{n}];
Wolfram Language code: Subscript[ℛ, 1] = HalfSpace[n, p]; Subscript[ℛ, 2] = ParametricRegion[p - a n + b v1 + c v2 + d v3 + e v4, {{a, 0, Infinity}, b, c, d, e}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (1)

A collection of random half-spaces in :

Wolfram Language code: Table[Graphics[{EdgeForm[Black], {RandomColor[], HalfSpace[RandomReal[{-1, 1}, 2], RandomReal[]]}}, ImageSize -> 30, Frame -> True, FrameTicks -> False], {30}]

In :

Wolfram Language code: Table[Graphics3D[{EdgeForm[Black], {RandomColor[], HalfSpace[RandomReal[{-1, 1}, 3], RandomReal[]]}}, ImageSize -> 30, Boxed -> True, Ticks -> False], {20}]
Wolfram Research (2015), HalfSpace, Wolfram Language function, https://reference.wolfram.com/language/ref/HalfSpace.html.

Text

Wolfram Research (2015), HalfSpace, Wolfram Language function, https://reference.wolfram.com/language/ref/HalfSpace.html.

CMS

Wolfram Language. 2015. "HalfSpace." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HalfSpace.html.

APA

Wolfram Language. (2015). HalfSpace. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HalfSpace.html

BibTeX

@misc{reference.wolfram_2026_halfspace, author="Wolfram Research", title="{HalfSpace}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/HalfSpace.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_halfspace, organization={Wolfram Research}, title={HalfSpace}, year={2015}, url={https://reference.wolfram.com/language/ref/HalfSpace.html}, note=[Accessed: 12-June-2026]}