WOLFRAM

Wolfram Language & System Documentation Center

LaguerreL[n,x]

gives the Laguerre polynomial TemplateBox[{n, x}, LaguerreL].

LaguerreL[n,a,x]

gives the generalized Laguerre polynomial TemplateBox[{n, a, x}, LaguerreL3].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities and Simplifications  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

LaguerreL

LaguerreL[n,x]

gives the Laguerre polynomial TemplateBox[{n, x}, LaguerreL].

LaguerreL[n,a,x]

gives the generalized Laguerre polynomial TemplateBox[{n, a, x}, LaguerreL3].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • Explicit polynomials are given when possible.
  • TemplateBox[{n, x}, LaguerreL]=TemplateBox[{n, 0, x}, LaguerreL3].
  • The Laguerre polynomials are orthogonal with weight function .
  • They satisfy the differential equation .
  • For certain special arguments, LaguerreL automatically evaluates to exact values.
  • LaguerreL can be evaluated to arbitrary numerical precision.
  • LaguerreL automatically threads over lists.
  • LaguerreL[n,x] is an entire function of x with no branch cut discontinuities.
  • LaguerreL can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (6)

Compute the 5^(th) Laguerre polynomial:

Wolfram Language code: LaguerreL[5, x]

Compute the associated Laguerre polynomial :

Wolfram Language code: LaguerreL[2, a, x]

Plot over a subset of the reals:

Wolfram Language code: Plot[LaguerreL[1 / 2, x], {x, -5, 5}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[LaguerreL[-1 / 3, z ^ 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[LaguerreL[1 / 2, x], {x, 0, 5}]

Series expansion at Infinity:

Wolfram Language code: Series[LaguerreL[1 / 2, x], {x, ∞, 4}]//Normal//FullSimplify

Scope  (41)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: LaguerreL[6., 5]
Wolfram Language code: LaguerreL[3, .51, .87]

Evaluate to high precision:

Wolfram Language code: N[LaguerreL[2 / 5, 1 / 3, 8 / 7], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: LaguerreL[2.3000000000000000000000000, 3, 3]

Complex number input:

Wolfram Language code: LaguerreL[2.5, 1.3, 8 + I]

Evaluate efficiently at high precision:

Wolfram Language code: LaguerreL[2 / 7, 4 / 3, 8 / 7`100]//Timing
Wolfram Language code: LaguerreL[1 / 5, 1 / 3, 1 / 7`1000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: LaguerreL[2 / 3, Interval[{1.1, 1.2}]]
Wolfram Language code: LaguerreL[2 / 3, 3 / 4, Interval[{2.1, 2.2}]]
Wolfram Language code: LaguerreL[2 / 3, 3 / 4, CenteredInterval[4 / 5, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: LaguerreL[1 / 2, Around[.9, 0.1]]

Compute the elementwise values of an array:

Wolfram Language code: LaguerreL[3, {{2, 0}, {1 / 2, -2}}]

Or compute the matrix LaguerreL function using MatrixFunction:

Wolfram Language code: MatrixFunction[LaguerreL[3, #]&, {{2, 0}, {1 / 2, -2}}]

Specific Values  (5)

Values of LaguerreL at fixed points:

Wolfram Language code: Table[LaguerreL[10, x ], {x, 1, 5}]

Values at zero:

Wolfram Language code: LaguerreL[0, 0]
Wolfram Language code: LaguerreL[0, 0, 0]

Find the first positive minimum of LaguerreL[10,x ]:

Wolfram Language code: xmin = x /. Solve[D[LaguerreL[10, x ], x] == 0, x][[1]]
Wolfram Language code: Plot[LaguerreL[10, x ], {x, 0, 10}, Epilog -> Style[Point[{xmin, LaguerreL[10, xmin ]}], PointSize[Large], Red]]

Compute the associated LaguerreL[7,x] polynomial:

Wolfram Language code: LaguerreL[7, x]

Different LaguerreL types give different symbolic forms:

Wolfram Language code: Table[LaguerreL[n, a, x], {n, 0, 3}, {a, 0, 1}]

Visualization  (3)

Plot the LaguerreL polynomial for various orders:

Wolfram Language code: Plot[{LaguerreL[1, x], LaguerreL[2, x], LaguerreL[3, x], LaguerreL[4, x]}, {x, -1, 10}]

Plot the real part of TemplateBox[{10}, LucasL](z):

Wolfram Language code: ComplexContourPlot[Re[LaguerreL[10, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{10}, LucasL](z):

Wolfram Language code: ComplexContourPlot[Im[LaguerreL[10, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot as real parts of two parameters vary:

Wolfram Language code: Plot3D[Re[LaguerreL[n, z]], {n, 0, 10}, {z, 0, 5}, PlotRange -> All]

Function Properties  (13)

The primary Laguerre function is defined for all real and complex values:

Wolfram Language code: FunctionDomain[LaguerreL[n, z], z]
Wolfram Language code: FunctionDomain[LaguerreL[n, z], z, Complexes]

The associated Laguerre function TemplateBox[{n, a, z}, LaguerreL3] has restrictions on and , but not :

Wolfram Language code: FunctionDomain[LaguerreL[n, a, z], z]//Reduce
Wolfram Language code: FunctionDomain[LaguerreL[n, a, z], z, Complexes]//Reduce

TemplateBox[{1, x}, LaguerreL] achieves all real and complex values:

Wolfram Language code: FunctionRange[LaguerreL[1, x], x, y]
Wolfram Language code: FunctionRange[LaguerreL[1, z], z, y, Complexes]

So do all associated TemplateBox[{1, n, x}, LaguerreL3]:

Wolfram Language code: FunctionRange[LaguerreL[1, n, x], x, y]
Wolfram Language code: FunctionRange[LaguerreL[1, n, x], x, y, Complexes]

Function range of TemplateBox[{2, x}, LaguerreL]:

Wolfram Language code: FunctionRange[LaguerreL[2, x], x, y]
Wolfram Language code: FunctionRange[LaguerreL[2, z], z, y, Complexes]

LaguerreL has the mirror property :

Wolfram Language code: LaguerreL[1, Conjugate[z]] == Conjugate[LaguerreL[1, z]]

LaguerreL threads elementwise over lists:

Wolfram Language code: LaguerreL[{1, 2, 3}, x]

TemplateBox[{n, x}, LaguerreL] is an analytic function of and :

Wolfram Language code: FunctionAnalytic[LaguerreL[n, x], {n, x}]

TemplateBox[{n, a, x}, LaguerreL3] is not analytic, but it is meromorphic:

Wolfram Language code: FunctionAnalytic[LaguerreL[n, a, x], {n, a, x}]
Wolfram Language code: FunctionMeromorphic[LaguerreL[n, a, x], {n, a, x}]

TemplateBox[{1, a, x}, LaguerreL3] is a decreasing function:

Wolfram Language code: FunctionMonotonicity[LaguerreL[1, a, x], x, Assumptions -> a∈ℝ, StrictInequalities -> True]

TemplateBox[{2, a, x}, LaguerreL3] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[LaguerreL[2, a, x], x, Assumptions -> a∈ℝ]

Laguerre polynomials are not injective for values other than 1:

Wolfram Language code: Table[FunctionInjective[LaguerreL[a, x], x], {a, 0, 4}]
Wolfram Language code: Plot[{LaguerreL[1, x], LaguerreL[2, x], LaguerreL[3, x], 3}, {x, -5, 5}]

TemplateBox[{n, a, x}, LaguerreL3] is surjective for odd :

Wolfram Language code: Table[FunctionSurjective[LaguerreL[n, x], x], {n, 4}]
Wolfram Language code: Table[FunctionSurjective[LaguerreL[n, a, x], x, Assumptions -> a∈ℝ], {n, 4}]
Wolfram Language code: Plot[{LaguerreL[3, x], LaguerreL[4, 2, x], -30}, {x, -5, 15}]

LaguerreL is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[LaguerreL[a, x], {a, x}]

TemplateBox[{n, a, x}, LaguerreL3] has no singularities or discontinuities in :

Wolfram Language code: FunctionSingularities[LaguerreL[n, a, x], x]
Wolfram Language code: FunctionDiscontinuities[LaguerreL[n, a, x], x]

TemplateBox[{2, a, x}, LaguerreL3] is convex:

Wolfram Language code: FunctionConvexity[LaguerreL[2, a, x], x, Assumptions -> a∈Reals]

TraditionalForm formatting:

Wolfram Language code: LaguerreL[n, z]//TraditionalForm
Wolfram Language code: LaguerreL[n, μ, z]//TraditionalForm

Differentiation  (3)

First derivative with respect to x:

Wolfram Language code: D[LaguerreL[n, x], x]

Higher derivatives with respect to x:

Wolfram Language code: Table[D[LaguerreL[n, x], {x, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to x when n=3:

Wolfram Language code: Plot[Evaluate[% /. n -> 3], {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to x:

Wolfram Language code: D[LaguerreL[n, x], {x, k}]// FullSimplify

Integration  (3)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[LaguerreL[n, x], x]

Definite integral:

Wolfram Language code: Integrate[LaguerreL[n, x], {x, 0, 5}]

More integrals:

Wolfram Language code: Integrate[x LaguerreL[n, x], x]//FullSimplify
Wolfram Language code: Integrate[ x LaguerreL[n, x^2], {x, 0, 5}]//FullSimplify

Series Expansions  (5)

Find the Taylor expansion using Series:

Wolfram Language code: Series[LaguerreL[n, x], {x, 0, 4}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[LaguerreL[10, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{LaguerreL[10, x], terms}, {x, 0, 10}, PlotRange -> {{0, 10}, {-30, 10}}]

General term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[LaguerreL[k, x], {x, 1, n}]

Find the series expansion at Infinity:

Wolfram Language code: Series[LaguerreL[n, x], {x, Infinity, 1}]

Find series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[LaguerreL[n, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

Taylor expansion at a generic point:

Wolfram Language code: Series[LaguerreL[n, x], {x, x0, 2}]// FullSimplify

Function Identities and Simplifications  (3)

LaguerreL may reduce to simpler form:

Wolfram Language code: LaguerreL[2, x]

Generating function of LaguerreL:

Wolfram Language code: GeneratingFunction[LaguerreL[n, x], n, t]

Recurrence identity:

Wolfram Language code: LaguerreL[n, x] == (2n + 3 - x/n + 1)LaguerreL[n + 1, x] - (n + 2/n + 1)LaguerreL[n + 2, x]//FullSimplify

Generalizations & Extensions  (1)

LaguerreL can be applied to a power series:

Wolfram Language code: LaguerreL[1 / 3, 1, Sin[x] + O[x] ^ 4]

Applications  (6)

Solve the Laguerre differential equation:

Wolfram Language code: DSolve[ {x y''[x] + (a + 1 - x)y'[x] + n y[x] == 0}, y[x], x]

Generalized Fourier series for functions defined on :

Wolfram Language code: Table[Integrate[Exp[-x]LaguerreL[n, x]Sin[x], {x, 0, Infinity}], {n, 0, 10}]
Wolfram Language code: Plot[{Sin[x], %. Table[LaguerreL[n, x], {n, 0, 10}]}, {x, 0, 4 Pi}]

Radial wave-function of the hydrogen atom:

Wolfram Language code: ψ[n_, l_, r_] := Sqrt[( (n - l - 1)!/(n + l)!)] E^-(r/n) ((2r/n))^l(2/n^2) LaguerreL[n - l - 1, 2l + 1, (2r/n)]

Compute the energy eigenvalue from the differential equation:

Wolfram Language code: energy[w_, r_, n_, l_] := Simplify[(1/w)(D[w, r, r] + (2/ r)D[w, r] - (l(l + 1)/r^2)w + (2/r)w)]

The energy is independent of the orbital quantum number l:

Wolfram Language code: Solve[(energy[ψ[n, l, r], r, n, l] - ℰ//FullSimplify) == 0, ℰ]

The number of derangement anagrams for a word with character counts :

Wolfram Language code: DerangementsCount[nvec_List] := Integrate[Exp[-x]Apply[Times, (-1) ^ nvec LaguerreL[nvec, x]], {x, 0, Infinity}]

Count the number of derangements for the word Mathematica:

Wolfram Language code: chars = Characters["Mathematica"]//ToLowerCase
Wolfram Language code: DerangementsCount[Tally[chars][[All, 2]]]

Direct count:

Wolfram Language code: Count[Permutations[chars], x_ /; Inner[UnsameQ, x, chars, And]]

Compare the value of the MarcumQ function for large arguments to its asymptotic formula:

Wolfram Language code: Refine[SurvivalFunction[RiceDistribution[m, a / Sqrt[m], 1], x / Sqrt[m]], m > 0 && x > 0]

Construct an approximation using the central limit theorem:

Wolfram Language code: SurvivalFunction[NormalDistribution[Mean[RiceDistribution[m, a / Sqrt[m], 1]], StandardDeviation[RiceDistribution[m, a / Sqrt[m], 1]]], x / Sqrt[m]]

Evaluate numerically:

Wolfram Language code: {%%, %} /. {m -> 3, a -> 8.2, x -> 9.}

An n-point Gauss–Laguerre quadrature rule is based on the roots of the n^(th)-order Laguerre polynomial. Compute the nodes and weights of an n-point Gauss–Laguerre quadrature rule for a given value of :

Wolfram Language code: n = 10;a = -1 / 2; laguerreNodes = x /. NSolve[LaguerreL[n, a, x], x]
Wolfram Language code: w1 = x |-> (Gamma[a + n + 1]/n!x)(1/LaguerreL[n - 1, a + 1, x]^2); laguerreWeights = w1[laguerreNodes]

Use the n-point Gaussian quadrature rule to numerically evaluate an integral:

Wolfram Language code: fun[x_] := Log[1 + x]; est1 = laguerreWeights.Map[fun, laguerreNodes]

Compare the result of the Gauss–Laguerre quadrature with the result from NIntegrate:

Wolfram Language code: est1 - NIntegrate[x^aE^-xfun[x], {x, 0, ∞}]

Properties & Relations  (7)

Get the list of coefficients in a Laguerre polynomial:

Wolfram Language code: CoefficientList[LaguerreL[4, a, x], x]

Use FunctionExpand to expand LaguerreL functions into simpler functions:

Wolfram Language code: FunctionExpand[LaguerreL[1 / 2, -1 / 2, x]]

LaguerreL can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[LaguerreL[n, x], x]

LaguerreL can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[LaguerreL[n, x], x]
Wolfram Language code: Activate[%]//FullSimplify

LaguerreL can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[LaguerreL[k, z], k]
Wolfram Language code: DifferenceRootReduce[LaguerreL[y, k, z], k]

General term in the series expansion of LaguerreL:

Wolfram Language code: SeriesCoefficient[LaguerreL[a, x], {x, 0, n}]

The generating function for LaguerreL:

Wolfram Language code: GeneratingFunction[LaguerreL[n, k], n, x]

Possible Issues  (1)

Cancellations in the polynomial form may lead to inaccurate numerical results:

Wolfram Language code: LaguerreL[100, 0, x] /. x -> N[5, 20]

Evaluate the function directly:

Wolfram Language code: LaguerreL[100, 0, N[5, 20]]
Wolfram Research (1988), LaguerreL, Wolfram Language function, https://reference.wolfram.com/language/ref/LaguerreL.html (updated 2022).

Text

Wolfram Research (1988), LaguerreL, Wolfram Language function, https://reference.wolfram.com/language/ref/LaguerreL.html (updated 2022).

CMS

Wolfram Language. 1988. "LaguerreL." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/LaguerreL.html.

APA

Wolfram Language. (1988). LaguerreL. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LaguerreL.html

BibTeX

@misc{reference.wolfram_2026_laguerrel, author="Wolfram Research", title="{LaguerreL}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/LaguerreL.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_laguerrel, organization={Wolfram Research}, title={LaguerreL}, year={2022}, url={https://reference.wolfram.com/language/ref/LaguerreL.html}, note=[Accessed: 13-June-2026]}