Wolfram Language & System Documentation Center

RegionBounds

RegionBounds[reg]

gives the bounds for the region reg.

RegionBounds[reg,"type"]

gives region bounds of the specified "type".

Details and Options

RegionBounds is also known as bounding box and bounding volume.
RegionBounds returns a list {{x_min,x_max},{y_min,y_max},…} of length equal to RegionEmbeddingDimension[reg].
For an unbounded region, one or several of the coordinate ranges can contain Infinity.
The following region range "type" specifications can be given:
"Minimal" minimal bounds (default)

"Sufficient" sufficient bounds

"Finite" finite range of interest, not necessarily bounding

Examples

open all close all

Basic Examples (3)

Find bounds for a region in :

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];

Wolfram Language code: bounds = RegionBounds[ℛ]

Visualize the bounds:

Wolfram Language code: Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[bounds]}, {Black, ℛ}}]

Find bounds for a region in :

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];

Wolfram Language code: bounds = RegionBounds[ℛ]

Visualize the bounds:

Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[bounds]}, ℛ}, Boxed -> False]

Unbounded regions have infinite bounds:

Wolfram Language code: RegionBounds[HalfLine[{{0, 0}, {1, 1}}]]

Wolfram Language code: RegionBounds[InfinitePlane[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}]]

Scope (27)

Basic Uses (3)

By default, the "Minimal" bounding region is returned:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 4 - x y + y ^ 4 ≤ 1., {x, y}];

Wolfram Language code: b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}], DiscretizeRegion[ℛ]]

Use "Finite" to get some finite bounding region even if the region is not bounded:

Wolfram Language code:

ℛ = InfiniteLine[{0, 0}, {1, 1}];
b = RegionBounds[ℛ, "Finite"]

Visualize bounds:

Wolfram Language code: Show[Graphics[{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}], DiscretizeRegion[ℛ]]

Other range types return infinite ranges:

Wolfram Language code: RegionBounds[ℛ, "Minimal"]

Wolfram Language code: RegionBounds[ℛ, "Sufficient"]

"Finite" may not necessarily return the smallest bounding region:

Wolfram Language code: ℛ = Ellipsoid[{0, 0}, {{5, 2}, {2, 5}}];

Wolfram Language code:

showBounds[b_] := Show[Graphics[{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}], DiscretizeRegion[ℛ]]

Wolfram Language code: {bm, bf} = {RegionBounds[ℛ, "Minimal"], RegionBounds[ℛ, "Finite"]};

Wolfram Language code: showBounds /@ {bm, bf}

Special Regions (7)

Regions in :

Wolfram Language code: RegionBounds[Point[{{1}, {2}, {3}}]]

Wolfram Language code: RegionBounds[Interval[{1, 3}]]

Regions in :

Wolfram Language code: RegionBounds[Point[{{1, 1}, {2, 3}, {3, 5}}]]

Wolfram Language code: RegionBounds[Circle[{0, 0}, 3]]

Wolfram Language code: RegionBounds[Disk[{0, 0}, {3, 5}]]

Visualize a region range in :

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];

Wolfram Language code: b = RegionBounds[ℛ];

Wolfram Language code: Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}, {Black, ℛ}}]

Regions in :

Wolfram Language code: RegionBounds[Point[{{1, 1, 1}, {2, 3, 4}, {3, 5, 8}}]]

Wolfram Language code: RegionBounds[Line[{{1, 2, 3}, {4, 5, 6}}]]

Wolfram Language code: RegionBounds[Polygon[{{1, 0, 0}, {0, 2, 0}, {0, 0, 3}}]]

Wolfram Language code: RegionBounds[Cylinder[{{0, 0, 0}, {0, 0, 1}}, 2]]

Visualize a region range in :

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];

Wolfram Language code: b = RegionBounds[ℛ];

Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}, ℛ}, Boxed -> False]

Regions in :

Wolfram Language code: RegionBounds[Simplex[{{1, 0, 0, 0}, {0, 2, 0, 0}, {0, 0, 3, 0}, {0, 0, 0, 4}}]]

