Wolfram Language & System Documentation Center

HeatTransferPDEComponent

HeatTransferPDEComponent[vars,pars]

yields a heat transfer PDE term with variables vars and parameters pars.

Details

HeatTransferPDEComponent returns a sum of differential operators to be used as a part of partial differential equations:

HeatTransferPDEComponent models the generation and propagation of thermal energy in physical systems by mechanisms such as convection, conduction and radiation.

HeatTransferPDEComponent models heat transfer phenomena with dependent variable temperature in [], independent variables in [] and time variable in [].
Stationary variables vars are vars={Θ[x₁,…,x_n],{x₁,…,x_n}}.
Time-dependent variables vars are vars={Θ[t,x₁,…,x_n],t,{x₁,…,x_n}}.
The non-conservative time-dependent heat transfer model HeatTransferPDEComponent is based on a convection-diffusion model with mass density , specific heat capacity , thermal conductivity , convection velocity vector and heat source :

The non-conservative stationary heat transfer PDE term is given by:

The implicit default boundary condition for the non-conservative model is a HeatOutflowValue.
The difference between the non-conservative model and the conservative model is the treatment of a convection velocity .
The units of the heat transfer model terms are in [ $TemplateBox[{InterpretationBox[, 1], {"W", , "/", , {"m", ^, 3}}, watts per meter cubed, {{(, "Watts", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ], or equivalently in [ $TemplateBox[{InterpretationBox[, 1], {"J", , "/(", , {"m", ^, 3}, , "s", , ")"}, joules per meter cubed second, {{(, "Joules", )}, /, {(, {{"Meters", ^, 3}, , "Seconds"}, )}}}, QuantityTF]$ ].
The following parameters pars can be given:

parameter	default	symbol
"HeatConvectionVelocity"	{0,…}	, flow velocity []
"HeatSource"	0	, heat source [ $TemplateBox[{InterpretationBox[, 1], {"W", , "/", , {"m", ^, 3}}, watts per meter cubed, {{(, "Watts", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]
"MassDensity"	1	, density [ $TemplateBox[{InterpretationBox[, 1], {"kg", , "/", , {"m", ^, 3}}, kilograms per meter cubed, {{(, "Kilograms", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]
"Material"	Automatic
"ModelForm"	"NonConservative"	none
"RegionSymmetry"	None
"SpecificHeatCapacity"	1	, specific heat capacity []
"ThermalConductivity"	IdentityMatrix	, thermal conductivity [

parameter	default	symbol
"CrossSectionalArea"	1	, cross-sectional area in [ $TemplateBox[{InterpretationBox[, 1], {{"m", ^, 2}}, meters squared, {"Meters", ^, 2}}, QuantityTF]$ ]
"HeatConvectionVelocity"	{0,…}	, flow velocity []
"HeatSource"	0	, heat source [ $TemplateBox[{InterpretationBox[, 1], {"W", , "/", , {"m", ^, 3}}, watts per meter cubed, {{(, "Watts", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]
"MassDensity"	1	, density [ $TemplateBox[{InterpretationBox[, 1], {"kg", , "/", , {"m", ^, 3}}, kilograms per meter cubed, {{(, "Kilograms", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]
"Material"	Automatic
"ModelForm"	"NonConservative"	none
"RegionSymmetry"	None
"Thickness"	1	, thickness in []
"SpecificHeatCapacity"	1	, specific heat capacity []
"ThermalConductivity"	IdentityMatrix	, thermal conductivity [

All parameters may depend on any of , and , as well as other dependent variables.
The number of independent variables determines the dimensions of and the length of .
Sometimes the heat equation is specified with a thermal diffusivity. The thermal diffusivity is the thermal conductivity divided by the density and the specific heat capacity at constant pressure.
The thermal convection velocity specifies the velocity with which a fluid transports heat. If no fluid is present, the thermal convection velocity is 0.
A heat source models thermal energy that is introduced (positive) or removed (negative) from the system.
A possible choice for the parameter "RegionSymmetry" is "Axisymmetric".
"Axisymmetric" region symmetry represents a truncated cylindrical coordinate system where the cylindrical coordinates are reduced by removing the angle variable as follows:
dimension reduction equation

1D

2D
The input specification for the parameters is exactly the same as for their corresponding operator terms.
Coupled equations can be generated with the same input specification as with the corresponding operator terms.
If no parameters are specified, the default heat transfer PDE is:

If the HeatTransferPDEComponent depends on parameters that are specified in the association pars as …,keyp_i…,p_iv_i,…, the parameters are replaced with .

Examples

open all close all

Basic Examples (3)

Define a time-independent heat transfer model:

Wolfram Language code: HeatTransferPDEComponent[{Θ[x], {x}}, <||>]

Define a time-dependent heat transfer model:

Wolfram Language code: HeatTransferPDEComponent[{Θ[t, x], t, {x}}, <||>]

Set up a time-dependent heat transfer model with particular material parameters:

Wolfram Language code:

HeatTransferPDEComponent[{Θ[t, x], t, {x}}, <|"MassDensity" -> ρ, "SpecificHeatCapacity" -> Subscript[C, p], "ThermalConductivity" -> {{κ}}|>]

Scope (10)

Basic Uses (5)

Set up a time-dependent heat transfer model for a particular material:

Wolfram Language code: HeatTransferPDEComponent[{Θ[t, x], t, {x}}, <|"Material" -> ["Tungston"]|>]

Set up a time-dependent heat transfer model for several material regions:

Wolfram Language code:

HeatTransferPDEComponent[{Θ[t, x, y], t, {x, y}}, <|"Material" -> {{y ≤ 1, ["Tungston"]}, {y > 1, ["Titanium"]}}|>]

Add a "Thickness" parameter:

Wolfram Language code:

vars = {Θ[x, y], {x, y}};
pars = <|"Thickness" -> d, "ThermalConductivity" -> k, "HeatSource" -> Q, "HeatConvectionVelocity" -> {vx, vy}|>;
HeatTransferPDEComponent[vars, pars]

Add a "CrossSectionalArea" parameter for a 1D model:

Wolfram Language code:

vars = {Θ[x], {x}};
pars = <|"CrossSectionalArea" -> A, "ThermalConductivity" -> k, "HeatSource" -> Q, "HeatConvectionVelocity" -> {vx}|>;
HeatTransferPDEComponent[vars, pars]

Add a "Thickness" parameter for a 1D axisymmetric region model:

Wolfram Language code:

vars = {Θ[r], {r}};
pars = <|"Thickness" -> d, "RegionSymmetry" -> "Axisymmetric", "ThermalConductivity" -> k, "HeatSource" -> Q, "HeatConvectionVelocity" -> {vr}|>;
HeatTransferPDEComponent[vars, pars]

1D (1)

Model a temperature field with two heat conditions at the sides:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[x], {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1}}];

Specify heat transfer model parameter thermal conductivity :

Wolfram Language code: pars = <|"ThermalConductivity" -> 0.026|>;

Specify heat surface conditions:

Wolfram Language code:

Subscript[Γ, Θ] = {HeatTemperatureCondition[x == 0, vars, pars, <|"SurfaceTemperature" -> 0|>], HeatTemperatureCondition[x == 1, vars, pars, <|"SurfaceTemperature" -> 1|>]}

Set up the equation:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, Subscript[Γ, Θ]}, Θ, x∈Ω];

Visualize the solution:

Wolfram Language code: Plot[Tfun[x], {x}∈Ω]

2D (1)

Model a ceramic strip that is embedded in a high-thermal-conductive material. The side boundaries of the strip are maintained at a constant temperature . The top surface of the strip is losing heat via both heat convection and heat radiation to the ambient environment at . The bottom boundary is assumed to be thermally insulated:

Model a temperature field and the thermal radiation and thermal transfer with:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[x, y], {x, y}};

Set up a rectangular domain with a width of and a height of :

Wolfram Language code: Ω = Rectangle[{0, 0}, {0.02, 0.01}];

Specify thermal conductivity :

Wolfram Language code: pars = <|"ThermalConductivity" -> 3|>;

Set up temperature surface boundary conditions at the left and right boundaries:

Wolfram Language code: Subscript[Γ, temp] = HeatTemperatureCondition[x == 0 || x == 0.02, vars, pars, <|"SurfaceTemperature" -> 1173|>]

Set up a heat transfer boundary condition on the top surface:

Wolfram Language code:

Subscript[Γ, convective] = HeatTransferValue[y == 0.01, vars, pars, <|"AmbientTemperature" -> 323, "HeatTransferCoefficient" -> 50|>]

Also set up a thermal radiation boundary condition on the top surface:

Wolfram Language code: Subscript[Γ, radiation] = HeatRadiationValue[y == 0.01, vars, pars, <|"AmbientTemperature" -> 323.|>]

Set up the equation:

Wolfram Language code:

eqn = {HeatTransferPDEComponent[vars, pars] == Subscript[Γ, convective] + Subscript[Γ, radiation], Subscript[Γ, temp]}

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[eqn, Θ, {x, y}∈Ω];

Visualize the solution:

Wolfram Language code: Legended[ContourPlot[Tfun[x, y], {x, y}∈Ω, ...], BarLegend[...]]

3D (1)

Model a temperature field with two heat conditions at the sides and an orthotropic thermal conductivity :

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[x, y, z], {x, y, z}};

Set up a region :

Wolfram Language code: Ω = Cuboid[];

Specify an orthotropic thermal conductivity :

Wolfram Language code: pars = <|"ThermalConductivity" -> {{1, 0, 0}, {0, 5, 0}, {0, 0, 10}}|>;

Specify heat surface conditions:

Wolfram Language code:

heatConditions = {HeatTemperatureCondition[x ≤ 1 / 4, vars, pars, <|"SurfaceTemperature" -> 0|>], HeatTemperatureCondition[x ≥ 3 / 4, vars, pars, <|"SurfaceTemperature" -> 1|>]}

Set up the equation with a thermal heat flux of applied at the left end for the first 300 seconds:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, heatConditions}, Θ, {x, y, z}∈Ω];

Visualize the solution:

Wolfram Language code: SliceContourPlot3D[Tfun[x, y, z], {...}, {x, y, z}∈Ω]

Time Dependent (1)

Model a temperature field and a thermal heat flux through part of the boundary with:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1 / 5}}];

Specify heat transfer model parameters mass density , specific heat capacity and thermal conductivity :

Wolfram Language code: pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026|>;

Specify a thermal heat flux of applied at the left end for the first 300 seconds:

Wolfram Language code: pars["HeatFlux"] = Piecewise[{{3, t ≤ 300}, {0, t > 300}}];

Set up initial conditions:

Wolfram Language code: ics = Θ[0, x] == 0;

Set up the equation with a thermal heat flux of applied at the left end for the first 300 seconds:

Wolfram Language code:

eqn = HeatTransferPDEComponent[vars, pars] == 
	HeatFluxValue[x == 0, vars, pars]

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, ics}, Θ, {t, 0, 600}, x∈Ω];

Visualize the solution:

Wolfram Language code: Manipulate[Show[Plot[Tfun[t, x], {x, -0.06, 0.2}, ...], Graphics[...]], {{t, 160}, 0, 600, 20}, Rule[...]]

Time-Dependent Nonlinear (1)

Model a temperature field with a nonlinear heat conductivity term with:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1 / 5}}];

Specify heat transfer model parameters mass density , specific heat capacity and a nonlinear thermal conductivity :

Wolfram Language code:

pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> {{0.026 + 10 ^ -2Θ[t, x] }}|>;

Specify a thermal heat flux of applied at the left end for the first 300 seconds:

Wolfram Language code: pars["HeatFlux"] = Piecewise[{{3, t ≤ 300}, {0, t > 300}}];

Set up initial conditions:

Wolfram Language code: ics = Θ[0, x] == 0;

Set up the equation with a thermal heat flux of applied at the left end for the first 300 seconds:

Wolfram Language code:

eqn = HeatTransferPDEComponent[vars, pars] == 
	HeatFluxValue[x == 0, vars, pars]

Solve the PDE:

Wolfram Language code: TfunNonlinear = NDSolveValue[{eqn, ics}, Θ, {t, 0, 600}, x∈Ω];

Solve a linear version of the PDE:

Wolfram Language code:

parsLinear = pars;
parsLinear["ThermalConductivity"] = 0.026;
TfunLinear = NDSolveValue[{HeatTransferPDEComponent[vars, parsLinear] == 
	HeatFluxValue[x == 0, vars, parsLinear], ics}, Θ, {t, 0, 600}, x∈Ω];

Visualize the solutions:

Wolfram Language code:

Manipulate[Show[Plot[{TfunNonlinear[t, x], TfunLinear[t, x]}, {x, -0.06, 0.2}, ...], Graphics[...]], {{t, 200}, 0, 600, 20}, Rule[...]]

Applications (8)

Model a temperature field with a heat source in a rod:

Wolfram Language code:

vars = {Θ[x], {x}};
pars = <|"ThermalConductivity" -> 0.026, "HeatSource" -> 1|>;
Ω = Line[{{0}, {1}}];
eqn = HeatTransferPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, HeatTemperatureCondition[x == 0, vars, pars, <|"SurfaceTemperature" -> 0|>]}, Θ, x∈Ω];

Visualize the solution:

Wolfram Language code: Plot[Tfun[x], {x}∈Ω]

Boundary Conditions (5)

Compute the temperature field with model variables and parameters with a thermal surface of at the left boundary:

Wolfram Language code:

vars = {Θ[t, x], t, {x}};
pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "SurfaceTemperature" -> Sin[π t / 300]|>;

Set up the equation:

Wolfram Language code: eqn = {HeatTransferPDEComponent[vars, pars] == 0, HeatTemperatureCondition[x == 0, vars, pars]}

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, Θ[0, x] == 0}, Θ, {t, 0, 600}, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution and note the sinusoidal temperature change on the left:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x, 0, 1 / 5}, ...], {{t, 320}, 0, 600, 20}, Rule[...]]

Compute the temperature field with model variables parameters :

Wolfram Language code:

vars = {Θ[t, x], t, {x}};
pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "HeatConvectionVelocity" -> {0.01}|>;

Set up the equation with a thermal outflow boundary at the right end:

Wolfram Language code:

eqn = HeatTransferPDEComponent[vars, pars] == 
	HeatOutflowValue[x == 1 / 5, vars, pars]

Define the initial temperature field:

Wolfram Language code: ics = Θ[0, x] == D[0.2 Erf[(x - 0.1) / 0.025], x];

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, ics}, Θ, {t, 0, 15}, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution and note how the energy leaves the domain through the thermal outflow boundary on the right:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x, 0, 1 / 5}, ...], {{t, 8}, 0, 15, 1 / 2}, Rule[...]]

Model a temperature field and a thermal radiation boundary with:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1 / 5}}];

Specify heat transfer model parameters mass density , specific heat capacity and thermal conductivity :

Wolfram Language code:

pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "ReferenceTemperature" -> -273.15|>;

Specify boundary condition parameters with a constant ambient temperature of and a surface emissivity of :

Wolfram Language code: pars["BC1"] = <|"Emissivity" -> 0.2, "AmbientTemperature" -> -25|>;

Specify the equation:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == HeatRadiationValue[x == 0, vars, pars, "BC1"]

Set up initial conditions:

Wolfram Language code: ics = Θ[0, x] == 0;

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, ics}, Θ, {t, 0, 600}, x∈Ω];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x}∈Ω, ...], {{t, 180}, 0, 600, 20}, Rule[...]]

Model a temperature field with heat transfer boundary:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1 / 5}}];

Specify heat transfer model parameters mass density , specific heat capacity and thermal conductivity :

Wolfram Language code:

pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026, "ReferenceTemperature" -> -273.15|>;

Specify boundary condition parameters with an external flow temperature of and a heat transfer coefficient of :

Wolfram Language code: pars["BC1"] = <|"HeatTransferCoefficient" -> 5, "AmbientTemperature" -> 10|>;

Specify the equation:

Wolfram Language code: eqn = HeatTransferPDEComponent[vars, pars] == HeatTransferValue[x == 0, vars, pars, "BC1"]

