WOLFRAM

Wolfram Language & System Documentation Center

HilbertFilter[data,ωc]

applies a Hilbert filter with a cutoff frequency ωc to an array of data.

HilbertFilter[data,ωc,n]

uses a filter kernel of length n.

HilbertFilter[data,ωc,n,wfun]

applies a smoothing window wfun to the filter kernel.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Parameters  
Options  
Padding  
SampleRate  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

HilbertFilter

HilbertFilter[data,ωc]

applies a Hilbert filter with a cutoff frequency ωc to an array of data.

HilbertFilter[data,ωc,n]

uses a filter kernel of length n.

HilbertFilter[data,ωc,n,wfun]

applies a smoothing window wfun to the filter kernel.

Details and Options

  • HilbertFilter is a finite-impulse response (FIR) discrete-time filter typically used to apply a 90-degree phase shift to a signal.
  • The data can be any of the following:
  • listarbitrary-rank numerical array
    tseriestemporal data such as TimeSeries and TemporalData
    imagearbitrary Image or Image3D object
    audioan Audio or Sound object
    videoa Video object
  • Data smoothing with cutoff frequency ωc reduces the susceptibility of the evaluation to signal noise with the amount of smoothing dependent on the value of the cutoff frequency ωc.
  • The cutoff frequency ωc should be between 0 and . Smaller values of ωc result in greater smoothing.
  • When applied to images and multidimensional arrays, filtering is applied successively to each dimension, starting at level 1. HilbertFilter[data,{ωc1,ωc2,…}] uses the frequency ωci for the ^(th) dimension.
  • HilbertFilter[data,ωc] uses a filter kernel length and smoothing window suitable for the cutoff frequency ωc and the input data.
  • Typical smoothing windows wfun include:
  • BlackmanWindowsmoothing with a Blackman window
    DirichletWindowno smoothing
    HammingWindowsmoothing with a Hamming window
    {v1,v2,…}use a window with values vi
    fcreate a window by sampling f between and
  • The following options can be given:
  • Padding "Fixed"the padding value to use
    SampleRate Automaticsample rate assumed for the input
  • By default, SampleRate->1 is assumed for images as well as data. For a sampled sound object of sample rate of r, SampleRate->r is used.
  • With SampleRate->r, the cutoff frequency ωc should be between 0 and r×.

Examples

open all close all

Basic Examples  (2)

Hilbert filtering of a cosine sequence:

Wolfram Language code: data = Table[Cos[2x], {x, 0, 2Pi, 0.1}]; ListLinePlot[{data, HilbertFilter[data, Pi, 51, Padding -> "Periodic"]}]

Hilbert filtering of an image:

Wolfram Language code: HilbertFilter[[image], Pi, 11]//ImageAdjust

Scope  (10)

Data  (7)

Filter a 1D pulse sequence:

Wolfram Language code: data = BoxMatrix[5, {41}]; ListLinePlot[{data, HilbertFilter[data, 1]}, PlotRange -> All]

Filter a 2D pulse sequence:

Wolfram Language code: data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}]; ListPlot3D[data]
Wolfram Language code: HilbertFilter[data, Pi, 5]//ListPlot3D

Filter a TimeSeries:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: filtered = HilbertFilter[ts, 50]
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original", "filtered"}, PlotRange -> All]

Hilbert filtering of a square wave audio signal:

Wolfram Language code: a = AudioGenerator["Square"]
Wolfram Language code: HilbertFilter[a, Quantity[15000, "Hertz"]]

Filter video frames:

Wolfram Language code: HilbertFilter[Video["ExampleData/fish.mp4"], 3]

Hilbert filtering of a 3D image:

Wolfram Language code: HilbertFilter[[image], Pi, 15]

Filter using exact precision:

Wolfram Language code: HilbertFilter[{0, 0, 0, 0, 1, 1, 1, 1}, Pi, 3]

Parameters  (3)

With an audio signal, a numeric cutoff frequency is interpreted as radians per second:

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-iz4x8)"]\);
Wolfram Language code: HilbertFilter[a, 10000 2 Pi] === HilbertFilter[a, Quantity[10000*2*Pi, "Radians"/"Seconds"]] === HilbertFilter[a, Quantity[10000, "Hertz"]]

Hilbert transform of a unit step sequence using a filter of length 5:

Wolfram Language code: HilbertFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 5]

Use a different cutoff frequency:

Wolfram Language code: HilbertFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi / 2, 5]

Use a specific window function:

Wolfram Language code: HilbertFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 5, BlackmanWindow]

Specify the window function as a numeric list:

Wolfram Language code: HilbertFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 5, {1, 1, 1, 1, 1}]

Use different cutoff frequencies in each dimension:

Wolfram Language code: HilbertFilter[[image], {Pi / 5, Pi}, 10]//ImageAdjust

Options  (5)

Padding  (3)

By default, "Fixed" padding is used:

Wolfram Language code: HilbertFilter[[image], Pi / 4, 10]//ImageAdjust

Use no padding to eliminate border artifacts:

Wolfram Language code: HilbertFilter[[image], Pi / 4, 10, Padding -> None]//ImageAdjust

Different padding methods result in different edge effects:

Wolfram Language code: ramp = Range[21] / 21. + RandomReal[.1, 21]; GraphicsRow@(ListLinePlot[{ramp, HilbertFilter[ramp, Pi, 10, Padding -> #]}, Axes -> False, PlotLabel -> If[# == 0, "Zero", #], ImageSize -> Small]& /@ {"Fixed", "Periodic", 0})

SampleRate  (2)

Use a half-band Hilbert filter, assuming a normalized sample rate of 1:

Wolfram Language code: HilbertFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, π / 2., 5]

Assume a sample rate of 3:

Wolfram Language code: HilbertFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, 3 π / 2., 5, SampleRate -> 3]

Apply a half-band Hilbert filter to audio sampled at a rate of :

Wolfram Language code: noise = AudioGenerator["White", 0.2]; sr = QuantityMagnitude@AudioSampleRate[noise]
Wolfram Language code: HilbertFilter[noise, sr π / 2., 21]//Periodogram

Applications  (1)

Create an amplitude modulated signal:

Wolfram Language code: am = Table[(1 + 0.5Sin[(2π/64) 2n])Cos[(2π/64) 11 n], {n, 0, 127}];

Use a Hilbert filter to obtain the envelope of the modulated signal:

Wolfram Language code: ListLinePlot[{am, Abs[am + I HilbertFilter[am, π, 11]]}]

Properties & Relations  (7)

Using a cutoff frequency of 0 returns a zero sequence:

Wolfram Language code: HilbertFilter[{0, 0, 0, 0, 1, 1, 1, 1}, 0]

Create a Hilbert filter using LeastSquaresFilterKernel and a Hamming window:

Wolfram Language code: n = 5; ω = 1.; win = Array[HammingWindow, n, {-1 / 2, 1 / 2}]; ker = win LeastSquaresFilterKernel[{"Hilbert", ω}, n]
Wolfram Language code: ListConvolve[ker, {0, 0, 0, 1, 1, 1, 1, 0, 0, 0}, Ceiling[n / 2], 0]

Compare with the result of HilbertFilter:

Wolfram Language code: HilbertFilter[{0, 0, 0, 1, 1, 1, 1, 0, 0, 0}, ω, n, win, Padding -> 0]

Impulse response of a Hilbert filter of length 21:

Wolfram Language code: h = HilbertFilter[ArrayPad[{1.}, 10], Pi, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

Magnitude spectrum of filter:

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

Impulse response of a Hilbert filter of length 21 without a smoothing window:

Wolfram Language code: h = HilbertFilter[ArrayPad[{1.}, 10], Pi, 21, None]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

Magnitude spectrum of the filter:

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

Impulse response of even-length Hilbert filter:

Wolfram Language code: h = HilbertFilter[ArrayPad[{1.}, 11], Pi, 22]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

Magnitude spectrum of filter:

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

The magnitude response of the Hilbert filter improves as the length of the filter is increased:

Wolfram Language code: Manipulate[ ListLinePlot[Abs[Fourier[HilbertFilter[ArrayPad[{1.}, 128], Pi, n], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 63, 2}]

The magnitude response of a half-band Hilbert filter of length 21:

Wolfram Language code: Plot[Evaluate@Abs[ListFourierSequenceTransform[HilbertFilter[ArrayPad[{1.}, 21], Pi / 2, 21], ω]], {ω, 0, π}, ...]

Possible Issues  (1)

Filtering a short list using PaddingNone may return an empty list:

Wolfram Language code: HilbertFilter[{0, 0, 0, 1, 1, 1, 1, 0, 0, 0}, 1.5, 11, Padding -> None]

Other paddings return same length sequence:

Wolfram Language code: HilbertFilter[{0, 0, 0, 1, 1, 1, 1, 0, 0, 0}, 1.5, 11, Padding -> "Fixed"]
Wolfram Research (2012), HilbertFilter, Wolfram Language function, https://reference.wolfram.com/language/ref/HilbertFilter.html (updated 2025).

Text

Wolfram Research (2012), HilbertFilter, Wolfram Language function, https://reference.wolfram.com/language/ref/HilbertFilter.html (updated 2025).

CMS

Wolfram Language. 2012. "HilbertFilter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/HilbertFilter.html.

APA

Wolfram Language. (2012). HilbertFilter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HilbertFilter.html

BibTeX

@misc{reference.wolfram_2026_hilbertfilter, author="Wolfram Research", title="{HilbertFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/HilbertFilter.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hilbertfilter, organization={Wolfram Research}, title={HilbertFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/HilbertFilter.html}, note=[Accessed: 13-June-2026]}