WOLFRAM

Wolfram Language & System Documentation Center

HatchFilling[]

is a two-dimensional graphics directive that specifies that faces of polygons and other filled graphics objects are to be drawn using closely spaced parallel lines.

HatchFilling["name"]

uses the specified line hatching "name".

HatchFilling[θ]

draws parallel lines with an angle θ.

HatchFilling[θ,r]

draws parallel lines with absolute thickness r.

HatchFilling[θ,r,d]

draws parallel lines with gaps of absolute thickness d.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Specification  
Applications  
Technical Drawing  
Design Patterns  
Visualization  
Neat Examples  
See Also
Related Guides
History
Cite this Page

HatchFilling

HatchFilling[]

is a two-dimensional graphics directive that specifies that faces of polygons and other filled graphics objects are to be drawn using closely spaced parallel lines.

HatchFilling["name"]

uses the specified line hatching "name".

HatchFilling[θ]

draws parallel lines with an angle θ.

HatchFilling[θ,r]

draws parallel lines with absolute thickness r.

HatchFilling[θ,r,d]

draws parallel lines with gaps of absolute thickness d.

Details

  • HatchFilling is also known as hatch or striped pattern.
  • HatchFilling is typically used to fill two‐dimensional polygons and areas with stripes.
  • Possible line hatching includes:
  • "Diagonal"diagonal lines
    "Horizontal"horizontal lines
    "Vertical"vertical lines
  • HatchFilling[θ,r,d] specifies that faces of filled graphics objects are to be drawn using parallel lines with an angle θ from the horizontal, a thickness r and distance d.
  • HatchFilling[] is effectively equivalent to HatchFilling[Pi/4].

Examples

open all close all

Basic Examples  (3)

Apply a hatch filling to a disk:

Wolfram Language code: Graphics[{HatchFilling[], Disk[]}]

Fill from a curve to the axis:

Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, Filling -> Axis, FillingStyle -> HatchFilling[]]

Plot the US with hatch filling:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", HatchFilling[]], Polygon[["United States"]]}]

Scope  (13)

Basic Uses  (7)

Apply hatch filling to graphics primitives:

Wolfram Language code: Graphics[{HatchFilling[], #}]& /@ {Triangle[], Disk[], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

Apply hatch filling to a plot:

Wolfram Language code: Plot[2Sin[x] + x, {x, 0, 15}, Filling -> Bottom, FillingStyle -> HatchFilling[Pi / 2]]

Apply hatch filling to a chart:

Wolfram Language code: BarChart[{1, 2, 3, 4}, ChartStyle -> (HatchFilling /@ RandomReal[{0, Pi / 2}, 4])]

Style a geometric region:

Wolfram Language code: Region[Style[ImplicitRegion[y^2 < x (-1 + x^3), {x, y}], HatchFilling[]]]

Apply hatch filling to an Image:

Wolfram Language code: Graphics[{HatchFilling[Pi / 4, 2], [image]}]

Show a schematic outline map:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", HatchFilling[]], Polygon[["austria"]]}]

Summary box:

Wolfram Language code: HatchFilling[0]

Specification  (6)

HatchFilling with no arguments draws parallel lines in a angle:

Wolfram Language code: Graphics[{HatchFilling[], Rectangle[]}]

Draw parallel lines at an angle θ in radians:

Wolfram Language code: Graphics[{HatchFilling[Pi / 2], Rectangle[]}]

Specify the angle in degrees:

Wolfram Language code: Graphics[{HatchFilling[90 Degree], Rectangle[]}]

Draw parallel lines with varying thickness:

Wolfram Language code: Table[Graphics[{HatchFilling[Pi / 4, r], Rectangle[]}], {r, 0.4, 4, 1}]

Draw parallel lines with varying spacing:

Wolfram Language code: Table[Graphics[{HatchFilling[Pi / 2, 0, d], EdgeForm[StandardGray], Rectangle[]}], {d, 10, 40, 10}]

Use a custom color:

Wolfram Language code: Graphics[{Red, HatchFilling[], Rectangle[]}]

Use predefined horizontal lines:

Wolfram Language code: Graphics[{HatchFilling["Horizontal"], Rectangle[]}]

Diagonal lines:

Wolfram Language code: Graphics[{HatchFilling["Diagonal"], Rectangle[]}]

Vertical lines:

Wolfram Language code: Graphics[{HatchFilling["Vertical"], Rectangle[]}]

Applications  (6)

Technical Drawing  (3)

Hatch patterns:

Wolfram Language code: Row[Table[Graphics[{HatchFilling[Pi / 4, .35, d], EdgeForm[{StandardGray, Thick}], Rectangle[{0, 0}, RoundingRadius -> .1]}], {d, 5, 20, 3}], Spacer[20]]
Wolfram Language code: Row[Table[Graphics[{HatchFilling[-Pi / 4, .35, d], EdgeForm[{StandardGray, Thick}], Rectangle[{0, 0}, RoundingRadius -> .1]}], {d, 5, 20, 3}], Spacer[20]]

Cross-hatching patterns:

Wolfram Language code: Row[Table[Graphics[{HatchFilling[Pi / 4, .3, d], EdgeForm[{StandardGray, Thick}], Rectangle[{0, 0}, RoundingRadius -> .1], HatchFilling[-Pi / 4, .3, d], Rectangle[{0, 0}, RoundingRadius -> .1]}], {d, 5, 20, 3}], Spacer[20]]

A mechanical drawing:

Wolfram Language code: Graphics[{EdgeForm[{StandardGray, Thick}], {HatchFilling[], Rectangle[]}, {FaceForm[StandardOrange], Rectangle[{1, 0}]}, {HatchFilling[], Rectangle[{2, 0}]}, ...}]

Design Patterns  (2)

Embossed line patterns:

Wolfram Language code: Graphics[{Blue, HatchFilling["Diagonal", 2, 7], Rectangle[{-12, -12}, {12, 7}], Red, HatchFilling["Diagonal", 5, 7], GraphicsComplex[...]}]

Vector repeat patterns:

Wolfram Language code: stripes[shape_, parms__] := {HatchFilling[Pi / 4, Sequence @@ #], shape} & /@ {parms}
Wolfram Language code: Graphics[stripes[Disk[], {1.5}]]
Wolfram Language code: Graphics[stripes[Disk[], {30, 40}]]
Wolfram Language code: Graphics[{stripes[Disk[], {1.5, 20}, {2, 30}]}]
Wolfram Language code: Graphics[stripes[Disk[], {1.5, 20}, {2, 30}, {4, 50}]]

Visualization  (1)

Plot a confidence interval:

Wolfram Language code: pdf = PDF[NormalDistribution[2, 1], x];
Wolfram Language code: Show[{Plot[pdf, {x, -1, 1}], Plot[pdf, {x, 1, 3}, Filling -> 0, FillingStyle -> HatchFilling[]], Plot[pdf, {x, 3, 5}]}, PlotRange -> {0, .4}]

Neat Examples  (1)

Use hatch filling to draw African countries:

Wolfram Language code: countries = EntityValue[["Africa"], "Entity"];
Wolfram Language code: styles = Directive[StandardGray, HatchFilling[#]] & /@ RandomReal[{0, Pi / 2}, Length[countries]];

Show a map:

Wolfram Language code: GeoGraphics[{GeoStyling[None], #2, EdgeForm[{Thin, StandardGray}], Polygon[#1]}&@@@ Thread[{countries, styles}], GeoBackground -> None]

Show a map with boundaries:

Wolfram Language code: GeoGraphics[{GeoStyling[None], #2, EdgeForm[None], Polygon[#1]}&@@@Thread[{countries, styles}], GeoBackground -> None]
Wolfram Research (2020), HatchFilling, Wolfram Language function, https://reference.wolfram.com/language/ref/HatchFilling.html.

Text

Wolfram Research (2020), HatchFilling, Wolfram Language function, https://reference.wolfram.com/language/ref/HatchFilling.html.

CMS

Wolfram Language. 2020. "HatchFilling." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HatchFilling.html.

APA

Wolfram Language. (2020). HatchFilling. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HatchFilling.html

BibTeX

@misc{reference.wolfram_2026_hatchfilling, author="Wolfram Research", title="{HatchFilling}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HatchFilling.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hatchfilling, organization={Wolfram Research}, title={HatchFilling}, year={2020}, url={https://reference.wolfram.com/language/ref/HatchFilling.html}, note=[Accessed: 13-June-2026]}