Wolfram Language & System Documentation Center

NLineIntegrate

NLineIntegrate[f,{x,y,…}∈curve]

computes the numerical scalar line integral of the function f[x,y,…] over the curve.

NLineIntegrate[{p,q,…},{x,y,…}∈curve]

computes the numerical vector line integral of the vector function {p[x,y,…],q[x,y,…],…}.

Details and Options

Line integrals are also known as curve integrals and work integrals.
Scalar line integrals integrate scalar functions along a curve. They typically compute things like length, mass and charge for a curve.
Vector line integrals are used to compute the work done by a vector function along a curve in the direction of its tangent. Typical vector functions include a force field, electric field and fluid velocity field.
The scalar line integral of the function f along a curve is given by:

… where $TemplateBox[{{{r, ^, {(, ', )}}, (, u, )}}, Norm]$ is the measure of a parametric curve segment.
The scalar line integral is independent of the parametrization and orientation of the curve. Any one-dimensional RegionQ object can be used as a curve.
The vector line integral of the function F along a curve is given by:

… where is projection of the vector function onto the tangent direction so only the component in the tangent direction gets integrated.
The vector line integral is independent of the parametrization of the curve, but it does depend on the orientation of the curve.
The orientation for a curve is given by a tangent vector field over the curve.

For a parametric curve ParametricRegion[{r₁[u],…,r_n[u]},…], the tangent vector field is taken to be ∂_ur[u].
Special curves in with their assumed tangent orientations include:

		Line[{p₁,p₂,…}]	the orientation follows the points in the order they are given from p₁ to p₂ etc.
		HalfLine[{p₁,p₂}] HalfLine[p,v]	the orientation is from p₁ to p₂ or in the v direction
		InfiniteLine[{p₁,p₂}] InfiniteLine[p,v]	the orientation is from p₁ to p₂ or in the v direction
		Circle[p,r]	the orientation is counterclockwise

Special curves in with their assumed tangent orientations include:

		Line[{p₁,p₂,…}]	the orientation follows the points in the order they are given from p₁ to p₂ etc.
		HalfLine[{p₁,p₂}] HalfLine[p,v]	the orientation is from p₁ to p₂ or in the v direction
		InfiniteLine[{p₁,p₂}] InfiniteLine[p,v]	the orientation is from p₁ to p₂ or in the v direction

Special curves in with their assumed tangent orientations include:

		Line[{p₁,p₂,…}]	the orientation follows the points in the order they are given
		HalfLine[{p₁,p₂}] HalfLine[p,v]	the orientation is from p₁ to p₂ the orientation is given by v
		InfiniteLine[{p₁,p₂}] InfiniteLine[p,v]	the orientation is from p₁ to p₂ the orientation is given by v

The coordinates along the curve can be specified using VectorSymbol. »
The following options can be given:

AccuracyGoal	Infinity	digits of absolute accuracy sought
MaxPoints	Automatic	maximum total number of sample points
MaxRecursion	Automatic	maximum number of recursive subdivisions
Method	Automatic	method to use
MinRecursion	0	minimum number of recursive subdivisions
PrecisionGoal	Automatic	digits of precision sought
WorkingPrecision	MachinePrecision	the precision used in internal computations

Examples

open all close all

Basic Examples (6)

Line integral of a scalar field over a circle:

Wolfram Language code: NLineIntegrate[2x, {x, y}∈Circle[{0, 0}, 1, {0, Pi / 2}]]

Line integral of a vector field over a space curve:

Wolfram Language code: NLineIntegrate[{x ^ 2 y z, 3x y, y ^ 2}, {x, y, z}∈ParametricRegion[{Cos[t], Sin[t], t}, {{t, 0, Pi / 2}}]]

Line integral of a scalar field in two dimensions:

Wolfram Language code: f = y ^ 2;

Curve over which to integrate:

Wolfram Language code: reg = ParametricRegion[{{t ^ (5 / 2), t}, 0 <= t <= 2}, {t}];

A contour plot of and the curve:

Wolfram Language code: Show[ContourPlot[f, {x, 0, 6}, {y, 0, 2}], ...]

The line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field in two dimensions:

Wolfram Language code: f = {x + 2y, x ^ 2};

Wolfram Language code: reg = Line[{{0, 0}, {2, 3 / 2}, {3, 0}}];

The vector field and the integration path:

Wolfram Language code: VectorPlot[f, {x, 0, 3}, {y, 0, 2}, ...]

The line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field in three dimensions:

Wolfram Language code: f = {z ^ 3, x ^ 3, y ^ 3};

Wolfram Language code: reg = Line[{{1, 1 / 2, 0}, {3, 2, 2}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, 0, 4}, {y, 0, 2}, {z, 0, 2}, Rule[...]], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Use VectorSymbol:

Wolfram Language code: NLineIntegrate[VectorSymbol["x"].VectorSymbol["x"], VectorSymbol["x"]∈Line[{{0, 0}, {0, 1}}]]

Use implicit vector notation:

Wolfram Language code: NLineIntegrate[x, x∈Line[{{0, 0}, {0, 1}}]]

Scope (34)

Basic Uses (5)

Line integral of a scalar field:

Wolfram Language code: f = Exp[x];

Wolfram Language code: NLineIntegrate[f, {x, y}∈Line[{{0, 0}, {2, 3}}]]

Line integral of a vector field over a line segment:

Wolfram Language code: NLineIntegrate[{x * y, x - y}, {x, y}∈Line[{{0, 0}, {1, 1}}]]

Line integral of a vector field in three dimensions:

Wolfram Language code: f = {x, x - y, z x ^ 2};

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈ParametricRegion[{Sin[t], t, 2t}, {{t, 0, Pi}}]]

LineIntegrate works with many special curves:

Wolfram Language code: f = {x ^ 2 y, x};

Wolfram Language code: NLineIntegrate[f, {x, y}∈Annulus[{0, 0}, {1, 2}, {0, Pi / 4}]]//Quiet

Line integral over a parametric curve:

Wolfram Language code: f = {Log[x], y};

Wolfram Language code: reg = ParametricRegion[{2t + 1, t ^ 2}, {{t, 0, 1}}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Scalar Functions (11)

Line integral of a scalar field over a curve:

Wolfram Language code: f = 2Abs[x - y] ^ (3 / 4);

Wolfram Language code: reg = ParametricRegion[{t, t ^ (3 / 2)}, {{t, 0, 8}}];

Contour plot of and the curve:

Wolfram Language code: Show[ContourPlot[f, {x, 0, 8}, {y, 0, 25}], ...]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over an arc of a circle:

Wolfram Language code: f = 1 / (x + Sin[y] + 1) ^ 3;

Wolfram Language code: reg = Circle[{0, 0}, 1, {0, Pi / 2}];

Wolfram Language code: ContourPlot[f, {x, 0, 1}, {y, 0, 1}, Epilog -> reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over a parametric curve:

Wolfram Language code: f = 1 / (x + 1) - y / 5;

Wolfram Language code: reg = ParametricRegion[{3 / 2t ^ 2, 4t}, {{t, -1, 1}}];

Contour plot of the function and the curve:

Wolfram Language code: Show[ContourPlot[f, {x, -1 / 2, 2}, {y, -4, 4}], ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over a circle:

Wolfram Language code: f = Sin[1 / (x ^ 3 + y + 1)];

Wolfram Language code: reg = Circle[{2, 3}, 3];

Wolfram Language code: ContourPlot[f, {x, -1, 5}, {y, 0, 6}, Epilog -> reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over a space curve:

Wolfram Language code: f = x + y - z;

Wolfram Language code: reg = ParametricRegion[{t ^ 3 / 3, Sqrt[2]t ^ 2 / 2, t}, {{t, 0, 1}}];

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a scalar field over the boundary of an annulus:

Wolfram Language code: f = 1 / Exp[x + y + 5];

Wolfram Language code: reg = Annulus[{0, 0}, {1, 2}, {0, 3 / 4Pi}];

Contour plot of the function and the curve:

Wolfram Language code: ContourPlot[f, {x, -2, 4}, {y, -1, 5}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over a closed polygon:

Wolfram Language code: f = Exp[Cos[Abs[x / 2 - y]]];

Wolfram Language code: reg = Line[{{0, 0}, {1, 2}, {0, 1}, {0, 0}}];

Contour plot of the function and the curve:

Wolfram Language code: ContourPlot[f, {x, 0, 1}, {y, 0, 2}, Epilog -> reg, AspectRatio -> Automatic]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over an elliptical path:

Wolfram Language code: f = 2 x y;

Wolfram Language code: reg = Circle[{0, 0}, {1, 1 / Sqrt[2]}];

Contour plot of the function and the curve:

Wolfram Language code: ContourPlot[f, {x, -1, 1}, {y, -1, 1}, Epilog -> reg, ImageSize -> Small]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]//Quiet

Line integral of a scalar field over a parametric curve:

Wolfram Language code: f = x / 2 + Sin[y] ^ 2;

Wolfram Language code: reg = ParametricRegion[{6Cos[t] - Cos[6t], 6Sin[t] - Sin[6t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[ContourPlot[f, {x, -10, 10}, {y, -10, 10}], RegionPlot[reg, BoundaryStyle -> Blue], ImageSize -> Small]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg, MaxRecursion -> 20]

Line integral of a scalar field over a circle:

Wolfram Language code: f = ArcTan[(y / x) ^ 2];

Wolfram Language code: reg = Circle[{0, 0}, 4];

Contour plot of and the curve:

Wolfram Language code: ContourPlot[f, {x, -4, 4}, {y, -4, 4}, Epilog -> reg, ImageSize -> Small]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a scalar field over the boundary of a sector of a disk:

Wolfram Language code: f = Cos[x - y];

Wolfram Language code: reg = Disk[{0, 0}, 3, {0, 3Pi / 4}];

Contour plot of and the curve:

Wolfram Language code: ContourPlot[f, {x, -3, 3}, {y, -1, 5}, ...]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Vector Functions (12)

Line integral of a vector field in three dimensions over a parametrized curve:

Wolfram Language code: f = {2x, x, 1};

Wolfram Language code: reg = ParametricRegion[{Sin[t], Cos[t], t}, {{t, 0, 2Pi}}];

Visualization of the vector field and the curve:

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, 0, 7}, ...], ...]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over a curve in two dimensions:

Wolfram Language code: f = {Sin[x], y};

Wolfram Language code: reg = ParametricRegion[{t ^ 2, t ^ 3}, {{t, 0, 1}}];

Wolfram Language code: Show[VectorPlot[f, {x, 0, 1}, {y, 0, 1}, Rule[...]], ...]

Line integral:

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field over a circular arc:

Wolfram Language code: f = {x * (x ^ 2 + y ^ 2), y * (x ^ 2 + y ^ 2)};

Wolfram Language code: reg = Circle[{0, 0}, 1, {0, Pi / 2}];

Wolfram Language code: VectorPlot[f, {x, 0, 1}, {y, 0, 1}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]//Quiet

Line integral of a vector field over a line segment:

Wolfram Language code: f = {Sqrt[x ^ 2 + y ^ 2], Sqrt[Abs[x + y]]};

Wolfram Language code: reg = Line[{{0, 0}, {2, 2}, {4, 0}}];

Wolfram Language code: VectorPlot[f, {x, -1, 5}, {y, -1, 3}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field over a parametrized curve in three dimensions:

Wolfram Language code: f = {x, x ^ 2 y ^ 2, 0};

Wolfram Language code: reg = ParametricRegion[{Cos[t] ^ 2, Cos[t]Sin[t], Sqrt[Cos[t](1 - Cos[t])]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, 0, 1}, Rule[...]], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over a curve:

Wolfram Language code: f = {x + y, y + z, z + x};

Wolfram Language code:

reg = ParametricRegion[{Sin[t] ^ 2 / Sqrt[2] + Cos[t] ^ 2, (1 - 1 / Sqrt[2])Cos[t]Sin[t], Sin[t] / Sqrt[2]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, 0, 1}, {y, -1, 1}, {z, -1, 1}, ...], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over an elliptical arc:

Wolfram Language code: f = {x, Sin[x y ^ 2]};

Wolfram Language code: reg = Circle[{0, 0}, {2, 1}, {0, Pi}];

Wolfram Language code: VectorPlot[f, {x, -2, 2}, {y, -1 / 2, 3 / 2}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field over a parametric curve:

Wolfram Language code: f = {x ^ 2, x ^ 2, Exp[y ^ 2 / 4]};

Wolfram Language code: reg = ParametricRegion[{(2 + Cos[3t])Cos[t], (2 + Cos[3t])Sin[t], Sin[3t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -3, 3}, {y, -3, 3}, {z, -1, 1}, ...], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over a parametric curve in three dimensions:

Wolfram Language code: f = {(y - 1) ^ 2z, x ^ 2y, 2x y};

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t] / 2, Sin[t] / 2}, {{t, 0, Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Rule[...]], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over a parametrized curve:

Wolfram Language code: f = {x ^ 2, 1 / 3, z ^ 2};

Wolfram Language code: reg = ParametricRegion[{2 / (1 + t ^ 2), 3t, 2t / (1 + t ^ 2)}, {{t, -10, 10}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, 0, 2}, {y, -30, 30}, {z, -1, 1}, ...], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over an elliptical path:

Wolfram Language code: f = {Sin[x ^ 4 y ^ 2], Sin[y]};

Wolfram Language code: reg = Circle[{0, 1}, {Sqrt[2], 1}];

Wolfram Language code: VectorPlot[f, {x, -2, 2}, {y, 0, 2}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field in higher dimensions:

Wolfram Language code: f = {x y, x ^ 2t z, y t, z t};

Wolfram Language code: NLineIntegrate[f, {x, y, z, t}∈Line[{{0, 0, 0, 0}, {1, 2, 3, 4}}]]

Special Curves (4)

Line integral over a circular arc:

Wolfram Language code: f = Sqrt[x] * Abs[y] ^ (3 / 4);

Wolfram Language code: reg = Circle[{0, 0}, 4, {-Pi / 2, Pi / 2}];

Wolfram Language code: ContourPlot[f, {x, 0, 4}, {y, -4, 4}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field over the boundary of a circular sector of radius 1:

Wolfram Language code: f = {Exp[Sin[3y]], y + x ^ 2};

Wolfram Language code: reg = Disk[{0, 0}, 1, {0, Pi / 2}];

Wolfram Language code: VectorPlot[f, {x, 0, 1}, {y, 0, 1}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral over a polygon:

Wolfram Language code: f = {1 / (x + 2y) ^ 2, -1 / (x + y)};

Wolfram Language code: reg = Line[{{1, 0}, {0, 1}, {-1, 0}, {0, -1}, {1, 0}}];

Wolfram Language code: VectorPlot[f, {x, -1, 1}, {y, -1, 1}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]//Quiet

Line integral over the boundary of an annulus:

Wolfram Language code: f = {-2y, x};

Wolfram Language code: reg = Annulus[{0, 0}, {1, 2}, {0, Pi / 4}];

Wolfram Language code: VectorPlot[f, {x, 0, 2}, {y, 0, 2}, ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg, AccuracyGoal -> 5]

Parametric Curves (2)

Line integral of a vector field over a spiral in three dimensions:

Wolfram Language code: f = {y - z, z - x, x - y};

Wolfram Language code: reg = ParametricRegion[{ Cos[t], Sin[t], t}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, 0, 2Pi}, ...], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a scalar field over a parametric curve:

Wolfram Language code: NLineIntegrate[Exp[-x], {x, y}∈ParametricRegion[{2t, 3t}, {{t, 0, Infinity}}]]

Options (8)

AccuracyGoal (1)

The option AccuracyGoal sets the number of digits of accuracy:

Wolfram Language code: exact = LineIntegrate[{1, x ^ 2}, {x, y}∈Circle[]]

Wolfram Language code: NLineIntegrate[{1, x ^ 2}, {x, y}∈Circle[], AccuracyGoal -> 15] - exact

The result with default settings only sets a PrecisionGoal:

Wolfram Language code: NLineIntegrate[{1, x ^ 2}, {x, y}∈Circle[]] - exact

MaxPoints (1)

The option MaxPoints stops the integration after a specified number of points has been evaluated:

Wolfram Language code: NLineIntegrate[1 / Sqrt[x ^ 4 + y ^ 4], {x, y}∈Circle[], MaxPoints -> 10]

With default options:

Wolfram Language code: NLineIntegrate[1 / Sqrt[x ^ 4 + y ^ 4], {x, y}∈Circle[]]

MaxRecursion (1)

The option MaxRecursion specifies the maximum number of recursive steps:

Wolfram Language code: reg = ParametricRegion[{Sin[t], 1}, {{t, 0, Pi}}];

Wolfram Language code: NLineIntegrate[{1 / Sqrt[x], x}, {x, y}∈reg]

Increasing the number of recursions:

Wolfram Language code: NLineIntegrate[{1 / Sqrt[x], x}, {x, y}∈reg, MaxRecursion -> 20]

The exact result is:

Wolfram Language code: LineIntegrate[{1 / Sqrt[x], x}, {x, y}∈reg]

Method (1)

The option Method can take the same values as in NIntegrate. For example:

Wolfram Language code: NLineIntegrate[{-Sin[y] ^ 3, x ^ 2}, {x, y}∈Circle[], Method -> "TrapezoidalRule", WorkingPrecision -> 15]

Wolfram Language code: NLineIntegrate[{-Sin[y] ^ 3, x ^ 2}, {x, y}∈Circle[], Method -> "NewtonCotesRule", WorkingPrecision -> 15]

Wolfram Language code: NLineIntegrate[{-Sin[y] ^ 3, x ^ 2}, {x, y}∈Circle[], Method -> "ClenshawCurtisRule", WorkingPrecision -> 15]

With the default option:

Wolfram Language code: NLineIntegrate[{-Sin[y] ^ 3, x ^ 2}, {x, y}∈Circle[], WorkingPrecision -> 15]

Compare to the truncated exact result:

Wolfram Language code: LineIntegrate[{-Sin[y] ^ 3, x ^ 2}, {x, y}∈Circle[]]

Wolfram Language code: %//N[#, 15]&

MinRecursion (1)

The option MinRecursion forces a minimum number of subdivisions:

Wolfram Language code: NLineIntegrate[Exp[-100(x ^ 2 + y ^ 2)], {x, y}∈Line[{{-60, -60}, {60, 60}}]]

Wolfram Language code: NLineIntegrate[Exp[-100(x ^ 2 + y ^ 2)], {x, y}∈Line[{{-60, -60}, {60, 60}}], MinRecursion -> 5]

Compare to the exact result:

Wolfram Language code: LineIntegrate[Exp[-100(x ^ 2 + y ^ 2)], {x, y}∈Line[{{-60, -60}, {60, 60}}]]

Wolfram Language code: N[%]

PrecisionGoal (1)

The option PrecisionGoal sets the relative tolerance in the integration:

Wolfram Language code: exact = LineIntegrate[{Exp[-y ^ 2], Sin[x]}, {x, y}∈Circle[{0, 0}, {1, 2}]]

Wolfram Language code:

NLineIntegrate[{Exp[-y ^ 2], Sin[x]}, {x, y}∈Circle[{0, 0}, {1, 2}], PrecisionGoal -> 20, MaxRecursion -> 20, WorkingPrecision -> 20] - exact

With default settings:

Wolfram Language code: NLineIntegrate[{Exp[-y ^ 2], Sin[x]}, {x, y}∈Circle[{0, 0}, {1, 2}]] - exact

WorkingPrecision (2)

If a WorkingPrecision is specified, the computation is done at that working precision:

Wolfram Language code: NLineIntegrate[1, {x, y}∈Circle[]]

Wolfram Language code: NLineIntegrate[1, {x, y}∈Circle[], WorkingPrecision -> 16]

The result has finite precision if the integrand has a finite precision:

Wolfram Language code: NLineIntegrate[{-y, 0.567x}, {x, y}∈Line[{{0, 0}, {2, 4}}]]

Applications (27)

College Calculus (10)

Line integral of a function over a line segment:

Wolfram Language code: f = Exp[x] y ^ 2 z ^ (3 / 2);

Wolfram Language code: reg = Line[{{-1, 3, 1}, {1, 7, 3}}];

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field over a curve:

Wolfram Language code: f = {x Sin[y], y Cos[z], z Sin[x]};

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t] ^ 2, -Cos[t]}, {{t, 0, Pi}}];

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Mass of a thin circular wire of radius 1 with linear density :

Wolfram Language code: ρ = BesselJ[1, x ^ 2 / 2] * y ^ 2;

Wolfram Language code: reg = Circle[{0, 0}, 1];

Wolfram Language code: NLineIntegrate[ρ, {x, y}∈reg]

Work done by the force field on a particle that moves along a line segment:

Wolfram Language code: f = {x - y ^ 3, y - z ^ 3, z - x ^ 3};

Wolfram Language code: reg = Line[{{0, 0, 0}, {1, 2, 3}}];

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Line integral of a vector field along a path:

Wolfram Language code: f = {Cos[x], Sin[y]};

Wolfram Language code: reg = Line[{{0, 0}, {3, 0}, {3, 3}, {0, 3}, {0, 0}}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field along a curve:

Wolfram Language code: f = {ArcTan[x ^ 2], y ^ 2};

Wolfram Language code: reg = ParametricRegion[{t, t ^ 2}, {{t, 0, 1}}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Work done by the force as a particle moves along the curve :

Wolfram Language code: f = {x ^ 2, y};

Wolfram Language code: reg = ParametricRegion[{t - Sin[t], 1 - Cos[t]}, {{t, 0, 2Pi}}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Line integral of a vector field along the unit circle centered at the origin:

Wolfram Language code: f = {x + y, x ^ 2};

Wolfram Language code: NLineIntegrate[f, {x, y}∈Circle[]]

Line integral of a vector field along a circle of radius 2 centered at the origin:

Wolfram Language code: f = {x ^ 2 / (x ^ 2 + y ^ 2), (y ^ 2 - x ^ 2) / (x ^ 2 + y ^ 2)};

Wolfram Language code: NLineIntegrate[f, {x, y}∈Circle[{0, 0}, 2]]//Quiet

Numerical value of the line integral of a vector field over a path:

Wolfram Language code: f = {Exp[Sin[x ^ 2]], Exp[Sqrt[x ^ 2 + y ^ 2]]};

Wolfram Language code: reg = ParametricRegion[{Sin[t ^ 2], Cos[t] ^ 3}, {{t, 0, 2Pi}}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg, WorkingPrecision -> 16]

Lengths (3)

Circumference of a circle:

Wolfram Language code: NLineIntegrate[1, {x, y}∈Circle[]]

Perimeter of a cardioid using a line integral:

Wolfram Language code: reg = ParametricRegion[{(2Cos[t] - Cos[2t]), (2Sin[t] - Sin[2t])}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[1, {x, y}∈reg]

The length can also be calculated with RegionMeasure:

Wolfram Language code: RegionMeasure[reg]

Perimeter of an astroid:

Wolfram Language code: reg = ParametricRegion[{Cos[t] ^ 3, Sin[t] ^ 3}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[1, {x, y}∈reg]

Areas (5)

Area of an ellipse with semiaxes of length 2 and 3, calculated using a line integral:

Wolfram Language code: NLineIntegrate[{-y / 2, x / 2}, {x, y}∈Circle[{0, 0}, {2, 3}]]

Area of the right-hand loop of the lemniscate computed using a line integral:

Wolfram Language code: f = {-y / 2, x / 2};

Wolfram Language code: reg = ParametricRegion[{Sqrt[Cos[2ϕ]]Cos[ϕ], Sqrt[Cos[2ϕ]]Sin[ϕ]}, {{ϕ, -Pi / 4, Pi / 4}}];

Wolfram Language code: Show[VectorPlot[f, {x, 0, 1}, {y, -1 / 2, 1 / 2}, ...], ...]

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Area of the epicycloid of parameters and :

Wolfram Language code: R = 2;

Wolfram Language code: r = 1 / 2;

Wolfram Language code: reg = ParametricRegion[{(R + r)Cos[t] - r Cos[(R + r) / r * t], (R + r)Sin[t] - r Sin[(R + r) / r * t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot[{-y / 2, x / 2}, {x, -3, 3}, {y, -3, 3}, ...], ...]

Wolfram Language code: NLineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

Area of the cardioid using a line integral:

Wolfram Language code: reg = ParametricRegion[{(2Cos[t] - Cos[2t]), (2Sin[t] - Sin[2t])}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

Area of an astroid using a line integral:

Wolfram Language code: reg = ParametricRegion[{Cos[t] ^ 3, Sin[t] ^ 3}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

Work by a Force (4)

Work done by a force force as an object is moved on a straight line:

Wolfram Language code: f = {0, 0, -1};

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈Line[{{0, 0, 0}, {1, 2, 3}}]]

Work done by the electric force as a charged particle of charge is moved from {1,1,0} to {2,2,0} in the electric field of a charged infinite wire of charge density :

Wolfram Language code: Subscript[ϵ, 0] = 8.854 * 10 ^ -12;

Wolfram Language code: q = 10 ^ -6;

Wolfram Language code: λ = 10 ^ -5;

Wolfram Language code: f = {(λ * q * x/2Pi Subscript[ϵ, 0](x ^ 2 + y ^ 2)), (λ * q * y/2Pi Subscript[ϵ, 0](x ^ 2 + y ^ 2)), 0};

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈Line[{{1, 1, 0}, {2, 2, 0}}]]

Work done by an elastic force directed toward the origin as a quarter of an ellipse is traced:

Wolfram Language code: f = {-2x, -2y};

Wolfram Language code: reg = Circle[{0, 0}, {1, 2}, {0, Pi / 2}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

Work of the electric force as a charge is moved along the axis from to infinity in the electric field of a charge :

Wolfram Language code: Subscript[ϵ, 0] = 8.854 * 10 ^ -12;

Wolfram Language code: Q = 2. * 10 ^ -5;

Wolfram Language code: q = 10 ^ -5;

Wolfram Language code: Subscript[x, 0] = 1;

Wolfram Language code:

f = {(Q * q * x/4π Subscript[ϵ, 0](x ^ 2 + y ^ 2 + z ^ 2) ^ (3 / 2)), (Q * q * y/4π Subscript[ϵ, 0](x ^ 2 + y ^ 2 + z ^ 2) ^ (3 / 2)), (Q * q * z/4π Subscript[ϵ, 0](x ^ 2 + y ^ 2 + z ^ 2) ^ (3 / 2))};

Wolfram Language code: reg = ParametricRegion[{Subscript[x, 0] + t, 0, 0}, {{t, 0, Infinity}}];

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Centroids (2)

Mass of a closed semicircular wire of radius 2 and unit linear density:

Wolfram Language code: reg = Disk[{0, 0}, 2, {0, Pi}];

Wolfram Language code: m = NLineIntegrate[1, {x, y}∈reg]

coordinate of the center of mass:

Wolfram Language code: (1 / m) * NLineIntegrate[x, {x, y}∈reg, AccuracyGoal -> 5]

coordinate of the center of mass:

Wolfram Language code: (1 / m) * NLineIntegrate[y, {x, y}∈reg, AccuracyGoal -> 5]

Moments of inertia of a helix-shaped wire of unit linear density:

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t], t / 10}, {{t, 0, 6Pi}}];

Wolfram Language code: ParametricPlot3D[{Cos[t], Sin[t], t / 10}, {t, 0, 6Pi}, ImageSize -> Small]

About the axis:

Wolfram Language code: NLineIntegrate[(y ^ 2 + z ^ 2), {x, y, z}∈reg]

About the axis:

Wolfram Language code: NLineIntegrate[(x ^ 2 + z ^ 2), {x, y, z}∈reg]

About the axis:

Wolfram Language code: NLineIntegrate[(x ^ 2 + y ^ 2), {x, y, z}∈reg]

Classical Theorems (3)

A vector field is conservative if its line integral depends only on the values at the endpoints, not on the path:

Wolfram Language code: f = {3 x^2 y, x^3};

The field is the gradient of a scalar function :

Wolfram Language code: g = x ^ 3 y;

Wolfram Language code: f == Grad[g, {x, y}]

All gradients of scalar fields are conservative. For example, the line integral of over the curve is:

Wolfram Language code: reg = ParametricRegion[{t ^ 2, Exp[t]}, {{t, 0, 1}}];

Wolfram Language code: NLineIntegrate[f, {x, y}∈reg]

This is the same as the difference of the values of at the endpoints of the curve:

Wolfram Language code: (g /. {x -> t ^ 2, y -> Exp[t]} /. t -> 1) - (g /. {x -> t ^ 2, y -> Exp[t]} /. t -> 0)//N

Green's theorem. The line integral of the vector field over a closed curve is:

Wolfram Language code: f = {x ^ 4, x * y ^ 2 + 1};

Wolfram Language code: NLineIntegrate[f, {x, y}∈Line[{{0, 0}, {1, 0}, {0, 1}, {0, 0}}]]

This can be related to a surface integral of over the region enclosed by the curve, where is defined as:

Wolfram Language code: g = D[f[[2]], x] - D[f[[1]], y];

Wolfram Language code: NIntegrate[g, {x, y}∈Triangle[{{0, 0}, {1, 0}, {0, 1}}]]

Stokes's theorem. The line integral of a vector field along a closed line in three dimensions is:

Wolfram Language code: f = {-y + x y ^ 2, x, z};

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t], 0}, {{t, 0, 2Pi}}];

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

This is equal to the surface integral of the Curl of on any surface having the curve as its boundary:

Wolfram Language code: reg2 = ParametricRegion[{Cos[t]Cos[p], Cos[t]Sin[p], Sin[t]}, {{p, 0, 2Pi}, {t, 0, Pi / 2}}];

Wolfram Language code: NSurfaceIntegrate[Curl[f, {x, y, z}], {x, y, z}∈reg2]

The surface integral across a different surface with the same boundary is the same:

Wolfram Language code: NSurfaceIntegrate[Curl[f, {x, y, z}], {x, y, z}∈ParametricRegion[{r Cos[t], r Sin[t], 0}, {{r, 0, 1}, {t, 0, 2Pi}}]]

Properties & Relations (5)

Apply N[LineIntegrate[…]] to obtain a numerical solution if the symbolic calculation fails:

Wolfram Language code: f = Sin[x + y + z];

Wolfram Language code: reg = ParametricRegion[{t ^ 2, t ^ 3, t ^ 4}, {{t, 0, 1}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

Wolfram Language code: N[LineIntegrate[f, {x, y, z}∈reg]]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Find the center of mass of a triangular wire of unit linear density:

Wolfram Language code: reg = Line[{{0, 0}, {1, 0}, {1, 1}, {0, 0}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Find the total mass:

Wolfram Language code: m = NLineIntegrate[1, {x, y}∈reg]

Find the component of the center of mass:

Wolfram Language code: 1 / m * NLineIntegrate[x, {x, y}∈reg]

Find the component:

Wolfram Language code: 1 / m * NLineIntegrate[y, {x, y}∈reg]//Quiet

The center of mass can also be obtained using RegionCentroid:

Wolfram Language code: RegionCentroid[reg]//N

Find the moment of inertia around the axis of a circular wire of unit linear density centered at the origin in the - plane:

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t], 0}, {{t, 0, 2Pi}}];

Wolfram Language code: NLineIntegrate[(x ^ 2 + y ^ 2), {x, y, z}∈reg]

The answer can also be computed with MomentOfInertia:

Wolfram Language code: MomentOfInertia[reg, {0, 0, 0}, {0, 0, 1}]//N

Find the length of an epicycloid:

Wolfram Language code: reg = ParametricRegion[{6 Cos[t] - Cos[6 t], 6 Sin[t] - Sin[6 t]}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[1, {x, y}∈reg]//Quiet

The same answer can be obtained using ArcLength:

Wolfram Language code: ArcLength[{6 Cos[t] - Cos[6 t], 6 Sin[t] - Sin[6 t]}, {t, 0, 2Pi}]

Find the area of an ellipse:

Wolfram Language code: reg = Circle[{0, 0}, {1 / Sqrt[2], 1 / Sqrt[3]}];

Wolfram Language code: NLineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

The result can be obtained using RegionMeasure:

Wolfram Language code: RegionMeasure[Disk[{0, 0}, {1 / Sqrt[2], 1 / Sqrt[3]}]]

Neat Examples (2)

Length of a catenary:

Wolfram Language code: reg = ParametricRegion[{t, Cosh[t]}, {{t, -1, 1}}];

Wolfram Language code: ParametricPlot[{t, Cosh[t]}, {t, -1, 1}, ImageSize -> Small]

Wolfram Language code: NLineIntegrate[1, {x, y}∈reg]

Integral of a vector field over a Clelia curve:

Wolfram Language code: f = {x ^ 2 + y, y ^ 2 + z, z ^ 2 + x};

Wolfram Language code: reg = ParametricRegion[{Cos[t]Cos[3t], Cos[t]Sin[3t], Sin[t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Rule[...]], ...]

Wolfram Language code: NLineIntegrate[f, {x, y, z}∈reg]

Top

NLineIntegrate

Details and Options

Examples

Basic Examples (6)

Scope (34)

Basic Uses (5)

Scalar Functions (11)

Vector Functions (12)

Special Curves (4)

Parametric Curves (2)

Options (8)

AccuracyGoal (1)

MaxPoints (1)

MaxRecursion (1)

Method (1)

MinRecursion (1)

PrecisionGoal (1)

WorkingPrecision (2)

Applications (27)

College Calculus (10)

Lengths (3)

Areas (5)

Work by a Force (4)

Centroids (2)

Classical Theorems (3)

Properties & Relations (5)

Neat Examples (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX