WOLFRAM

Wolfram Language & System Documentation Center

HeatTransferValue[pred,vars,pars]

represents a thermal transfer boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

HeatTransferValue[pred,vars,pars,lkey]

represents a thermal transfer boundary condition with local parameters specified in pars[lkey].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
2D  
Coupled Equations  
See Also
Tech Notes
Related Guides
History
Cite this Page

HeatTransferValue

HeatTransferValue[pred,vars,pars]

represents a thermal transfer boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

HeatTransferValue[pred,vars,pars,lkey]

represents a thermal transfer boundary condition with local parameters specified in pars[lkey].

Details

  • HeatTransferValue specifies a boundary condition for HeatTransferPDEComponent and is used as part of the modeling equation:
  • HeatTransferValue is typically used to model the effect of a cooling or heating flow outside the simulation domain. Common examples include a heat sink.
  • HeatTransferValue models thermal energy transferred across a boundary with dependent variable temperature [TemplateBox[{InterpretationBox[, 1], "K", kelvins, "Kelvins"}, QuantityTF]], independent variables in [TemplateBox[{InterpretationBox[, 1], "m", meters, "Meters"}, QuantityTF]] and time variable in [TemplateBox[{InterpretationBox[, 1], "s", seconds, "Seconds"}, QuantityTF]].
  • Stationary variables vars are vars={Θ[x1,…,xn],{x1,…,xn}}.
  • Time-dependent variables vars are vars={Θ[t,x1,…,xn],t,{x1,…,xn}}.
  • The non-conservative time-dependent heat transfer model HeatTransferPDEComponent is based on a convection-diffusion model with mass density , specific heat capacity , thermal conductivity , convection velocity vector and heat source :
  • The heat transfer value HeatTransferValue with heat transfer coefficient in units of [TemplateBox[{InterpretationBox[, 1], {"W", , "/(", , {"m", ^, 2}, , "K", , ")"}, watts per meter squared kelvin, {{(, "Watts", )}, /, {(, {{"Meters", ^, 2}, , "Kelvins"}, )}}}, QuantityTF]] and external temperature [TemplateBox[{InterpretationBox[, 1], "K", kelvins, "Kelvins"}, QuantityTF]] and boundary unit normal models:
  • Model parameters pars as specified for HeatTransferPDEComponent.
  • The following additional model parameters pars can be given:
  • parameterdefaultsymbol
    "AmbientTemperature"0, ambient temperature [TemplateBox[{InterpretationBox[, 1], "K", kelvins, "Kelvins"}, QuantityTF]]
    "HeatTransferCoefficient", heat transfer coefficient [TemplateBox[{InterpretationBox[, 1], {"W", , "/(", , {"m", ^, 2}, , "K", , ")"}, watts per meter squared kelvin, {{(, "Watts", )}, /, {(, {{"Meters", ^, 2}, , "Kelvins"}, )}}}, QuantityTF]]
  • To localize model parameters, a key lkey can be specified, and values from association pars[lkey] are used for model parameters.
  • All model parameters may depend on any of , and , as well as other dependent variables.
  • HeatTransferValue is a special case of HeatFluxValue.
  • HeatTransferValue evaluates to a generalized NeumannValue.
  • The boundary predicate pred can be specified as in NeumannValue.
  • If the HeatTransferValue depends on parameters that are specified in the association pars as …,keypi…,pivi,…, the parameters are replaced with .

Examples

open all close all

Basic Examples  (2)

Set up a thermal convection boundary condition:

Wolfram Language code: HeatTransferValue[x ≥ 0, {Θ[t, x, y], t, {x}}, <|"AmbientTemperature" -> Subscript[Θ, ext][t, x, y], "HeatTransferCoefficient" -> h|>]

Model a temperature field with heat transfer boundary:

rho C_p(partialTheta(t, x))/(partialt)+del .(-k del Theta(t,x))^(︷^( heat transfer model )) =|_(Gamma_(x=0))h (Theta_(ext)(t,x)-Theta(t,x))^(︷^( heat transfer boundary ))

Set up the heat transfer model variables vars:

Wolfram Language code: vars = {Θ[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1 / 5}}];

Specify heat transfer model parameters mass density , specific heat capacity and thermal conductivity :

Wolfram Language code: pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "ReferenceTemperature" -> -273.15|>;

Specify boundary condition parameters with an external flow temperature of 10 °C and a heat transfer coefficient of :

Wolfram Language code: pars["BC1"] = <|"HeatTransferCoefficient" -> 5, "AmbientTemperature" -> 10|>;

Specify the equation:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == HeatTransferValue[x == 0, vars, pars, "BC1"]

Set up initial conditions:

Wolfram Language code: ics = Θ[0, x] == 0;

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, ics}, Θ, {t, 0, 600}, x∈Ω];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x}∈Ω, ...], {{t, 160}, 0, 600, 20}, Rule[...]]

Scope  (4)

Basic Uses  (2)

Define model variables vars for a transient acoustic pressure field with model parameters pars and a specific boundary condition parameter:

Wolfram Language code: vars = {Θ[t, x, y], t, {x, y}}; pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "BoundaryCondition1" -> <|"AmbientTemperature" -> T1, "HeatTransferCoefficient" -> h1|>|>; HeatTransferValue[x == 1, vars, pars, "BoundaryCondition1"]

Define model variables vars for a transient acoustic pressure field with model parameters pars and multiple specific parameter boundary conditions:

Wolfram Language code: vars = {Θ[t, x, y], t, {x, y}}; pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "BoundaryCondition1" -> <|"AmbientTemperature" -> T1, "HeatTransferCoefficient" -> h1|>, "BoundaryCondition2" -> <|"AmbientTemperature" -> T2, "HeatTransferCoefficient" -> h2|>|>;

