WOLFRAM

Wolfram Language & System Documentation Center

ConicGradientFilling[{col1,col2,…,coln}]

is a two-dimensional graphics directive specifying that faces of polygons and other filled graphics objects are to be drawn using a progressive transition between colors coli along a circle.

ConicGradientFilling[{θ1,θ2,…,θn}{col1,col2,…,coln}]

uses the colors coli at angles θi.

ConicGradientFilling[{θ1,θ2,…,θn}{col1,col2,…,coln},{x,y}]

rotates from the center point {x,y}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Specifications  
Properties & Relations  
Basic Applications  
Gradient Colors  
See Also
Related Guides
History
Cite this Page

ConicGradientFilling

ConicGradientFilling[{col1,col2,…,coln}]

is a two-dimensional graphics directive specifying that faces of polygons and other filled graphics objects are to be drawn using a progressive transition between colors coli along a circle.

ConicGradientFilling[{θ1,θ2,…,θn}{col1,col2,…,coln}]

uses the colors coli at angles θi.

ConicGradientFilling[{θ1,θ2,…,θn}{col1,col2,…,coln},{x,y}]

rotates from the center point {x,y}.

Details

Examples

open all close all

Basic Examples  (2)

Apply a conic gradient filling to a disk:

Wolfram Language code: Graphics[{ConicGradientFilling[{Red, Blue}], Disk[]}]

Style a sector chart:

Wolfram Language code: SectorChart[Tuples[{1, 2}, 2], ChartStyle -> ConicGradientFilling["Pastel", ImageScaled[{0.5, 0.5}]], ...]

Scope  (12)

Basic Uses  (6)

Apply gradient filling to graphics primitives:

Wolfram Language code: Graphics[{ConicGradientFilling[{RGBColor[0.6705882352941176, 0.8627450980392157, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], #}]& /@ {RegularPolygon[5], Disk[], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

Apply gradient filling to a plot:

Wolfram Language code: Plot[2Sin[x] + x, {x, 0, 15}, Filling -> Bottom, FillingStyle -> ConicGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]]

Apply gradient filling to a chart:

Wolfram Language code: SectorChart[Tuples[{1, 2}, 2], ChartStyle -> ConicGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}, ImageScaled[{0.5, 0.5}]], ...]

Style a geometric region:

Wolfram Language code: Region[Style[ImplicitRegion[y^2 < x (-1 + x^3), {x, y}], ConicGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]]]

Show a schematic outline map:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", ConicGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]], Polygon[["austria"]]}]

Summary box:

Wolfram Language code: ConicGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]

Specifications  (6)

ConicGradientFilling with no arguments draws a progressive transition from Black to White:

Wolfram Language code: Graphics[{ConicGradientFilling[], RegularPolygon[30]}]

Use a custom color sequence:

Wolfram Language code: Graphics[{ConicGradientFilling[#], RegularPolygon[20]}] & /@ {{GrayLevel[0], GrayLevel[0.85]}, {RGBColor[1, 0, 0], RGBColor[1, 0.5, 0.5], RGBColor[1, 0.85, 0.85]}, {RGBColor[0.5, 0, 0.5], RGBColor[0, 0, 1], RGBColor[0, 1, 0], RGBColor[1, 1, 0], RGBColor[1, 0.5, 0], RGBColor[1, 0, 0]}}

Specify the colors at given angles:

Wolfram Language code: Graphics[{ConicGradientFilling[# -> {RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], RegularPolygon[20]}]& /@ {{0, Pi / 2}, {Pi / 2, Pi}, {Pi, 3Pi / 2}}

Specify the angle in degrees:

Wolfram Language code: Graphics[{ConicGradientFilling[{30°, 60°} -> {RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], RegularPolygon[20]}]

Use predefined color scheme from ColorData:

Wolfram Language code: Graphics[{ConicGradientFilling[#], RegularPolygon[20]}]& /@ {"SunsetColors", "BlueGreenYellow", "DeepSeaColors"}

Use LightDarkSwitched to specify different colors for light and dark modes:

Wolfram Language code: graphic = Graphics[{ConicGradientFilling[{LightDarkSwitched[RGBColor[0.7803921568627451, 0.9084967320261438, 1.], Hue[0.11, 0.22, 1]], LightDarkSwitched[RGBColor[0.011764705882352941, 0.5882352941176471, 1.], Hue[0.105, 0.988, 1]]}], RegularPolygon[40]}];
Wolfram Language code: {LightModePane[graphic], DarkModePane[graphic]}

Specify center points relatively to the width of the graphic objects:

Wolfram Language code: Graphics[{ConicGradientFilling[ {RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}, {0.5, 0.5}], RegularPolygon[40], RegularPolygon[{1, 1}, 1, 20]}]

Center points by fractions of the whole image:

Wolfram Language code: Graphics[{ConicGradientFilling[{RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}, ImageScaled[{0.5, 0.5}]], RegularPolygon[40], RegularPolygon[{1, 1}, 1, 40]}]

Properties & Relations  (5)

Basic Applications  (2)

Show gradient colors with different angles:

Wolfram Language code: gradient[angles_ -> colors_] := Graphics[{ConicGradientFilling[angles -> colors], Disk[]}]
Wolfram Language code: gradient[# -> {RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}] & /@ {{0, Pi / 4}, {0, Pi / 2}, {0, Pi}}

Show gradient colors with different center points:

Wolfram Language code: gradient[colors_, pts_] := Graphics[{{ConicGradientFilling[colors, pts], Disk[]}}]

Along the axis with :

Wolfram Language code: gradient[{RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}, #] & /@ {{0, 1 / 2}, {1 / 3, 1 / 2}, {2 / 3, 1 / 2}, {1, 1 / 2}}

Along the axis with :

Wolfram Language code: gradient[{RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}, #] & /@ {{1 / 2, 0}, {1 / 2, 1 / 3}, {1 / 2, 2 / 3}, {1 / 2, 1}}

Along the diagonal:

Wolfram Language code: gradient[{RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}, #] & /@ {{1 / 3, 1 / 3}, {1 / 2, 1 / 2}, {2 / 3, 2 / 3}, {1, 1}}

Gradient Colors  (3)

Collection of gradient colors in ColorData:

Wolfram Language code: ColorData["Gradients"]//Short

Show gradients:

Wolfram Language code: display[scheme_] := Graphics[{ConicGradientFilling[scheme], Disk[]}]
Wolfram Language code: display /@ Take[ColorData["Gradients"], -30]

Collection of gradient colors in the Wolfram Data Repository:

Wolfram Language code: uigradients = ResourceData["UI Color Gradients"];
Wolfram Language code: Keys[uigradients]//Short

Show gradients:

Wolfram Language code: display[name_ -> color_] := Graphics[{ConicGradientFilling[color], Disk[]}]
Wolfram Language code: display /@ Normal[Take[uigradients, 60]]

Collection of hue colors in the Wolfram Data Repository:

Wolfram Language code: hues = ResourceData["Hue Color Gradients"];
Wolfram Language code: hues//Short

Show gradients:

Wolfram Language code: display[color_] := Graphics[{ConicGradientFilling[color], Disk[]}]
Wolfram Language code: display /@ hues
Wolfram Research (2020), ConicGradientFilling, Wolfram Language function, https://reference.wolfram.com/language/ref/ConicGradientFilling.html.

Text

Wolfram Research (2020), ConicGradientFilling, Wolfram Language function, https://reference.wolfram.com/language/ref/ConicGradientFilling.html.

CMS

Wolfram Language. 2020. "ConicGradientFilling." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ConicGradientFilling.html.

APA

Wolfram Language. (2020). ConicGradientFilling. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConicGradientFilling.html

BibTeX

@misc{reference.wolfram_2026_conicgradientfilling, author="Wolfram Research", title="{ConicGradientFilling}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ConicGradientFilling.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_conicgradientfilling, organization={Wolfram Research}, title={ConicGradientFilling}, year={2020}, url={https://reference.wolfram.com/language/ref/ConicGradientFilling.html}, note=[Accessed: 12-June-2026]}