Wolfram Language code: RegionBounds[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

Wolfram Language code: RegionBounds[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

Specify the "Finite" type to get finite bounds for unbounded regions:

Wolfram Language code: ℛ = InfiniteLine[{{10, 11}, {12, 13}}];

Wolfram Language code: {RegionBounds[ℛ], RegionBounds[ℛ, "Finite"]}

Formula Regions (3)

A union of two disks as an ImplicitRegion:

Wolfram Language code:

ℛ = ImplicitRegion[x^2 + y^2 ≤ 4∨(x - 3)^2 + y^2 ≤ 3, {x, y}];
d = DiscretizeRegion[ℛ]

Wolfram Language code: b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], d]

A union of two cylinders as an ImplicitRegion:

Wolfram Language code:

ℛ = ImplicitRegion[x^2 + y^2 ≤ 2∨(x - 2)^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}];
d = DiscretizeRegion[ℛ, {{-4, 4}, {-2, 2}, {0, 2}}]

Wolfram Language code: b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}}, Boxed -> False], d]

A rational parametrization of a disk represented as a ParametricRegion:

Wolfram Language code:

ℛ = ParametricRegion[{(1 - t ^ 2) / (1 + t ^ 2), 2t / (1 + t ^ 2)}, {t}];
d = DiscretizeRegion[ℛ]

Wolfram Language code: b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], d]

Mesh Regions (4)

MeshRegion in 2D:

Wolfram Language code:

ℛ = DelaunayMesh[RandomReal[1, {50, 2}]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], ℛ]

MeshRegion in 3D:

Wolfram Language code:

ℛ = DelaunayMesh[RandomReal[1, {100, 3}]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}}, Boxed -> False], ℛ]

BoundaryMeshRegion in 2D:

Wolfram Language code:

ℛ = ConvexHullMesh[RandomReal[1, {50, 2}]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], ℛ]

BoundaryMeshRegion in 3D:

Wolfram Language code:

ℛ = ConvexHullMesh[RandomReal[1, {100, 3}]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}}, Boxed -> False], ℛ]

Derived Regions (4)

RegionIntersection of two regions:

Wolfram Language code:

ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], DiscretizeRegion[ℛ]]

RegionUnion of mixed-dimensional regions:

Wolfram Language code:

ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], DiscretizeRegion[ℛ]]

TransformedRegion:

Wolfram Language code:

ℛ = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{3, 2}]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code:

Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], DiscretizeRegion[ℛ, {{-3, 3}, {-2, 2}}]]

RegionBoundary:

Wolfram Language code: ℛ = RegionBoundary[Disk[{0, 0}, 1]]

Wolfram Language code: b = RegionBounds[ℛ]

Wolfram Language code: Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}, Blue, ℛ}]

Geographic Regions (2)

Polygons with GeoPosition:

Wolfram Language code:

ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, 
   {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, 
   {40.083686, -88.271512}, {40.083659999999995, -88.267046},  ... 33323}, {40.098112, -88.228687}, 
   {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, 
   {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, 
   {40.090741, -88.235745}}}]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}}, Boxed -> False], Region[ℛ]]

The boundary of a polygon with GeoGridPosition:

Wolfram Language code:

ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, 
   {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, 
   {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, 
   {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, 
   {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, 
   {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code: Show[Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], Region[Style[ℛ, Blue]]]

CSG Regions (2)

CSGRegion in 2D:

Wolfram Language code:

ℛ = CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code:

Show[
	Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], ℛ]

CSGRegion in 3D:

Wolfram Language code:

ℛ = CSGRegion["Difference", {Ball[], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code:

Show[
	Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], , Cuboid@@Transpose[b]}}], ℛ, Boxed -> False]

Subdivision Regions (2)

SubdivisionRegion in 2D:

Wolfram Language code:

ℛ = SubdivisionRegion[Rectangle[]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code:

Show[
	Graphics[{{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@Transpose[b]}}], ℛ]

SubdivisionRegion in 3D:

Wolfram Language code:

ℛ = SubdivisionRegion[Tetrahedron[]];
b = RegionBounds[ℛ]

Visualize bounds:

Wolfram Language code:

Show[
	Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], , Cuboid@@Transpose[b]}}], ℛ, Boxed -> False]

