InverseFourierCosTransform[F[
],
,t]
gives the symbolic inverse Fourier cosine transform of F[ω] in the variable ω as f[t] in the variable t.
InverseFourierCosTransform[F[ω],ω,
]
gives the numeric inverse Fourier cosine transform at the numerical value 
.
InverseFourierCosTransform
InverseFourierCosTransform[F[
],
,t]
gives the symbolic inverse Fourier cosine transform of F[ω] in the variable ω as f[t] in the variable t.
InverseFourierCosTransform[F[ω],ω,
]
gives the numeric inverse Fourier cosine transform at the numerical value 
.
InverseFourierCosTransform[F[ω1,…,ωn],{ω1,… ,ωn},{t1,…,tn}]
gives the multidimensional inverse Fourier cosine transform of F[ω1,…,ωn].
Details and Options
- The Fourier cosine transform is a particular way of viewing the Fourier transform without the need for complex numbers or negative frequencies.
- Joseph Fourier designed his famous transform using this and the Fourier sine transform, and they are still used in applications like signal processing, statistics and image and video compression.
- The inverse Fourier cosine transform of the frequency domain function
is the time domain function 
for 
: - The inverse Fourier cosine transform of a function
is by default defined as 
. - The multidimensional inverse Fourier cosine transform of a function
is by default defined as 
or when using vector notation, ![(2/pi)^(n/2)int_(omega in TemplateBox[{}, PositiveReals]^n)F(omega) cos(omega t)domega](Files/InverseFourierCosTransform.en/13.png "(2/pi)^(n/2)int_(omega in TemplateBox[{}, PositiveReals]^n)F(omega) cos(omega t)domega")
. - Different choices of definitions can be specified using the option FourierParameters.
- The integral is computed using numerical methods if the third argument,
, is given a numerical value. - The asymptotic inverse Fourier cosine transform can be computed using Asymptotic.
- There are several related Fourier transformations:
-
FourierTransform infinite continuous-time functions (FT) FourierSequenceTransform infinite discrete-time functions (DTFT) FourierCoefficient finite continuous-time functions (FS) Fourier finite discrete-time functions (DFT) - The inverse Fourier cosine transform is an automorphism in the Schwartz vector space of functions whose derivatives are rapidly decreasing and thus induces an automorphism in its dual: the space of tempered distributions. These include absolutely integrable functions, well-behaved functions of polynomial growth and compactly supported distributions.
- Hence, InverseFourierCosTransform not only works with absolutely integrable functions on
, but it can also handle a variety of tempered distributions such as DiracDelta to enlarge the pool of functions or generalized functions it can effectively transform. - The lower limit of the integral is effectively taken to be
![TemplateBox[{0, -}, Superscript]](Files/InverseFourierCosTransform.en/16.png "TemplateBox[{0, -}, Superscript]")
, so that the inverse Fourier cosine transform of the Dirac delta function 
is equal to 
. » - The following options can be given:
-
AccuracyGoal Automatic digits of absolute accuracy sought Assumptions $Assumptions assumptions to make about parameters FourierParameters {0,1} parameters to define the inverse Fourier cosine transform GenerateConditions False whether to generate answers that involve conditions on parameters PerformanceGoal $PerformanceGoal aspects of performance to optimize PrecisionGoal Automatic digits of precision sought WorkingPrecision Automatic the precision used in internal computations - Common settings for FourierParameters include:
-
{0,1} 
{1,1} 
{-1,1} 
{0,2Pi} 
{a,b} 
Examples
open all close allBasic Examples (6)
Compute the inverse Fourier cosine transform of a function:
InverseFourierCosTransform[UnitBox[ω - 1 / 2], ω, t]Plot the function and its inverse cosine transform:
{Plot[UnitBox[ω - 1 / 2], {ω, 0, 2}, Exclusions -> None], Plot[%, {t, 0, 10}]}Inverse Fourier cosine transform of reciprocal square root:
InverseFourierCosTransform[1 / Sqrt[ω], ω, t]For a different convention, change the parameters:
InverseFourierCosTransform[1 / Sqrt[ω], ω, t, FourierParameters -> {1, -2π}]Inverse Fourier cosine transform of a Gaussian is another Gaussian:
InverseFourierCosTransform[E ^ (-ω ^ 2), ω, t]{Plot[E ^ (-ω ^ 2), {ω, 0, 3}, PlotRange -> Full], Plot[%, {t, 0, 5}, PlotRange -> Full]}Compute the inverse Fourier cosine transform of a multivariate function:
InverseFourierCosTransform[1 / Sqrt[u ^ 2 + v ^ 2], {u, v}, {x, y}]Plot3D[%, {x, 0, 2}, {y, 0, 2}, PlotRange -> {0, 10}, Mesh -> None]Compute the inverse transform at a single point:
InverseFourierCosTransform[Exp[-ω ^ 2] Sin[ω], ω, 0.3]Scope (43)
Basic Uses (3)
Inverse Fourier cosine transform of a function for a symbolic parameter 
:
InverseFourierCosTransform[HeavisideTheta[ω], ω, t]Inverse Fourier cosine transforms involving trigonometric functions:
InverseFourierCosTransform[Sin[ω] / (ω E ^ ω), ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[Cos[α ω ^ 2], ω, t, Assumptions -> α > 0]
Plot[% /. α -> 1 / 4, {t, 0, 4}]Evaluate the inverse Fourier cosine transform for a numerical value of the parameter 
:
InverseFourierCosTransform[Exp[-ω] / Sqrt[ω], ω, 1.3]Algebraic Functions (4)
Inverse Fourier cosine transform of power functions:
InverseFourierCosTransform[ω ^ (n - 1), ω, t, Assumptions -> 0 < n < 1]For integer 
, the result is a derivative of DiracDelta:
InverseFourierCosTransform[ω ^ 2, ω, t]Inverse cosine transforms for rational functions:
InverseFourierCosTransform[1 / (1 + ω ^ 2), ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[ω / (1 + ω ^ 2), ω, t]Plot[%, {t, 0, 4}]Inverse Fourier cosine transform of a quotient of two nonlinear polynomials:
InverseFourierCosTransform[(1 - ω ^ 2) / (ω ^ 2 + 1) ^ 2, ω, t]Plot[%, {t, 0, 4}]Inverse Fourier cosine transform of a quotient of quadratic and quartic polynomials:
InverseFourierCosTransform[ω ^ 2 / (ω ^ 4 + 1), ω, t]Plot[%, {t, 0, 10}]Exponential and Logarithmic Functions (4)
Inverse Fourier cosine transforms of exponential functions:
InverseFourierCosTransform[Exp[-α ω], ω, t, Assumptions -> Re[α] > 0]
InverseFourierCosTransform[Exp[-ω], ω, t]Plot[%, {t, 0, 4}]Inverse Fourier cosine transform of a Gaussian is itself:
InverseFourierCosTransform[Exp[-ω ^ 2 / 2] , ω, t]Plot[%, {t, 0, 4}]Inverse Fourier cosine transforms of products of exponential and trigonometric functions:
InverseFourierCosTransform[Exp[α ω] Sin[ β ω], ω, t, Assumptions -> {α < 0, β > 0}]
Plot[% /. {α -> -3 / 4, β -> 1 / 4}, {t, 0, 4}]InverseFourierCosTransform[Exp[-ω ^ 2] Sin[ω], ω, t]Plot[%, {t, 0, 4}]Inverse cosine transforms of logarithmic functions:
InverseFourierCosTransform[Log[ω]UnitBox[ω - 1 / 2], ω, t]Plot[%, {t, 0, 10}]InverseFourierCosTransform[Log[ω] / Sqrt[ω], ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[Log[1 + ω] / ω, ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[Log[1 + 9 / ω ^ 2], ω, t]Plot[%, {t, 0, 4}]Trigonometric Functions (5)
Expressions involving trigonometric functions:
InverseFourierCosTransform[Sin[2ω] ^ 2 / ω ^ 2, ω, t]Plot[%, {t, 0, 4}]Composition of elementary functions:
InverseFourierCosTransform[Cos[α ω ^ 2], ω, t, Assumptions -> α > 0]
Plot[% /. α -> 3 / 4, {t, 0, 10}]Ratio of sine and product of exponential and linear functions:
InverseFourierCosTransform[(Sin[ω]/ω Exp[ω]), ω, t]Plot[%, {t, 0, 10}]Inverse Fourier cosine transforms of arctangent functions:
InverseFourierCosTransform[ArcTan[2 / ω], ω, t]Plot[%, {t, 0, 10}]InverseFourierCosTransform[ArcTan[ω] / ω, ω, t]Plot[%, {t, 0, 10}]Inverse Fourier cosine transform of Sech is another Sech:
InverseFourierCosTransform[Sech[3 ω], ω, t]Plot[%, {t, 0, 5}]Special Functions (9)
Sinc function:
InverseFourierCosTransform[Sinc[ω], ω, t]Plot[%, {t, 0, 4}, Exclusions -> None]Inverse Fourier cosine transforms of expressions involving ExpIntegralEi:
InverseFourierCosTransform[ExpIntegralEi[-ω], ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[ω ExpIntegralEi[-ω], ω, t]Plot[%, {t, 0, 4}]Expression involving Erfc:
InverseFourierCosTransform[ω Erfc[α ω], ω, t, Assumptions -> α > 0]
Plot[% /. α -> 3, {t, 0, 10}]Expression involving SinIntegral:
InverseFourierCosTransform[SinIntegral[ω] - π / 2, ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[CosIntegral[α ω], ω, t, Assumptions -> {α > 0, t > α}]Plot[%, {t, 0, 4}]Inverse cosine transforms for BesselJ functions:
InverseFourierCosTransform[BesselJ[0, α ω], ω, t, Assumptions -> {α > 0, 0 < t < α}]
Plot[% /. α -> 2, {t, 0, 4}]InverseFourierCosTransform[BesselJ[2 n, α ω], ω, t, Assumptions -> {α > 0, 0 < t < α}]
Plot[% /. {α -> 2, n -> 2}, {t, 0, 4}]InverseFourierCosTransform[BesselJ[n, α ω] / ω ^ n, ω, t, Assumptions -> {α > 0, 0 < t < α, n∈PositiveIntegers}]
Plot[% /. {α -> 2, n -> 2}, {t, 0, 4}]InverseFourierCosTransform[BesselJ[0, Sqrt[ω]], ω, t]Plot[%, {t, 0, 4}]Cosine transforms for BesselY functions:
InverseFourierCosTransform[BesselY[0, α ω], ω, t, Assumptions -> {α > 0, t > α}]
Plot[% /. α -> 2, {t, 0, 4}]InverseFourierCosTransform[BesselY[n, α ω] ω ^ n, ω, t, Assumptions -> {α > 0, t > α, Abs[Re[n]] < 1 / 2}]
Plot[% /. {α -> 2, n -> 1 / 3}, {t, 0, 4}]Cosine transform for a BesselK function:
InverseFourierCosTransform[BesselK[0, ω], ω, t]Plot[%, {t, 0, 4}]Inverse cosine transform for a hypergeometric function is a BesselK function:
InverseFourierCosTransform[Hypergeometric2F1[1, 2, 1 / 2, -ω ^ 2], ω, t]Plot[%, {t, 0, 10}]Piecewise Functions and Distributions (4)
Inverse Fourier cosine transform of a piecewise function:
f[ω_] = Piecewise[{{ω, 0 ≤ ω ≤ 1}, {0, ω > 1}}, Exclusions -> None];
Plot[f[ω], {ω, 0, 1.5}, Exclusions -> None]InverseFourierCosTransform[f[ω], ω, t]Restriction of a sine function to a half-period:
Plot[Sin[α ω]UnitBox[α ω / π - 1 / 2] /. α -> 3π / 2, {ω, 0, 1}]Simplify[InverseFourierCosTransform[Sin[α ω]UnitBox[α ω / π - 1 / 2], ω, t], α > π]f[ω_] = Piecewise[{{ω, 0 ≤ ω ≤ 1}, {2 - ω, 1 < ω ≤ 2}, {0, 2 < ω }}];
Plot[f[ω], {ω, 0, 3}]InverseFourierCosTransform[f[ω], ω, t]Transforms in terms of FresnelC:
InverseFourierCosTransform[UnitStep[ω - 1] / Sqrt[ω], ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[(1 - UnitStep[ω - 1]) / Sqrt[ω], ω, t]Plot[%, {t, 0, 4}]Periodic Functions (2)
Inverse Fourier cosine transform of cosine:
InverseFourierCosTransform[Cos[ω], ω, t]Inverse Fourier cosine transform of SquareWave:
Plot[SquareWave[ω + 1 / 4], {ω, 0, 4}, Exclusions -> None]InverseFourierCosTransform[SquareWave[ω + 1 / 4], ω, t]Generalized Functions (4)
Inverse Fourier cosine transforms of expressions involving HeavisideTheta:
Plot[HeavisideTheta[ω - 1], {ω, 0, 2}, Exclusions -> None]InverseFourierCosTransform[HeavisideTheta[ω - 1], ω, t]Plot[ω HeavisideTheta[ω] HeavisideTheta[1 - ω], {ω, 0, 1.5}, Exclusions -> None]InverseFourierCosTransform[ω HeavisideTheta[ω] HeavisideTheta[1 - ω], ω, t]Plot[HeavisideTheta[ω - 1] / ω ^ 2, {ω, 0, 5}, Exclusions -> None]InverseFourierCosTransform[HeavisideTheta[ω - 1] / ω ^ 2, ω, t]Inverse Fourier cosine transform involving DiracDelta:
InverseFourierCosTransform[DiracDelta[ω], ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[DiracDelta[ω - 1], ω, t]Plot[%, {t, 0, 4}]InverseFourierCosTransform[DiracDelta'[ω - 1], ω, t]Plot[%, {t, 0, 4}]Inverse Fourier cosine transform involving HeavisideLambda:
Plot[HeavisideLambda[ω - 1], {ω, 0, 4}]InverseFourierCosTransform[HeavisideLambda[ω - 1], ω, t]Inverse Fourier cosine transform involving HeavisidePi:
Plot[HeavisidePi[ω - (3/2)], {ω, 0, 3}, Exclusions -> None]InverseFourierCosTransform[HeavisidePi[ω - (3/2)], ω, t]Multivariate Functions (3)
Inverse Fourier cosine transform of rational function in two variables:
InverseFourierCosTransform[1 / ((1 + u ^ 2) (1 + v ^ 2)), {u, v}, {x, y}]{Plot3D[1 / ((1 + u ^ 2) (1 + v ^ 2)), {u, 0, 5}, {v, 0, 5}, Mesh -> None], Plot3D[%, {x, 0, 5}, {y, 0, 5}, Mesh -> None]}Inverse Fourier cosine transform of exponential in two variables:
InverseFourierCosTransform[Exp[-u ^ 2 - v ^ 2], {u, v}, {x, y}]{Plot3D[Exp[-u ^ 2 - v ^ 2], {u, 0, 5}, {v, 0, 5}, Mesh -> None], Plot3D[%, {x, 0, 5}, {y, 0, 5}, Mesh -> None]}Inverse Fourier cosine transform of product of exponential and SquareWave:
Plot3D[E ^ (-u)SquareWave[v + 1 / 4], {u, 0, 5}, {v, 0, 5}, Mesh -> None]InverseFourierCosTransform[E ^ (-u)SquareWave[v + 1 / 4], {u, v}, {x, y}]Formal Properties (3)
Inverse Fourier cosine transform of a first-order derivative:
InverseFourierCosTransform[F'[ω], ω, t]Inverse Fourier cosine transform of a second-order derivative:
InverseFourierCosTransform[F''[ω], ω, t]Inverse Fourier cosine transform threads itself over equations:
InverseFourierCosTransform[F'[ω] == 1 / (ω ^ 2 + 1), ω, t]Numerical Evaluation (2)
Calculate the inverse Fourier cosine transform at a single point:
InverseFourierCosTransform[(1/Sqrt[ω]), ω, .9]Alternatively, calculate the Fourier cosine transform symbolically:
InverseFourierCosTransform[(1/Sqrt[ω]), ω, t]Then evaluate it for specific value of 
:
N[% /. t -> .9]Options (8)
AccuracyGoal (1)
The option AccuracyGoal sets the number of digits of accuracy:
exact = InverseFourierCosTransform[HeavisideLambda[ω - 1], ω, 9 / 10]InverseFourierCosTransform[HeavisideLambda[ω - 1], ω, .9, AccuracyGoal -> 5] - exactInverseFourierCosTransform[HeavisideLambda[ω - 1], ω, .9] - exactAssumptions (1)
Use Assumptions to indicate the region of interest for the parameters:
InverseFourierCosTransform[BesselJ[0, ω], ω, t, Assumptions -> t > 1]InverseFourierCosTransform[BesselJ[0, ω], ω, t, Assumptions -> t < 1]FourierParameters (3)
Inverse Fourier cosine transform for the unit box function with different parameters:
params = {{0, 1}, {1, 1}, {-1, 1}, {0, 2 π}};
funs = funs = Table[InverseFourierCosTransform[UnitBox[ω - (1/2)], ω, t, FourierParameters -> p], {p, params}]Create a nicely formatted table of the results:
header = { "Parameters", HoldForm@InverseFourierCosTransform[UnitBox[ω - (1/2)], ω, t]};
Grid[Prepend[Transpose[{params, funs}], header], IconizedObject[«Grid options»]]//TraditionalFormUse a nondefault setting for a different definition of transform:
InverseFourierCosTransform[Exp[-ω], ω, t, FourierParameters -> {1, 1}]To get the original function back, use the same FourierParameters setting:
FourierCosTransform[%, t, ω, FourierParameters -> {1, 1}]Set up your particular global choice of parameters to work once per session:
SetOptions[InverseFourierCosTransform, FourierParameters -> {0, 2π}]InverseFourierCosTransform[1, ω, t]//TraditionalFormSetOptions[InverseFourierCosTransform, FourierParameters -> {0, 1}]GenerateConditions (1)
Use GenerateConditionsTrue to get parameter conditions for when a result is valid:
InverseFourierCosTransform[Exp[α ω], ω, t, GenerateConditions -> True]PrecisionGoal (1)
The option PrecisionGoal sets the relative tolerance in the integration:
exact = InverseFourierCosTransform[8 / (ω ^ 2 + 1), ω, 1 / 2]InverseFourierCosTransform[8 / (ω ^ 2 + 1), ω, .5, PrecisionGoal -> 10] - exactInverseFourierCosTransform[8 / (ω ^ 2 + 1), ω, .5] - exactWorkingPrecision (1)
If a WorkingPrecision is specified, the computation is done at that working precision:
exact = InverseFourierCosTransform[8 / (ω ^ 2 + 1), ω, 1 / 2]InverseFourierCosTransform[8 / (ω ^ 2 + 1), ω, .5, WorkingPrecision -> 18] - exactInverseFourierCosTransform[8 / (ω ^ 2 + 1), ω, .5] - exactApplications (4)
Ordinary Differential Equations (1)
Consider the following ODE with initial condition 
:
OdEqn = y''[t] + Ω^2y[t] == Cos[t];Apply the Fourier cosine transform to the ODE:
FourierCosTransform[OdEqn, t, ω]Solve for the Fourier cosine transform of 
:
SolveValues[%, FourierCosTransform[y[t], t, ω]][[1]] /. y'[0] -> 1Find the inverse Fourier cosine transform with 
and 
:
icf[t_] = InverseFourierCosTransform[%, ω, t] /. {κ -> 1, Ω -> 1 / 2}//TrigToExpCompare with DSolveValue:
DSolveValue[{OdEqn /. {κ -> 1, Ω -> 1 / 2}, y'[0] == 1, y[0] == icf[0]}, y[t], t]//TrigToExpPartial Differential Equations (1)
Solve the heat equation for 
, 
: 
with initial condition 
for 
and Neumann boundary condition 
for 
:
eqn = D[u[x, t], t] == α ^ 2 D[u[x, t], x, x];Apply the Fourier cosine transform to the ODE on 
:
FourierCosTransform[eqn, x, ω]
DSolveValue[{D[u1[ω, t], t] == α^2 (-ω^2u1[ω, t] - Sqrt[(2/π)] u^(1, 0)[0, t]), u1[ω, 0] == FourierCosTransform[f[x], x, ω][ω]}, u1[ω, t], t] /. {u^(1, 0)[0, K[1]] -> g[K[1]]}//ExpandCompute the inverse cosine transform of the exponential functions:
h[x_] = InverseFourierCosTransform[Sqrt[(2/π)]E^-t α^2 ω^2, ω, x];
l[x] = InverseFourierCosTransform[-Sqrt[(2/π)]α^2E^(K[1] - t) α^2 ω^2 , ω, x];Convolution property gives the inverse cosine transform of the first summand to get the solution:
1 / 2Integrate[f[τ](h[x + τ] + h[x - τ]), {τ, 0, ∞}] + Integrate[l[x]g[K[1]], {K[1], 0, t}]Consider the special case with 
, 
and 
:
% /. {f -> Function[u, UnitBox[u - 1 / 2]], g -> Function[u, 0], α -> 1}Compare with DSolveValue:
DSolveValue[{eqn /. α -> 1, {u[x, 0] == UnitBox[x - 1 / 2], Derivative[1, 0][u][0, t] == 0}}, u[x, t], {x, t}, Assumptions -> {t > 0 && x > 0}]Plot the initial conditions and solutions for different values of 
.
Plot[{UnitBox[x - 1 / 2], Evaluate@Table[%, {t, {.005, .1, .3, .8}}]}, {x, 0, 4}, PlotLegends -> {UnitBox[x - 1 / 2], .005, .1, .3, .8}, Exclusions -> None]Evaluation of Integrals (2)
Calculate the following definite integral:
Inactive[Integrate][(1/(ω ^ 2 + 9)(ω ^ 2 + 4)), {ω, 0, ∞}]Inverse Fourier cosine transform preserves integration of products over 
:
Inactive[Integrate][InverseFourierCosTransform[(1/(ω ^ 2 + 9)), ω, t]InverseFourierCosTransform[1 / (ω ^ 2 + 4), ω, t], {t, 0, ∞}]Activate[%]Compare with Integrate:
Integrate[(1/(ω ^ 2 + 9)(ω ^ 2 + 4)), {ω, 0, ∞}]Calculate the following definite integral for 
:
Inactive[Integrate][(1/(α ^ 2 + ω ^ 2) ^ 2), {ω, 0, ∞}]Compute inverse fourier cosine transform of the square root of the integrand:
InverseFourierCosTransform[( 1/α^2 + ω^2), ω, x, Assumptions -> α > 0]Inactive[Integrate][Abs[E^-α x] ^ 2, {x, -∞, ∞}] == Inactive[Integrate][Abs[(Sqrt[(2/π)] α/α^2 + ω^2)] ^ 2, {ω, -∞, ∞}]Integrate[E^-2α x, {x, 0, ∞}, Assumptions -> α > 0] == HoldForm[(2α ^ 2/π)]Inactive[Integrate][( 1/(α^2 + ω^2) ^ 2), {ω, 0, ∞}]Solve for the definite integral:
SolveValues[ReleaseHold[%], Inactive[Integrate][( 1/(α^2 + ω^2) ^ 2), {ω, 0, ∞}]][[1]]Compare with Integrate:
Integrate[( 1/(α^2 + ω^2) ^ 2), {ω, 0, ∞}, Assumptions -> α > 0]Properties & Relations (4)
By default, the inverse Fourier cosine transform of 
is:
HoldForm[InverseFourierCosTransform[F[ω], ω, t] = HoldForm[Sqrt[2 / π]] * Integrate[F[ω]Cos[ω t], {ω, 0, ∞}]]//TraditionalFormFor 
, the definite integral becomes:
Sqrt[2 / π]Integrate[Exp[-ω ^ 2]Cos[ω]Cos[ω t], {ω, 0, ∞}]//FullSimplifyCompare with InverseFourierCosTransform:
InverseFourierCosTransform[Exp[-ω ^ 2]Cos[ω], ω, t]//TrigToExp//SimplifyUse Asymptotic to compute an asymptotic approximation:
Asymptotic[Inactive[InverseFourierCosTransform][ E ^ (-ω ^ 3), ω, t], t -> 0]FourierCosTransform and InverseFourierCosTransform are mutual inverses:
FourierCosTransform[InverseFourierCosTransform[F[ω], ω, t], t, ω]InverseFourierCosTransform[FourierCosTransform[g[t], t, ω], ω, t]FourierCosTransform[1 / (ω ^ 2 + 1), ω, t]InverseFourierCosTransform[%, t, ω]For even functions results are identical to InverseFourierTransform:
InverseFourierCosTransform[Sin[ω] / ω, ω, t]InverseFourierTransform[Sin[ω] / ω, ω, t ]
Simplify[% - %%, t > 0]Possible Issues (1)
The result from a Fourier cosine transform may not have the same form as the original:
InverseFourierCosTransform[UnitStep[1 + ω] UnitStep[1 - ω], ω, t]FourierCosTransform[%, t, ω]Inverse Fourier cosine transforms may require generalized functions such as DiracDelta:
InverseFourierCosTransform[1, ω, t]FourierCosTransform[%, t, ω]Neat Examples (2)
Inverse Fourier cosine transform as a Meijer function:
InverseFourierCosTransform[t / (t ^ 3 + 1), t, ω]Create a table of basic inverse Fourier cosine transforms:
flist = {ω ^ n, E ^ (-a ω), Exp[-ω ^ 2], Sinc[ω], DiracDelta[ω - a], Log[ω], UnitStep[ω], UnitBox[ω], ω Erfc[a ω], ConditionalExpression[BesselJ[2, ω], 0 < t < 1], ConditionalExpression[BesselY[0, a ω], t > a]};Grid[Prepend[{#, Assuming[{a > 0}, Assuming[{a > 0}, Simplify[InverseFourierCosTransform[#1, ω, t]]]]}& /@ flist, {f[t], InverseFourierCosTransform[f[ω], ω, t]}], IconizedObject[«Grid options»]]//TraditionalFormText
Wolfram Research (1999), InverseFourierCosTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseFourierCosTransform.html (updated 2025).
CMS
Wolfram Language. 1999. "InverseFourierCosTransform." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/InverseFourierCosTransform.html.
APA
Wolfram Language. (1999). InverseFourierCosTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseFourierCosTransform.html