FourierSinTransform
FourierSinTransform[f[t],t,ω]
gives the symbolic Fourier sine transform of f[t] in the variable t as F[ω] in the variable ω.
FourierSinTransform[f[t],t,
]
gives the numeric Fourier sine transform at the numerical value 
.
FourierSinTransform[f[t1,…,tn],{t1,…,tn},{ω1,…,ωn}]
gives the multidimensional Fourier sine transform of f[t1,…,tn].
Details and Options
- The Fourier sine transform is a particular way of viewing the Fourier transform without the need for complex numbers or negative frequencies.
- Joseph Fourier designed his famous transform using this and the Fourier cosine transform, and they are still used in applications like signal processing, statistics and image and video compression.
- The Fourier sine transform of the time domain function
is the frequency domain function 
for 
: - The Fourier sine transform of a function
is by default defined to be 
. - The multidimensional Fourier sine transform of a function
is by default defined to be 
or when using vector notation, ![(2/pi)^(n/2)int_(t in TemplateBox[{}, PositiveReals]^n )f(t) sin(omega t)dt](Files/FourierSinTransform.en/11.png "(2/pi)^(n/2)int_(t in TemplateBox[{}, PositiveReals]^n )f(t) sin(omega t)dt")
. - Different choices of definitions can be specified using the option FourierParameters.
- The integral is computed using numerical methods if the third argument,
, is given a numerical value. - The asymptotic Fourier sine transform can be computed using Asymptotic.
- There are several related Fourier transformations:
-
FourierTransform infinite continuous-time functions (FT) FourierSequenceTransform infinite discrete-time functions (DTFT) FourierCoefficient finite continuous-time functions (FS) Fourier finite discrete-time functions (DFT) - The Fourier sine transform is an automorphism in the Schwartz vector space of functions whose derivatives are rapidly decreasing and thus induces an automorphism in its dual: the space of tempered distributions. These include absolutely integrable functions, well-behaved functions of polynomial growth and compactly supported distributions.
- Hence, FourierSinTransform not only works with absolutely integrable functions on
, but it can also handle a variety of tempered distributions such as DiracDelta to enlarge the pool of functions or generalized functions it can effectively transform. - The following options can be given:
-
AccuracyGoal Automatic digits of absolute accuracy sought Assumptions $Assumptions assumptions to make about parameters FourierParameters {0,1} parameters to define the Fourier sine transform GenerateConditions False whether to generate answers that involve conditions on parameters PerformanceGoal $PerformanceGoal aspects of performance to optimize PrecisionGoal Automatic digits of precision sought WorkingPrecision Automatic the precision used in internal computations - Common settings for FourierParameters include:
-
{0,1} 
{1,1} 
{-1,1} 
{0,2Pi} 
{a,b} 
Examples
open all close allBasic Examples (6)
Compute the Fourier sine transform of a function:
FourierSinTransform[t / (t ^ 2 + 1), t, ω]Plot the function and its Fourier sine transform:
{Plot[t / (t ^ 2 + 1), {t, 0, 10}], Plot[%, {ω, 0, 10}]}Fourier sine transform of an exponential function:
FourierSinTransform[Exp[-t], t, ω]For a different convention, change the parameters:
FourierSinTransform[Exp[-t], t, ω, FourierParameters -> {1, 2π}]Fourier sine transform of the reciprocal of a square root:
FourierSinTransform[1 / Sqrt[t], t, ω]Compute the Fourier sine transform of a multivariate function:
FourierSinTransform[UnitBox[x - 1 / 2, y - 1 / 2], {x, y}, {u, v}]Plot the function and its transform:
{Plot3D[UnitBox[x - 1 / 2, y - 1 / 2], {x, 0, 2}, {y, 0, 2}, Exclusions -> None, Mesh -> None], Plot3D[%, {u, 0, 3}, {v, 0, 3}, Mesh -> None]}Compute the transform at a single point:
FourierSinTransform[Cos[t] / t, t, 1.2]Scope (37)
Basic Uses (3)
Fourier sine transform of a function for a symbolic parameter 
:
FourierSinTransform[HeavisideTheta[t], t, ω]Plot[%, {ω, 0, 4}]Fourier sine transforms involving trigonometric functions:
FourierSinTransform[Cos[t] / (t E ^ t), t, ω]Plot[%, {ω, 0, 4}]FourierSinTransform[Sin[t] / t ^ 2, t, ω]Plot[%, {ω, 0, 4}]Evaluate the Fourier sine transform for a numerical value of the parameter 
:
FourierSinTransform[Exp[-t] / Sqrt[t], t, 1.3]Algebraic Functions (3)
Fourier sine transform of power functions:
FourierSinTransform[t ^ (n - 1), t, ω, Assumptions -> 0 < n < 1]Sine transform of rational functions:
FourierSinTransform[1 / t, t, ω]FourierSinTransform[1 / (α + t), t, ω, Assumptions -> Abs[Arg[α]] < π]
Plot[% /. α -> 1, {ω, 0, 5}]FourierSinTransform[1 / (α ^ 2 + t ^ 2), t, ω, Assumptions -> α > 0]
Plot[% /. α -> 2, {ω, 0, 5}]FourierSinTransform[t / (α ^ 2 + t ^ 2), t, ω, Assumptions -> α > 0]
FourierSinTransform[t / (1 + t ^ 2), t, ω]Plot[%, {ω, 0, 5}]FourierSinTransform[t / (t ^ 2 + α ^ 2) ^ 2, t, ω, Assumptions -> α > 0]
Plot[% /. α -> 2, {ω, 0, 5}]Fourier sine transform of a quotient of two polynomials:
FourierSinTransform[t / (t ^ 4 + 4), t, ω]Plot[%, {ω, 0, 6}]Exponential and Logarithmic Functions (3)
Fourier sine transforms for exponential functions:
FourierSinTransform[Exp[-α t], t, ω, Assumptions -> Re[α] > 0]
Plot[% /. α -> 3, {ω, 0, 4}]FourierSinTransform[t Exp[-α t], t, ω, Assumptions -> Re[α] > 0]
Plot[% /. α -> 1, {ω, 0, 4}]FourierSinTransform[(E^-t - E^-2 t) / t ^ 2, t, ω]Plot[%, {ω, 0, 4}]Fourier sine transform of a Gaussian:
FourierSinTransform[Exp[-α t ^ 2], t, ω, Assumptions -> Re[α] > 0]
FourierSinTransform[Exp[-t ^ 2], t, ω]Plot[%, {ω, 0, 20}]FourierSinTransform[t Exp[-α t ^ 2], t, ω, Assumptions -> Abs[Arg[α]] < π / 2]
Plot[% /. α -> 1 / 2, {ω, 0, 8}]Sine transforms of logarithmic functions:
FourierSinTransform[Log[t] / t, t, ω]Plot[%, {ω, 0, 10}]FourierSinTransform[Log[1 + α ^ 2t ^ 2] / t, t, ω, Assumptions -> α > 0]
Plot[% /. α -> 3, {ω, 0, 4}]FourierSinTransform[Log[Abs[(t + α) / (t - α)]], t, ω, Assumptions -> α > 0]
Plot[% /. α -> 4, {ω, 0, 4}]FourierSinTransform[t Log[t] / (t ^ 2 + 4), t, ω]Plot[%, {ω, 0, 8}]Trigonometric Functions (3)
Composition of elementary functions:
FourierSinTransform[Cos[α t ^ 2], t, ω, Assumptions -> α > 0]//Simplify
Plot[% /. α -> 3 / 4, {ω, 0, 10}]FourierSinTransform[Sin[α t ^ 2], t, ω, Assumptions -> α > 0]//Simplify
Plot[% /. α -> 3 / 4, {ω, 0, 10}]FourierSinTransform[Sin[α t] / t, t, ω, Assumptions -> α > 0]
Plot[% /. α -> 2, {ω, 0, 4}]FourierSinTransform[Sin[α t] ^ 2 / t, t, ω, Assumptions -> α > 0]
Plot[% /. α -> 2, {ω, 0, 10}]Fourier sine transform of the product of exponential and trigonometric functions:
FourierSinTransform[Exp[-α t] Sin[ β t] / t, t, ω, Assumptions -> Re[α] > Im[β]]
Plot[% /. {α -> 1 / 3, β -> 1 / 2}, {ω, 0, 5}]FourierSinTransform[Exp[-α t] Cos[β t], t, ω, Assumptions -> Re[α] > Abs[Im[β]]]
Plot[% /. {α -> 3, β -> 2}, {ω, 0, 40}]Fourier sine transforms of arctangent functions:
FourierSinTransform[ArcTan[t], t, ω]Plot[%, {ω, 0, 10}]FourierSinTransform[ArcTan[2 / t], t, ω]Plot[%, {ω, 0, 10}]Special Functions (8)
Fourier sine transforms of expressions involving the Sinc function:
FourierSinTransform[Sinc[t] / t, t, ω]Plot[%, {ω, 0, 4}]FourierSinTransform[Sinc[t] ^ 2, t, ω]Plot[%, {ω, 0, 10}]Fourier sine transform of ExpIntegralEi:
FourierSinTransform[ExpIntegralEi[-t], t, ω]Plot[%, {ω, 0, 10}]Transform of Erf:
FourierSinTransform[Erf[t], t, ω]Plot[%, {ω, 0, 5}]Transform of Erfc:
FourierSinTransform[Erfc[α t], t, ω, Assumptions -> α > 0]
Plot[% /. α -> 1 / 2, {ω, 0, 5}]Expression involving the SinIntegral:
FourierSinTransform[SinIntegral[t] - π / 2, t, ω, Assumptions -> ω > 1]Plot[%, {ω, 0, 5}]FourierSinTransform[CosIntegral[α t], t, ω, Assumptions -> {α > 0, ω > α}]
Plot[% /. α -> 1 / 2, {ω, 0, 5}]Sine transforms for BesselJ functions:
FourierSinTransform[BesselJ[0, α t], t, ω, Assumptions -> {α > 0, ω > α}]
Plot[% /. α -> 1 / 2, {ω, 0, 5}]FourierSinTransform[BesselJ[2 n + 1, α t], t, ω, Assumptions -> {α > 0, 0 < ω < α}]
Plot[% /. {α -> 1 / 2, n -> 1}, {ω, 0, 3 / 4}]FourierSinTransform[BesselJ[n + 1, α t] / t ^ n, t, ω, Assumptions -> {α > 0, 0 < ω < α, n∈PositiveIntegers}]
Plot[% /. {α -> 2, n -> 1}, {ω, 0, 3}]Sine transforms for BesselY functions:
FourierSinTransform[BesselY[0, α t], t, ω, Assumptions -> {α > 0}]
Plot[% /. α -> 2, {ω, 0, 5}]FourierSinTransform[BesselY[n - 1, α t] t ^ n, t, ω, Assumptions -> {α > 0, ω > α, Abs[Re[n]] < 1 / 2}]
Plot[% /. {α -> 1, n -> 1 / 3}, {ω, 0, 5}]Piecewise Functions and Distributions (4)
Fourier sine transform of a piecewise function:
f[t_] = Piecewise[{{t, 0 ≤ t ≤ 1}, {0, t > 1}}];
Plot[f[t], {t, 0, 1.5}, Exclusions -> None]FourierSinTransform[f[t], t, ω]Restriction of a sine function to a half-period:
Plot[Sin[α t]UnitBox[α t / π - 1 / 2] /. α -> 3π / 2, {t, 0, 1}]Simplify[FourierSinTransform[Sin[α t]UnitBox[α t / π - 1 / 2], t, ω], α > π]f[t_] = Piecewise[{{t, 0 ≤ t ≤ 1}, {2 - t, 1 < t ≤ 2}, {0, 2 < t }}];
Plot[f[t], {t, 0, 3}]FourierSinTransform[f[t], t, ω]Transforms in terms of FresnelS:
FourierSinTransform[UnitStep[t - 1] / Sqrt[t], t, ω]Plot[%, {ω, 0, 10}]FourierSinTransform[(1 - UnitStep[t - 1]) / Sqrt[t], t, ω]Plot[%, {ω, 0, 10}]Periodic Functions (2)
Fourier sine transform of sine:
FourierSinTransform[Sin[t], t, ω]Fourier sine transform of SquareWave:
Plot[SquareWave[t], {t, 0, 4}, Exclusions -> None]FourierSinTransform[SquareWave[t], t, ω]Generalized Functions (4)
Fourier sine transforms of expressions involving HeavisideTheta:
Plot[HeavisideTheta[t - 1], {t, 0, 2}, Exclusions -> None]FourierSinTransform[HeavisideTheta[t - 1], t, ω]Plot[t ^ 2 HeavisideTheta[t] HeavisideTheta[1 - t], {t, 0, 1.5}, Exclusions -> None]FourierSinTransform[t ^ 2 HeavisideTheta[t] HeavisideTheta[1 - t], t, ω]Fourier sine transforms involving DiracDelta:
FourierSinTransform[DiracDelta[t - 1], t, ω]Plot[%, {ω, 0, 5}]FourierSinTransform[DiracDelta'[t - 1], t, ω]Plot[%, {ω, 0, 5}]Fourier sine transform involving HeavisideLambda:
Plot[HeavisideLambda[t - 1], {t, 0, 4}]FourierSinTransform[HeavisideLambda[t - 1], t, ω]Fourier sine transform involving HeavisidePi:
Plot[HeavisidePi[t - (3/2)], {t, 0, 3}, Exclusions -> None]FourierSinTransform[HeavisidePi[t - (3/2)], t, ω]Multivariate Functions (2)
Fourier sine transform of an exponential functions in two variables:
FourierSinTransform[Exp[-x - y], {x, y}, {u, v}]{Plot3D[Exp[-x - y], {x, 0, 5}, {y, 0, 5}, Mesh -> None], Plot3D[%, {u, 0, 5}, {v, 0, 5}, Mesh -> None]}FourierSinTransform[Exp[-x ^ 2 - y ^ 2], {x, y}, {u, v}]{Plot3D[Exp[-x ^ 2 - y ^ 2], {x, 0, 5}, {y, 0, 5}, Mesh -> None], Plot3D[%, {u, 0, 5}, {v, 0, 5}, Mesh -> None]}Fourier sine transform of product of exponential and SquareWave:
Plot3D[E ^ (-x)SquareWave[y], {x, 0, 5}, {y, 0, 5}, Mesh -> None]FourierSinTransform[E ^ (-x)SquareWave[y], {x, y}, {u, v}]Formal Properties (3)
Fourier sine transform of a first-order derivative:
FourierSinTransform[f'[t], t, ω]Fourier sine transform of a second-order derivative:
FourierSinTransform[f''[t], t, ω]Fourier sine transform threads itself over equations:
FourierSinTransform[f'[t] == 1 / t ^ (1 / 2), t, ω]Numerical Evaluation (2)
Calculate the Fourier sine transform at a single point:
FourierSinTransform[(1/Sqrt[t]), t, .9]Alternatively, calculate the Fourier sine transform symbolically:
FourierSinTransform[(1/Sqrt[t]), t, ω]Then evaluate it for specific value of 
:
N[% /. ω -> .9]Options (8)
AccuracyGoal (1)
The option AccuracyGoal sets the number of digits of accuracy:
exact = FourierSinTransform[HeavisideLambda[t - 1], t, 9 / 10]FourierSinTransform[HeavisideLambda[t - 1], t, .9, AccuracyGoal -> 5] - exactFourierSinTransform[HeavisideLambda[t - 1], t, .9] - exactAssumptions (1)
Fourier sine transform of BesselJ is a piecewise function:
FourierSinTransform[BesselJ[1, t], t, ω, Assumptions -> ω < 1]FourierSinTransform[BesselJ[1, t], t, ω, Assumptions -> ω > 1]FourierParameters (3)
Fourier sine transform for the unit box function with different parameters:
params = {{0, 1}, {1, 1}, {-1, 1}, {0, 2 π}};
funs = funs = Table[FourierSinTransform[UnitBox[t - (1/2)], t, ω, FourierParameters -> p], {p, params}]Create a nicely formatted table of the results:
header = { "Parameters", HoldForm@FourierSinTransform[UnitBox[t - (1/2)], t, ω]};
Grid[Prepend[Transpose[{params, funs}], header], IconizedObject[«Grid options»]]//TraditionalFormUse a nondefault setting for a different definition of the transform:
FourierSinTransform[Exp[-t], t, ω, FourierParameters -> {1, 1}]To get the inverse, use the same FourierParameters setting:
InverseFourierSinTransform[%, ω, t, FourierParameters -> {1, 1}]Set up your particular global choice of parameters once per session:
SetOptions[FourierSinTransform, FourierParameters -> {0, 2π}]FourierSinTransform[1, t, ω]//TraditionalFormSetOptions[FourierSinTransform, FourierParameters -> {0, 1}]GenerateConditions (1)
Use GenerateConditions True to get the parameter conditions necessary for the result to be valid:
FourierSinTransform[Exp[α t], t, ω, GenerateConditions -> True]PrecisionGoal (1)
The option PrecisionGoal sets the relative tolerance in the integration:
exact = FourierSinTransform[HeavisideLambda[t - 1], t, 9 / 10]FourierSinTransform[HeavisideLambda[t - 1], t, .9, PrecisionGoal -> 5] - exactFourierSinTransform[HeavisideLambda[t - 1], t, .9] - exactWorkingPrecision (1)
If a WorkingPrecision is specified, the computation is done at that working precision:
exact = FourierSinTransform[Exp[-t ^ 2], t, 1 / 2]FourierSinTransform[Exp[-t ^ 2], t, .5, WorkingPrecision -> 20] - exactFourierSinTransform[Exp[-t ^ 2], t, .5] - exactApplications (4)
Ordinary Differential Equations (1)
Consider the following ODE with initial condition 
:
OdEqn = y''[t] + Ω^2y[t] == Sin[t]Apply the Fourier sine transform to the ODE:
FourierSinTransform[OdEqn, t, ω]SolveValues[%, FourierSinTransform[y[t], t, ω]][[1]] /. y[0] -> 1Find the inverse Fourier sine transform with 
and 
:
ift[t_] = InverseFourierSinTransform[%, ω, t] /. {κ -> 1, Ω -> 1 / 2}//ExpToTrigCompare with DSolveValue:
DSolveValue[{(OdEqn /. {κ -> 1, Ω -> 1 / 2}), y[0] == 1, y'[0] == ift'[0]}, y[t], t]//FullSimplifyPartial Differential Equations (1)
Solve the infinite diffusion problem for 
, 
: 
with initial condition 
for 
and boundary condition 
for 
:
eqn = D[u[x, t], t] == α ^ 2 D[u[x, t], x, x];Fourier sine transform with respect to 
:
FourierSinTransform[eqn, x, ω]
DSolveValue[{D[u1[ω, t], t] == -α^2ω (ω u1[ω, t] - Sqrt[(2/π)] A), u1[ω, 0] == 0}, u1[ω, t], t]Compute the inverse sine transform:
Simplify[InverseFourierSinTransform[%, ω, x], {x > 0}]Compare with DSolveValue:
FullSimplify[DSolveValue[{eqn, u[x, 0] == 0, u[0, t] == A}, u[x, t], {x, t}, Assumptions -> {t > 0 && x > 0 && α∈Reals}], {x > 0, t > 0}]Consider the special case with 
and 
:
Plot[Evaluate@Table[% /. {α -> 1, A -> 5}, {t, {.005, .1, .3, .8}}], {x, 0, 4}, PlotLegends -> {.005, .1, .3, .8}]Evaluation of Integrals (2)
Calculate the following definite integral for 
:
Inactive[Integrate][(ω Sin[α ω]/1 + ω ^ 2), {ω, 0, ∞}]Compute the Fourier sine transform of an exponential function:
FourierSinTransform[E^-x, x, ω, Assumptions -> x > 0]Apply the Fourier sine inversion formula:
E^-x == Sqrt[2 / π] Sqrt[(2/π)]Inactive[Integrate][( ω/1 + ω^2) Sin[ω x], {ω, 0, ∞}]Solve for the definite integral:
SolveValues[%, Inactive[Integrate][( ω/1 + ω^2) Sin[ω x], {ω, 0, ∞}]][[1]] /. x -> αCompare with Integrate:
Integrate[(ω Sin[α ω]/1 + ω ^ 2), {ω, 0, ∞}, Assumptions -> α > 0]Calculate the following definite integral for 
:
Inactive[Integrate][(ω ^ 2/(α ^ 2 + ω ^ 2) ^ 2), {ω, 0, ∞}]Compute the Fourier sine transform of an exponential function:
FourierSinTransform[E^-x, x, ω, Assumptions -> x > 0]Inactive[Integrate][Abs[E^-α x] ^ 2, {x, -∞, ∞}] == Inactive[Integrate][Abs[(Sqrt[(2/π)] ω/α^2 + ω^2)] ^ 2, {ω, -∞, ∞}]Integrate[E^-2α x, {x, 0, ∞}, Assumptions -> α > 0] == HoldForm[(2/π)]Inactive[Integrate][( ω ^ 2/(α^2 + ω^2) ^ 2), {ω, 0, ∞}]Solve for the definite integral:
SolveValues[ReleaseHold[%], Inactive[Integrate][( ω ^ 2/(α^2 + ω^2) ^ 2), {ω, 0, ∞}]][[1]]Compare with Integrate:
Integrate[( ω ^ 2/(α^2 + ω^2) ^ 2), {ω, 0, ∞}, Assumptions -> α > 0]Properties & Relations (4)
By default, the Fourier sine transform of 
is:
HoldForm[FourierSinTransform[f[t], t, ω] = HoldForm[Sqrt[2 / π]] * Integrate[f[t]Sin[ω t], {t, 0, ∞}]]For 
, the definite integral becomes:
Sqrt[2 / π]Integrate[Exp[-t ^ 2]Sin[t]Sin[ω t], {t, 0, ∞}]//FullSimplifyCompare with FourierSinTransform:
FourierSinTransform[Exp[-t ^ 2]Sin[t], t, ω]//TrigToExp//SimplifyUse Asymptotic to compute an asymptotic approximation:
Asymptotic[Inactive[FourierSinTransform][E ^ (-t ^ 3), t, ω], ω -> 0]FourierSinTransform and InverseFourierSinTransform are mutual inverses:
InverseFourierSinTransform[FourierSinTransform[f[t], t, ω], ω, t]FourierSinTransform[InverseFourierSinTransform[G[ω], ω, t], t, ω]FourierSinTransform[t / (t ^ 2 + 1), t, ω]InverseFourierSinTransform[%, ω, t]Results from FourierSinTransform and FourierTransform differ by a factor of 
for odd functions:
FourierSinTransform[Cos[t] / t, t, ω]FourierTransform[Cos[t] / t, t, ω]The results differ by a factor of 
for ω>0:
Simplify[% - I %%, ω > 0]Possible Issues (1)
The result from an inverse Fourier sine transform may not have the same form as the original:
FourierSinTransform[UnitStep[1 + t] UnitStep[1 - t], t, ω]InverseFourierSinTransform[%, ω, t]The Fourier sine transform may be given in terms of generalized functions such as DiracDelta:
FourierSinTransform[t, t, ω]InverseFourierSinTransform[%, ω, t]Neat Examples (2)
The Fourier sine transform represented in terms of MeijerG:
FourierSinTransform[t / (t ^ 3 + 1), t, ω]Create a table of basic Fourier sine transforms:
flist = {t ^ n, E ^ (-a t), Exp[-t ^ 2], Sinc[t] ^ 2, DiracDelta[t - a], Log[t], UnitStep[t], UnitBox[t], Erf[ a t], ConditionalExpression[BesselJ[1, t], ω < 1], ConditionalExpression[ BesselY[0, t], 0 < ω < 1]};Grid[Prepend[{#, Assuming[{a > 0}, Simplify[FourierSinTransform[#1, t, ω]]]}& /@ flist, {f[t], FourierSinTransform[f[t], t, ω]}], IconizedObject[«Grid options»]]//TraditionalFormText
Wolfram Research (1999), FourierSinTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/FourierSinTransform.html (updated 2025).
CMS
Wolfram Language. 1999. "FourierSinTransform." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/FourierSinTransform.html.
APA
Wolfram Language. (1999). FourierSinTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FourierSinTransform.html