Applications (5)

Find a bounding Sphere to a region's bounding box:

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];

Compute corner points of bounding box:

Wolfram Language code: {min, max} = Transpose[RegionBounds[ℛ]];

Wolfram Language code: boundingBox = Cuboid[min, max];

Compute bounding sphere:

Wolfram Language code: boundingSphere = Sphere[RegionCentroid[boundingBox], EuclideanDistance[min, max] / 2];

Visualize bounding surfaces:

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox, boundingSphere}], Boxed -> False]

Find a bounding Ellipsoid to a region's bounding box:

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];

Wolfram Language code: bounds = RegionBounds[ℛ];

Compute the bounding box:

Wolfram Language code: boundingBox = Cuboid@@Transpose[bounds];

Compute a bounding ellipsoid to the bounding box:

Wolfram Language code: r = (Sqrt[3]/2) EuclideanDistance@@@bounds;

Wolfram Language code: boundingEllipsoid = Ellipsoid[RegionCentroid[boundingBox], r];

Visualize bounding surfaces:

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox, boundingEllipsoid}], Boxed -> False]

Check for possible region inclusion by checking if bounding boxes overlap:

Wolfram Language code:

r1 = Disk[{0, 0}, {3, 4}];
r2 = Disk[{9, 0}, {4, 3}];

Wolfram Language code: Graphics[{r1, r2}]

Compute bounds for each region:

Wolfram Language code: {b1, b2} = {RegionBounds[r1], RegionBounds[r2]};

For each dimension, check if bounds intersect:

Wolfram Language code: intersections = MapThread[Function[{i1, i2}, Interval[] =!= IntervalIntersection[Interval[i1], Interval[i2]]], {b1, b2}]

Bounding boxes overlap if and only if bounds in every dimension overlap:

Wolfram Language code: AllTrue[intersections, TrueQ]

Create a fast membership rejection test:

Wolfram Language code: ℛ = ImplicitRegion[4 z^4 + 9 (x^2 + y^2 - 4 z^2) ≤ 1, {x, y, z}];

Create a region member function:

Wolfram Language code: rmf = RegionMember[ℛ];

Create a member function for the region's bounding box:

Wolfram Language code: bounds = N@RegionBounds[ℛ];

Wolfram Language code: bmf = RegionMember[Cuboid@@Transpose[bounds]];

Generate points for testing:

Wolfram Language code: pts = RandomVariate[UniformDistribution[2bounds], 10 ^ 5];

Use region member function to select member points after filtering with bounding box member function:

Wolfram Language code: {tb, pb} = Timing[Select[Select[pts, bmf], rmf]];

Compare the timing of only using the region member function:

Wolfram Language code: {tr, pr} = Timing[Select[pts, rmf]];

Wolfram Language code: {tb, tr}

Both approaches return the same member points:

Wolfram Language code: pb === pr

Fit an oriented bounding box of least area to a region:

Wolfram Language code: ℛ = [image];

Find the transform for each edge of the region's convex hull that aligns it with the axis:

Wolfram Language code: chm = ConvexHullMesh[MeshCoordinates[ℛ]]

Wolfram Language code: lines = MeshPrimitives[chm, "Line"];

Wolfram Language code: yaxis = Line[{{0, 0}, {0, 1}}];

Wolfram Language code: tl = Table[Last[FindGeometricTransform[yaxis, l]], {l, lines}];

Compute oriented bounding boxes aligned with each edge of the convex hull:

Wolfram Language code: bounds = Table[RegionBounds[TransformedRegion[chm, t]], {t, tl}];

Wolfram Language code: bboxes = Table[Rectangle@@Transpose[b], {b, bounds}];

Find the transform that will orient the bounding box with the smallest area to the region:

Wolfram Language code: areas = Area /@ bboxes;

Wolfram Language code: index = Position[areas, Min[areas], 1][[1, 1]];

Wolfram Language code: tf = Last[FindGeometricTransform[lines[[index]], yaxis]];

Visualize the oriented bounding box and region:

Wolfram Language code: g = Graphics[{EdgeForm[LightRed], Lighter[Yellow, 0.5], GeometricTransformation[bboxes[[index]], tf]}];

Wolfram Language code: Show[g, ℛ]

Properties & Relations (7)

The range is finite for bounded regions:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Subscript[ℛ, 2] = InfiniteLine[{{0, 0}, {1, 1}}];

Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionBounds[Subscript[ℛ, 1]]}

The range is infinite for unbounded regions:

Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionBounds[Subscript[ℛ, 2]]}

RegionBounds may be used as input to DiscretizeRegion:

Wolfram Language code: ℛ = RegionUnion[Disk[], InfiniteLine[{0, 0}, {1, 1}]];

Wolfram Language code: bounds = RegionBounds[ℛ, "Finite"]

Double the default DiscretizeRegion bounding range:

Wolfram Language code: {DiscretizeRegion[ℛ, bounds], DiscretizeRegion[ℛ, 2 bounds]}

RegionBounds may be used as input to VoronoiMesh:

Wolfram Language code:

pts = RandomReal[{-1, 1}, {25, 2}];
g = Graphics[{Orange, Point[pts]}]

Wolfram Language code: bounds = RegionBounds[Point[pts]]

VoronoiMesh at varying bounding ranges:

Wolfram Language code: Table[Show[VoronoiMesh[pts, n bounds], g], {n, 3}]

RegionBounds may be used to specify a PlotRange to DiscretizeGraphics:

Wolfram Language code: ℛ = Disk[{0, 0}, 1];

Wolfram Language code: bounds = RegionBounds[ℛ, "Finite"]

VoronoiMesh at varying bounding ranges:

Wolfram Language code: Table[DiscretizeGraphics[ℛ, PlotRange -> (n bounds/3) + 1], {n, 3}]

Transpose a 2D region's bounds to get coordinates for Rectangle:

Wolfram Language code:

ℛ = Disk[{0, 0}, 2];
b = RegionBounds[ℛ]

Wolfram Language code: t = Transpose[b]

Wolfram Language code: Graphics[{EdgeForm[LightRed], Lighter[Yellow, 0.5], Rectangle@@t, LightBlue, ℛ}]

Transpose a 3D region's bounds to get coordinates for Cuboid:

Wolfram Language code:

ℛ = Ball[{0, 0, 0}, 2];
b = RegionBounds[ℛ]

Wolfram Language code: t = Transpose[b]

Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@t}, ℛ}, Boxed -> False]

Region bounds may be passed directly into UniformDistribution:

Wolfram Language code:

ℛ = Disk[{0, 0}, 1];
Graphics[{LightBlue, EdgeForm[Gray], ℛ}]

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ]

Uniformly sample over the bounded region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 3];

Wolfram Language code: Graphics[{ℛ, AbsolutePointSize[1.6], Orange, Point /@ pts}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

RegionBounds

Details and Options

Examples

Basic Examples (3)

Scope (27)

Basic Uses (3)

Special Regions (7)

Formula Regions (3)

Mesh Regions (4)

Derived Regions (4)

Geographic Regions (2)

CSG Regions (2)

Subdivision Regions (2)

Applications (5)

Properties & Relations (7)

Text

CMS

APA

BibTeX

BibLaTeX

RegionBounds

Details and Options

Examples

Basic Examples (3)

Scope (27)

Basic Uses (3)

Special Regions (7)

Formula Regions (3)

Mesh Regions (4)

Derived Regions (4)

Geographic Regions (2)

CSG Regions (2)

Subdivision Regions (2)

Applications (5)

Properties & Relations (7)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX