WOLFRAM

Wolfram Language & System Documentation Center

AppellF4[a,b,c1,c2,x,y]

is the Appell hypergeometric function of two variables .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Differentiation  
Series Expansions  
Applications  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

AppellF4

AppellF4[a,b,c1,c2,x,y]

is the Appell hypergeometric function of two variables .

Details

  • AppellF4 belongs to the family of Appell functions that generalize the hypergeometric series and solves the system of Horn PDEs with polynomial coefficients.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • has a primary definition through the hypergeometric series , which is convergent inside the region sqrt(TemplateBox[{x}, Abs])+sqrt(TemplateBox[{y}, Abs])<1.
  • The region of convergence of the Appell F4 series for real values of its arguments is the following:
  • In general, satisfies the following Horn PDE system »:
  • reduces to when or .
  • For certain special arguments, AppellF4 automatically evaluates to exact values.
  • AppellF4 can be evaluated to arbitrary numerical precision.

Examples

open all close all

Basic Examples  (7)

Evaluate numerically:

Wolfram Language code: AppellF4[2, 1, 3, 4, 1 / 5, 0.3]

The defining sum:

Wolfram Language code: Sum[x^m y^n( Pochhammer[a, m + n]Pochhammer[b, m + n] /Pochhammer[c1, m]Pochhammer[c2, n]m! n!), {m, 0, Infinity}, {n, 0, Infinity}]

Plot over a subset of the reals:

Wolfram Language code: Plot[AppellF4[1 / 2, 3 / 2, 1 / 3, 4, 0.1, y], {y, -1 / 2, 1 / 3}]

Plot over a subset of the complexes:

Wolfram Language code: Plot[Abs[AppellF4[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, z I]], {z, -1 / 2, 1 / 2}]
Wolfram Language code: ReImPlot[AppellF4[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, z I], {z, -1 / 2, 1 / 2}]

Plot a family of AppellF4 functions:

Wolfram Language code: Plot[Table[Abs[AppellF4[1 / 2, 1 / 3, 1 / 4, 1 / 5, n / 15 I, z I]], {n, -3, 3}]//Evaluate, {z, -1 / 3, 1 / 3}]

Series expansion at the origin:

Wolfram Language code: Series[AppellF4[1, 2, 3, 4, 5, x], {x, 0, 3}]

TraditionalForm formatting:

Wolfram Language code: AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, y]//TraditionalForm

Scope  (17)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: AppellF4[3, 2, 1, 2, 1 / 5, 0.1]
Wolfram Language code: AppellF4[-2, -1, -2.3, 2 / 3 + I, 0.1, 0.3]

Evaluate to high precision:

Wolfram Language code: N[AppellF4[3, 2, 1, 2, 1 / 5, 1 / 7], 10]

The precision of the output tracks the precision of the input:

Wolfram Language code: AppellF4[3, 2, 1, 2, 1 / 5, 0.100000000000000000001]

Complex number inputs:

Wolfram Language code: AppellF1[I, 1, 1 + I, 3.2, 0.1, 0.1 + 0.1 I]

Evaluate AppellF4 efficiently at high precision:

Wolfram Language code: AppellF4[3, 2, 1, 2, 1 / 7, 1 / 5`100]//Timing
Wolfram Language code: AppellF4[3, 2, 1, 2, 1 / 3, -1 / 5`100 + I];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: AppellF4[ 3 / 2, -4, 5, 1 / 2, 0, Around[2.1, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: AppellF4[3 / 2, -4, 5, 1 / 2, 0, {{1 / 2, 2}, {2, 1 / 2}}]

Or compute the matrix AppellF4 function using MatrixFunction:

Wolfram Language code: MatrixFunction[AppellF4[3 / 2, -4, 5, 1 / 2, 0, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

Specific Values  (3)

Values at fixed points:

Wolfram Language code: AppellF4[1 / 2, 1 / 3, 1 / 4, 1 / 2, 0, 2]
Wolfram Language code: AppellF4[3 / 2, -4, 5, 1 / 2, 0, 2]

Simplify to Hypergeometric2F1 functions:

Wolfram Language code: AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, 0]
Wolfram Language code: AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], 0, y]

Value at zero:

Wolfram Language code: AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], 0, 0]

Visualization  (3)

Plot the AppellF4 function for various parameters:

Wolfram Language code: Plot[{AppellF4[1 / 2, 3 / 2, 1 / 3, 4, x, 0.1], AppellF4[1 / 2, 3 / 2, 1 / 3, 4, x, 0], AppellF4[1 / 2, 3 / 2, 1 / 3, 4, x, -0.1]}, {x, -1 / 3, 1 / 3}]

Plot AppellF4 as a function of its second parameter :

Wolfram Language code: Plot[{AppellF4[1 / 2, 3 / 2, 1 / 3, 4, 0.1, y], AppellF4[1 / 2, 3 / 2, 1 / 3, 4, 0.07, y], AppellF4[1 / 2, 3 / 2, 1 / 3, 4, 0, y]}, {y, -1 / 3, 1 / 3}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[AppellF4[2, 3, 1 / 3, 2, 0, z]], {z, -1 - I, 1 + I}]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[AppellF4[2, 3, 1 / 3, 2, 0, z]], {z, -5 - 5I, 5 + 5I}]

Differentiation  (4)

First derivative with respect to x:

Wolfram Language code: D[AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, y], x]

First derivative with respect to y:

Wolfram Language code: D[AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, y], y]

Higher derivatives with respect to y:

Wolfram Language code: Table[D[AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, y], {y, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to y when a=1/2, b=3/2, c1=1/3, c2=4 and x=1/5:

Wolfram Language code: Plot[Evaluate[% /. {a -> 1 / 2, b -> 3 / 2, Subscript[c, 1] -> 1 / 3, Subscript[c, 2] -> 4, x -> 1 / 10}], {y, -1 / 3, 1 / 3}, Rule[...]]

Formula for the ^(th) derivative with respect to y:

Wolfram Language code: D[AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, y], {y, n}]

Series Expansions  (1)

Find the Taylor expansion using Series:

Wolfram Language code: Series[AppellF4[a, b, Subscript[c, 1], Subscript[c, 2], x, y], {x, 0, 2}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[AppellF4[1 / 2, 1 / 3, 1 / 4, 1 / 5, x, .1], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF4[1 / 2, 1 / 3, 1 / 4, 1 / 5, x, .1], terms}//Evaluate, {x, 0, 1 / 3}]

Applications  (1)

The Appell function solves the following system of PDEs with polynomial coefficients:

Wolfram Language code: pde = {x (1 - x) f^(2, 0)[x, y] - y^2 f^(0, 2)[x, y] - 2x y f^(1, 1)[x, y] + (Subscript[c, 1] - (a + b + 1)x)f^(1, 0)[x, y] - (a + b + 1)y f^(0, 1)[x, y] - a b f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] - x^2 f^(2, 0)[x, y] - 2x yf^(1, 1)[x, y] + (Subscript[c, 2] - (a + b + 1)y)f^(0, 1)[x, y] - (a + b + 1)xf^(1, 0)[x, y] - a b f[x, y] == 0};

Check that is a solution:

Wolfram Language code: (pde /. {a -> 1 / 2, b -> 3 / 2, Subscript[c, 1] -> 1 / 3, Subscript[c, 2] -> 4}) /. f -> Function[{x, y}, AppellF4[1 / 2, 3 / 2, 1 / 3, 4, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-1 / 10, 1 / 10}, {2}, WorkingPrecision -> 50]]

Neat Examples  (1)

Many elementary and special functions are special cases of AppellF4:

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (2023), AppellF4, Wolfram Language function, https://reference.wolfram.com/language/ref/AppellF4.html.

Text

Wolfram Research (2023), AppellF4, Wolfram Language function, https://reference.wolfram.com/language/ref/AppellF4.html.

CMS

Wolfram Language. 2023. "AppellF4." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AppellF4.html.

APA

Wolfram Language. (2023). AppellF4. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AppellF4.html

BibTeX

@misc{reference.wolfram_2026_appellf4, author="Wolfram Research", title="{AppellF4}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF4.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf4, organization={Wolfram Research}, title={AppellF4}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF4.html}, note=[Accessed: 12-June-2026]}