Maximize
Details and Options
- Maximize is also known as supremum, symbolic optimization and global optimization (GO).
- Maximize finds the global maximum of f subject to the constraints given.
- Maximize is typically used to find the largest possible values given constraints. In different areas, this may be called the best strategy, best fit, best configuration and so on.
- Maximize returns a list of the form {fmax,{x->xmax,y->ymax,…}}.
- If f and cons are linear or polynomial, Maximize will always find a global maximum.
- The constraints cons can be any logical combination of:
-
lhs==rhs equations lhs>rhs, lhs≥rhs, lhs<rhs, lhs≤rhs inequalities (LessEqual,…) lhsrhs, lhsrhs, lhsrhs, lhsrhs vector inequalities (VectorLessEqual,…) Exists[…], ForAll[…] quantified conditions {x,y,…}∈rdom region or domain specification - Maximize[{f,cons},x∈rdom] is effectively equivalent to Maximize[{f,cons∧x∈rdom},x].
- For x∈rdom, the different coordinates can be referred to using Indexed[x,i].
- Possible domains rdom include:
-
Reals real scalar variable Integers integer scalar variable Vectors[n,dom] vector variable in 
Matrices[{m,n},dom] matrix variable in 
ℛ vector variable restricted to the geometric region 
- By default, all variables are assumed to be real.
- Maximize will return exact results if given exact input. With approximate input, it automatically calls NMaximize.
- Maximize will return the following forms:
-
{fmax,{xxmax,…}} finite maximum {-∞,{xIndeterminate,…}} infeasible, i.e. the constraint set is empty {∞,{xxmax,…}} unbounded, i.e. the values of f can be arbitrarily large - If the maximum is achieved only infinitesimally outside the region defined by the constraints, or only asymptotically, Maximize will return the supremum and the closest specifiable point.
- Even if the same maximum is achieved at several points, only one is returned.
- N[Maximize[…]] calls NMaximize for optimization problems that cannot be solved symbolically.
- Maximize[f,x,WorkingPrecision->n] uses n digits of precision while computing a result. »
Examples
open all close allBasic Examples (5)
Maximize a univariate function:
Maximize[-2x ^ 2 - 3x + 5, x]Maximize a multivariate function:
Maximize[1 - (x y - 3) ^ 2, {x, y}]Maximize a function subject to constraints:
Maximize[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]A maximization problem containing parameters:
Maximize[a x ^ 2 + b x + c, x]Maximize a function over a geometric region:
Maximize[x + y, {x, y}∈Disk[]]Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[{x, y} /. Last[%]]}]]Scope (36)
Basic Uses (7)
Maximize 
over the unconstrained reals:
Maximize[Sin[x] + Cos[x], x]Maximize 
subject to constraints 
:
Maximize[{x + 2y, x ^ 2 + 2y ^ 2 ≤ 3 && x + y == 2 && x ≥ 1}, {x, y}]Constraints may involve arbitrary logical combinations:
Maximize[{x y, x ^ 2 + y ^ 2 ≤ 1 || (x + 1) ^ 2 + (y - 1) ^ 2 ≤ 2}, {x, y}]Maximize[{x + y, x ≤ y ^ 2}, {x, y}]
Maximize[{x + y, x ^ 2 + y ^ 2 < 0}, {x, y}]
The supremum value may not be attained:
Maximize[-Exp[x], x]
Use a vector variable and a vector inequality:
Maximize[{{-1, -1}.v, {{1, 2}, {1, 0}}.v{3, -1}}, v]Univariate Problems (7)
Unconstrained univariate polynomial maximization:
Maximize[-x ^ 4 + 2x ^ 3 + 5x - 7, x]Constrained univariate polynomial maximization:
Maximize[{-3x ^ 2 - x + 9, 2x ^ 3 + 5x - 7 ≥ 0}, x]Maximize[-E ^ (2E ^ x) + Log[x ^ 2 + 1] + 20x, x]Analytic functions over bounded constraints:
Maximize[{AiryAi[x + Sin[x]] + Cos[x ^ 2], -5 ≤ x ≤ 5}, x]Plot[AiryAi[x + Sin[x]] + Cos[x ^ 2], {x, -5, 5}, Epilog -> {Red, Point[{x /. %[[2]], %[[1]]}]}]Maximize[{BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], 0 ≤ x ≤ 10}, x]
Plot[BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], {x, 0, 10}, Epilog -> {Red, Point[{x /. %[[2]], %[[1]]}]}]Maximize[{Sin[x], -1 / 2 ≤ Cos[x] ≤ 1 / 2}, x]Combination of trigonometric functions with commensurable periods:
Maximize[Sin[E ^ (x / 3) - 3 x] + 2 Cos[2 E ^ (x / 3) - 6 x + 1] ^ 2, x]Combination of periodic functions with incommensurable periods:
Maximize[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], x]
Show[{Plot[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], {x, -50, 50}], Graphics[{Red, Line[{{-50, %[[1]]}, {50, %[[1]]}}]}]}]Maximize[{Floor[x + UnitStep[x - 1]] - x, Ceiling[Abs[x]] < 5}, x]Unconstrained problems solvable using function property information:
Maximize[SinhIntegral[DawsonF[x]], x]Maximize[BesselJ[7 / 4, x ^ 2 + x + 1], x]Multivariate Problems (9)
Multivariate linear constrained maximization:
Maximize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]Linear-fractional constrained maximization:
Maximize[{(2x + y - z) / (5x - 7y + 3), 0 ≤ x + y + z ≤ 1 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]Unconstrained polynomial maximization:
Maximize[x ^ 2 - 2y - 1 - (x ^ 2 - 2y) ^ 2, {x, y}]Constrained polynomial optimization can always be solved:
Maximize[{x y - 1, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]The maximum value may not be attained:
Maximize[{1 - x ^ 2, x y ≥ 1}, {x, y}]
The objective function may be unbounded:
Maximize[{x, x y ≤ 1}, {x, y}]
There may be no points satisfying the constraints:
Maximize[{x, x ^ 2 + y ^ 2 < 0}, {x, y}]
Quantified polynomial constraints:
Maximize[{-(x + 7)^2 - (y - 8)^2, Subscript[∀, z]Subscript[∃, w]3 z^2 w + (x + y) z^4 - 1 == (x^3 - x y + y^2 - 1) w^2}, {x, y}]Maximize[{-x - Sqrt[x + y] , x Sqrt[y] ≥ 1}, {x, y}]Bounded transcendental maximization:
Maximize[{E ^ x + Log[y], x Log[y] == 2 && -10 ≤ x ≤ 10 && 1 / 10 ≤ y ≤ 10}, {x, y}]Maximize[{-Max[x - y, Abs[y]], Min[x - 2, x - y ^ 2] ≥ Abs[x y - 1]}, {x, y}]Maximize[v.{1, -1}, {VectorGreaterEqual[{{{1, 0}, {0, 1}, {-1, -2}}.v, {0, 0, -2}}, "ExponentialCone"]}, v]Maximize concave objective function 
such that 
is positive semidefinite and 
:
res = Maximize[{Log[x + y], (| | |
| ----- | ----- |
| x + y | 1 |
| 1 | x - y |)Underscript[, {"SemidefiniteCone", 2}]0 && 1 ≤ x ≤ 10 && -1 ≤ y ≤ 1}, {x, y}]Plot the region and the minimizing point:
Show[Plot3D[Log[x + y], {x, 1, 10}, {y, -1, 1}, ...], Graphics3D[{Red, PointSize[0.05], Point[{x, y, Log[x + y]} /. res[[2]]]}]]Parametric Problems (4)
Parametric linear optimization:
Maximize[{8x + 7y, -6 x - 4 y ≤ 8 - 5 a - 7 b && 7 x + 5 y ≤ a + 4 b && -x + y ≤ 6 + 4a - 5 b && -4 x + 7 y ≤ -1 - 2 a - 7 b && 5 y ≤ 6 - 9 b}, {x, y}]The maximum value is a continuous function of parameters:
max = %[[1]];Plot3D[max, {a, -3, 3}, {b, 0, 3}]Parametric quadratic optimization:
Maximize[{-(x - 1) ^ 2 - (2y - 1) ^ 2, x + 2y ≤ a + b && 2x - y ≤ a - b + 1 && x - 2y ≤ 2a - b + 1}, {x, y}]The maximum value is a continuous function of parameters:
max = %[[1]];Plot3D[max, {a, -5, 5}, {b, -5, 5}]Unconstrained parametric polynomial maximization:
Maximize[-x ^ 4 + a x ^ 2 + b, x]Constrained parametric polynomial maximization:
Maximize[{-x ^ 2 - y ^ 2, x ^ 3 + y ^ 2 == a}, {x, y}]Optimization over Integers (3)
Maximize[{x ^ 3 Log[x] - E ^ x, x > 0}, x, Integers]Maximize[Sin[2x] + Cos[3x], x, Integers]
Show[{ListPlot[Table[Sin[2x] + Cos[3 x], {x, 0, 10000}]], Graphics[{Red, Line[{{0, %[[1]]}, {10000, %[[1]]}}]}]}]Maximize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}, Integers]Polynomial maximization over the integers:
Maximize[{-x ^ 2 - x y + 1, x y ≥ 1}, {x, y}, Integers]Optimization over Regions (6)
ℛ = Cylinder[{{1, 2, 3}, {3, 2, 1}}, 1];Maximize[z, {x, y, z}∈ℛ]Graphics3D[{{Opacity[0.5], Green, ℛ}, {Red, PointSize[Large], Point[{x, y, z} /. Last[%]]}}]Find the maximum distance between points in two regions:
Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Line[{{-(1/2), -(1/2)}, {-(1/2), (1/2)}, {(1/2), (1/2)}, {(1/2), -(1/2)}, {-(1/2), -(1/2)}}];Maximize[(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}]//RootReduceGraphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{{x, y}, {u, v}} /. Last[%]]}}]Find the maximum 
such that the triangle and ellipse still intersect:
Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Circle[{(1/3), (1/3)}, {2 r, r}];Maximize[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]Find the maximum 
for which 
contains the given three points:
Subscript[ℛ, 3] = Disk[{a, b}, {r, 2 - r}];Maximize[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]Graphics[{{LightBlue, Subscript[ℛ, 3]} /. Last[%], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]Use 
to specify that 
is a vector in 
:
ℛ = Sphere[];Maximize[x.{1, 2, 3}, x∈ℛ]Find the maximum distance between points in two regions:
Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];Maximize[EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}]//RootReduceGraphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]Options (2)
Method (1)
Specify that Maximize should use cylindrical algebraic decomposition:
maxcad = Maximize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "CAD"]maxlm = Maximize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "LagrangeMultipliers"]maxdef = Maximize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}]RootReduce[maxcad] === RootReduce[maxlm] === RootReduce[maxdef]WorkingPrecision (1)
Finding the exact solution takes a long time:
TimeConstrained[Maximize[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}], 60]With WorkingPrecision->200, you get an exact maximum value, but it might be incorrect:
Maximize[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}, WorkingPrecision -> 200]//TimingApplications (13)
Basic Applications (3)
Find the maximal area among rectangles with a unit perimeter:
Maximize[{x y, 2x + 2y == 1 && x > 0 && y > 0}, {x, y}]Find the maximal area among triangles with a unit perimeter:
triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a;
s = 1 / 2(a + b + c);Maximize[{Sqrt[s(s - a)(s - b)(s - c)], triangle && a + b + c == 1}, {a, b, c}]Find the maximum height reached by a projectile:
Maximize[ {v Sin[α] t - 5 t ^ 2, t ≥ 0 && 0 < Sin[α] ≤ 1 && v > 0}, t]Refine[%, 0 < Sin[α] ≤ 1 && v > 0]Find the maximum range of a projectile:
Maximize[{v Cos[α] t, v Sin[α] t - 5 t ^ 2 == 0 && t ≥ 0 && v > 0 && 0 ≤ Sin[α] ≤ 1 && 0 ≤ Cos[α] ≤ 1 && Sin[α] ^ 2 + Cos[α] ^ 2 == 1}, {Sin[α], Cos[α], t}]Refine[%, v > 0]Geometric Distances (9)
The largest distance of a point in a region ℛ to a given point p and a point q realizing the largest distance is given by Maximize[EuclideanDistance[p,q],q∈ℛ]. Find the largest distance and the farthest point from {1,1} in the unit Disk[]:
p = {1, 1};
q = {q1, q2};
ℛ = Disk[];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]//RootReduceGraphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]Find the largest distance and the farthest point from {1,3/4} in the standard unit simplex Simplex[2]:
p = {1, 3 / 4};
q = {q1, q2};
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]Find the largest distance and the farthest point from {1,1,1} in the standard unit sphere Sphere[]:
p = {1, 1, 1};
q = {q1, q2, q3};
ℛ = Sphere[];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]//RootReduceGraphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]Find the largest distance and the farthest point from {-1/3,1/3,1/3} in the standard unit simplex Simplex[3]:
p = {-1 / 3, 1 / 3, 1 / 3};
q = {q1, q2, q3};
ℛ = Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]Graphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]The diameter of a region ℛ is the maximum distance between two points in ℛ. The diameter and a pair of farthest points in ℛ can be computed through Maximize[EuclideanDistance[p,q],{p∈ℛ,q∈ℛ}]. Find the diameter and a pair of farthest points in Circle[]:
ℛ = Circle[];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]Graphics[{{ℛ}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]Find the diameter and a pair of farthest points in the standard unit simplex Simplex[2]:
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]Find the diameter and a pair of farthest points in the standard unit cube Cuboid[]:
ℛ = Cuboid[];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]Graphics3D[{{Opacity[0.5], ℛ}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]The farthest points p∈ and q∈ and their distance can be found through Maximize[EuclideanDistance[p,q],{p∈,q∈}]. Find the farthest points in Disk[{0,0}] and Rectangle[{3,3}] and the distance between them:
𝒫 = Disk[{0, 0}]; 𝒬 = Rectangle[{3, 3}];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]//RootReduceGraphics[{{StandardBlue, EdgeForm[Gray], 𝒫, 𝒬}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]Find the farthest points in Line[{{0,0,0},{1,1,1}}] and Ball[{5,5,0},1] and the distance between them:
𝒫 = Line[{{0, 0, 0}, {1, 1, 1}}]; 𝒬 = Ball[{5, 5, 0}, 1];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]//RootReduceGraphics3D[{{𝒫, {Opacity[0.5], 𝒬}}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]Geometric Centers (1)
If ℛ⊆n is a region that is full dimensional, then the Chebyshev center is the center of the largest inscribed ball of ℛ. The center and the radius of the largest inscribed ball of ℛ can be found through Maximize[-SignedRegionDistance[ℛ,p], p∈ℛ]. Find the Chebyshev center and the radius of the largest inscribed ball for Rectangle[]:
ℛ = Rectangle[];p = {p1, p2};{d, prul} = Maximize[-SignedRegionDistance[ℛ, p], p∈ℛ]Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p /. prul, d]}, {Red, Point[p /. prul]}}]Find the Chebyshev center and the radius of the largest inscribed ball for Triangle[]:
ℛ = Triangle[];{d, prul} = Maximize[-SignedRegionDistance[ℛ, p], p∈ℛ]Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p /. prul, d]}, {Red, Point[p /. prul]}}]Properties & Relations (4)
Maximize gives an exact global maximum of the objective function:
f = Expand[-Product[(x - i)(x - 100 - i), {i, 5}]];Maximize[f, x]Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], Green, Point[{x /. %[[2]], %[[1]]}]}]NMaximize attempts to find a global maximum numerically, but may find a local maximum:
NMaximize[f, x]Plot[f, {x, 0.5, 5.5}, Epilog -> {PointSize[Medium], Red, Point[{x /. %[[2]], %[[1]]}]}]FindMaximum finds local maxima depending on the starting point:
FindMaximum[f, {x, #}]& /@ {1, 50}Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], {Red, Point[{x /. %[[1, 2]], %[[1, 1]]}]}, {Green, Point[{x /. %[[2, 2]], %[[2, 1]]}]}}]The maximum point satisfies the constraints, unless messages say otherwise:
m = Maximize[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]x ^ 2 + y ^ 2 ≤ 1 /. m[[2]]The given point maximizes the distance from the point {2,
}:
RegionPlot[x ^ 2 + y ^ 2 ≤ 1, {x, -1.2, 2.2}, {y, -1.2, 2.2}, Epilog -> {PointSize[Medium], {Red, Point[{x, y} /. m[[2]]]}, {Green, Point[{2, 3 / 2}]}}]When the maximum is not attained, Maximize may give a point on the boundary:
Maximize[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 < 1}, {x, y}]
Here the objective function tends to the maximum value when y tends to infinity:
Maximize[{1 - x, x y == 1 && x > 0}, {x, y}]
Maximize can solve linear programming problems:
Maximize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]LinearProgramming can be used to solve the same problem given in matrix notation:
c = {2, 3, -1};
m = {{1, 1, 1}, {1, 1, 1}, {1, -1, 1}, {1, -1, 1}, {1, -1, -1}};
b = {{1, 1}, {2, -1}, {1, 1}, {2, -1}, {3, 0}};LinearProgramming[-c, m, b, -Infinity]This computes the maximum value:
c.%Use RegionBounds to compute the bounding box:
f = x^4 + 3 x^2 y + 2 x^2 y^2 - y^3 + y^4 ≤ 0;
ℛ = ImplicitRegion@@{f, {x, y}}RegionBounds[ℛ]Use Maximize and Minimize to compute the same bounds:
{{x1, x2}, {y1, y2}} = {Minimize[#, {x, y}∈ℛ][[1]], Maximize[#, {x, y}∈ℛ][[1]]}& /@ {x, y}Show[{Graphics[{LightBlue, Rectangle[{x1, y1}, {x2, y2}]}], RegionPlot[f, {x, x1 - 1, x2 + 1}, {y, y1 - 1, y2 + 1}]}]Possible Issues (1)
Maximize requires that all functions present in the input be real-valued:
Maximize[{-x - y, Sqrt[x] - Sqrt[y] == 0}, {x, y}]Values for which the equation is satisfied but the square roots are not real are disallowed:
{Sqrt[x] - Sqrt[y] == 0, Sqrt[x], Sqrt[y]} /. {x -> -1, y -> -1}Text
Wolfram Research (2003), Maximize, Wolfram Language function, https://reference.wolfram.com/language/ref/Maximize.html (updated 2021).
CMS
Wolfram Language. 2003. "Maximize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Maximize.html.
APA
Wolfram Language. (2003). Maximize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Maximize.html