Set up initial conditions:

Wolfram Language code: ics = Θ[0, x] == 0;

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, ics}, Θ, {t, 0, 600}, x∈Ω];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x}∈Ω, ...], {{t, 160}, 0, 600, 20}, Rule[...]]

Model a temperature field and a thermal insulation and a thermal heat flux boundary with:

Set up the heat transfer model variables :

Wolfram Language code: vars = {Θ[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1 / 5}}];

Specify heat transfer model parameters mass density , specific heat capacity and thermal conductivity :

Wolfram Language code: pars = <|"MassDensity" -> 1.2, "SpecificHeatCapacity" -> 1006.14, "ThermalConductivity" -> 0.026|>;

Specify boundary condition parameters for a heat flux of :

Wolfram Language code: pars["BC1"] = <|"HeatFlux" -> 3|>;

Specify the equation:

Wolfram Language code:

eqn = HeatTransferPDEComponent[vars, pars] == 
	HeatInsulationValue[x == 0, vars, pars] + HeatFluxValue[x == 1 / 5, vars, pars, "BC1"]

Set up initial conditions:

Wolfram Language code: ics = Θ[0, x] == 0;

Solve the PDE:

Wolfram Language code: Tfun = NDSolveValue[{eqn, ics}, Θ, {t, 0, 600}, x∈Ω];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[Tfun[t, x], {x}∈Ω, ...], {{t, 140}, 0, 600, 20}, Rule[...]]

Coupled Equations (2)

Solve a coupled heat and mass transport model:

(partialTheta(t, x))/(partialt)+del .(-k del Theta(t,x))-Q^(︷^( heat transfer model )) = 0; (partialc(t,x))/(partialt)+del .(-d del c(t,x))-R^(︷^( mass transport model )) = 0

Set up the heat transfer mass transport model variables :

Wolfram Language code:

hvars = {Θ[t, x], t, {x}};
mvars = {c[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1}}];

Specify heat transfer and mass transport model parameters, heat source , thermal conductivity , mass diffusivity and mass source :

Wolfram Language code:

pars = <|"ThermalConductivity" -> 0.01, "HeatSource" -> 0.2 * R, "DiffusionCoefficient" -> 0.01, "MassSource" -> R, R -> -10 ^ -3 * Θ[t, x] * c[t, x]|>;

Set up the model and initial conditions:

Wolfram Language code: eqn = {HeatTransferPDEComponent[hvars, pars] == 0, MassTransportPDEComponent[mvars, pars] == 0}

Set up initial conditions:

Wolfram Language code: ics = {Θ[0, x] == 200 + 800x, c[0, x] == 800};

Solve the model:

Wolfram Language code: {Tfun, cfun} = NDSolveValue[{eqn, ics}, {Θ, c}, {t, 0, 10}, {x}∈Ω];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[{cfun[t, x], Tfun[t, x]}, {x}∈Ω, ...], {{t, 1.3}, 0, 10}, Rule[...]]

