Wolfram Language & System Documentation Center

Hexahedron

Hexahedron[{p₁,p₂,…,p₈}]

represents a filled hexahedron with corners p₁, p₂, …, p₈.

Hexahedron[{{p_1,1,p_1,2,…,p_1,8},{p_2,1,…},…}]

represents a collection of hexahedra.

Details and Options

Hexahedron can be used as a geometric region and a graphics primitive.
Hexahedron represents a filled polyhedron given by the polygon faces {p₄,p₃,p₂,p₁}, {p₁,p₂,p₆,p₅}, {p₂,p₃,p₇,p₆}, {p₃,p₄,p₈,p₇}, {p₄,p₁,p₅,p₈}, and {p₅,p₆,p₇,p₈}.

CanonicalizePolyhedron can be used to convert a hexahedron to an explicit Polyhedron object.
Hexahedron can be used in Graphics3D.
In graphics, the points p_i can be Scaled and Dynamic expressions.
Graphics rendering is affected by directives such as FaceForm, EdgeForm, Opacity, Texture, and color.
The following options and settings can be used in graphics:

VertexColors	Automatic	vertex colors to be interpolated
VertexNormals	Automatic	effective vertex normals for shading
VertexTextureCoordinates	None	coordinates for textures

Examples

open all close all

Basic Examples (3)

A hexahedron:

Wolfram Language code: Graphics3D[Hexahedron[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 1}, {1, 1, 1}, {0, 1, 1}}]]

A styled hexahedron:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code:

{Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{EdgeForm[Dashed], ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Volume and centroid:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: Volume[ℛ]

Wolfram Language code: RegionCentroid[ℛ]

Scope (18)

Graphics (8)

Specification (2)

A single hexahedron:

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}};

Wolfram Language code: Graphics3D[Hexahedron[pts]]

Multiple hexahedrons:

Wolfram Language code: pts1 = {{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}};

Wolfram Language code: pts2 = pts1 + 2;

Wolfram Language code: Graphics3D[Hexahedron[{pts1, pts2}]]

Styling (3)

FaceForm and EdgeForm can be used to specify the styles of the faces and edges:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

Apply a Texture to the faces:

Wolfram Language code:

ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}, {0.5, 0}, {1, 0.5}, {0.5, 1}, {0, 0.5}}];

Wolfram Language code: Graphics3D[{Texture[[image]], ℛ}, Lighting -> "Neutral"]

Assign VertexColors to vertices:

Wolfram Language code:

ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}, VertexColors -> {Black, Red, Yellow, Green, Blue, Magenta, White, Cyan}];

Wolfram Language code: Graphics3D[ℛ, Lighting -> "Neutral"]

Coordinates (3)

Specify coordinates by fractions of the plot range:

Wolfram Language code:

ℛ = Hexahedron[{Scaled[{0, 0, 0}], Scaled[{0.5, 0, 0}], Scaled[{1, 0.5, 0}], Scaled[{0.5, 0.5, 0}], Scaled[{0, 0, 0.5}], Scaled[{0.5, 0, 0.5}], Scaled[{1, 0.5, 0.5}], Scaled[{0.5, 0.5, 0.5}]}];

Wolfram Language code: Graphics3D[ℛ, PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

Specify scaled offsets from the ordinary coordinates:

Wolfram Language code:

ℛ = Hexahedron[{Scaled[{0, 0, 0.5}, {0, 0, 0}], Scaled[{0, 0, 0.5}, {1, 0, 0}], Scaled[{0, 0, 0.5}, {2, 1, 0}], Scaled[{0, 0, 0.5}, {1, 1, 0}], Scaled[{0, 0, 0.5}, {0, 0, 1}], Scaled[{0, 0, 0.5}, {1, 0, 1}], Scaled[{0, 0, 0.5}, {2, 1, 1}], Scaled[{0, 0, 0.5}, {1, 1, 1}]}];

Wolfram Language code: Graphics3D[ℛ, PlotRange -> {{0, 2}, {0, 2}, {0, 2}}, Axes -> True]

Points can be Dynamic:

Wolfram Language code:

DynamicModule[{x}, {Slider[Dynamic[x], {0.5, 1}], Graphics3D[Hexahedron[{{0, 0, 0}, Dynamic[x{1, 0, 0}], {2, 1, 0}, {1, 1, 0}, Dynamic[x{0, 0, 1}], Dynamic[x{1, 0, 1}], {2, 1, 1}, {1, 1, 1}}]]}]

Regions (10)

Embedding dimension is the dimension of the space in which the hexahedron lives:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {1, 2, 3}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

Volume:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}, Boxed -> False]

Distance from a point:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: {RegionDistance[ℛ, {1, 2, 3}], RegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

The equidistance contours for a hexahedron:

Wolfram Language code:

ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -1, 3}, {y, -1.5, 3}, {z, -1.5, 3}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

Signed distance from a point:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2, 3}], SignedRegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

Nearest point in the region:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: {RegionNearest[ℛ, {1, 2, 3}], RegionNearest[ℛ, {(1/3), (1/4), (1/5)}]}

Nearest points to an enclosing sphere:

Wolfram Language code:

spherePoints[{n_, m_}, c_, r_] := 
	Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];

Wolfram Language code:

pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2];
npl = Table[RegionNearest[ℛ, p], {p, pl}];

Wolfram Language code:

Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A hexahedron is bounded:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: r = RegionBounds[ℛ]

Wolfram Language code:

Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, 
	Boxed -> False]

Integrate over a hexahedron region:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: Integrate[x + y + z, {x, y, z}∈ℛ]

Optimize over a hexahedron region:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations in a hexahedron region:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

