WOLFRAM

Wolfram Language & System Documentation Center

NevilleThetaD[z,m]

gives the Neville theta function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

NevilleThetaD

NevilleThetaD[z,m]

gives the Neville theta function .

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • NevilleThetaD[z,m] is a meromorphic function of z and has a complicated branch cut structure in the complex m plane.
  • For certain special arguments, NevilleThetaD automatically evaluates to exact values.
  • NevilleThetaD can be evaluated to arbitrary numerical precision.
  • NevilleThetaD automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: NevilleThetaD[2., 0.3]

Plot over a subset of the reals::

Wolfram Language code: Plot[NevilleThetaD[x, 1 / 3], {x, -10, 10}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[NevilleThetaD[z ^ 2, 1 / 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Scope  (28)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: NevilleThetaD[2, .5]
Wolfram Language code: NevilleThetaD[E, .7]

Evaluate to high precision:

Wolfram Language code: N[NevilleThetaD[1 / 6, 1 / 3], 50]
Wolfram Language code: N[NevilleThetaD[6Pi, 7 / 11], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: NevilleThetaD[1.21111111111000001, 5]

Complex number inputs:

Wolfram Language code: N[NevilleThetaD[2 + I, 5 - I]]

Evaluate efficiently at high precision:

Wolfram Language code: NevilleThetaD[2, 1 / 7`100]//Timing
Wolfram Language code: NevilleThetaD[2, 13`10000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: NevilleThetaD[Around[2, 0.01], 1 / 2]

Compute the elementwise values of an array:

Wolfram Language code: NevilleThetaD[π I / 3, {{.2, 1}, {1, .2}}]

Or compute the matrix NevilleThetaD function using MatrixFunction:

Wolfram Language code: MatrixFunction[NevilleThetaD[π I / 3, #]&, {{.2, 1}, {1, .2}}]//N

Specific Values  (3)

Values at corners of the fundamental cell:

Wolfram Language code: Table[NevilleThetaD[u1 EllipticK[m] + u2 I EllipticK[1 - m], m], {u1, {0, 1}}, {u2, {0, 1}}]

NevilleThetaD for special values of elliptic parameter:

Wolfram Language code: NevilleThetaD[u, 0]
Wolfram Language code: NevilleThetaD[u, 1]

Find the first positive maximum of NevilleThetaD[x,1/2]:

Wolfram Language code: xmax = x /. FindRoot[D[NevilleThetaD[x, 1 / 2 ], x] == 0, {x, 3}]
Wolfram Language code: Plot[NevilleThetaD[x, 1 / 2 ], {x, -10, 10}, Epilog -> Style[Point[{xmax, NevilleThetaD[xmax, 1 / 2 ]}], PointSize[Large], Red]]

Visualization  (3)

Plot the NevilleThetaD functions for various values of the parameter:

Wolfram Language code: Plot[{NevilleThetaD[x, -1 / 2], NevilleThetaD[x, 1 / 2], NevilleThetaD[x, 1 / 3]}, {x, -5, 5}]

Plot NevilleThetaD as a function of its parameter :

Wolfram Language code: Plot[{NevilleThetaD[1, m], NevilleThetaD[2, m], NevilleThetaD[3, m]}, {m, -10, 1}, PlotRange -> Automatic]

Plot the real part of TemplateBox[{z, {1, /, 2}}, NevilleThetaD]:

Wolfram Language code: ComplexContourPlot[Re[NevilleThetaD[z, 1 / 2]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{z, {1, /, 2}}, NevilleThetaD]:

Wolfram Language code: ComplexContourPlot[Im[NevilleThetaD[z, 1 / 2]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

Function Properties  (12)

The real domain of NevilleThetaD:

Wolfram Language code: FunctionDomain[NevilleThetaD[x, 0], x]

The complex domain of NevilleThetaD:

Wolfram Language code: FunctionDomain[NevilleThetaD[z, 0], z, Complexes]

Function range of TemplateBox[{x, 0}, NevilleThetaD]:

Wolfram Language code: FunctionRange[NevilleThetaD[x, 0], x, y]//Quiet

Function range of TemplateBox[{x, 1}, NevilleThetaD]:

Wolfram Language code: FunctionRange[NevilleThetaD[x, 1], x, y]//Quiet

NevilleThetaD is an even function:

Wolfram Language code: NevilleThetaD[-x, 1] == NevilleThetaD[x, 1]

NevilleThetaD threads elementwise over lists:

Wolfram Language code: NevilleThetaD[{2, 3, 4, 5}, 0.5]

TemplateBox[{x, m}, NevilleThetaD] is an analytic function of for :

Wolfram Language code: FunctionAnalytic[NevilleThetaD[x, m], x]

TemplateBox[{x, {1, /, 3}}, NevilleThetaD] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[Subscript[ϑ, d](x❘(1/3)), x]

TemplateBox[{x, {1, /, 3}}, NevilleThetaD] is not injective:

Wolfram Language code: FunctionInjective[Subscript[ϑ, d](x❘(1/3)), x]
Wolfram Language code: Plot[{NevilleThetaD[x, 1 / 3], .95}, {x, -5, 5}]

TemplateBox[{x, {1, /, 3}}, NevilleThetaD] is not surjective:

Wolfram Language code: FunctionSurjective[Subscript[ϑ, d](x❘(1/3)), x]
Wolfram Language code: Plot[{Subscript[ϑ, d](x❘(1/3)), 1.2}, {x, -10, 10}]

TemplateBox[{x, {1, /, m}}, NevilleThetaD] is non-negative:

Wolfram Language code: Table[FunctionSign[Subscript[ϑ, d](x❘(1/m)), x], {m, 4}]

TemplateBox[{x, {1, /, m}}, NevilleThetaD] does not have either singularity or discontinuity for noninteger m:

Wolfram Language code: Table[FunctionSingularities[Subscript[ϑ, d](x❘(1/m)), x], {m, 4}]
Wolfram Language code: Table[FunctionDiscontinuities[Subscript[ϑ, d](x❘(1/m)), x], {m, 4}]

TemplateBox[{x, m}, NevilleThetaD] is affine only for and otherwise it is neither convex nor concave:

Wolfram Language code: Table[FunctionConvexity[Subscript[ϑ, d](x❘1 / m), x], {m, 5}]

TraditionalForm formatting:

Wolfram Language code: NevilleThetaD[z, m]//TraditionalForm

Differentiation  (2)

The first-order derivatives:

Wolfram Language code: D[NevilleThetaD[u, m], u]
Wolfram Language code: D[NevilleThetaD[u, m], m]

Higher-order derivatives:

Wolfram Language code: Table[D[NevilleThetaD[u, 1 / 3], {u, k}], {k, 1, 3}]//Simplify//TraditionalForm

Plot the higher-order derivatives:

Wolfram Language code: Plot[%, {u, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[NevilleThetaD[x, m], {x, 1, 2}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[NevilleThetaD[x, 1 / 3], {x, 1, m}], {m, 1, 5, 2}]//N; Plot[{NevilleThetaD[x, 1 / 3], terms}, {x, -5, 5}, MaxRecursion -> 1]

The Taylor expansion for small elliptic parameter :

Wolfram Language code: Series[NevilleThetaD[u, m], {m, 0, 2}]

The Taylor expansion around :

Wolfram Language code: Series[NevilleThetaD[u, m], {m, 1, 1}]

Generalizations & Extensions  (1)

NevilleThetaD can be applied to power series:

Wolfram Language code: NevilleThetaD[Sin[z] + O[z]^4, m]

Applications  (8)

Plot over the arguments' plane:

Wolfram Language code: Plot3D[NevilleThetaD[x, m], {x, -3 / 2Pi, 3 / 2Pi}, {m, -1, 1}]

Conformal map from a unit triangle to the unit disk:

Wolfram Language code: w[z_] := With[{ζ = (z Gamma[1 / 3]^3/2^-2 / 33^1 / 44π (1 / 2)), m = Sin[Pi / 12] ^ 2}, (2 ^ (1 / 3)(1 + Sqrt[3])(NevilleThetaC[ζ, m] - NevilleThetaN[ζ, m]) ((-2 + Sqrt[3])NevilleThetaC[ζ, m] - NevilleThetaN[ζ, m])) / (NevilleThetaC[ζ, m] ^ 2 - 2NevilleThetaC[ζ, m]NevilleThetaN[ζ, m] + NevilleThetaN[ζ, m] ^ 2 + 2 3 ^ (1 / 4)NevilleThetaD[ζ, m] NevilleThetaS[ζ, m])]

Show points before and after the map:

Wolfram Language code: trianglePoints = Flatten[Table[α Table[N[#1 + j / 16(#2 - #1)], {j, 0, 16}]&@@@({{2, -1 + I Sqrt[3]}, {-1 + I Sqrt[3], -1 - I Sqrt[3]}, {-1 - I Sqrt[3], 2}} / (2Sqrt[3])), {α, 1 / 8, 1, 1 / 8}]];
Wolfram Language code: Row[{Graphics[Point[{Re[#], Im[#]}]& /@ trianglePoints, Frame -> True, ImageSize -> Small], Graphics[Point[{Re[#], Im[#]}]& /@ (w /@ trianglePoints), Frame -> True, ImageSize -> Small]}, Spacer[20]]

Uniformization of a Fermat cubic :

Wolfram Language code: {a[u_], b[u_]} = With[{m = (2 - Sqrt[3]) / 4}, {-1 + (4 3^1 / 4 NevilleThetaD[u, m] NevilleThetaS[u, m]) / ((NevilleThetaC[u, m] - NevilleThetaN[u, m])^2 + 2 3^1 / 4 NevilleThetaD[u, m] NevilleThetaS[u, m]), -(2^1 / 3 (NevilleThetaC[u, m] - NevilleThetaN[u, m]) ((-1 + Sqrt[3]) NevilleThetaC[u, m] + (1 + Sqrt[3]) NevilleThetaN[u, m])) / ((NevilleThetaC[u, m] - NevilleThetaN[u, m])^2 + 2 3^1 / 4 NevilleThetaD[u, m] NevilleThetaS[u, m])}];

Plot the curve for real :

Wolfram Language code: ListPlot[Table[{a[u], b[u]}, {u, -Pi, Pi, 0.1}], AspectRatio -> Automatic]

Verify that points on the curve satisfy :

Wolfram Language code: Cases[%, Point[l__] :> Map[Total, l ^ 3], Infinity, 1]

Parametrize a lemniscate by arc length:

Wolfram Language code: lemniscate[s_] := {NevilleThetaC[Sqrt[2] s, 1 / 2] NevilleThetaD[Sqrt[2] s, 1 / 2], NevilleThetaC[Sqrt[2] s, 1 / 2] NevilleThetaS[Sqrt[2] s, 1 / 2] / Sqrt[2] } / NevilleThetaN[Sqrt[2] s, 1 / 2]^2

Show the classical and arc length parametrizations:

Wolfram Language code: r[θ_] := If[Cos[2θ] > 0, Sqrt[Cos[2θ]], 0];
Wolfram Language code: Row[{ParametricPlot[{r[θ]Cos[θ], r[θ]Sin[θ]}, {θ, -Pi, Pi}, ImageSize -> Small], ParametricPlot[Evaluate[lemniscate[s]], {s, 0, (Gamma[(1/4)]^2/Sqrt[2 π])}, ImageSize -> Small]}, Spacer[20]]

Complex parametrization of a sphere:

Wolfram Language code: ellipticSphere[{α_, β_}, m_] := {(Sqrt[m] NevilleThetaS[α, m] NevilleThetaS[β, m]/NevilleThetaN[α, m] NevilleThetaN[β, m]), (I Sqrt[m] NevilleThetaC[α, m] NevilleThetaC[β, m]/Sqrt[1 - m] NevilleThetaN[α, m] NevilleThetaN[β, m]), (NevilleThetaD[α, m] NevilleThetaD[β, m]/Sqrt[1 - m] NevilleThetaN[α, m] NevilleThetaN[β, m])}

The square of all points on the complex sphere is 1:

Wolfram Language code: N[ellipticSphere[{1 - 2I, 3 + 2I}, 1 / 2], 20]
Wolfram Language code: %.%

Conformal map from an ellipse to the unit disk:

Wolfram Language code: w[z_, {a_, b_}] := With[{m = InverseEllipticNomeQ[(a - b) ^ 2 / (a + b) ^ 2]}, (Sqrt[m]NevilleThetaS[(2ArcSin[z / Sqrt[a ^ 2 - b ^ 2]] EllipticK[m]) / Pi, m]) / NevilleThetaN[ (2ArcSin[z / Sqrt[a ^ 2 - b ^ 2]]EllipticK[m]) / Pi, m]]

Visualize the map:

Wolfram Language code: ParametricPlot[{Re[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], Im[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]]}, {ρ, 0, 1}, {φ, 0, 2Pi}, Mesh -> 15]

Cartesian coordinates of a pendulum:

Wolfram Language code: x[t_] = (2l NevilleThetaD[Sqrt[g / l]t, Sin[φ0 / 2] ^ 2] * NevilleThetaS[Sqrt[g / l]t, Sin[φ0 / 2] ^ 2]Sin[φ0 / 2]) / NevilleThetaN[Sqrt[g / l]t, Sin[φ0 / 2] ^ 2] ^ 2; y[t_] = l - (2l NevilleThetaD[Sqrt[g / l]t, Sin[φ0 / 2] ^ 2] ^ 2) / NevilleThetaN[Sqrt[g / l]t, Sin[φ0 / 2] ^ 2] ^ 2;

Plot the time dependence of the coordinates:

Wolfram Language code: Block[{l = 1, g = 9.81, φ0 = Pi / 4}, Plot[{x[t], y[t]}, {t, 0.1, 12}]]

Plot the trajectory:

Wolfram Language code: ParametricPlot[{x[t], y[t]} /. {l -> 1, g -> 9.81, φ0 -> Pi / 2}, {t, 0.1, 12}]

Current flow in a rectangular conducting sheet with voltage applied at a pair of opposite corners:

Wolfram Language code: flow[m_] = (NevilleThetaD[x, m] NevilleThetaD[y, 1 - m] NevilleThetaS[x, m] NevilleThetaS[y, 1 - m]) / (NevilleThetaC[x, m] NevilleThetaC[y, 1 - m] NevilleThetaN[x, m] NevilleThetaN[y, 1 - m]);

Plot the flow lines:

Wolfram Language code: With[{m = 0.4}, ContourPlot[flow[m], {x, 0, EllipticK[m]}, {y, 0, EllipticK[1 - m]}, ContourShading -> False, MaxRecursion -> 1, Contours -> {0.02, 0.13, 0.3, 0.54, 0.9, 1.46, 2.53, 5.17, 28.4}]]

Properties & Relations  (4)

Basic simplifications are automatically carried out:

Wolfram Language code: NevilleThetaD[-z, m]
Wolfram Language code: NevilleThetaD[z + 2 EllipticK[m], m]

All Neville theta functions are a multiple of shifted NevilleThetaD:

Wolfram Language code: NevilleThetaD[z + EllipticK[m], m]
Wolfram Language code: NevilleThetaD[z + I EllipticK[1 - m], m]
Wolfram Language code: NevilleThetaD[z + EllipticK[m] + I EllipticK[1 - m], m]//Simplify

Use FullSimplify for expressions containing Neville theta functions:

Wolfram Language code: NevilleThetaS[z, m] == (NevilleThetaD[z, m]/JacobiDS[z, m])//FullSimplify

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[NevilleThetaD[z, 1 / 3]^3 + NevilleThetaD[z, 1 / 2] + z == 1, {z, 1}]

Possible Issues  (1)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: NevilleThetaS[10. ^ 3, 2]
Wolfram Language code: Block[{$MaxExtraPrecision = 100}, N[NevilleThetaS[10 ^ 3, 2], 20]]
Wolfram Research (1996), NevilleThetaD, Wolfram Language function, https://reference.wolfram.com/language/ref/NevilleThetaD.html.

Text

Wolfram Research (1996), NevilleThetaD, Wolfram Language function, https://reference.wolfram.com/language/ref/NevilleThetaD.html.

CMS

Wolfram Language. 1996. "NevilleThetaD." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NevilleThetaD.html.

APA

Wolfram Language. (1996). NevilleThetaD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NevilleThetaD.html

BibTeX

@misc{reference.wolfram_2026_nevillethetad, author="Wolfram Research", title="{NevilleThetaD}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/NevilleThetaD.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_nevillethetad, organization={Wolfram Research}, title={NevilleThetaD}, year={1996}, url={https://reference.wolfram.com/language/ref/NevilleThetaD.html}, note=[Accessed: 13-June-2026]}