TriangleCenter
TriangleCenter[tri,type]
gives the specified type of center for the triangle tri.
TriangleCenter[tri]
gives the centroid of the triangle.
Details
- TriangleCenter gives a list of coordinates.
- The triangle tri can be given as {p1,p2,p3}, Triangle[{p1,p2,p3}] or Polygon[{p1,p2,p3}].
- The following center types can be given:
-
{"AngleBisectingCevianEndpoint",p} endpoint of the cevian bisecting the angle at the vertex p "Centroid" centroid {"CevianEndpoint",center,p} endpoint of the cevian passing through the vertex p and the specified center "Circumcenter" center of the circumcircle {"Excenter",p} center of the excircle opposite from the vertex p {"Foot",p} foot of the altitude passing through the vertex p "Incenter" center of the incircle {"Midpoint",p} midpoint of the side opposite from the vertex p "NinePointCenter" center of nine-point circle "Orthocenter" orthocenter {"SymmedianEndpoint",p} endpoint of the symmedian passing through the vertex p "SymmedianPoint" symmedian point - In the form {"type",p}, p can be a symbolic point specification in a GeometricScene, or it can be an explicit vertex of the form {x,y}, Point[{x,y}] or the index i of the vertex. When given in the short form "type", the vertex p2 is used.
- In the form {"CevianEndpoint",center,p}, the center can be given as a center type such as "Centroid" or as a point specification. When given in the short form {"CevianEndpoint",center}, the vertex p2 is used.
- In any form that specifies a vertex p, a value of All will return a list of three values corresponding to the vertices.
- TriangleCenter can be used with symbolic points in GeometricScene.
Examples
open all close allBasic Examples (2)
Find the incenter of a triangle:
TriangleCenter[{{0, 0}, {3, 0}, {3, 4}}, "Incenter"]TriangleCenter[{{0, 0}, {3, 0}, {3, a}}, "Incenter"]Calculate the incenter of a triangle:
tri = {{0, 0}, {3, 0}, {3, 4}};
pt = TriangleCenter[tri, "Incenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Circle[pt, TriangleMeasurement[tri, "Inradius"]], Point[pt]}]Calculate the excenter of a triangle at the specified vertex:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleCenter[{{0, 0}, {3, 0}, {3, 4}}, "Excenter"]pt = TriangleCenter[{{0, 0}, {3, 0}, {3, 4}}, {"Excenter", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Circle[pt, TriangleMeasurement[tri, {"Exradius", {0, 0}}]], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed], Point[pt]}]Calculate all of the excenters:
TriangleCenter[tri, {"Excenter", All}]Scope (12)
Calculate the endpoint of an angle bisector:
tri = {{0, 0}, {1, 0}, {1, Sqrt[3]}};
pt = TriangleCenter[tri, "AngleBisectingCevianEndpoint"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, "AngleBisectingCevian"], Dashed], Point[pt]}]Calculate the centroid of a triangle:
tri = {{-1, 0}, {1, 0}, {0, Sqrt[3]}};
pt = TriangleCenter[tri, "Centroid"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Point[pt]}]Calculate the endpoint of a cevian passing through the orthocenter:
tri = {{0, 0}, {1, 0}, {1 / 2, Sqrt[3]}};
pt = TriangleCenter[tri, {"CevianEndpoint", "Orthocenter"}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Cevian", "Orthocenter"}], Dashed], TriangleConstruct[tri, "Orthocenter"], Point[pt]}]Calculate the endpoint of a cevian passing through a different vertex:
pt2 = TriangleCenter[tri, {"CevianEndpoint", "Orthocenter", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Cevian", "Orthocenter", {0, 0}}], Dashed], TriangleConstruct[tri, "Orthocenter"], Point[pt2]}]Calculate the endpoint of a cevian through an arbitrary center point:
pt3 = TriangleCenter[tri, {"CevianEndpoint", {1 / 2, 1 / 2}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Cevian", {1 / 2, 1 / 2}}], Dashed], Point[{1 / 2, 1 / 2}], Point[pt3]}]Calculate the circumcenter of a triangle:
tri = {{0, 0}, {1, 0}, {0, 1}};
pt = TriangleCenter[tri, "Circumcenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Circle[pt, TriangleMeasurement[tri, "Circumradius"]], Point[pt]}]Calculate the excenter of a triangle at the specified vertex:
tri = {{0, 0}, {3, 0}, {3, 4}};
pt = TriangleCenter[{{0, 0}, {3, 0}, {3, 4}}, {"Excenter", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Circle[pt, TriangleMeasurement[tri, {"Exradius", {0, 0}}]], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed], Point[pt]}]Calculate all of the excenters:
TriangleCenter[tri, {"Excenter", All}]Calculate the foot of an altitude of a triangle at the specified vertex:
tri = {{-1, 0}, {2, 0}, {0, 3}};
pt = TriangleCenter[tri, {"Foot", {0, 3}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Altitude", {0, 3}}], Dashed], Point[pt]}]Calculate the incenter of a triangle:
tri = {{0, 0}, {3, 0}, {3, 4}};
pt = TriangleCenter[tri, "Incenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Circle[pt, TriangleMeasurement[tri, "Inradius"]], Point[pt]}]Calculate the midpoint of a side of a triangle:
tri = {{-1, -1}, {2, -4}, {1, 3}};
pt = TriangleCenter[tri, {"Midpoint", {2, -4}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Point[pt]}]Calculate the nine-point center of a triangle:
tri = {{0, 0}, {3, 0}, {1, 2}};
pt = TriangleCenter[tri, "NinePointCenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Foot", All}], TriangleConstruct[tri, {"Midpoint", All}], Midpoint[{TriangleConstruct[tri, "Orthocenter"], #}]& /@ tri, Circle[pt, TriangleMeasurement[tri, "NinePointRadius"]], Point[pt]}]Calculate the orthocenter of a triangle:
tri = {{0, 0}, {3, 0}, {1, 2}};
pt = TriangleCenter[tri, "Orthocenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Altitude", All}], Dashed], Point[pt]}]Calculate the endpoint of a symmedian:
tri = {{0, 0}, {3, 0}, {1, 4}};
pt = TriangleCenter[tri, "SymmedianEndpoint"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, "AngleBisector"], Dashed], Style[TriangleConstruct[tri, "Median"], Red], Style[TriangleConstruct[tri, "Symmedian"], Blue], Point[pt]}]Calculate the symmedian point of a triangle:
tri = {{0, 0}, {3, 0}, {1, 4}};
pt = TriangleCenter[tri, "SymmedianPoint"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Symmedian", All}], Dashed], Point[pt]}]Properties & Relations (20)
Angle Bisector and Incenter (3)
An angle bisector endpoint is the intersection of an angle bisector and the opposite side:
tri = {{0, 0}, {1, 0}, {1, Sqrt[3]}};
TriangleCenter[tri, "AngleBisectingCevianEndpoint"]RegionIntersection[TriangleConstruct[tri, "AngleBisector"], TriangleConstruct[tri, "OppositeSide"]]RegionEqual[%, Point[%%]]The angle bisectors of a triangle intersect at the incenter:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, {"AngleBisector", All}]RegionIntersection@@%TriangleCenter[tri, "Incenter"]TriangleConstruct[{a,b,c},"Incircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Incenter"],TriangleMeasurement[{a,b,c},"Inradius"]]:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, "Incircle"]Circle[TriangleCenter[tri, "Incenter"], TriangleMeasurement[tri, "Inradius"]]Median, Midpoint and Centroid (3)
A median intersects the opposite side at the midpoint:
tri = {{-1, 0}, {2, 1}, {0, 1}};
TriangleCenter[tri, "Midpoint"]RegionIntersection[TriangleConstruct[tri, "Median"], TriangleConstruct[tri, "OppositeSide"]]The medians of a triangle intersect at the centroid:
tri = {{-1, 0}, {1, 0}, {0, Sqrt[3]}};
TriangleConstruct[tri, {"Median", All}]RegionIntersection@@%TriangleCenter[tri, "Centroid"]TriangleCenter[{a,b,c}] is equivalent to RegionCentroid[Triangle[{a,b,c}]]:
tri = {{-1, 0}, {1, 0}, {0, Sqrt[3]}};
TriangleCenter[tri]RegionCentroid[Triangle[tri]]Perpendicular Bisector, Midpoint and Circumcenter (3)
The perpendicular bisector of a side passes through the midpoint of that side:
tri = {{2, 0}, {1, 2}, {-1, 0}};
TriangleCenter[tri, "Midpoint"]RegionIntersection[TriangleConstruct[tri, "PerpendicularBisector"], TriangleConstruct[tri, "OppositeSide"]]The perpendicular bisectors of a triangle intersect at the circumcenter:
tri = {{0, 0}, {1, 0}, {0, 1}};
TriangleConstruct[tri, {"PerpendicularBisector", All}]RegionIntersection@@%TriangleCenter[tri, "Circumcenter"]TriangleConstruct[{a,b,c},"Circumcircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Circumcenter"],TriangleMeasurement[{a,b,c},"Circumradius"]]:
tri = {{0, 0}, {1, 0}, {0, 1}};
TriangleConstruct[tri, "Circumcircle"]Circle[TriangleCenter[tri, "Circumcenter"], TriangleMeasurement[tri, "Circumradius"]]Altitude, Foot and Orthocenter (2)
The foot of an altitude is the intersection of the altitude and the opposite side:
tri = {{-1, 0}, {2, 1}, {1, 3}};
TriangleCenter[tri, "Foot"]RegionIntersection[TriangleConstruct[tri, "Altitude"], TriangleConstruct[tri, "OppositeSide"]]The altitudes of a triangle intersect at the orthocenter:
tri = {{-1, 0}, {2, 1}, {1, 3}};
TriangleConstruct[tri, {"Altitude", All}]RegionIntersection@@%TriangleCenter[tri, "Orthocenter"]Symmedian, Median and Angle Bisector (3)
The endpoint of a symmedian at a vertex is the intersection of the symmedian and the opposite side:
tri = {{0, 0}, {3, 0}, {1, 4}};
TriangleCenter[tri, "SymmedianEndpoint"]RegionIntersection[TriangleConstruct[tri, "Symmedian"], TriangleConstruct[tri, "OppositeSide"]]The angle bisector at a vertex also bisects the angle formed by the median and symmedian at that vertex:
tri = {{0, 0}, {3, 0}, {1, 4}};
pt = TriangleCenter[tri, "AngleBisectingCevianEndpoint"]PlanarAngle[{TriangleCenter[tri, "SymmedianEndpoint"], {3, 0}, pt}]PlanarAngle[{pt, {3, 0}, TriangleCenter[tri, "Midpoint"]}]The symmedians of a triangle intersect at the symmedian point:
tri = {{0, 0}, {3, 0}, {1, 4}};
TriangleConstruct[tri, {"Symmedian", All}]RegionIntersection@@%TriangleCenter[tri, "SymmedianPoint"]Exterior Angle Bisector and Excenter (2)
The excenter opposite a vertex is the intersection of the exterior angle bisectors of the opposite angles:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleCenter[tri, "Excenter"]TriangleConstruct[tri, {"ExteriorAngleBisector", {0, 0}}]TriangleConstruct[tri, {"ExteriorAngleBisector", {3, 4}}]RegionIntersection[%, %%]TriangleConstruct[{a,b,c},"Excircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Excenter"],TriangleMeasurement[{a,b,c},"Exradius"]]:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, "Excircle"]Circle[TriangleCenter[tri, "Excenter"], TriangleMeasurement[tri, "Exradius"]]Nine-Point Circle, Foot, Midpoint, Orthocenter (2)
The nine-point circle of a triangle passes through the feet of the altitudes, the midpoints of the sides and the midpoints of the segments from the vertices to the orthocenter:
tri = {{0, 0}, {3, 0}, {1, 2}};
circ = TriangleConstruct[tri, "NinePointCircle"]feet = TriangleCenter[tri, {"Foot", All}]RegionMember[circ, feet]midpoints = TriangleCenter[tri, {"Midpoint", All}]RegionMember[circ, midpoints]orthoMidpoints = Midpoint[{#, TriangleCenter[tri, "Orthocenter"]}]& /@ triRegionMember[circ, orthoMidpoints]TriangleConstruct[{a,b,c},"NinePointCircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"NinePointCenter"],TriangleMeasurement[{a,b,c},"NinePointRadius"]]:
tri = {{0, 0}, {3, 0}, {1, 2}};
TriangleConstruct[tri, "NinePointCircle"]Circle[TriangleCenter[tri, "NinePointCenter"], TriangleMeasurement[tri, "NinePointRadius"]]Euler Line, Centroid, Circumcenter, Orthocenter and Nine-Point Center (1)
The Euler line passes through the centroid, circumcenter, orthocenter and nine-point center:
tri = {{-1, 0}, {2, 0}, {1, 2}};
ℓ = TriangleConstruct[tri, "EulerLine"]RegionMember[ℓ, {TriangleCenter[tri, "Centroid"], TriangleCenter[tri, "Circumcenter"], TriangleCenter[tri, "Orthocenter"], TriangleCenter[tri, "NinePointCenter"]}]Midpoint (1)
TriangleCenter[{a,b,c},"Midpoint"] is equivalent to Midpoint[{a,c}]:
TriangleCenter[{{-1, 2}, {0, 0}, {3, 4}}, "Midpoint"]Midpoint[{{-1, 2}, {3, 4}}]Text
Wolfram Research (2019), TriangleCenter, Wolfram Language function, https://reference.wolfram.com/language/ref/TriangleCenter.html.
CMS
Wolfram Language. 2019. "TriangleCenter." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TriangleCenter.html.
APA
Wolfram Language. (2019). TriangleCenter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TriangleCenter.html