Applications (4)

Convert a Cuboid to a Hexahedron:

Wolfram Language code: c = Cuboid[{1, 2, 3}, {4, 5, 6}];

Wolfram Language code:

h = c /. Cuboid[{x0_, y0_, z0_}, {x1_, y1_, z1_}] :> Hexahedron[{{x0, y0, z0}, {x1, y0, z0}, {x1, y1, z0}, {x0, y1, z0}, {x0, y0, z1}, {x1, y0, z1}, {x1, y1, z1}, {x0, y1, z1}}]

Wolfram Language code: Graphics3D /@ {c, h}

Convert a Parallelepiped to a Hexahedron:

Wolfram Language code: c = Parallelepiped[{1, 2, 3}, {{2, 0, 0}, {2, 3, 0}, {0, 3, 2}}];

Wolfram Language code:

h = c /. Parallelepiped[p_, {v1_, v2_, v3_}] :> 
	Hexahedron[{p, p + v1, p + v1 + v2, p + v2, p + v3, p + v1 + v3, p + v1 + v2 + v3, p + v2 + v3}]

Wolfram Language code: Graphics3D /@ {c, h}

Create a square frustum parameterized by base width, top width, and height:

Wolfram Language code:

SquareFrustum[wb_, wt_, h_] := With[{p0 = {0, 0, 0}, p5 = {(wb - wt/2), (wb - wt/2), h}}, Hexahedron[{p0, p0 + {wb, 0, 0}, p0 + {wb, wb, 0}, p0 + {0, wb, 0}, p5, p5 + {wt, 0, 0}, p5 + {wt, wt, 0}, p5 + {0, wt, 0}}]]

Wolfram Language code: SquareFrustum[9, 5, 6]

Wolfram Language code: Graphics3D@%

Create a tiling of hexahedra:

Wolfram Language code:

hl = Table[Hexahedron[TranslationTransform[{i, j, k}] /@ {{2, 2, 1}, {3, 2, 1}, {4, 3, 1}, {3, 3, 1}, {2, 3, 2}, {3, 3, 2}, {4, 4, 2}, {3, 4, 2}}], {i, 1, 5}, {j, 1, 5}, {k, 1, 5}];

Wolfram Language code: Graphics3D[{EdgeForm[Directive[Thin, Gray]], FaceForm[Opacity[0.3]], hl}, Boxed -> False]

Properties & Relations (4)

Hexahedron is a generalization of a Cuboid in dimension 3:

Wolfram Language code:

Subscript[ℛ, 1] = Hexahedron[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}, {0, 0, 1}, {0, 1, 1}, {1, 1, 1}, {1, 0, 1}}];
Subscript[ℛ, 2] = Cuboid[{0, 0, 0}, {1, 1, 1}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A hexahedron can be represented as the union of five tetrahedra:

Wolfram Language code: pts = {{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}, {-1, -1, 1}, {1, -1, 1}, {1, 1, 1}, {-1, 1, 1}};

Wolfram Language code: Graphics3D[Hexahedron[pts], Boxed -> False]

Point index list of tetrahedra vertices:

Wolfram Language code: ti = {{1, 2, 3, 6}, {1, 3, 8, 6}, {1, 3, 4, 8}, {1, 6, 8, 5}, {3, 8, 6, 7}};

Wolfram Language code: Graphics3D[{Opacity@0.4, Table[Tetrahedron[pts[[i]]], {i, ti}]}, Boxed -> False]

A hexahedron can also be represented as the union of six tetrahedra:

Wolfram Language code: pts = {{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}, {-1, -1, 1}, {1, -1, 1}, {1, 1, 1}, {-1, 1, 1}};

Wolfram Language code: ti = {{1, 6, 8, 5}, {1, 2, 8, 6}, {2, 7, 8, 6}, {1, 8, 3, 4}, {1, 8, 2, 3}, {1, 8, 7, 3}};

Wolfram Language code: Graphics3D[{Opacity@0.4, Table[Tetrahedron[pts[[i]]], {i, ti}]}, Boxed -> False]

ImplicitRegion can represent any Hexahedron:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[Subscript[t, 3] ≥ 0 && Subscript[t, 2] ≥ 0 && Subscript[t, 1] - Subscript[t, 2] ≥ 0 && 1 - Subscript[t, 1] + Subscript[t, 2] ≥ 0 && 1 - Subscript[t, 2] ≥ 0 && 1 - Subscript[t, 3] ≥ 0, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}];
Subscript[ℛ, 2] = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples (2)

Random collection of hexahedrons:

Wolfram Language code:

Graphics3D[Table[{EdgeForm[Opacity[.3]], Hue[RandomReal[]], GeometricTransformation[Hexahedron[], AffineTransform[{RandomReal[1, {3, 3}], RandomReal[1.5, 3]}]]}, {30}]]

Sweep a hexahedron around an axis:

Wolfram Language code: ℛ = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 2}, {1, 0, 2}, {2, 1, 1}, {1, 1, 1}}];

Wolfram Language code:

Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[ℛ, RotationTransform[c, {0, 0, 1}, {0, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 24}]}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Hexahedron

Details and Options

Examples

Basic Examples (3)

Scope (18)

Graphics (8)

Specification (2)

Styling (3)

Coordinates (3)

Regions (10)

Applications (4)

Properties & Relations (4)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

Hexahedron

Details and Options

Examples

Basic Examples (3)

Scope (18)

Graphics (8)

Specification (2)

Styling (3)

Coordinates (3)

Regions (10)

Applications (4)

Properties & Relations (4)

Neat Examples (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX