WOLFRAM

Wolfram Language & System Documentation Center

RadialGradientFilling[{col1,col2,…,coln}]

is a two-dimensional graphics directive specifying that faces of polygons and other filled graphics objects are to be drawn using concentric circles of colors coli.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln}]

uses the colors coli at radii ri.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln},{x,y}]

radiates from the center point {x,y}.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln},{{x,y},{r1,r2}}]

radiates from the center point {x,y} in concentric axis-aligned ellipsoids with semiaxes length proportional to ri.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln},{{x,y},{r1,r2}},padding]

uses the specified padding when drawing beyond the boundary radii r1 and rn.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Specifications  
Applications  
Basic Applications  
Gradient Colors  
See Also
Related Guides
History
Cite this Page

RadialGradientFilling

RadialGradientFilling[{col1,col2,…,coln}]

is a two-dimensional graphics directive specifying that faces of polygons and other filled graphics objects are to be drawn using concentric circles of colors coli.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln}]

uses the colors coli at radii ri.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln},{x,y}]

radiates from the center point {x,y}.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln},{{x,y},{r1,r2}}]

radiates from the center point {x,y} in concentric axis-aligned ellipsoids with semiaxes length proportional to ri.

RadialGradientFilling[{r1,r2,…,rn}{col1,col2,…,coln},{{x,y},{r1,r2}},padding]

uses the specified padding when drawing beyond the boundary radii r1 and rn.

Details

Examples

open all close all

Basic Examples  (3)

Apply a radial gradient filling to a disk:

Wolfram Language code: Graphics[{RadialGradientFilling[{Red, Blue}], Disk[]}]

Plot a vector field with background gradient color indicating the vector magnitude:

Wolfram Language code: VectorPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, Prolog -> {RadialGradientFilling[{RGBColor[0.3333333333333333, 0.33333444516101063, 0.7999993899776093], RGBColor[0.7333334647852516, 0.4666657489994649, 0.7333327996289224], RGBColor[1., 0.6199986160387776, 0.3333351332181643], RGBColor[1., 0.8333326141376257, 0.3333348899233049]}, ImageScaled[{0.5, 0.5}]], Rectangle[ImageScaled[{0, 0}], ImageScaled[{1, 1}]]}, FrameTicks -> False]

A radial gradient filling of the US map:

Wolfram Language code: GeoGraphics[{RadialGradientFilling[{RGBColor[0.6705882352941176, 0.8627450980392157, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], Polygon[["United States"]]}, GeoBackground -> None]

Scope  (14)

Basic Uses  (6)

Apply gradient filling to graphics primitives:

Wolfram Language code: Graphics[{RadialGradientFilling[{RGBColor[0.6705882352941176, 0.8627450980392157, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], #}]& /@ {Rectangle[], Disk[], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

Apply gradient filling to a plot:

Wolfram Language code: Plot[2Sin[x] + x, {x, 0, 15}, Filling -> Bottom, FillingStyle -> RadialGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]]

Apply gradient filling to a chart:

Wolfram Language code: BarChart[{1, 2, 3, 4}, ChartStyle -> RadialGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]]

Style a geometric region:

Wolfram Language code: Region[Style[ImplicitRegion[y^2 < x (-1 + x^3), {x, y}], RadialGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]]]

Show a schematic outline map:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", RadialGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]], Polygon[["austria"]]}]

Summary box:

Wolfram Language code: RadialGradientFilling[{RGBColor[0.85359477124183, 0.9389978213507625, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}]

Specifications  (8)

RadialGradientFilling with no arguments draws a progressive transition from Black to White:

Wolfram Language code: Graphics[{RadialGradientFilling[], RegularPolygon[4]}]

Use a custom color sequence:

Wolfram Language code: Graphics[{RadialGradientFilling[#], RegularPolygon[20]}] & /@ {{GrayLevel[0], GrayLevel[0.85]}, {RGBColor[1, 0, 0], RGBColor[1, 0.5, 0.5], RGBColor[1, 0.85, 0.85]}, {RGBColor[0.5, 0, 0.5], RGBColor[0, 0, 1], RGBColor[0, 1, 0], RGBColor[1, 1, 0], RGBColor[1, 0.5, 0], RGBColor[1, 0, 0]}}

Specify the scaled position of each color:

Wolfram Language code: Graphics[{RadialGradientFilling[# -> {RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], RegularPolygon[20]}]& /@ {{0, 1}, {0.25, 1}, {0.75, 1}}

Scaled positions are taken to be relative to the width of the graphic objects:

Wolfram Language code: Graphics[{RadialGradientFilling[{0, 1} -> {RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], RegularPolygon[40], RegularPolygon[{1, 1}, 1, 20]}]

Specify color positions by fractions of the whole image:

Wolfram Language code: Graphics[{RadialGradientFilling[{ImageScaled[0], ImageScaled[1]} -> {RGBColor[0.7803921568627451, 0.9084967320261438, 1.], RGBColor[0.011764705882352941, 0.5882352941176471, 1.]}], RegularPolygon[40], RegularPolygon[{1, 1}, 1, 40]}]

Use predefined color scheme from ColorData:

Wolfram Language code: Graphics[{RadialGradientFilling[#], RegularPolygon[20]}]& /@ {"SunsetColors", "BlueGreenYellow", "DeepSeaColors"}

Use LightDarkSwitched to specify different colors for light and dark modes:

Wolfram Language code: graphic = Graphics[{RadialGradientFilling[{LightDarkSwitched[RGBColor[0.7803921568627451, 0.9084967320261438, 1.], Hue[0.11, 0.22, 1]], LightDarkSwitched[RGBColor[0.011764705882352941, 0.5882352941176471, 1.], Hue[0.105, 0.988, 1]]}], RegularPolygon[40]}];
Wolfram Language code: {LightModePane[graphic], DarkModePane[graphic]}

Specify the center of the concentric circles:

Wolfram Language code: Graphics[{RadialGradientFilling[{RGBColor[1, 0.75, 0], GrayLevel[0]}, #], RegularPolygon[4]}]& /@ {{0, 0}, {0.25, 0.25}, {0.5, 0.5}, {1, 1}}

Specify semiaxis:

Wolfram Language code: Graphics[{RadialGradientFilling[{RGBColor[1, 0.75, 0], GrayLevel[0]}, {{0.5, 0.5}, #}], RegularPolygon[4]}] & /@ {{1, 1}, {0.4, 1}, {1, 0.4}}

Specify the padding behavior:

Wolfram Language code: Graphics[{RadialGradientFilling[{RGBColor[0.93, 0.27, 0.27], RGBColor[1, 0.75, 0]}, {{0.5, 0.5}, {0.1, 0.1}}, #], RegularPolygon[4]}]& /@ {"Fixed", "Periodic", "Reflected"}

Applications  (5)

Basic Applications  (2)

Show gradient colors with different radii:

Wolfram Language code: gradient[radii_ -> colors_] := Graphics[{RadialGradientFilling[radii -> colors], Disk[]}]
Wolfram Language code: gradient[# -> {RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}] & /@ {{0, 1}, {1 / 3, 1}, {2 / 3, 1}}

Show gradient colors with different center points:

Wolfram Language code: gradient[colors_, pts_] := Graphics[{{RadialGradientFilling[colors, pts], Disk[]}, {PointSize[0.05], Point[pts - 1 / 2]}}]

Along the axis with :

Wolfram Language code: gradient[{RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}, #] & /@ {{0, 1 / 2}, {1 / 3, 1 / 2}, {2 / 3, 1 / 2}, {1, 1 / 2}}

Along the axis with :

Wolfram Language code: gradient[{RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}, #] & /@ {{1 / 2, 0}, {1 / 2, 1 / 3}, {1 / 2, 2 / 3}, {1 / 2, 1}}

Along the diagonal:

Wolfram Language code: gradient[{RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.]}, #] & /@ {{0, 0}, {1 / 2, 1 / 2}, {2 / 3, 2 / 3}, {1, 1}}

Gradient Colors  (3)

Collection of gradient colors in ColorData:

Wolfram Language code: ColorData["Gradients"]//Short

Show gradients:

Wolfram Language code: display[scheme_] := Graphics[{RadialGradientFilling[scheme], Disk[]}]
Wolfram Language code: display /@ Take[ColorData["Gradients"], -30]

Collection of gradient colors in the Wolfram Data Repository:

Wolfram Language code: uigradients = ResourceData["UI Color Gradients"];
Wolfram Language code: Keys[uigradients]//Short

Show gradients:

Wolfram Language code: display[name_ -> color_] := Graphics[{RadialGradientFilling[color], Disk[]}]
Wolfram Language code: display /@ Normal[Take[uigradients, 60]]

Collection of hue colors in the Wolfram Data Repository:

Wolfram Language code: hues = ResourceData["Hue Color Gradients"];
Wolfram Language code: hues//Short

Show gradients:

Wolfram Language code: display[color_] := Graphics[{RadialGradientFilling[color], Disk[]}]
Wolfram Language code: display /@ hues

Reverse the order of the colors:

Wolfram Language code: display[Reverse[#]]& /@ hues
Wolfram Research (2020), RadialGradientFilling, Wolfram Language function, https://reference.wolfram.com/language/ref/RadialGradientFilling.html.

Text

Wolfram Research (2020), RadialGradientFilling, Wolfram Language function, https://reference.wolfram.com/language/ref/RadialGradientFilling.html.

CMS

Wolfram Language. 2020. "RadialGradientFilling." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RadialGradientFilling.html.

APA

Wolfram Language. (2020). RadialGradientFilling. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RadialGradientFilling.html

BibTeX

@misc{reference.wolfram_2026_radialgradientfilling, author="Wolfram Research", title="{RadialGradientFilling}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/RadialGradientFilling.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_radialgradientfilling, organization={Wolfram Research}, title={RadialGradientFilling}, year={2020}, url={https://reference.wolfram.com/language/ref/RadialGradientFilling.html}, note=[Accessed: 12-June-2026]}