InverseFourierSinTransform[F[
],
,t]
gives the symbolic inverse Fourier sine transform of F[ω] in the variable ω as f[t] in the variable t.
InverseFourierSinTransform[F[ω],ω,
]
gives the numeric inverse Fourier sine transform at the numerical value 
.
InverseFourierSinTransform
InverseFourierSinTransform[F[
],
,t]
gives the symbolic inverse Fourier sine transform of F[ω] in the variable ω as f[t] in the variable t.
InverseFourierSinTransform[F[ω],ω,
]
gives the numeric inverse Fourier sine transform at the numerical value 
.
InverseFourierSinTransform[F[ω1,…,ωn],{ω1,… ,ωn},{t1,…,tn}]
gives the multidimensional inverse Fourier sine transform of F[ω1,…,ωn].
Details and Options
- The Fourier sine transform is a particular way of viewing the Fourier transform without the need for complex numbers or negative frequencies.
- Joseph Fourier designed his famous transform using this and the Fourier cosine transform, and they are still used in applications like signal processing, statistics and image and video compression.
- The inverse Fourier sine transform of the frequency domain function
is the time domain function 
for 
: - The inverse Fourier sine transform of a function
is by default defined as 
. - The multidimensional inverse Fourier sine transform of a function
is by default defined as 
or when using vector notation, ![(2/pi)^(n/2)int_(omega in TemplateBox[{}, PositiveReals]^n) F(omega) sin(omega t)domega](Files/InverseFourierSinTransform.en/13.png "(2/pi)^(n/2)int_(omega in TemplateBox[{}, PositiveReals]^n) F(omega) sin(omega t)domega")
. - Different choices of definitions can be specified using the option FourierParameters.
- The integral is computed using numerical methods if the third argument,
, is given a numerical value. - The asymptotic inverse Fourier sine transform can be computed using Asymptotic.
- There are several related Fourier transformations:
-
FourierTransform infinite continuous-time functions (FT) FourierSequenceTransform infinite discrete-time functions (DTFT) FourierCoefficient finite continuous-time functions (FS) Fourier finite discrete-time functions (DFT) - The inverse Fourier sine transform is an automorphism in the Schwartz vector space of functions whose derivatives are rapidly decreasing and,thus induces an automorphism in its dual: the space of tempered distributions. These include absolutely integrable functions, well-behaved functions of polynomial growth and compactly supported distributions.
- Hence, InverseFourierTransform not only works with absolutely integrable functions on
but it can also handle a variety of tempered distributions such as DiracDelta to enlarge the pool of functions or generalized functions it can effectively transform. - The following options can be given:
-
AccuracyGoal Automatic digits of absolute accuracy sought Assumptions $Assumptions assumptions to make about parameters FourierParameters {0,1} parameters to define the inverse Fourier sine transform GenerateConditions False whether to generate answers that involve conditions on parameters PerformanceGoal $PerformanceGoal aspects of performance to optimize PrecisionGoal Automatic digits of precision sought WorkingPrecision Automatic the precision used in internal computations - Common settings for FourierParameters include:
-
{0,1} 
{1,1} 
{-1,1} 
{0,2Pi} 
{a,b} 
Examples
open all close allBasic Examples (4)
Compute the inverse Fourier sine transform of a function:
InverseFourierSinTransform[ω / (ω ^ 2 + 1), ω, t]Plot the function and its inverse Fourier sine transform:
{Plot[ω / (ω ^ 2 + 1), {ω, 0, 10}], Plot[%, {t, 0, 10}]}Inverse Fourier sine transform of an exponential function:
InverseFourierSinTransform[Exp[-ω], ω, t]For a different convention, change the parameters:
InverseFourierSinTransform[Exp[-ω], ω, t, FourierParameters -> {1, 2π}]Compute the inverse Fourier sine transform of a multivariate function:
InverseFourierSinTransform[UnitBox[u - 1 / 2, v - 1 / 2], {u, v}, {x, y}]Plot the function and its transform:
{Plot3D[UnitBox[u - 1 / 2, v - 1 / 2], {u, 0, 2}, {v, 0, 2}, Exclusions -> None, Mesh -> None], Plot3D[%, {x, 0, 3}, {y, 0, 3}, Mesh -> None]}Compute the transform at a single point:
InverseFourierSinTransform[Cos[ω] / ω, ω, 1.2]Scope (38)
Basic Uses (3)
Inverse Fourier sine transform of a function for a symbolic parameter 
:
InverseFourierSinTransform[HeavisideTheta[ω], ω, t]Inverse Fourier sine transforms involving trigonometric functions:
InverseFourierSinTransform[Cos[ω] / (ω E ^ ω), ω, t]Plot[%, {t, 0, 4}]InverseFourierSinTransform[Sin[ω] / ω ^ 2, ω, t]Plot[%, {t, 0, 2}]Evaluate the inverse Fourier sine transform for a numerical value of the parameter 
:
InverseFourierSinTransform[Exp[-ω] / Sqrt[ω], ω, 1.3]Algebraic Functions (3)
Inverse Fourier sine transform of power functions:
InverseFourierSinTransform[ω ^ (n - 1), ω, t, Assumptions -> 0 < n < 1]Inverse sine transform of rational functions:
InverseFourierSinTransform[1 / ω, ω, t]InverseFourierSinTransform[1 / (α + ω), ω, t, Assumptions -> Abs[Arg[α]] < π]
Plot[% /. α -> 1, {t, 0, 5}]InverseFourierSinTransform[1 / (α ^ 2 + ω ^ 2), ω, t, Assumptions -> α > 0]
Plot[% /. α -> 2, {t, 0, 5}]InverseFourierSinTransform[ω / (α ^ 2 + ω ^ 2), ω, t, Assumptions -> α > 0]
Plot[% /. α -> 1 / 2, {t, 0, 10}]InverseFourierSinTransform[ω / (ω ^ 2 + α ^ 2) ^ 2, ω, t, Assumptions -> α > 0]
Plot[% /. α -> 2, {t, 0, 4}]Inverse Fourier sine transform of a quotient of two polynomials:
InverseFourierSinTransform[ω / (ω ^ 4 + 4), ω, t]Plot[%, {t, 0, 6}]Exponential and Logarithmic functions (3)
Inverse Fourier sine transforms for exponential functions:
InverseFourierSinTransform[Exp[-α ω], ω, t, Assumptions -> Re[α] > 0]
Plot[% /. α -> 3, {t, 0, 10}]InverseFourierSinTransform[ω Exp[-α ω], ω, t, Assumptions -> Re[α] > 0]
Plot[% /. α -> 1, {t, 0, 6}]InverseFourierSinTransform[(E^-ω - E^-2 ω) / ω ^ 2, ω, t]Plot[%, {t, 0, 10}]Inverse Fourier sine transform of a Gaussian:
InverseFourierSinTransform[Exp[-α ω ^ 2], ω, t, Assumptions -> Re[α] > 0]
Plot[% /. α -> 1 / 4, {t, 0, 5}]InverseFourierSinTransform[ω Exp[-α ω ^ 2], ω, t, Assumptions -> Abs[Arg[α]] < π / 2]
Plot[% /. α -> 2, {t, 0, 8}]Inverse sine transforms of logarithmic functions:
InverseFourierSinTransform[Log[ω] / ω, ω, t]Plot[%, {t, 0, 10}]InverseFourierSinTransform[Log[1 + α ^ 2ω ^ 2] / ω, ω, t, Assumptions -> α > 0]
Plot[% /. α -> 3, {t, 0, 4}]InverseFourierSinTransform[Log[Abs[(ω + α) / (ω - α)]], ω, t, Assumptions -> α > 0]
Plot[% /. α -> 4, {t, 0, 4}]InverseFourierSinTransform[ω Log[ω] / (ω ^ 2 + 4), ω, t]Plot[%, {t, 0, 8}]Trigonometric Functions (3)
Composition of elementary functions:
InverseFourierSinTransform[Cos[α ω ^ 2], ω, t, Assumptions -> α > 0]//Simplify
Plot[% /. α -> 3 / 4, {t, 0, 10}]InverseFourierSinTransform[Sin[α ω ^ 2], ω, t, Assumptions -> α > 0]//Simplify
Plot[% /. α -> 3 / 4, {t, 0, 10}]InverseFourierSinTransform[Sin[α ω] / ω, ω, t, Assumptions -> α > 0]
Plot[% /. α -> 2, {t, 0, 4}]InverseFourierSinTransform[Sin[α ω] ^ 2 / ω, ω, t, Assumptions -> α > 0]
Plot[% /. α -> 2, {t, 0, 10}]Inverse Fourier sine transform of product of exponential and trigonometric functions:
InverseFourierSinTransform[Exp[-α ω] Sin[ β ω] / ω, ω, t, Assumptions -> Re[α] > Im[β]]
Plot[% /. {α -> 1 / 3, β -> 1 / 2}, {t, 0, 5}]InverseFourierSinTransform[Exp[-α ω] Cos[β ω], ω, t, Assumptions -> Re[α] > Abs[Im[β]]]
Plot[% /. {α -> 1, β -> 1}, {t, 0, 40}, PlotRange -> All]Inverse Fourier sine transforms of arctangent functions:
InverseFourierSinTransform[ArcTan[ω], ω, t]Plot[%, {t, 0, 10}]InverseFourierSinTransform[ArcTan[2 / ω], ω, t]Plot[%, {t, 0, 10}]Special Functions (8)
Inverse Fourier sine transform of ExpIntegralEi:
InverseFourierSinTransform[ExpIntegralEi[-ω], ω, t]Plot[%, {t, 0, 10}]Transform of Erf:
InverseFourierSinTransform[Erf[ω], ω, t]Plot[%, {t, 0, 5}]Transform of Erfc:
InverseFourierSinTransform[Erfc[α ω], ω, t, Assumptions -> α > 0]
Plot[% /. α -> 1 / 2, {t, 0, 5}]Expression involving SinIntegral:
InverseFourierSinTransform[SinIntegral[ω] - π / 2, ω, t, Assumptions -> t > 1]Plot[%, {t, 0, 5}]InverseFourierSinTransform[CosIntegral[α ω], ω, t, Assumptions -> {α > 0, t > α}]
Plot[% /. α -> 1 / 2, {t, 0, 5}]Inverse sine transforms for BesselJ functions:
InverseFourierSinTransform[BesselJ[0, α ω], ω, t, Assumptions -> {α > 0, t > α}]
Plot[% /. α -> 1 / 2, {t, 0, 5}]InverseFourierSinTransform[BesselJ[2 n + 1, α ω], ω, t, Assumptions -> {α > 0, 0 < t < α}]
Plot[% /. {α -> 1 / 2, n -> 1}, {t, 0, .5}]InverseFourierSinTransform[BesselJ[n + 1, α ω] / ω ^ n, ω, t, Assumptions -> {α > 0, 0 < t < α, n∈PositiveIntegers}]
Plot[% /. {α -> 2, n -> 1}, {t, 0, 2.5}]Inverse sine transforms for BesselY functions:
InverseFourierSinTransform[BesselY[0, α ω], ω, t, Assumptions -> {α > 0}]
Plot[% /. α -> 2, {t, 0, 5}]InverseFourierSinTransform[BesselY[n - 1, α ω] ω ^ n, ω, t, Assumptions -> {α > 0, t > α, Abs[Re[n]] < 1 / 2}]
Plot[% /. {α -> 1, n -> 1 / 3}, {t, 0, 5}]Inverse sine transform for a Sinc function:
InverseFourierSinTransform[Sinc[ω] ^ 2, ω, t]Plot[%, {t, 0, 5}]Piecewise Functions and Distributions (4)
Inverse Fourier sine transform of a piecewise function:
f[ω_] = Piecewise[{{ω, 0 ≤ ω ≤ 1}, {0, ω > 1}}];
Plot[f[ω], {ω, 0, 1.5}, Exclusions -> None]InverseFourierSinTransform[f[ω], ω, t]Restriction of a sine function to a half-period:
Plot[Sin[α ω]UnitBox[α ω / π - 1 / 2] /. α -> 3π / 2, {ω, 0, 1}]Simplify[InverseFourierSinTransform[Sin[α ω]UnitBox[α ω / π - 1 / 2], ω, t], α > π]f[ω_] = Piecewise[{{ω, 0 ≤ ω ≤ 1}, {2 - ω, 1 < ω ≤ 2}, {0, 2 < ω }}];
Plot[f[ω], {ω, 0, 3}]InverseFourierSinTransform[f[ω], ω, t]Transforms in terms of FresnelS:
InverseFourierSinTransform[UnitStep[ω - 1] / Sqrt[ω], ω, t]Plot[%, {t, 0, 10}]InverseFourierSinTransform[(1 - UnitStep[ω - 1]) / Sqrt[ω], ω, t]Plot[%, {t, 0, 10}]Periodic Functions (2)
Inverse Fourier sine transform of sine:
InverseFourierSinTransform[Sin[ω], ω, t]Inverse Fourier sine transform of SquareWave:
Plot[SquareWave[ω], {ω, 0, 4}, Exclusions -> None]InverseFourierSinTransform[SquareWave[ω], ω, t]Generalized Functions (4)
Inverse Fourier sine transforms of expressions involving HeavisideTheta:
Plot[HeavisideTheta[ω - 1], {ω, 0, 2}, Exclusions -> None]InverseFourierSinTransform[HeavisideTheta[ω - 1], ω, t]Plot[ω ^ 2 HeavisideTheta[ω] HeavisideTheta[1 - ω], {ω, 0, 1.5}, Exclusions -> None]InverseFourierSinTransform[ω ^ 2 HeavisideTheta[ω] HeavisideTheta[1 - ω], ω, t]Inverse Fourier sine transforms involving DiracDelta:
InverseFourierSinTransform[DiracDelta[ω - 1], ω, t]Plot[%, {t, 0, 5}]InverseFourierSinTransform[DiracDelta'[ω - 1], ω, t]Plot[%, {t, 0, 5}]Inverse Fourier sine transform involving HeavisideLambda:
Plot[HeavisideLambda[ω - 1], {ω, 0, 4}]InverseFourierSinTransform[HeavisideLambda[ω - 1], ω, t]Inverse Fourier sine transform involving HeavisidePi:
Plot[HeavisidePi[ω - (3/2)], {ω, 0, 3}, Exclusions -> None]InverseFourierSinTransform[HeavisidePi[ω - (3/2)], ω, t]Multivariate Functions (3)
Inverse Fourier sine transform of a rational function in two variables:
InverseFourierSinTransform[u v / ((1 + u ^ 2)(1 + v ^ 2)), {u, v}, {x, y}]{Plot3D[u v / ((1 + u ^ 2)(1 + v ^ 2)), {u, 0, 5}, {v, 0, 5}, Mesh -> None], Plot3D[%, {x, 0, 5}, {y, 0, 5}, Mesh -> None]}InverseFourierSinTransform[Exp[-u ^ 2 - v ^ 2], {u, v}, {x, y}]{Plot3D[Exp[-u ^ 2 - v ^ 2], {u, 0, 5}, {v, 0, 5}, Mesh -> None], Plot3D[%, {x, 0, 5}, {y, 0, 5}, Mesh -> None]}Inverse Fourier sine transform of product of exponential and SquareWave:
Plot3D[E ^ (-u)SquareWave[v], {u, 0, 5}, {v, 0, 5}, Mesh -> None]InverseFourierSinTransform[E ^ (-u)SquareWave[v], {u, v}, {x, y}]Formal Properties (3)
Inverse Fourier sine transform of a first-order derivative:
InverseFourierSinTransform[F'[ω], ω, t]Inverse Fourier sine transform of a second-order derivative:
InverseFourierSinTransform[F''[ω], ω, t]Inverse Fourier sine transform threads itself over equations:
InverseFourierSinTransform[F'[ω] == 1 / ω ^ (1 / 2), ω, t]Numerical Evaluation (2)
Calculate the Inverse Fourier sine transform at a single point:
InverseFourierSinTransform[(1/Sqrt[ω]), ω, .9]Alternatively, calculate the inverse Fourier sine transform symbolically:
InverseFourierSinTransform[(1/Sqrt[ω]), ω, t]Then evaluate it for specific value of 
:
N[% /. t -> .9]Options (8)
AccuracyGoal (1)
The option AccuracyGoal sets the number of digits of accuracy:
exact = InverseFourierSinTransform[HeavisideLambda[ω - 1], ω, 9 / 10]InverseFourierSinTransform[HeavisideLambda[ω - 1], ω, .9, AccuracyGoal -> 5] - exactInverseFourierSinTransform[HeavisideLambda[ω - 1], ω, .9] - exactAssumptions (1)
Use Assumptions to indicate the region of interest for the parameters:
InverseFourierSinTransform[BesselJ[0, ω], ω, t, Assumptions -> t > 1]InverseFourierSinTransform[BesselJ[0, ω], ω, t, Assumptions -> t < 1]FourierParameters (3)
Inverse Fourier sine transform for the unit box function with different parameters:
params = {{0, 1}, {1, 1}, {-1, 1}, {0, 2 π}};
funs = funs = Table[InverseFourierSinTransform[UnitBox[ω - (1/2)], ω, t, FourierParameters -> p], {p, params}]Create a nicely formatted table of the results:
header = { "Parameters", HoldForm@InverseFourierSinTransform[UnitBox[ω - (1/2)], ω, t]};
Grid[Prepend[Transpose[{params, funs}], header], IconizedObject[«Grid options»]]//TraditionalFormUse a nondefault setting for a different definition of the transform:
InverseFourierSinTransform[Exp[-ω], ω, t, FourierParameters -> {1, 1}]To get the inverse, use the same FourierParameters setting:
FourierSinTransform[%, t, ω, FourierParameters -> {1, 1}]Set up your particular global choice of parameters once per session:
SetOptions[InverseFourierSinTransform, FourierParameters -> {0, 2π}]InverseFourierSinTransform[1, ω, t]//TraditionalFormSetOptions[InverseFourierSinTransform, FourierParameters -> {0, 1}]GenerateConditions (1)
Use GenerateConditions True to get parameter conditions for when a result is valid:
InverseFourierSinTransform[Exp[α ω], ω, t, GenerateConditions -> True]PrecisionGoal (1)
The option PrecisionGoal sets the relative tolerance in the integration:
exact = InverseFourierSinTransform[HeavisideLambda[ω - 1], ω, 9 / 10]InverseFourierSinTransform[HeavisideLambda[ω - 1], ω, .9, PrecisionGoal -> 5] - exactInverseFourierSinTransform[HeavisideLambda[ω - 1], ω, .9] - exactWorkingPrecision (1)
If a WorkingPrecision is specified, the computation is done at that working precision:
exact = InverseFourierSinTransform[Exp[-ω ^ 2], ω, 1 / 2]InverseFourierSinTransform[Exp[-ω ^ 2], ω, .5, WorkingPrecision -> 20] - exactInverseFourierSinTransform[Exp[-ω ^ 2], ω, .5] - exactApplications (4)
Ordinary Differential Equations (1)
Consider the following ODE with initial condition 
:
OdEqn = y''[t] + Ω^2y[t] == Sin[t]Apply the Fourier sine transform to the ODE:
FourierSinTransform[OdEqn, t, ω]SolveValues[%, FourierSinTransform[y[t], t, ω]][[1]] /. y[0] -> 1Find the inverse Fourier sine transform with 
and 
:
ift[t_] = InverseFourierSinTransform[%, ω, t] /. {κ -> 1, Ω -> 1 / 2}//ExpToTrigCompare with DSolveValue:
DSolveValue[{(OdEqn /. {κ -> 1, Ω -> 1 / 2}), y[0] == 1, y'[0] == ift'[0]}, y[t], t]//FullSimplifyPartial Differential Equations (1)
Solve the infinite diffusion problem for 
, 
: 
with initial condition 
for 
and boundary condition 
for 
:
eqn = D[u[x, t], t] == α ^ 2 D[u[x, t], x, x];Fourier sine transform with respect to 
:
FourierSinTransform[eqn, x, ω]
DSolveValue[{D[u1[ω, t], t] == -α^2ω (ω u1[ω, t] - Sqrt[(2/π)] A), u1[ω, 0] == 0}, u1[ω, t], t]Compute the inverse sine transform:
Simplify[InverseFourierSinTransform[%, ω, x], x > 0]Compare with DSolveValue:
FullSimplify[DSolveValue[{eqn, u[x, 0] == 0, u[0, t] == A}, u[x, t], {x, t}, Assumptions -> {t > 0 && x > 0 && α∈Reals}], {x > 0, t > 0}]Consider the special case with 
and 
:
Plot[Evaluate@Table[% /. {α -> 1, A -> 5}, {t, {.005, .1, .3, .8}}], {x, 0, 4}, PlotLegends -> {.005, .1, .3, .8}]Evaluation of Integrals (2)
Calculate the following definite integral for 
:
Inactive[Integrate][(ω Sin[α ω]/1 + ω ^ 2), {ω, 0, ∞}]Fourier sine transform of an exponential function:
FourierSinTransform[E^-x, x, ω, Assumptions -> x > 0]Apply Fourier sine inversion formula:
E^-x == Sqrt[2 / π] Sqrt[(2/π)]Inactive[Integrate][( ω/1 + ω^2) Sin[ω x], {ω, 0, ∞}]Solve for the definite integral:
SolveValues[%, Inactive[Integrate][( ω/1 + ω^2) Sin[ω x], {ω, 0, ∞}]][[1]] /. x -> αCompare with Integrate:
Integrate[(ω Sin[α ω]/1 + ω ^ 2), {ω, 0, ∞}, Assumptions -> α > 0]Calculate the following definite integral for 
:
Inactive[Integrate][(ω ^ 2/(α ^ 2 + ω ^ 2) ^ 2), {ω, 0, ∞}]Compute inverse Fourier sine transform of the square root of the integrand:
InverseFourierSinTransform[( ω/α^2 + ω^2), ω, x, Assumptions -> α > 0]Inactive[Integrate][Abs[E^-α x] ^ 2, {x, -∞, ∞}] == Inactive[Integrate][Abs[(Sqrt[(2/π)] ω/α^2 + ω^2)] ^ 2, {ω, -∞, ∞}]Integrate[E^-2α x, {x, 0, ∞}, Assumptions -> α > 0] == HoldForm[(2/π)]Inactive[Integrate][( ω ^ 2/(α^2 + ω^2) ^ 2), {ω, 0, ∞}]Solve for the definite integral:
SolveValues[ReleaseHold[%], Inactive[Integrate][( ω ^ 2/(α^2 + ω^2) ^ 2), {ω, 0, ∞}]][[1]]Compare with Integrate:
Integrate[( ω ^ 2/(α^2 + ω^2) ^ 2), {ω, 0, ∞}, Assumptions -> α > 0]Properties & Relations (4)
By default, the inverse Fourier sine transform of 
is:
HoldForm[InverseFourierSinTransform[F[ω], ω, t] = HoldForm[Sqrt[2 / π]] * Integrate[F[ω]Sin[ω t], {ω, 0, ∞}]]//TraditionalFormFor 
, the definite integral becomes:
Sqrt[2 / π]Integrate[Exp[-ω ^ 2]Sin[ω]Sin[ω t], {ω, 0, ∞}]Compare with InverseFourierSinTransform:
InverseFourierSinTransform[Exp[-ω ^ 2]Sin[ω], ω, t]//TrigToExp//SimplifyUse Asymptotic to compute an asymptotic approximation:
Asymptotic[Inactive[InverseFourierSinTransform][E ^ (-ω ^ 3), ω, t], t -> 0]FourierSinTransform and InverseFourierSinTransform are mutual inverses:
InverseFourierSinTransform[FourierSinTransform[f[t], t, ω], ω, t]FourierSinTransform[InverseFourierSinTransform[G[ω], ω, t], t, ω]FourierSinTransform[t / (t ^ 2 + 1), t, ω]InverseFourierSinTransform[%, ω, t]For odd functions, results are identical to InverseFourierTransform except for a factor -:
InverseFourierSinTransform[Cos[ω] / ω, ω, t]InverseFourierTransform[Cos[ω] / ω, ω , t]The results differ by a factor of - for 
:
Simplify[% + I %%, t > 0]Possible Issues (2)
The result from a Fourier sine transform may not have the same form as the original:
InverseFourierSinTransform[UnitStep[1 + ω] UnitStep[1 - ω], ω, t]FourierSinTransform[%, t, ω]Inverse Fourier sine transforms may require generalized functions such as DiracDelta:
InverseFourierSinTransform[ω, ω, t]FourierSinTransform[%, t, ω]Neat Examples (2)
The inverse Fourier sine transform represented in terms of MeijerG:
InverseFourierSinTransform[ω / (ω ^ 3 + 1), ω, t]Create a table of basic inverse Fourier sine transforms:
flist = {ω ^ n, E ^ (-a ω), Exp[-ω ^ 2], Sinc[ω] ^ 2, DiracDelta[ω - a], Log[ω], UnitStep[ω], UnitBox[ω], Erf[a ω], ConditionalExpression[BesselJ[1, ω], t < 1], ConditionalExpression[BesselY[0, ω], 0 < t < 1]};Grid[Prepend[{#, Assuming[{a > 0}, Simplify[InverseFourierSinTransform[#1, ω, t]]]}& /@ flist, {f[ω], InverseFourierSinTransform[f[ω], ω, t]}], IconizedObject[«Grid options»]]//TraditionalFormText
Wolfram Research (1999), InverseFourierSinTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseFourierSinTransform.html (updated 2025).
CMS
Wolfram Language. 1999. "InverseFourierSinTransform." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/InverseFourierSinTransform.html.
APA
Wolfram Language. (1999). InverseFourierSinTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseFourierSinTransform.html