Solve a coupled heat transfer and mass transport model with a thermal transfer value and a mass flux value on the boundary:

(partialTheta(t, x))/(partialt)+del .(-k del Theta(t,x))-Q^(︷^( heat transfer model )) = |_(Gamma_(x=1))h (Theta_(ext)(t,x)-Theta(t,x))^(︷^( heat transfer boundary )); (partialc(t,x))/(partialt)+del .(-d del c(t,x))-R^(︷^( mass transport model )) = |_(Gamma_(x=0||x=1))q (t,x)^(︷^( mass flux boundary ))

Set up the heat transfer mass transport model variables :

Wolfram Language code:

hvars = {Θ[t, x], t, {x}};
mvars = {c[t, x], t, {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {1}}];

Specify heat transfer and mass transport model parameters, heat source , thermal conductivity , mass diffusivity and mass source :

Wolfram Language code:

pars = <|"ThermalConductivity" -> 0.01, "HeatSource" -> 0.2 * R, "DiffusionCoefficient" -> 0.01, "MassSource" -> R, R -> -10 ^ -3 * Θ[t, x] * c[t, x]|>;

Specify boundary condition parameters for a thermal convection value with an external flow temperature of 1000 K and a heat transfer coefficient of :

Wolfram Language code: pars["BC1"] = <|"AmbientTemperature" -> 1000, "HeatTransferCoefficient" -> 0.1|>;

