WOLFRAM

Wolfram Language & System Documentation Center

TriangleMeasurement[tri,type]

gives the specified type of measurement for the triangle tri.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

TriangleMeasurement

TriangleMeasurement[tri,type]

gives the specified type of measurement for the triangle tri.

Details

  • The triangle tri can be given as {p1,p2,p3}, Triangle[{p1,p2,p3}] or Polygon[{p1,p2,p3}].
  • The following measurement types can be given:
  • "Area"area
    "Circumradius"radius of circumcircle
    {"Exradius",p}radius of excircle opposite vertex p
    {"ExteriorAngle",p}exterior angle at vertex p
    {"FullExteriorAngle",p}full exterior angle at vertex p
    {"Height",p}height of the triangle measured from vertex p
    "Inradius"radius of incircle
    {"InteriorAngle",p}interior angle at vertex p
    "NinePointRadius"radius of nine-point circle
    "Perimeter"perimeter
    "Semiperimeter"semiperimeter
  • In the form {"type",p}, p can be a symbolic point specification in a GeometricScene, or it can be an explicit vertex of the form {x,y}, Point[{x,y}] or the index i of the vertex. When given in the short form "type", the vertex p2 is used.
  • In any form that specifies a vertex p, a value of All will return a list of three values corresponding to the vertices.
  • TriangleMeasurement can be used with symbolic points in GeometricScene.

Examples

open all close all

Basic Examples  (2)

Calculate the semiperimeter of a triangle:

Wolfram Language code: TriangleMeasurement[{{0, 0}, {3, 0}, {3, 4}}, "Semiperimeter"]

Calculate the exradius of a triangle at the specified vertex:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, {"Exradius", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Excircle", {0, 0}}], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed]}]

Calculate all of the exradii:

Wolfram Language code: TriangleMeasurement[tri, {"Exradius", All}]

Scope  (11)

Calculate the area of a triangle:

Wolfram Language code: TriangleMeasurement[{{0, 0}, {3, 0}, {0, 4}}, "Area"]

Calculate the area using symbolic coordinates:

Wolfram Language code: TriangleMeasurement[{{0, 0}, {b, 0}, {0, h}}, "Area"]

Calculate the circumradius of a triangle:

Wolfram Language code: tri = {{0, -2}, {1, 2}, {-1, 1}}; TriangleMeasurement[tri, "Circumradius"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Circumcircle"]}]

Calculate the exradius of a triangle at the specified vertex:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[{{0, 0}, {3, 0}, {3, 4}}, {"Exradius", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Excircle", {0, 0}}], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed]}]

Calculate the exterior angle of a triangle at the specified vertex:

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, {"ExteriorAngle", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

Calculate the full exterior angle of a triangle at the specified vertex:

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, {"FullExteriorAngle", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

Calculate the height of a triangle:

Wolfram Language code: tri = {{2, 0}, {1, 3}, {-1, 0}}; TriangleMeasurement[tri, "Height"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

Calculate the inradius of a triangle:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, "Inradius"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Incircle"]}]

Calculate the interior angle of a triangle at the specified vertex:

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, {"InteriorAngle", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

Calculate the nine-point center of a triangle:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {1, 2}}; TriangleMeasurement[tri, "NinePointRadius"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Foot", All}], TriangleConstruct[tri, {"Midpoint", All}], Midpoint[{TriangleConstruct[tri, "Orthocenter"], #}]& /@ tri, TriangleConstruct[tri, "NinePointCircle"]}]

Calculate the perimeter of a triangle:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, "Perimeter"]

Calculate the semiperimeter of a triangle:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, "Semiperimeter"]

Properties & Relations  (11)

TriangleMeasurement[{a,b,c}] is equivalent to Area[Triangle[{a,b,c}]]:

Wolfram Language code: TriangleMeasurement[{{0, 0}, {3, 0}, {0, 4}}]
Wolfram Language code: Area[Triangle[{{0, 0}, {3, 0}, {0, 4}}]]

TriangleConstruct[{a,b,c},"Circumcircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Circumcenter"],TriangleMeasurement[{a,b,c},"Circumradius"]]:

Wolfram Language code: tri = {{0, 0}, {1, 0}, {0, 1}}; TriangleConstruct[tri, "Circumcircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "Circumcenter"], TriangleMeasurement[tri, "Circumradius"]]

TriangleConstruct[{a,b,c},"Excircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Excenter"],TriangleMeasurement[{a,b,c},"Exradius"]]:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleConstruct[tri, "Excircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "Excenter"], TriangleMeasurement[tri, "Exradius"]]

TriangleConstruct[{a,b,c},"ExteriorAngle"] is equivalent to PlanarAngle[{a,b,c},"Exterior"]:

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, "ExteriorAngle"]
Wolfram Language code: PlanarAngle[tri, "Exterior"]

TriangleConstruct[{a,b,c},"FullExteriorAngle"] is equivalent to PlanarAngle[{a,b,c},"FullExterior"]:

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, "FullExteriorAngle"]
Wolfram Language code: PlanarAngle[tri, "FullExterior"]

TriangleMeasurement[{a,b,c},"Height"] is equivalent to ArcLength[TriangleConstruct[{a,b,c},"Altitude"]]:

Wolfram Language code: tri = {{-1, 0}, {2, 0}, {1, 2}}; TriangleMeasurement[tri, "Height"]
Wolfram Language code: TriangleConstruct[tri, "Altitude"]
Wolfram Language code: ArcLength[%]

TriangleConstruct[{a,b,c},"Incircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Incenter"],TriangleMeasurement[{a,b,c},"Inradius"]]:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleConstruct[tri, "Incircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "Incenter"], TriangleMeasurement[tri, "Inradius"]]

TriangleConstruct[{a,b,c},"InteriorAngle"] is equivalent to PlanarAngle[{a,b,c},"Interior"]:

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, "InteriorAngle"]
Wolfram Language code: PlanarAngle[tri, "Interior"]

TriangleConstruct[{a,b,c},"NinePointCircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"NinePointCenter"],TriangleMeasurement[{a,b,c},"NinePointRadius"]]:

Wolfram Language code: tri = {{0, 0}, {3, 0}, {1, 2}}; TriangleConstruct[tri, "NinePointCircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "NinePointCenter"], TriangleMeasurement[tri, "NinePointRadius"]]

TriangleConstruct[{a,b,c},"Perimeter"] is equivalent to Perimeter[Triangle[{a,b,c}]]:

Wolfram Language code: tri = {{-1, 0}, {2, 0}, {1, 2}}; TriangleMeasurement[tri, "Perimeter"]
Wolfram Language code: Perimeter[Triangle[tri]]

TriangleConstruct[{a,b,c},"Semiperimeter"] is equivalent to Perimeter[Triangle[{a,b,c}]]/2:

Wolfram Language code: tri = {{-1, 0}, {2, 0}, {1, 2}}; TriangleMeasurement[tri, "Semiperimeter"]
Wolfram Language code: Perimeter[Triangle[tri]] / 2
Wolfram Research (2019), TriangleMeasurement, Wolfram Language function, https://reference.wolfram.com/language/ref/TriangleMeasurement.html.

Text

Wolfram Research (2019), TriangleMeasurement, Wolfram Language function, https://reference.wolfram.com/language/ref/TriangleMeasurement.html.

CMS

Wolfram Language. 2019. "TriangleMeasurement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TriangleMeasurement.html.

APA

Wolfram Language. (2019). TriangleMeasurement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TriangleMeasurement.html

BibTeX

@misc{reference.wolfram_2026_trianglemeasurement, author="Wolfram Research", title="{TriangleMeasurement}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/TriangleMeasurement.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_trianglemeasurement, organization={Wolfram Research}, title={TriangleMeasurement}, year={2019}, url={https://reference.wolfram.com/language/ref/TriangleMeasurement.html}, note=[Accessed: 13-June-2026]}