WOLFRAM

Wolfram Language & System Documentation Center

NevilleThetaS[z,m]

gives the Neville theta function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

NevilleThetaS

NevilleThetaS[z,m]

gives the Neville theta function .

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • NevilleThetaS[z,m] is a meromorphic function of z and has a complicated branch cut structure in the complex m plane.
  • For certain special arguments, NevilleThetaS automatically evaluates to exact values.
  • NevilleThetaS can be evaluated to arbitrary numerical precision.
  • NevilleThetaS automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: NevilleThetaS[2.5, 0.3]

Plot over a subset of the reals::

Wolfram Language code: Plot[NevilleThetaS[x, 1 / 3], {x, -10, 10}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[NevilleThetaS[z, 1 / 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Scope  (27)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: NevilleThetaS[-5., 1]
Wolfram Language code: NevilleThetaS[Pi / 6., 0]

Evaluate to high precision:

Wolfram Language code: N[NevilleThetaS[5 / 7, 2 / 3], 50]
Wolfram Language code: N[NevilleThetaS[2Pi, 7 / 11], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: NevilleThetaS[2.211111100011100001, 2 / 3]

Complex number inputs:

Wolfram Language code: N[NevilleThetaS[1 + I, 5 - I]]

Evaluate efficiently at high precision:

Wolfram Language code: NevilleThetaS[2, 1 / 2`100]//Timing
Wolfram Language code: NevilleThetaS[2, 17`1000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: NevilleThetaS[Around[2, 0.01], 1 / 2]

Compute the elementwise values of an array:

Wolfram Language code: NevilleThetaS[π I / 3, {{0, 1}, {1, 0}}]

Or compute the matrix NevilleThetaS function using MatrixFunction:

Wolfram Language code: MatrixFunction[NevilleThetaS[π I / 3, #]&, {{0, 1}, {1, 0}}]//N

Specific Values  (3)

Values at corners of the fundamental cell:

Wolfram Language code: Table[NevilleThetaS[u1 EllipticK[m] + u2 I EllipticK[1 - m], m], {u1, {0, 1}}, {u2, {0, 1}}]

NevilleThetaS for special values of elliptic parameter:

Wolfram Language code: NevilleThetaS[x, 0]
Wolfram Language code: NevilleThetaS[x, 1]

Find the first positive maximum of NevilleThetaS[x,1/2]:

Wolfram Language code: xmax = x /. FindRoot[D[NevilleThetaS[x, 1 / 2 ], x] == 0, {x, 2}]
Wolfram Language code: Plot[NevilleThetaS[x, 1 / 2 ], {x, -9, 9}, Epilog -> Style[Point[{xmax, NevilleThetaS[xmax, 1 / 2 ]}], PointSize[Large], Red]]

Visualization  (3)

Plot the NevilleThetaS functions for various values of the parameter:

Wolfram Language code: Plot[{NevilleThetaS[x, -1 / 2], NevilleThetaS[x, 1 / 2], NevilleThetaS[x, 1 / 3]}, {x, -5, 5}]

Plot NevilleThetaS as a function of its parameter :

Wolfram Language code: Plot[{NevilleThetaS[1, m], NevilleThetaS[2, m], NevilleThetaS[3, m]}, {m, -10, 5}, PlotRange -> Automatic]

Plot the real part of TemplateBox[{z, {1, /, 2}}, NevilleThetaS]:

Wolfram Language code: ComplexContourPlot[Re[NevilleThetaS[z, 1 / 2]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{z, {1, /, 2}}, NevilleThetaS]:

Wolfram Language code: ComplexContourPlot[Im[NevilleThetaS[z, 1 / 2]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

Function Properties  (11)

The real domain of NevilleThetaS:

Wolfram Language code: FunctionDomain[NevilleThetaS[x, 0], x]

The complex domain of NevilleThetaS:

Wolfram Language code: FunctionDomain[NevilleThetaS[z, 0], z, Complexes]

Function range of TemplateBox[{x, 0}, NevilleThetaS]:

Wolfram Language code: FunctionRange[NevilleThetaS[x, 0], x, y]//Quiet

Function range of TemplateBox[{x, 1}, NevilleThetaS]:

Wolfram Language code: FunctionRange[NevilleThetaS[x, 1], x, y]//Quiet

NevilleThetaS threads elementwise over lists:

Wolfram Language code: NevilleThetaS[{1, 2, 3, 4}, 0.4]

TemplateBox[{x, m}, NevilleThetaS] is an analytic function of for :

Wolfram Language code: FunctionAnalytic[NevilleThetaS[x, m], x]

TemplateBox[{x, {1, /, 3}}, NevilleThetaS] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[Subscript[ϑ, s](x❘(1/3)), x]

TemplateBox[{x, {1, /, 3}}, NevilleThetaS] is not injective:

Wolfram Language code: FunctionInjective[Subscript[ϑ, s](x❘(1/3)), x]
Wolfram Language code: Plot[{NevilleThetaS[x, 1 / 3], .5}, {x, -7, 7}]

TemplateBox[{x, {1, /, 3}}, NevilleThetaS] is not surjective:

Wolfram Language code: FunctionSurjective[Subscript[ϑ, s](x❘(1/3)), x]
Wolfram Language code: Plot[{Subscript[ϑ, s](x❘(1/3)), 1.3}, {x, -10, 10}]

TemplateBox[{x, m}, NevilleThetaS] is neither non-negative nor non-positive for noninteger :

Wolfram Language code: Table[FunctionSign[Subscript[ϑ, s](x❘(1/n)), x], {n, 4}]

TemplateBox[{x, m}, NevilleThetaS] has no singularities or discontinuities for noninteger :

Wolfram Language code: Table[FunctionSingularities[Subscript[ϑ, d](x❘(1/n)), x], {n, 4}]
Wolfram Language code: Table[FunctionDiscontinuities[Subscript[ϑ, d](x❘(1/n)), x], {n, 4}]

TemplateBox[{x, m}, NevilleThetaS] is affine only for and otherwise it is neither convex nor concave:

Wolfram Language code: Table[FunctionConvexity[Subscript[ϑ, d](x❘1 / n), x], {n, 5}]

TraditionalForm formatting:

Wolfram Language code: NevilleThetaS[z, m]//TraditionalForm

Differentiation  (2)

The first-order derivatives:

Wolfram Language code: D[NevilleThetaS[u, m], u]
Wolfram Language code: D[NevilleThetaS[u, m], m]

Higher-order derivatives:

Wolfram Language code: Table[D[NevilleThetaS[u, 1 / 3], {u, k}], {k, 1, 3}]//Simplify//TraditionalForm

Plot the higher-order derivatives:

Wolfram Language code: Plot[%, {u, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[NevilleThetaS[x, m], {x, 1, 2}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[NevilleThetaS[x, 1 / 2], {x, 1, m}], {m, 1, 3, 1}]//N; Plot[{NevilleThetaS[x, 1 / 2], terms}, {x, -10, 10}]

The Taylor expansion for small elliptic parameter :

Wolfram Language code: Series[NevilleThetaS[x, m], {m, 0, 2}]

The Taylor expansion around :

Wolfram Language code: Series[NevilleThetaS[x, m], {m, 1, 1}]

Generalizations & Extensions  (1)

NevilleThetaS can be applied to power series:

Wolfram Language code: NevilleThetaS[Sin[z] + O[z]^4, m]

Applications  (7)

Plot over the arguments' plane:

Wolfram Language code: Plot3D[NevilleThetaS[x, m], {x, -3 / 2Pi, 3 / 2Pi}, {m, -1, 1}]

Conformal map from a unit triangle to the unit disk:

Wolfram Language code: w[z_] := With[{ζ = (z Gamma[(1/3)]^3/π 2^1 / 3 3^1 / 4), m = Sin[(π/12)]^2}, (2^1 / 3 (1 + Sqrt[3]) (NevilleThetaC[ζ, m] - NevilleThetaN[ζ, m]) ((-2 + Sqrt[3]) NevilleThetaC[ζ, m] - NevilleThetaN[ζ, m])) / (NevilleThetaC[ζ, m]^2 - 2 NevilleThetaC[ζ, m] NevilleThetaN[ζ, m] + NevilleThetaN[ζ, m]^2 + 2 3^1 / 4 NevilleThetaD[ζ, m] NevilleThetaS[ζ, m])]

Show points before and after the map:

Wolfram Language code: trianglePoints = Flatten[Table[α Table[N[#1 + j / 16(#2 - #1)], {j, 0, 16}]&@@@({{2, -1 + I Sqrt[3]}, {-1 + I Sqrt[3], -1 - I Sqrt[3]}, {-1 - I Sqrt[3], 2}} / (2Sqrt[3])), {α, 1 / 8, 1, 1 / 8}]];
Wolfram Language code: Row[{Graphics[Point[{Re[#], Im[#]}]& /@ trianglePoints, Frame -> True, ImageSize -> Small], Graphics[Point[{Re[#], Im[#]}]& /@ (w /@ trianglePoints), Frame -> True, ImageSize -> Small]}, Spacer[20]]

Uniformization of a Fermat cubic :

Wolfram Language code: {a[u_], b[u_]} = With[{m = (2 - Sqrt[3]) / 4}, {-1 + (4 3^1 / 4 NevilleThetaD[u, m] NevilleThetaS[u, m]) / ((NevilleThetaC[u, m] - NevilleThetaN[u, m])^2 + 2 3^1 / 4 NevilleThetaD[u, m] NevilleThetaS[u, m]), -(2^1 / 3 (NevilleThetaC[u, m] - NevilleThetaN[u, m]) ((-1 + Sqrt[3]) NevilleThetaC[u, m] + (1 + Sqrt[3]) NevilleThetaN[u, m])) / ((NevilleThetaC[u, m] - NevilleThetaN[u, m])^2 + 2 3^1 / 4 NevilleThetaD[u, m] NevilleThetaS[u, m])}];

Plot the curve for real :

Wolfram Language code: ListPlot[Table[{a[u], b[u]}, {u, -Pi, Pi, 0.1}], AspectRatio -> Automatic, ImageSize -> Small]

Verify that points on the curve satisfy :

Wolfram Language code: Cases[%, Point[l__] :> Map[Total, l ^ 3], Infinity, 1]

Current flow in a rectangular conducting sheet with voltage applied at a pair of opposite corners:

Wolfram Language code: flow[m_] = NevilleThetaD[x, m] NevilleThetaD[y, 1 - m] NevilleThetaS[x, m] NevilleThetaS[y, 1 - m] / (NevilleThetaC[x, m] NevilleThetaC[y, 1 - m] NevilleThetaN[x, m] NevilleThetaN[y, 1 - m]);

Plot the flow lines:

Wolfram Language code: With[{m = 0.2}, ContourPlot[flow[m], {x, 0, EllipticK[m]}, {y, 0, EllipticK[1 - m]}, ContourShading -> False, Contours -> 50]]

Parametrize a lemniscate by arc length:

Wolfram Language code: lemniscate[s_] := With[{t = Sqrt[2]s}, {NevilleThetaC[t, (1/2)] NevilleThetaD[t, (1/2)], (NevilleThetaC[t, (1/2)] NevilleThetaS[t, (1/2)]/Sqrt[2])} / NevilleThetaN[t, (1/2)]^2]

Show the classical and arc length parametrizations:

Wolfram Language code: r[θ_] := If[Cos[2θ] > 0, Sqrt[Cos[2θ]], 0];
Wolfram Language code: Row[{ParametricPlot[{r[θ]Cos[θ], r[θ]Sin[θ]}, {θ, -Pi, Pi}, ImageSize -> Small], ParametricPlot[Evaluate[lemniscate[s]], {s, 0, (Gamma[(1/4)]^2/Sqrt[2 π])}, ImageSize -> Small]}, Spacer[20]]

Complex parametrization of a sphere:

Wolfram Language code: ellipticSphere[{α_, β_}, m_] := {(Sqrt[m] NevilleThetaS[α, m] NevilleThetaS[β, m]/NevilleThetaN[α, m] NevilleThetaN[β, m]), (I Sqrt[m] NevilleThetaC[α, m] NevilleThetaC[β, m]/Sqrt[1 - m] NevilleThetaN[α, m] NevilleThetaN[β, m]), (NevilleThetaD[α, m] NevilleThetaD[β, m]/Sqrt[1 - m] NevilleThetaN[α, m] NevilleThetaN[β, m])}

The square of all points on the complex sphere is 1:

Wolfram Language code: N[ellipticSphere[{1 - 2I, 3 + 2I}, 1 / 2], 20]
Wolfram Language code: %.%

Conformal map from an ellipse to the unit disk:

Wolfram Language code: w[z_, {a_, b_}] := With[{m = InverseEllipticNomeQ[(a - b) ^ 2 / (a + b) ^ 2]}, (Sqrt[m]NevilleThetaS[(2ArcSin[z / Sqrt[a ^ 2 - b ^ 2]] EllipticK[m]) / Pi, m]) / NevilleThetaN[ (2ArcSin[z / Sqrt[a ^ 2 - b ^ 2]]EllipticK[m]) / Pi, m]]

Visualize the map:

Wolfram Language code: ParametricPlot[{Re[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], Im[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]]}, {ρ, 0, 1}, {φ, 0, 2Pi}, Mesh -> 15]

Properties & Relations  (4)

Basic simplifications are automatically carried out:

Wolfram Language code: NevilleThetaS[-z, m]
Wolfram Language code: NevilleThetaS[z + 2 EllipticK[m], m]

All Neville theta functions are a multiple of shifted NevilleThetaS:

Wolfram Language code: NevilleThetaS[z + EllipticK[m], m]
Wolfram Language code: NevilleThetaS[z + I EllipticK[1 - m], m]
Wolfram Language code: NevilleThetaS[z + EllipticK[m] + I EllipticK[1 - m], m]//Simplify

Use FullSimplify for expressions containing Neville theta functions:

Wolfram Language code: NevilleThetaS[z, m] == (NevilleThetaD[z, m]/JacobiDS[z, m])//FullSimplify

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[NevilleThetaS[z, (1/3)]^3 + NevilleThetaS[z, (1/2)] + z == 3, {z, 1}]

Possible Issues  (1)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: NevilleThetaS[10. ^ 3, 2]
Wolfram Language code: Block[{$MaxExtraPrecision = 100}, N[NevilleThetaS[10 ^ 3, 2], 20]]
Wolfram Research (1996), NevilleThetaS, Wolfram Language function, https://reference.wolfram.com/language/ref/NevilleThetaS.html.

Text

Wolfram Research (1996), NevilleThetaS, Wolfram Language function, https://reference.wolfram.com/language/ref/NevilleThetaS.html.

CMS

Wolfram Language. 1996. "NevilleThetaS." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NevilleThetaS.html.

APA

Wolfram Language. (1996). NevilleThetaS. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NevilleThetaS.html

BibTeX

@misc{reference.wolfram_2026_nevillethetas, author="Wolfram Research", title="{NevilleThetaS}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/NevilleThetaS.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_nevillethetas, organization={Wolfram Research}, title={NevilleThetaS}, year={1996}, url={https://reference.wolfram.com/language/ref/NevilleThetaS.html}, note=[Accessed: 13-June-2026]}