WOLFRAM

Wolfram Language & System Documentation Center

StraussPointProcess[μ,γ,rs,d]

represents a Strauss point process with constant intensity μ, interaction parameter γ and interaction radius rs in d.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Method  
Applications  
Possible Issues  
See Also
Related Guides
History
Cite this Page

StraussPointProcess

StraussPointProcess[μ,γ,rs,d]

represents a Strauss point process with constant intensity μ, interaction parameter γ and interaction radius rs in d.

Details

  • StraussPointProcess models point configurations with a constant repulsive pairwise interaction for points within radius rs of each other but that are otherwise uniformly distributed.
  • The Strauss model is typically used when the process interaction has a constant penalty for points within radius rs, including for locations of plants, birds nests and biological cells.
  •     
  • The Strauss point process can be defined as a GibbsPointProcess in terms of its intensity μ and the pair potential ϕ or pair interaction h, which are both parametrized by γ and rs as follows:
  • pair potential
    pair interaction
  • A point configuration from a Strauss point process StraussPointProcess[μ,γ,rs,d] in an observation region reg has density function proportional to , where m=sum_(i!=j)Boole[TemplateBox[{{{p, _, i}, -, {p, _, j}}}, Norm]<r_s] with respect to PoissonPointProcess[1,d].
  • The Papangelou conditional density for adding a point to a point configuration is where m=sum_iBoole[TemplateBox[{{{p, _, i}, -, q}}, Norm]<r_s].
  • StraussPointProcess allows μ, γ and r_(s) to be any positive numbers such that , and d to be any positive integer.
  • StraussPointProcess simplifies to HardcorePointProcess when and to PoissonPointProcess when . Smaller values of gamma inhibit points being closer than r_(s).
  • Possible Method settings in RandomPointConfiguration for StraussPointProcess are:
  • "MCMC"Markov chain Monte Carlo birth and death
    "Exact"coupling from the past
  • Possible PointProcessEstimator settings in EstimatedPointProcess for StraussPointProcess are:
  • Automaticautomatically choose the parameter estimator
    "MaximumPseudoLikelihood"maximize the pseudo-likelihood
  • StraussPointProcess can be used with such functions as RipleyK and RandomPointConfiguration.

Examples

open all close all

Basic Examples  (2)

Sample from a Strauss point process:

Wolfram Language code: domain = Rectangle[{0, 0}, {10, 10}];
Wolfram Language code: pts = RandomPointConfiguration[StraussPointProcess[30, 0.1, 1., 2], domain]

Visualize the points in the sample:

Wolfram Language code: ListPlot[pts]

Sample from a geo region:

Wolfram Language code: reg = Entity["Country", "Switzerland"]
Wolfram Language code: pts = RandomPointConfiguration[StraussPointProcess[Quantity[1., "Kilometers" ^ -2], .5, Quantity[50., "Kilometers"], 2], reg]
Wolfram Language code: GeoListPlot[pts]

Scope  (4)

Generate several realizations from a Strauss point process in :

Wolfram Language code: proc = StraussPointProcess[100, 0.5, 0.1, 2]; reg = Rectangle[];
Wolfram Language code: sample = RandomPointConfiguration[proc, reg, 3]
Wolfram Language code: ListPlot[sample]

Estimate the process:

Wolfram Language code: Clear[μ, γ, R];EstimatedPointProcess[sample, StraussPointProcess[μ, γ, R, 2]]

Generate several realizations from a Strauss point process on the surface of the Earth:

Wolfram Language code: μ = Quantity[10. ^ -2, "Kilometers" ^ -2]; rs = Quantity[5., "Kilometers"]; γ = .5;
Wolfram Language code: proc = StraussPointProcess[μ, γ, rs, 2]; reg = GeoDisk[Entity["Island", "Santorini"], Quantity[30, "Kilometers"]];
Wolfram Language code: sample = RandomPointConfiguration[proc, reg, 2]
Wolfram Language code: GeoListPlot[sample]

Estimate the process:

Wolfram Language code: Clear[μ, γ, rs]; EstimatedPointProcess[sample, StraussPointProcess[μ, γ, rs, 2]]

Generate samples with an increasing interacting radius:

Wolfram Language code: proc = StraussPointProcess[10, 0.3, r, 2];
Wolfram Language code: sample[r_] := RandomPointConfiguration[proc, Rectangle[{0, 0}, {10, 10}]]
Wolfram Language code: range = {.5, 1, 2};
Wolfram Language code: Table[ListPlot[sample[r], PlotLabel -> Row[{"r = ", r}]], {r, range}]

Generate samples with increasing interacting parameter γ:

Wolfram Language code: proc = StraussPointProcess[10, γ, 1, 2];
Wolfram Language code: sample[γ_] := RandomPointConfiguration[proc, Rectangle[{0, 0}, {10, 10}]];
Wolfram Language code: gammas = {0.01, 0.1, 0.9};
Wolfram Language code: samples = Table[sample[γ], {γ, gammas}];
Wolfram Language code: Table[ListPlot[sample[γ], PlotLabel -> Row[{"γ = ", γ}]], {γ, gammas}]

Options  (4)

Method  (4)

Use the Markov chain Monte Carlo simulation method:

Wolfram Language code: proc = StraussPointProcess[10 ^ 3, .2, .1, 2]; reg = Disk[];
Wolfram Language code: RandomPointConfiguration[proc, reg, Method -> "MCMC"]

Specify the number of recursive calls to the sampler:

Wolfram Language code: RandomPointConfiguration[proc, reg, Method -> {"MCMC", MaxRecursion -> 6}]

Specify the length of run:

Wolfram Language code: RandomPointConfiguration[proc, reg, Method -> {"MCMC", "LengthOfRun" -> 5000}]

Provide an initial state for the simulation:

Wolfram Language code: proc = StraussPointProcess[50, 0.3, .1, 2]; reg = Disk[];
Wolfram Language code: RandomPointConfiguration[proc, reg, Method -> {"MCMC", "InitialState" -> RandomPoint[reg, 100]}]

Visualize the birth and death process at different stages:

Wolfram Language code: proc = StraussPointProcess[50, 0.3, .1, 2]; reg = Disk[];
Wolfram Language code: path = Table[ BlockRandom[ SeedRandom[1]; RandomPointConfiguration[proc, reg, Method -> {"MCMC", "InitialState" -> {{0., 0.4}, {-0.3, -0.2}}, "LengthOfRun" -> len}]["Points"]] , {len, 1, 100}];
Wolfram Language code: Animate[ Graphics[{Lighter[GrayLevel[.4], .8], Disk[{0, 0}, 1.02], Black, PointSize[0.02], Point[path[[i]]]}] , {i, 1, Length[path], 1}, TrackedSymbols :> i, SaveDefinitions -> True, AnimationRate -> 2, AnimationRunning -> False]

Use coupling from the past for exact sampling:

Wolfram Language code: proc = StraussPointProcess[8, 0.4, 0.2, 2];
Wolfram Language code: pts = RandomPointConfiguration[proc, Rectangle[{0, 0}, {5, 5}], Method -> "Exact"]
Wolfram Language code: ListPlot[pts]

Applications  (1)

Compute the average number of points in a unit disk for a Strauss point process:

Wolfram Language code: 𝒟 = PointCountDistribution[StraussPointProcess[20, 1, .2, 2], Disk[]];
Wolfram Language code: NExpectation[n, n𝒟, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]

Possible Issues  (2)

By default, the simulation will run until the number of points converges to a steady state, or until the default number of iterations is reached:

Wolfram Language code: proc = StraussPointProcess[10 ^ 3, .2, .01, 2]; reg = Disk[];
Wolfram Language code: RandomPointConfiguration[proc, reg]

Raise the number of recursive calls to the sampler:

Wolfram Language code: RandomPointConfiguration[proc, reg, Method -> {"MCMC", MaxRecursion -> 6}]

Specify a larger length of run:

Wolfram Language code: RandomPointConfiguration[proc, reg, Method -> {"MCMC", "LengthOfRun" -> 5 * 10 ^ 4}]

The objective function for estimating the parameters is the pseudo log-likelihood:

Wolfram Language code: proc = StraussPointProcess[50, 0.5, 0.1, 2]; reg = Rectangle[];
Wolfram Language code: BlockRandom[sample = RandomPointConfiguration[proc, reg], RandomSeeding -> 4]
Wolfram Language code: est = EstimatedPointProcess[sample, StraussPointProcess[μ, γ, r, 2]]

The estimated process has a higher pseudo log-likelihood:

Wolfram Language code: sample["PseudoLogLikelihood", est]
Wolfram Language code: sample["PseudoLogLikelihood", proc]

Both processes generate data that looks similar:

Wolfram Language code: sample2 = RandomPointConfiguration[est, reg]
Wolfram Language code: ListPlot[{sample["Points"], sample2["Points"]}]
Wolfram Research (2020), StraussPointProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/StraussPointProcess.html.

Text

Wolfram Research (2020), StraussPointProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/StraussPointProcess.html.

CMS

Wolfram Language. 2020. "StraussPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/StraussPointProcess.html.

APA

Wolfram Language. (2020). StraussPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StraussPointProcess.html

BibTeX

@misc{reference.wolfram_2026_strausspointprocess, author="Wolfram Research", title="{StraussPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/StraussPointProcess.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_strausspointprocess, organization={Wolfram Research}, title={StraussPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/StraussPointProcess.html}, note=[Accessed: 13-June-2026]}