WOLFRAM

Wolfram Language & System Documentation Center

AppellF3[a1,a2,b1,b2,c,x,y]

is the Appell hypergeometric function of two variables .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Differentiation  
Series Expansions  
Applications  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

AppellF3

AppellF3[a1,a2,b1,b2,c,x,y]

is the Appell hypergeometric function of two variables .

Details

  • AppellF3 belongs to the family of Appell functions that generalize the hypergeometric series and solves the system of Horn PDEs with polynomial coefficients.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • has a primary definition through the hypergeometric series , which is convergent inside the region max(TemplateBox[{x}, Abs],TemplateBox[{y}, Abs])<1.
  • The region of convergence of the Appell F3 series for real values of its arguments is the following:
  • In general, satisfies the following Horn PDE system »:
  • reduces to when or .
  • For certain special arguments, AppellF3 automatically evaluates to exact values.
  • AppellF3 can be evaluated to arbitrary numerical precision.

Examples

open all close all

Basic Examples  (7)

Evaluate numerically:

Wolfram Language code: AppellF3[2, 1, 3, 4, 5, 0.7, 0.3]

The defining sum:

Wolfram Language code: Sum[x^m y^n(( Pochhammer[a1, m]Pochhammer[a2, n]Pochhammer[b1, m] Pochhammer[b2, n]) / (Pochhammer[c, m + n]m! n!)), {m, 0, Infinity}, {n, 0, Infinity}]

Plot over a subset of the reals:

Wolfram Language code: Plot[AppellF3[1, 2, 3, 6, 1 / 5, -1 / 3, y], {y, -3 / 4, 1 / 5}]

Plot over a subset of the complexes:

Wolfram Language code: Plot[Abs[AppellF3[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, 1 / 7, z I]], {z, -3 / 4, 3 / 4}]

Plot a family of AppellF3 functions:

Wolfram Language code: Plot[Table[Abs[AppellF3[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, 1 / 2 + n / 5 I, 1 / 2 + z I]], {n, -3, 3}]//Evaluate, {z, -9 / 10, 1}]

Series expansion at the origin:

Wolfram Language code: Series[AppellF3[1, 1, 1, 1, 1, 4, x], {x, 0, 3}]

TraditionalForm formatting:

Wolfram Language code: AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, y]//TraditionalForm

Scope  (17)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: AppellF3[3, 2, 1, 2, 3, 1 / 3, 0.2]
Wolfram Language code: AppellF3[-2, -1, -2, 5, 2 / 3 + I, 0.4, 0.3]

Evaluate to high precision:

Wolfram Language code: N[AppellF3[3, 2, 1, 2, 3, 1 / 3, 2 / 5], 10]

The precision of the output tracks the precision of the input:

Wolfram Language code: AppellF3[3, 2, 1, 2, 3, 1 / 3, 0.400000000000000000001]

Complex number inputs:

Wolfram Language code: AppellF3[I, 1, 1 + I, 3.2, 1 / 2, 0.5, 0.2 + 0.5 I]

Evaluate AppellF3 efficiently at high precision:

Wolfram Language code: AppellF3[3, 2, 1, 2, 1 / 3, 1 / 7, 1 / 5`100]//Timing
Wolfram Language code: AppellF3[3, 2, 1, 2, 7, 1 / 3, -1 / 5`100 + I];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: AppellF3[ 1 / 2, 3 / 2, -4, 5, 1 / 2, 0, Around[2.1, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: AppellF3[1 / 2, 3 / 2, -4, 5, 1 / 2, 0, {{1 / 2, 2}, {2, 1 / 2}}]

Or compute the matrix AppellF3 function using MatrixFunction:

Wolfram Language code: MatrixFunction[AppellF3[1 / 2, 3 / 2, -4, 5, 1 / 2, 0, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

Specific Values  (3)

Values at fixed points:

Wolfram Language code: AppellF3[1 / 2, 1 / 3, 1 / 2, 1, 3, 0, 2]
Wolfram Language code: AppellF3[2, 1 / 3, 1 / 4, 1, 4, 0, 2]

Simplify to Hypergeometric2F1 functions:

Wolfram Language code: AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, 0]
Wolfram Language code: AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, 0, y]

Value at zero:

Wolfram Language code: AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, 0, 0]

Visualization  (3)

Plot the AppellF3 function for various parameters:

Wolfram Language code: Plot[{AppellF3[1, 2, 3, 6, 1 / 5, x, 1 / 30], AppellF3[2, 1, 3, 1 / 3, 2, x, 0], AppellF3[2, 1, 3, 1 / 3, 2, x, -1 / 2]}, {x, -1 / 2, 1 / 5}]

Plot AppellF3 as a function of its second parameter :

Wolfram Language code: Plot[{AppellF3[1, 2, 3, 6, 1 / 5, -1 / 2, y], AppellF3[1, 2, 3, 6, 1 / 5, -1 / 5, y], AppellF3[1, 2, 3, 6, 1 / 5, -1 / 100, y]}, {y, -1 / 2, 1 / 5}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[AppellF3[2, 1, 3, 1 / 3, 2, 0, z]], {z, -5 - 5I, 5 + 5I}]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[AppellF3[2, 1, 3, 1 / 3, 2, 0, z]], {z, -5 - 5I, 5 + 5I}]

Differentiation  (4)

First derivative with respect to x:

Wolfram Language code: D[AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, y], x]

First derivative with respect to y:

Wolfram Language code: D[AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, y], y]

Higher derivatives with respect to y:

Wolfram Language code: Table[D[AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to y when a1=a2=2, b1=b2=5, c=1/2 and x=1/5:

Wolfram Language code: Plot[Evaluate[% /. {Subscript[a, 1] -> 2, Subscript[a, 2] -> 2, Subscript[b, 1] -> 5, Subscript[b, 2] -> 5, c -> 1 / 2, x -> 1 / 5}], {y, -1 / 2, 1 / 5}, Rule[...]]

Formula for the ^(th) derivative with respect to y:

Wolfram Language code: D[AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, y], {y, n}]

Series Expansions  (1)

Find the Taylor expansion using Series:

Wolfram Language code: Series[AppellF3[Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c, x, y], {x, 0, 2}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[AppellF3[1, 2, 3, 6, 1 / 5, x, .3], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF3[1, 2, 3, 6, 1 / 5, x, .3], terms}//Evaluate, {x, -9 / 10, 1 / 2}]

Applications  (1)

The Appell function solves the following system of PDEs with polynomial coefficients:

Wolfram Language code: pde = {x (1 - x) f^(2, 0)[x, y] + y f^(1, 1)[x, y] + (c - (Subscript[a, 1] + Subscript[b, 1] + 1)x)f^(1, 0)[x, y] - Subscript[a, 1] Subscript[b, 1] f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] + x f^(1, 1)[x, y] + (c - (Subscript[a, 2] + Subscript[b, 2] + 1)y)f^(0, 1)[x, y] - Subscript[a, 2] Subscript[b, 2] f[x, y] == 0};

Check that is a solution:

Wolfram Language code: (pde /. {Subscript[a, 1] -> 1, Subscript[a, 2] -> 2, Subscript[b, 1] -> 3, Subscript[b, 2] -> 6, c -> 1 / 5}) /. f -> Function[{x, y}, AppellF3[1, 2, 3, 6, 1 / 5, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-1 / 2, 1 / 2}, {2}, WorkingPrecision -> 50]]

Neat Examples  (1)

Many elementary and special functions are special cases of AppellF3:

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (2023), AppellF3, Wolfram Language function, https://reference.wolfram.com/language/ref/AppellF3.html.

Text

Wolfram Research (2023), AppellF3, Wolfram Language function, https://reference.wolfram.com/language/ref/AppellF3.html.

CMS

Wolfram Language. 2023. "AppellF3." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AppellF3.html.

APA

Wolfram Language. (2023). AppellF3. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AppellF3.html

BibTeX

@misc{reference.wolfram_2026_appellf3, author="Wolfram Research", title="{AppellF3}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF3.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf3, organization={Wolfram Research}, title={AppellF3}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF3.html}, note=[Accessed: 13-June-2026]}