TriangleConstruct
TriangleConstruct[tri,type]
gives the specified type of construct for the triangle tri.
Details
- TriangleConstruct can give a Point, Line, InfiniteLine, Circle or Triangle object.
- The triangle tri can be given as {p1,p2,p3}, Triangle[{p1,p2,p3}] or Polygon[{p1,p2,p3}].
- The following point types can be given:
-
{"AngleBisectingCevianEndpoint",p} endpoint of the cevian bisecting the angle at the vertex p "Centroid" centroid {"CevianEndpoint",center,p} endpoint of the cevian passing through the vertex p and the specified center "Circumcenter" center of the circumcircle {"Excenter",p} center of the excircle opposite from the vertex p {"Foot",p} foot of the altitude passing through the vertex p "Incenter" center of the incircle {"Midpoint",p} midpoint of the side opposite from the vertex p "NinePointCenter" center of nine-point circle "Orthocenter" orthocenter {"SymmedianEndpoint",p} endpoint of the symmedian passing through the vertex p "SymmedianPoint" symmedian point - The following line types can be given:
-
{"Altitude",p} altitude passing through the vertex p {"AngleBisectingCevian",p} cevian bisecting the interior angle at the vertex p {"AngleBisector",p} bisector of the interior angle at the vertex p "Boundary" boundary {"Cevian",center,p} cevian passing through the vertex p and the specified center "EulerLine" Euler line {"ExteriorAngleBisector",p} bisector of the exterior angle at the vertex p {"Median",p} median passing through the vertex p {"OppositeSide",p} side opposite from the vertex p {"PerpendicularBisector",p} perpendicular bisector of the side opposite from p {"Symmedian",p} symmedian passing through the vertex p - The following circle types can be given:
-
"Circumcircle" circumscribed circle {"Excircle",p} excircle opposite from the vertex p "Incircle" inscribed circle "NinePointCircle" nine-point circle - The following triangle types can be given:
-
"AntimedialTriangle" antimedial triangle "MedialTriangle" medial triangle "Triangle" original triangle - In the form {"type",p}, p can be a symbolic point specification in a GeometricScene, or it can be an explicit vertex of the form {x,y}, Point[{x,y}] or the index i of the vertex. When given in the short form "type", the vertex p2 is used.
- In the forms {"CevianEndpoint",center,p} and {"Cevian",center,p}, the center can be given as a center type such as "Centroid" or as a point specification. When given in the short form {"CevianEndpoint",center}, the vertex p2 is used.
- In any form that specifies a vertex p, a value of All will return a list of three values corresponding to the vertices.
- TriangleConstruct can be used with symbolic points in GeometricScene.
Examples
open all close allBasic Examples (2)
Calculate the altitude of a triangle:
tri = {{-1, 0}, {2, 1}, {1, 3}};
alt = TriangleConstruct[tri, "Altitude"]Graphics[{Style[Triangle[tri], Opacity[0.2]], alt}]Calculate the excenter of a triangle at the specified vertex:
tri = {{0, 0}, {3, 0}, {3, 4}};
circ = TriangleConstruct[{{0, 0}, {3, 0}, {3, 4}}, {"Excircle", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], circ, Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed]}]Scope (29)
Points (12)
Calculate the endpoint of an angle bisector:
tri = {{0, 0}, {1, 0}, {1, Sqrt[3]}};
pt = TriangleConstruct[tri, "AngleBisectingCevianEndpoint"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, "AngleBisectingCevian"], Dashed], pt}]Calculate the centroid of a triangle:
tri = {{-1, 0}, {1, 0}, {0, Sqrt[3]}};
pt = TriangleConstruct[tri, "Centroid"]Graphics[{Style[Triangle[tri], Opacity[0.2]], pt}]Calculate the endpoint of a cevian passing through the orthocenter:
tri = {{0, 0}, {1, 0}, {1 / 2, Sqrt[3]}};
pt = TriangleConstruct[tri, {"CevianEndpoint", "Orthocenter"}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Cevian", "Orthocenter"}], Dashed], TriangleConstruct[tri, "Orthocenter"], pt}]Calculate the endpoint of a cevian passing through a different vertex:
pt2 = TriangleConstruct[tri, {"CevianEndpoint", "Orthocenter", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Cevian", "Orthocenter", {0, 0}}], Dashed], TriangleConstruct[tri, "Orthocenter"], pt2}]Calculate the endpoint of a cevian through an arbitrary center point:
pt3 = TriangleConstruct[tri, {"CevianEndpoint", {1 / 2, 1 / 2}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Cevian", {1 / 2, 1 / 2}}], Dashed], Point[{1 / 2, 1 / 2}], pt3}]Calculate the circumcenter of a triangle:
tri = {{0, 0}, {1, 0}, {0, 1}};
pt = TriangleConstruct[tri, "Circumcenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Circumcircle"], pt}]Calculate the excenter of a triangle at the specified vertex:
tri = {{0, 0}, {3, 0}, {3, 4}};
pt = TriangleConstruct[{{0, 0}, {3, 0}, {3, 4}}, {"Excenter", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Excircle", {0, 0}}], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed], pt}]Calculate all of the excenters:
TriangleConstruct[tri, {"Excenter", All}]Calculate the foot of an altitude of a triangle at the specified vertex:
tri = {{-1, 0}, {2, 0}, {0, 3}};
pt = TriangleConstruct[tri, {"Foot", {0, 3}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Altitude", {0, 3}}], Dashed], pt}]Calculate the incenter of a triangle:
tri = {{0, 0}, {3, 0}, {3, 4}};
pt = TriangleConstruct[tri, "Incenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Incircle"], pt}]Calculate the midpoint of a side of a triangle:
tri = {{-1, -1}, {2, -4}, {1, 3}};
pt = TriangleConstruct[tri, {"Midpoint", {2, -4}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], pt}]Calculate the nine-point center of a triangle:
tri = {{0, 0}, {3, 0}, {1, 2}};
pt = TriangleConstruct[tri, "NinePointCenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Foot", All}], TriangleConstruct[tri, {"Midpoint", All}], Midpoint[{TriangleConstruct[tri, "Orthocenter"], #}]& /@ tri, TriangleConstruct[tri, "NinePointCircle"], pt}]Calculate the orthocenter of a triangle:
tri = {{0, 0}, {3, 0}, {1, 2}};
pt = TriangleConstruct[tri, "Orthocenter"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Altitude", All}], Dashed], pt}]Calculate the endpoint of a symmedian:
tri = {{0, 0}, {3, 0}, {1, 4}};
pt = TriangleConstruct[tri, "SymmedianEndpoint"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, "AngleBisector"], Dashed], Style[TriangleConstruct[tri, "Median"], Red], Style[TriangleConstruct[tri, "Symmedian"], Blue], pt}]Calculate the symmedian point of a triangle:
tri = {{0, 0}, {3, 0}, {1, 4}};
pt = TriangleConstruct[tri, "SymmedianPoint"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, {"Symmedian", All}], Dashed], pt}]Lines (10)
Calculate the altitude of a triangle:
tri = {{-1, 0}, {2, 1}, {1, 3}};
alt = TriangleConstruct[tri, "Altitude"]Graphics[{Style[Triangle[tri], Opacity[0.2]], alt}]Calculate the angle bisector of a triangle:
tri = {{1, Sqrt[3]}, {0, 0}, {1, 0}};
bis = TriangleConstruct[tri, "AngleBisector"]Graphics[{Style[Triangle[tri], Opacity[0.2]], bis}, PlotRange -> {{-1, 2}, {-1, 2}}]Get the angle bisector as a line segment:
cev = TriangleConstruct[tri, "AngleBisectingCevian"]Graphics[{Style[Triangle[tri], Opacity[0.2]], cev}]Calculate the boundary of a triangle:
tri = {{1, 0}, {2, -1}, {3, 3}};
line = TriangleConstruct[tri, "Boundary"]Graphics[{Style[Triangle[tri], Opacity[0.2]], line}]Calculate a cevian passing through the orthocenter:
tri = {{0, 0}, {1, 0}, {1 / 2, Sqrt[3]}};
line = TriangleConstruct[tri, {"Cevian", "Orthocenter"}]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Orthocenter"], line}]Calculate the cevian passing through a different vertex:
line2 = TriangleConstruct[tri, {"Cevian", "Orthocenter", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Orthocenter"], line2}]Calculate a cevian through an arbitrary center point:
line3 = TriangleConstruct[tri, {"Cevian", {1 / 2, 1 / 2}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], Point[{1 / 2, 1 / 2}], line3}]Calculate the Euler line of a triangle:
tri = {{-1, 0}, {2, 0}, {1, 2}};
line = TriangleConstruct[tri, "EulerLine"]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Orthocenter"], TriangleConstruct[tri, "Circumcenter"], TriangleConstruct[tri, "Centroid"], TriangleConstruct[tri, "NinePointCenter"], line}]Calculate the exterior angle bisector at a vertex:
tri = {{0, 0}, {1, 0}, {1, Sqrt[3]}};
line = TriangleConstruct[tri, "ExteriorAngleBisector"]Graphics[{Style[Triangle[tri], Opacity[0.2]], line}]
Calculate a median of a triangle:
tri = {{-1, 0}, {2, 1}, {0, 1}};
line = TriangleConstruct[tri, "Median"]Graphics[{Style[Triangle[tri], Opacity[0.2]], line}]Calculate the side opposite from a specified vertex:
tri = {{2, 3}, {-1, 2}, {1, 4}};
line = TriangleConstruct[Triangle[tri], "OppositeSide"]Graphics[{Style[Triangle[tri], Opacity[0.2]], line}]Calculate the perpendicular bisector of a side of a triangle:
tri = {{2, 0}, {1, 2}, {-1, 0}};
line = TriangleConstruct[Triangle[tri], "PerpendicularBisector"]Graphics[{Style[Triangle[tri], Opacity[0.2]], line}]tri = {{0, 0}, {3, 0}, {1, 4}};
line = TriangleConstruct[tri, "Symmedian"]Graphics[{Style[Triangle[tri], Opacity[0.2]], Style[TriangleConstruct[tri, "AngleBisector"], Dashed], Style[TriangleConstruct[tri, "Median"], Red], Style[line, Blue]}]Circles (4)
Calculate the circumcircle of a triangle:
tri = {{0, -2}, {1, 2}, {-1, 1}};
circ = TriangleConstruct[tri, "Circumcircle"]Graphics[{Style[Triangle[tri], Opacity[0.2]], circ}]Calculate the excenter of a triangle at the specified vertex:
tri = {{0, 0}, {3, 0}, {3, 4}};
circ = TriangleConstruct[{{0, 0}, {3, 0}, {3, 4}}, {"Excircle", {0, 0}}]Graphics[{Style[Triangle[tri], Opacity[0.2]], circ, Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed]}]Calculate the incircle of a triangle:
tri = {{0, 0}, {3, 0}, {3, 4}};
circ = TriangleConstruct[tri, "Incircle"]Graphics[{Style[Triangle[tri], Opacity[0.2]], circ}]Calculate the nine-point center of a triangle:
tri = {{0, 0}, {3, 0}, {1, 2}};
circ = TriangleConstruct[tri, "NinePointCircle"]Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Foot", All}], TriangleConstruct[tri, {"Midpoint", All}], Midpoint[{TriangleConstruct[tri, "Orthocenter"], #}]& /@ tri, circ}]Triangles (3)
Calculate the antimedial triangle of a triangle:
tri = {{-2, 1}, {0, 0}, {1, 1}};
tri2 = TriangleConstruct[tri, "AntimedialTriangle"]Graphics[{Style[Triangle[tri], Opacity[0.2], Red], Style[tri2, Opacity[0.2], Blue]}]Calculate the medial triangle of a triangle:
tri = {{-2, 1}, {0, 0}, {1, 1}};
tri2 = TriangleConstruct[tri, "MedialTriangle"]Graphics[{Style[Triangle[tri], Opacity[0.2], Red], Style[tri2, Opacity[0.2], Blue]}]tri = {{-2, 1}, {0, 0}, {1, 1}};
TriangleConstruct[tri]Properties & Relations (28)
Angle Bisector and Incenter (5)
An angle bisector endpoint is the intersection of an angle bisector and the opposite side:
tri = {{0, 0}, {1, 0}, {1, Sqrt[3]}};
TriangleConstruct[tri, "AngleBisectingCevianEndpoint"]RegionIntersection[TriangleConstruct[tri, "AngleBisector"], TriangleConstruct[tri, "OppositeSide"]]RegionEqual[%, %%]The angle bisectors of a triangle intersect at the incenter:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, {"AngleBisector", All}]RegionIntersection@@%TriangleConstruct[tri, "Incenter"]TriangleConstruct[{a,b,c},"AngleBisector"] is equivalent to AngleBisector[{a,b,c}]:
TriangleConstruct[{{1, 0}, {0, 0}, {1, 1}}, "AngleBisector"]AngleBisector[{{1, 0}, {0, 0}, {1, 1}}]TriangleConstruct[{a,b,c},"Incircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Incenter"],TriangleMeasurement[{a,b,c},"Inradius"]]:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, "Incircle"]Circle[TriangleCenter[tri, "Incenter"], TriangleMeasurement[tri, "Inradius"]]TriangleConstruct[{a,b,c},"Incircle"] is equivalent to Circle@@Insphere[{a,b,c}]:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, "Incircle"]Insphere[tri]Median, Midpoint and Centroid (3)
A median intersects the opposite side at the midpoint:
tri = {{-1, 0}, {2, 1}, {0, 1}};
TriangleConstruct[tri, "Midpoint"]RegionIntersection[TriangleConstruct[tri, "Median"], TriangleConstruct[tri, "OppositeSide"]]The medians of a triangle intersect at the centroid:
tri = {{-1, 0}, {1, 0}, {0, Sqrt[3]}};
TriangleConstruct[tri, {"Median", All}]RegionIntersection@@%TriangleConstruct[tri, "Centroid"]TriangleConstruct[{a,b,c},"Centroid"] is equivalent to Point[RegionCentroid[Triangle[{a,b,c}]]]:
tri = {{-1, 0}, {1, 0}, {0, Sqrt[3]}};
TriangleConstruct[tri, "Centroid"]Point[RegionCentroid[Triangle[tri]]]Perpendicular Bisector, Midpoint and Circumcenter (5)
The perpendicular bisector of a side passes through the midpoint of that side:
tri = {{2, 0}, {1, 2}, {-1, 0}};
TriangleConstruct[tri, "Midpoint"]RegionIntersection[TriangleConstruct[tri, "PerpendicularBisector"], TriangleConstruct[tri, "OppositeSide"]]The perpendicular bisectors of a triangle intersect at the circumcenter:
tri = {{0, 0}, {1, 0}, {0, 1}};
TriangleConstruct[tri, {"PerpendicularBisector", All}]RegionIntersection@@%TriangleConstruct[tri, "Circumcenter"]TriangleConstruct[{a,b,c},"PerpendicularBisector"] is equivalent to PerpendicularBisector[{a,c}]:
TriangleConstruct[{{2, 0}, {1, 2}, {-1, 0}}, "PerpendicularBisector"]PerpendicularBisector[{{2, 0}, {-1, 0}}]TriangleConstruct[{a,b,c},"Circumcircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Circumcenter"],TriangleMeasurement[{a,b,c},"Circumradius"]]:
tri = {{0, 0}, {1, 0}, {0, 1}};
TriangleConstruct[tri, "Circumcircle"]Circle[TriangleCenter[tri, "Circumcenter"], TriangleMeasurement[tri, "Circumradius"]]TriangleConstruct[{a,b,c},"Circumcircle"] is equivalent to Circle@@Circumsphere[{a,b,c}]:
tri = {{0, 0}, {1, 0}, {0, 1}};
TriangleConstruct[tri, "Circumcircle"]Circumsphere[tri]Altitude, Foot and Orthocenter (2)
The foot of an altitude is the intersection of the altitude and the opposite side:
tri = {{-1, 0}, {2, 1}, {1, 3}};
TriangleConstruct[tri, "Foot"]RegionIntersection[TriangleConstruct[tri, "Altitude"], TriangleConstruct[tri, "OppositeSide"]]The altitudes of a triangle intersect at the orthocenter:
tri = {{-1, 0}, {2, 1}, {1, 3}};
TriangleConstruct[tri, {"Altitude", All}]RegionIntersection@@%TriangleConstruct[tri, "Orthocenter"]Symmedian, Median and Angle Bisector (3)
The endpoint of a symmedian at a vertex is the intersection of the symmedian and the opposite side:
tri = {{0, 0}, {3, 0}, {1, 4}};
TriangleConstruct[tri, "SymmedianEndpoint"]RegionIntersection[TriangleConstruct[tri, "Symmedian"], TriangleConstruct[tri, "OppositeSide"]]The angle bisector at a vertex also bisects the angle formed by the median and symmedian at that vertex:
tri = {{0, 0}, {3, 0}, {1, 4}};
pt = TriangleCenter[tri, "AngleBisectingCevianEndpoint"]PlanarAngle[{TriangleCenter[tri, "SymmedianEndpoint"], {3, 0}, pt}]PlanarAngle[{pt, {3, 0}, TriangleCenter[tri, "Midpoint"]}]The symmedians of a triangle intersect at the symmedian point:
tri = {{0, 0}, {3, 0}, {1, 4}};
TriangleConstruct[tri, {"Symmedian", All}]RegionIntersection@@%TriangleConstruct[tri, "SymmedianPoint"]Exterior Angle Bisector and Excenter (3)
The excenter opposite from a vertex is the intersection of the exterior angle bisectors of the opposite angles:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, "Excenter"]TriangleConstruct[tri, {"ExteriorAngleBisector", {0, 0}}]TriangleConstruct[tri, {"ExteriorAngleBisector", {3, 4}}]RegionIntersection[%, %%]TriangleConstruct[{a,b,c},"ExteriorAngleBisector"] is equivalent to AngleBisector[{a,b,c},"Exterior"]:
tri = {{1, 0}, {0, 0}, {1, 1}};
TriangleConstruct[tri, "ExteriorAngleBisector"]AngleBisector[tri, "Exterior"]TriangleConstruct[{a,b,c},"Excircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"Excenter"],TriangleMeasurement[{a,b,c},"Exradius"]]:
tri = {{0, 0}, {3, 0}, {3, 4}};
TriangleConstruct[tri, "Excircle"]Circle[TriangleCenter[tri, "Excenter"], TriangleMeasurement[tri, "Exradius"]]Nine-Point Circle, Foot, Midpoint, Orthocenter (2)
The nine-point circle of a triangle passes through the feet of the altitudes, the midpoints of the sides and the midpoints of the segments from the vertices to the orthocenter:
tri = {{0, 0}, {3, 0}, {1, 2}};
circ = TriangleConstruct[tri, "NinePointCircle"]feet = TriangleCenter[tri, {"Foot", All}]RegionMember[circ, feet]midpoints = TriangleCenter[tri, {"Midpoint", All}]RegionMember[circ, midpoints]orthoMidpoints = Midpoint[{#, TriangleCenter[tri, "Orthocenter"]}]& /@ triRegionMember[circ, orthoMidpoints]TriangleConstruct[{a,b,c},"NinePointCircle"] is equivalent to Circle[TriangleCenter[{a,b,c},"NinePointCenter"],TriangleMeasurement[{a,b,c},"NinePointRadius"]]:
tri = {{0, 0}, {3, 0}, {1, 2}};
TriangleConstruct[tri, "NinePointCircle"]Circle[TriangleCenter[tri, "NinePointCenter"], TriangleMeasurement[tri, "NinePointRadius"]]Euler Line, Centroid, Circumcenter, Orthocenter and Nine-Point Center (1)
The Euler line passes through the centroid, circumcenter, orthocenter and nine-point center:
tri = {{-1, 0}, {2, 0}, {1, 2}};
line = TriangleConstruct[tri, "EulerLine"]RegionMember[line, {TriangleCenter[tri, "Centroid"], TriangleCenter[tri, "Circumcenter"], TriangleCenter[tri, "Orthocenter"], TriangleCenter[tri, "NinePointCenter"]}]Midpoint (1)
TriangleConstruct[{a,b,c},"Midpoint"] is equivalent to Point[Midpoint[{a,c}]]:
TriangleConstruct[{{-1, 2}, {0, 0}, {3, 4}}, "Midpoint"]Midpoint[{{-1, 2}, {3, 4}}]Boundary (1)
TriangleConstruct[{a,b,c},"Boundary"] is equivalent to RegionBoundary[Triangle[{a,b,c}]]:
tri = {{0, 0}, {2, 0}, {2, 3}};
TriangleConstruct[tri, "Boundary"]RegionBoundary[Triangle[tri]]Medial and Antimedial Triangle (2)
TriangleConstruct[{a,b,c},"MedialTriangle"] is equivalent to Triangle[TriangleCenter[tri,{"Midpoint",All}]]:
tri = {{-2, 1}, {0, 0}, {1, 1}};
TriangleConstruct[tri, "MedialTriangle"]Triangle[TriangleCenter[tri, {"Midpoint", All}]]The antimedial triangle is the triangle whose medial triangle is the original triangle:
tri = {{-2, 1}, {0, 0}, {1, 1}};
TriangleConstruct[tri, "AntimedialTriangle"]TriangleConstruct[{{3, 0}, {-1, 2}, {-3, 0}}, "MedialTriangle"]Text
Wolfram Research (2019), TriangleConstruct, Wolfram Language function, https://reference.wolfram.com/language/ref/TriangleConstruct.html.
CMS
Wolfram Language. 2019. "TriangleConstruct." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TriangleConstruct.html.
APA
Wolfram Language. (2019). TriangleConstruct. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TriangleConstruct.html