WOLFRAM

Wolfram Language & System Documentation Center

MergingFunction

is an option for functions such as TimeSeries and PersistentSymbol that specifies a function to apply to a list of values.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
TimeSeries  
EventSeries  
PersistentSymbol  
See Also
Related Guides
History
Cite this Page

MergingFunction

MergingFunction

is an option for functions such as TimeSeries and PersistentSymbol that specifies a function to apply to a list of values.

Details

  • MergingFunction is typically used to process a list of values for cases in which repetition, alternatives or aggregation is possible.
  • The merging function takes a list of given values and can return another list or a combination of these values into a single one.
  • Some common settings for MergingFunction returning another list include:
  • Identityreturn the list of all values
    Flattenreturn the flattened list of all values
    Unionreturn the sorted list without duplicates
    DeleteDuplicatesreturn the original list without duplicates
  • Some common settings for MergingFunction returning a single value include:
  • Firstreturn only the first value
    Lastreturn only the last value
    Apply[MissingFallback]return the first value that is not Missing
    Merge[f]merge associations using the function f
  • For lists of numeric values, other common settings returning a single value include:
  • Meanreturn the mean of all values
    Medianreturn the median of all values
    Minreturn the minimum value
    Maxreturn the maximum value
    Totalreturn the sum of all values

Examples

open all close all

Basic Examples  (3)

By default, TimeSeries takes the mean value for duplicate timestamps:

Wolfram Language code: TimeSeries[{1, 2, 3, 4, 5}, {{4.2, 4.2, 5.3, 6.1, 6.1}}]
Wolfram Language code: Normal[%]

Take the total of the corresponding values:

Wolfram Language code: TimeSeries[{1, 2, 3, 4, 5}, {{4.2, 4.2, 5.3, 6.1, 6.1}}, MergingFunction -> Total]// Normal

Create a number of persistent values with key "pval" at different persistence locations:

Wolfram Language code: PersistentSymbol["pval", "FrontEndSession"] = 1; PersistentSymbol["pval", "Local"] = 2;

Give all values that exist on $PersistencePath:

Wolfram Language code: PersistentSymbol["pval", MergingFunction -> Identity]

Give only the first value found:

Wolfram Language code: PersistentSymbol["pval", MergingFunction -> First]

Create a number of persistent values with key "lval" at different persistence locations:

Wolfram Language code: PersistentSymbol["lval", "KernelSession"] = {11, 12}; PersistentSymbol["lval", "FrontEndSession"] = {}; PersistentSymbol["lval", "Local"] = {1, {2, 12}};

Give the list of all values found:

Wolfram Language code: PersistentSymbol["lval", MergingFunction -> Identity]

Join the list values:

Wolfram Language code: PersistentSymbol["lval", MergingFunction -> Apply[Join]]

Flatten all sublists:

Wolfram Language code: PersistentSymbol["lval", MergingFunction -> Flatten]

Scope  (5)

TimeSeries  (1)

By default, TimeSeries takes the mean value for duplicate timestamps:

Wolfram Language code: values = Quantity[{20, 22, 21, 23, 22}, "Millimeters"];
Wolfram Language code: times = {Yesterday, Today, Tomorrow, Today, Tomorrow};
Wolfram Language code: TimeSeries[values, {times}]
Wolfram Language code: Normal[%]

Take the maximum of the corresponding values:

Wolfram Language code: TimeSeries[values, {times}, MergingFunction -> Max]// Normal

EventSeries  (1)

By default, EventSeries stores all time-value pairs, including duplicate times:

Wolfram Language code: values = RandomWord[5]
Wolfram Language code: times = RandomDate[Quantity[-3, "Days"], 5, DateGranularity -> "Day"]
Wolfram Language code: EventSeries[values, {times}]// Normal

Take the first value for each timestamp:

Wolfram Language code: EventSeries[values, {times}, MergingFunction -> First]// Normal

Group values corresponding to the same timestamp:

Wolfram Language code: EventSeries[values, {times}, MergingFunction -> Identity]// Normal

PersistentSymbol  (3)

Create a complement of persistent values with key "lval" at various locations:

Wolfram Language code: PersistentSymbol["lval", "FrontEndSession"] = {}; PersistentSymbol["lval", "KernelSession"] = {11, 12}; PersistentSymbol["lval", "Local"] = {1, {2, 12}};

List all existing values for the key "lval" on $PersistencePath:

Wolfram Language code: PersistentSymbol["lval", MergingFunction -> Identity]

By default, only the first value is returned:

Wolfram Language code: PersistentSymbol["lval"]

Join and flatten all sublists:

Wolfram Language code: PersistentSymbol["lval", MergingFunction -> Flatten]

Join all sublists:

Wolfram Language code: PersistentSymbol["lval", MergingFunction -> Apply[Join]]

Create a complement of persistent associations with name "aval" at various locations:

Wolfram Language code: PersistentSymbol["aval", "FrontEndSession"] = <|"key1" -> 2, "key2" -> {3, 4}|>; PersistentSymbol["aval", "KernelSession"] = <|"key1" -> 3|>; PersistentSymbol["aval", "Local"] = <|"key2" -> 2, "key3" -> {8, 9}|>;

List all existing values on $PersistencePath:

Wolfram Language code: PersistentSymbol["aval", MergingFunction -> Identity]

Merge the values of identical keys in the associations:

Wolfram Language code: PersistentSymbol["aval", MergingFunction -> Merge[Flatten]]

Define a default value for "mylist" with a custom merging function:

Wolfram Language code: PersistentSymbol["mylist", "Installation"] = {};
Wolfram Language code: io = PersistentObject["mylist", "Installation"]
Wolfram Language code: io["MergingFunction"] = Flatten;

Define additional values at different persistence locations:

Wolfram Language code: PersistentSymbol["mylist", "Local"] = 3; PersistentSymbol["mylist", "FrontEndSession"] = {1, 2};

For looking up values, the custom merging function is now used:

Wolfram Language code: PersistentSymbol["mylist"]
Wolfram Research (2017), MergingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/MergingFunction.html (updated 2026).

Text

Wolfram Research (2017), MergingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/MergingFunction.html (updated 2026).

CMS

Wolfram Language. 2017. "MergingFunction." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/MergingFunction.html.

APA

Wolfram Language. (2017). MergingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MergingFunction.html

BibTeX

@misc{reference.wolfram_2026_mergingfunction, author="Wolfram Research", title="{MergingFunction}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/MergingFunction.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mergingfunction, organization={Wolfram Research}, title={MergingFunction}, year={2026}, url={https://reference.wolfram.com/language/ref/MergingFunction.html}, note=[Accessed: 12-June-2026]}