Make use of "BoundaryCondition1":

Wolfram Language code: HeatTransferValue[x == 0, vars, pars, "BoundaryCondition1"]

Make use of "BoundaryCondition2":

Wolfram Language code: HeatTransferValue[x == 1, vars, pars, "BoundaryCondition2"]

2D  (1)

Model a ceramic strip that is embedded in a high-thermal-conductive material. The side boundaries of the strip are maintained at a constant temperature . The top surface of the strip is losing heat via both heat convection and heat radiation to the ambient environment at . The bottom boundary, however, is assumed to be thermally insulated:

Model a temperature field and the thermal radiation and thermal transfer with:

del .(-k del Theta(x,y))^(︷^( heat transfer model )) =|_(Gamma_(x=0))epsilon k_B ((Theta_(amb)-Theta_(ref))^4-(Theta(x,y)-Theta_(ref))^( 4))^(︷^( heat radiation boundary ))+|_(Gamma_(x=0))h (Theta_(ext)(x,y)-Theta(x,y))^(︷^( heat transfer boundary ))

Set up the heat transfer model variables vars:

Wolfram Language code: vars = {Θ[x, y], {x, y}};

Set up a rectangular domain with a width of and a height of :

Wolfram Language code: Ω = Rectangle[{0, 0}, {0.02, 0.01}];

Specify thermal conductivity :

Wolfram Language code: pars = <|"ThermalConductivity" -> 3|>;

Set up temperature surface boundary conditions at the left and right boundaries:

Wolfram Language code: Subscript[Γ, temp] = HeatTemperatureCondition[x == 0 || x == 0.02, vars, pars, <|"SurfaceTemperature" -> 1173|>]

Set up a heat transfer boundary condition on the top surface:

Wolfram Language code: Subscript[Γ, convective] = HeatTransferValue[y == 0.01, vars, pars, <|"AmbientTemperature" -> 323, "HeatTransferCoefficient" -> 50|>]

Also set up a thermal radiation boundary condition on the top surface:

Wolfram Language code: Subscript[Γ, radiation] = HeatRadiationValue[y == 0.01, vars, pars, <|"AmbientTemperature" -> 323.|>]

Set up the equation:

Wolfram Language code: eqn = {HeatTransferPDEComponent[vars, pars] == Subscript[Γ, convective] + Subscript[Γ, radiation], Subscript[Γ, temp]}

Solve the PDE:

Wolfram Language code: Θfun = NDSolveValue[eqn, Θ, {x, y}∈Ω];

Visualize the solution:

Wolfram Language code: Legended[ContourPlot[Θfun[x, y], {x, y}∈Ω, ...], BarLegend[...]]

Coupled Equations  (1)

Solve a coupled heat transfer and mass transport model with a thermal transfer value and a mass flux value on the boundary:

(partialTheta(t, x))/(partialt)+del .(-k del Theta(t,x))-Q^(︷^( heat transfer model )) = |_(Gamma_(x=1))h (Theta_(ext)(t,x)-Theta(t,x))^(︷^( heat transfer boundary )); (partialc(t,x))/(partialt)+del .(-d del c(t,x))-R^(︷^( mass transport model )) = |_(Gamma_(x=0||x=1))q (t,x)^(︷^( mass flux boundary ))

Set up the heat transfer mass transport model variables vars:

Wolfram Language code: hvars = {Θ[t, x], t, {x}}; mvars = {c[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1}}];

Specify heat transfer and mass transport model parameters, heat source , thermal conductivity , mass diffusivity and mass source :

Wolfram Language code: pars = <|"ThermalConductivity" -> 0.01, "HeatSource" -> 0.2 * R, "DiffusionCoefficient" -> 0.01, "MassSource" -> R, R -> -10 ^ -3 * Θ[t, x] * c[t, x]|>;

Specify boundary condition parameters for a thermal convection value with an external flow temperature of 1000 K and a heat transfer coefficient of :

Wolfram Language code: pars["BC1"] = <|"AmbientTemperature" -> 1000, "HeatTransferCoefficient" -> 0.1|>;

Specify the equation:

Wolfram Language code: eqn = {HeatTransferPDEComponent[hvars, pars] == HeatTransferValue[x == 1, hvars, pars, "BC1"], MassTransportPDEComponent[mvars, pars] == NeumannValue[20, x == 0 || x == 1]}

Set up initial conditions:

Wolfram Language code: ics = {Θ[0, x] == 200 + 800x, c[0, x] == 800};

Solve the model:

Wolfram Language code: {Tfun, cfun} = NDSolveValue[{eqn, ics}, {Θ, c}, {t, 0, 10}, {x, 0, 1}];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[{cfun[t, x], Tfun[t, x]}, {x}∈Ω, ...], {{t, 1.7}, 0, 10}, Rule[...]]
Wolfram Research (2020), HeatTransferValue, Wolfram Language function, https://reference.wolfram.com/language/ref/HeatTransferValue.html.

Text

Wolfram Research (2020), HeatTransferValue, Wolfram Language function, https://reference.wolfram.com/language/ref/HeatTransferValue.html.

CMS

Wolfram Language. 2020. "HeatTransferValue." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeatTransferValue.html.

APA

Wolfram Language. (2020). HeatTransferValue. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeatTransferValue.html

BibTeX

@misc{reference.wolfram_2026_heattransfervalue, author="Wolfram Research", title="{HeatTransferValue}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeatTransferValue.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heattransfervalue, organization={Wolfram Research}, title={HeatTransferValue}, year={2020}, url={https://reference.wolfram.com/language/ref/HeatTransferValue.html}, note=[Accessed: 12-June-2026]}