Specify the equation:

Wolfram Language code:

eqn = {HeatTransferPDEComponent[hvars, pars] == HeatTransferValue[x == 1, hvars, pars, "BC1"], MassTransportPDEComponent[mvars, pars] == NeumannValue[20, x == 0 || x == 1]}

Set up initial conditions:

Wolfram Language code: ics = {Θ[0, x] == 200 + 800x, c[0, x] == 800};

Solve the model:

Wolfram Language code: {Tfun, cfun} = NDSolveValue[{eqn, ics}, {Θ, c}, {t, 0, 10}, {x, 0, 1}];

Visualize the solution:

Wolfram Language code: Manipulate[Plot[{cfun[t, x], Tfun[t, x]}, {x}∈Ω, ...], {{t, 1.7}, 0, 10}, Rule[...]]

Possible Issues (1)

For symbolic computation, the "ThermalConductivity" parameter should be given as a matrix:

Wolfram Language code:

HeatTransferPDEComponent[{Θ[x, y], {x, y}}, <|"MassDensity" -> ρ, "SpecificHeatCapacity" -> Subscript[C, p], "ThermalConductivity" -> {{Subscript[κ, 11], 0}, {0, Subscript[κ, 12]}}|>]//Activate

For numeric values, the "ThermalConductivity" parameter is automatically converted to a matrix of proper dimensions:

Wolfram Language code:

HeatTransferPDEComponent[{Θ[x, y], {x, y}}, <|"MassDensity" -> ρ, "SpecificHeatCapacity" -> Subscript[C, p], "ThermalConductivity" -> 1|>]

This automatic conversion is not possible for symbolic input:

Wolfram Language code:

HeatTransferPDEComponent[{Θ[t, x], t, {x}}, <|"MassDensity" -> ρ, "SpecificHeatCapacity" -> Subscript[C, p], "ThermalConductivity" -> κ|>]

Not providing the properly dimensioned matrix will result in an error:

Wolfram Language code: %//Activate

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

HeatTransferPDEComponent

Details

Examples

Basic Examples (3)

Scope (10)

Basic Uses (5)

1D (1)

2D (1)

3D (1)

Time Dependent (1)

Time-Dependent Nonlinear (1)

Applications (8)

Boundary Conditions (5)

Coupled Equations (2)

Possible Issues (1)

Text

CMS

APA

BibTeX

BibLaTeX

dimension	reduction	equation
1D
2D

HeatTransferPDEComponent

Details

Examples

Basic Examples (3)

Scope (10)

Basic Uses (5)

1D (1)

2D (1)

3D (1)

Time Dependent (1)

Time-Dependent Nonlinear (1)

Applications (8)

Boundary Conditions (5)

Coupled Equations (2)

Possible Issues (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX