Wolfram Language & System Documentation Center

Prism

Prism[{p₁,…,p₆}]

represents a filled prism connecting the triangles {p₁,p₂,p₃} and {p₄,p₅,p₆}.

Details and Options

Prism can be used as a geometric region and a graphics primitive.
Prism represents a filled polyhedron given by the polygon faces {p₁,p₃,p₆,p₄}, {p₂,p₁,p₄,p₅}, {p₆,p₃,p₂,p₅}, {p₁,p₂,p₃}, and {p₄,p₆,p₅}.

CanonicalizePolyhedron can be used to convert a prism to an explicit Polyhedron object.
Prism can be used in Graphics3D.
In graphics, the points p_i can be Scaled and Dynamic expressions.
Graphics rendering is affected by directives such as FaceForm, EdgeForm, Opacity, Texture, and color.
The following options and settings can be used in graphics:

VertexColors	Automatic	vertex colors to be interpolated
VertexNormals	Automatic	effective vertex normals for shading
VertexTextureCoordinates	None	coordinates for textures

Examples

open all close all

Basic Examples (3)

A prism:

Wolfram Language code: Graphics3D[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

A styled prism:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

Wolfram Language code:

{Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{EdgeForm[Dashed], ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Volume and centroid:

Wolfram Language code: Volume[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

Wolfram Language code: RegionCentroid[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

Scope (18)

Graphics (8)

Specification (2)

A single prism:

Wolfram Language code: Graphics3D[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

Multiple prisms:

Wolfram Language code:

v1 = {{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}};
v2 = v1 + 2;

Wolfram Language code: Graphics3D[Prism[{v1, v2}]]

Styling (3)

FaceForm and EdgeForm can be used to specify the styles of the faces and edges:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

Apply a Texture to the faces:

Wolfram Language code:

ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}, VertexTextureCoordinates -> {{0, 0}, {1, 1}, {1, 0}, {1, 1}, {1, 0}, {0, 1}}];

Wolfram Language code: Graphics3D[{Texture[[image]], ℛ}, Lighting -> "Neutral"]

Assign VertexColors to vertices:

Wolfram Language code:

Graphics3D[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}, VertexColors -> ColorData[60, "ColorList"]]]

Coordinates (3)

Specify coordinates by fractions of the plot range:

Wolfram Language code:

ℛ = Prism[{Scaled[{0.5, 0., 0.5}], Scaled[{0., 0., 0.}], Scaled[{1., 0., 0.}], Scaled[{0.5, 1., 0.5}], Scaled[{0., 1., 0.}], Scaled[{1., 1., 0.}]}];

Wolfram Language code: Graphics3D[ℛ, PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

Specify scaled offsets from the ordinary coordinates:

Wolfram Language code:

ℛ = Prism[{Scaled[{0, 0, 0.5}, {1, 0, 1}], Scaled[{0, 0, 0.5}, {0, 0, 0}], Scaled[{0, 0, 0.5}, {2, 0, 0}], Scaled[{0, 0, 0.5}, {1, 2, 1}], Scaled[{0, 0, 0.5}, {0, 2, 0}], Scaled[{0, 0, 0.5}, {2, 2, 0}]}] ;

Wolfram Language code: Graphics3D[ℛ, PlotRange -> {{0, 2}, {0, 2}, {0, 2}}, Axes -> True]

Points can be Dynamic:

Wolfram Language code:

DynamicModule[{x}, {Slider[Dynamic[x], {0.5, 1}], Graphics3D[Prism[{Dynamic[x{1, 0, 1}], {0, 0, 0}, Dynamic[x{2, 0, 0}], {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]}]

Regions (10)

Embedding dimension is the dimension of the space in which the prism lives:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {1, 2, 3}]}

Get conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

Volume:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}, Boxed -> False]

Distance from a point:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: {RegionDistance[ℛ, {1, 0, 0}], RegionDistance[ℛ, {3, 3, 3}]}

The equidistance contours for a prism:

Wolfram Language code:

ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -1.5, 3}, {y, -1.5, 3.5}, {z, -1.5, 3}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

Signed distance from a point:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2, 3}], SignedRegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

Nearest point in the region:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: {RegionNearest[ℛ, {1, 2, 3}], RegionNearest[ℛ, {(1/3), (1/4), (1/5)}]}

Nearest points to an enclosing sphere:

Wolfram Language code:

spherePoints[{n_, m_}, c_, r_] := 
	Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];

Wolfram Language code:

pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2];
npl = Table[RegionNearest[ℛ, p], {p, pl}];

Wolfram Language code:

Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A prism is bounded:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: r = RegionBounds[ℛ]

Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

Integrate over a prism region:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: Integrate[x + y + z, {x, y, z}∈ℛ]

Optimize over a prism region:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations in a prism region:

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -1 && z^2 == x y && {x, y, z}∈ℛ, {x, y, z}]

Properties & Relations (2)

A prism can be represented as the union of three tetrahedra:

Wolfram Language code: pts = {{1, 1, 2}, {2, 2, 2}, {0, 2, 2}, {1, 1, 0}, {2, 2, 0}, {0, 2, 0}};

Wolfram Language code: Graphics3D[Prism[pts], Boxed -> False]

Point index list of tetrahedra vertices:

Wolfram Language code: ti = {{6, 3, 2, 1}, {5, 6, 2, 1}, {4, 6, 5, 1}};

Wolfram Language code: Graphics3D[{Opacity@0.4, Table[Tetrahedron[pts[[i]]], {i, ti}]}, Boxed -> False]

ImplicitRegion can represent any Prism region:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[Subscript[t, 2] ≥ 0 && Subscript[t, 1] - Subscript[t, 3] ≥ 0 && Subscript[t, 1] + Subscript[t, 3] ≤ 2 && Subscript[t, 3] ≥ 0 && Subscript[t, 2] ≤ 2, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}];
Subscript[ℛ, 2] = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples (1)

Sweep a prism around an axis:

Wolfram Language code: ℛ = Prism[{{1, 0.5, 1}, {0, 0, 0}, {2, 0, 0}, {1, 1.5, 1}, {0, 2, 0}, {2, 2, 0}}];

Wolfram Language code:

Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[ℛ, RotationTransform[c, {0, 0, 1}, {2, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 25}]}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Prism

Details and Options

Examples

Basic Examples (3)

Scope (18)

Graphics (8)

Specification (2)

Styling (3)

Coordinates (3)

Regions (10)

Properties & Relations (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

Prism

Details and Options

Examples

Basic Examples (3)

Scope (18)

Graphics (8)

Specification (2)

Styling (3)

Coordinates (3)

Regions (10)

Properties & Relations (2)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX