WOLFRAM

Wolfram Language & System Documentation Center

HeatTemperatureCondition[pred,vars,pars]

represents a thermal surface boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

HeatTemperatureCondition[pred,vars,pars,lkey]

represents a thermal surface boundary condition with local parameters specified in pars[lkey].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
1D  
3D  
Applications  
See Also
Tech Notes
Related Guides
History
Cite this Page

HeatTemperatureCondition

HeatTemperatureCondition[pred,vars,pars]

represents a thermal surface boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

HeatTemperatureCondition[pred,vars,pars,lkey]

represents a thermal surface boundary condition with local parameters specified in pars[lkey].

Details

Examples

open all close all

Basic Examples  (1)

Set up a thermal surface boundary condition:

Wolfram Language code: HeatTemperatureCondition[x ≥ 0, {Θ[t, x, y], t, {x, y}}, <|"SurfaceTemperature" -> Subscript[Θ, s][t, x, y]|>]

Scope  (4)

Basic Uses  (2)

Define model variables vars for a transient temperature field with model parameters pars and a specific boundary condition parameter:

Wolfram Language code: vars = {Θ[t, x, y], t, {x, y}}; pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "BoundaryCondition1" -> <|"SurfaceTemperature" -> T1|>|>; HeatTemperatureCondition[x == 1, vars, pars, "BoundaryCondition1"]

Define model variables vars for a transient temperature field with model parameters pars and multiple specific parameter boundary conditions:

Wolfram Language code: vars = {Θ[t, x, y], t, {x, y}}; pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "BoundaryCondition1" -> <|<|"SurfaceTemperature" -> T1|>|>, "BoundaryCondition2" -> <|<|"SurfaceTemperature" -> T2|>|>|>;
Wolfram Language code: HeatTemperatureCondition[x == 0, vars, pars, "BoundaryCondition1"]
Wolfram Language code: HeatTemperatureCondition[x == 1, vars, pars, "BoundaryCondition2"]

1D  (1)

Model a temperature field with two heat conditions at the sides:

del .(-k del Theta(x))^(︷^( heat transfer model)) =0

Set up the heat transfer model variables vars:

Wolfram Language code: vars = {Θ[x], {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1}}];

Specify the heat transfer model parameter thermal conductivity :

Wolfram Language code: pars = <|"ThermalConductivity" -> 0.026|>;

Specify the heat surface conditions:

Wolfram Language code: heatConditons = {HeatTemperatureCondition[x == 0, vars, pars, <|"SurfaceTemperature" -> 0|>], HeatTemperatureCondition[x == 1, vars, pars, <|"SurfaceTemperature" -> 1|>]};

Set up the equation:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, heatConditons}, Θ, x∈Ω];

Visualize the solution:

Wolfram Language code: Plot[Tfun[x], {x}∈Ω]

3D  (1)

Model a temperature field with two heat conditions at the sides and an orthotropic thermal conductivity :

del .(-k del Theta(x,y,z))^(︷^( heat transfer model)) =0

Set up the heat transfer model variables vars:

Wolfram Language code: vars = {Θ[x, y, z], {x, y, z}};

Set up a region :

Wolfram Language code: Ω = Cuboid[];

Specify an orthotropic thermal conductivity :

Wolfram Language code: pars = <|"ThermalConductivity" -> {{1, 0, 0}, {0, 5, 0}, {0, 0, 10}}|>;

Specify the heat surface conditions:

Wolfram Language code: heatConditons = {HeatTemperatureCondition[x ≤ 1 / 4, vars, pars, <|"SurfaceTemperature" -> 0|>], HeatTemperatureCondition[x ≥ 3 / 4, vars, pars, <|"SurfaceTemperature" -> 1|>]};

Set up the equation with a thermal heat flux of applied at the left end for the first 300 seconds:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, heatConditons}, Θ, {x, y, z}∈Ω];

Visualize the solution:

Wolfram Language code: SliceContourPlot3D[Tfun[x, y, z], {"XStackedPlanes", "YStackedPlanes", "ZStackedPlanes"}, {x, y, z}∈Ω]

Applications  (1)

Compute the temperature field with model variables vars and parameters pars with a thermal surface of at the left boundary:

Wolfram Language code: vars = {Θ[t, x], t, {x}}; pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "SurfaceTemperature" -> Sin[π t / 300]|>;

Set up the equation:

Wolfram Language code: eqn = {HeatTransferPDEComponent[vars, pars] == 0, HeatTemperatureCondition[x == 0, vars, pars]};

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, Θ[0, x] == 0}, Θ, {t, 0, 600}, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution and note the sinusoidal temperature change on the left:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x, 0, 1 / 5}, ...], {{t, 320}, 0, 600, 20}, Rule[...]]
Wolfram Research (2020), HeatTemperatureCondition, Wolfram Language function, https://reference.wolfram.com/language/ref/HeatTemperatureCondition.html.

Text

Wolfram Research (2020), HeatTemperatureCondition, Wolfram Language function, https://reference.wolfram.com/language/ref/HeatTemperatureCondition.html.

CMS

Wolfram Language. 2020. "HeatTemperatureCondition." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeatTemperatureCondition.html.

APA

Wolfram Language. (2020). HeatTemperatureCondition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeatTemperatureCondition.html

BibTeX

@misc{reference.wolfram_2026_heattemperaturecondition, author="Wolfram Research", title="{HeatTemperatureCondition}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeatTemperatureCondition.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heattemperaturecondition, organization={Wolfram Research}, title={HeatTemperatureCondition}, year={2020}, url={https://reference.wolfram.com/language/ref/HeatTemperatureCondition.html}, note=[Accessed: 12-June-2026]}