Wolfram Language & System Documentation Center

Polygon

Polygon[{p₁,…,p_n}]

represents a filled polygon with points p_i.

Polygon[{p₁,…,p_n}{{q₁,…,q_m},…}]

represents a polygon with holes {q₁,…,q_m},….

Polygon[{poly₁,poly₂,…}]

represents a collection of polygons poly_i.

Polygon[{p₁,…,p_n},data]

represents a polygon in which coordinates given as integers i in data are taken to be p_i.

Polygon

Polygon[{p₁,…,p_n}]

represents a filled polygon with points p_i.

Polygon[{p₁,…,p_n}{{q₁,…,q_m},…}]

represents a polygon with holes {q₁,…,q_m},….

Polygon[{poly₁,poly₂,…}]

represents a collection of polygons poly_i.

Polygon[{p₁,…,p_n},data]

represents a polygon in which coordinates given as integers i in data are taken to be p_i.

Details and Options

Polygon can be used as a geometric region and a graphics primitive.
Polygon[{p₁,…,p_n}] is a plane region, representing all the points inside the closed curve with line segments {p₁,p₂},…,{p_n-1,p_n} and {p_n,p₁}.
A point is an element of the polygon if a ray from the point in any direction in the plane crosses the boundary line segments an odd number of times.

Polygon[{p₁,…,p_n}{{q₁,…,q_m},…}] specifies a polygon with holes consisting of an outer polygon Polygon[{p₁,…,p_n}] and one or several inner polygons Polygon[{q₁,…,q_m}],….
A point is an element of the polygon if it is in the outer polygon but not in any inner polygon.

Polygon[{poly₁,poly₂,…}] is a collection of polygons poly_i with or without holes and is treated as a union of poly_i for geometric computations.

Polygon[{p₁,…,p_n},data] effectively replaces integers i that appear as coordinates in data by the corresponding p_i.

	Polygon[{p₁,…,p_n},{b₁,…,b_n}]	polygon boundary points {p_b₁,…,p_{b_k}}
	Polygon[{p₁,…,p_n},{{o₁,…,o_k}{{i₁,…,i_l},…}]	outer polygon boundary points {p_o₁,…,p_{o_k}} and inner polygon boundary {p_i₁,…,p_{i_l}} etc.
	Polygon[{p₁,…,p_n},{{b₁,…,b_n},{o₁,…,o_k}{{i₁,…,i_l},…},…}]	a collection of several polygons

As a geometric region, the points p_i can have any embedding dimension, but must all lie in a plane and have the same embedding dimension.
In a graphic, the points p_i can be Scaled, Offset, ImageScaled and Dynamic expressions.
Graphics rendering is affected by directives such as FaceForm, EdgeForm, Texture, Specularity, Opacity and color.
FaceForm[front,back] can be used to specify different styles for the front and back of polygons in 3D. The front is defined by the right-hand rule and the direction of the first three points.
The following options and settings can be used in graphics:

VertexColors	Automatic	vertex colors to be interpolated
VertexNormals	Automatic	effective vertex normals for shading
VertexTextureCoordinates	None	coordinates for textures

Polygon can be used with symbolic points in GeometricScene.

Examples

open all close all

Basic Examples (2)

A polygon:

Wolfram Language code: pol = Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}]

Its graphic image:

Wolfram Language code: Graphics[pol]

Its area:

Wolfram Language code: Area[pol]

Differently styled 3D polygons:

Wolfram Language code: pol = Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}];

Wolfram Language code: {Graphics3D[{Pink, pol}], Graphics3D[{EdgeForm[Thick], Pink, pol}], Graphics3D[{EdgeForm[Dashed], Pink, pol}]}

Scope (22)

Graphics (12)

Specification (3)

A collection of polygons:

Wolfram Language code: p2 = {{0, 0}, {1, 0}, {0, 1}};

Wolfram Language code: Graphics[Polygon[{p2, p2 + 1}]]

Wolfram Language code: p3 = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};

Wolfram Language code: Graphics3D[Polygon[{p3, p3 + 1}]]

Polygons with multiple vertices:

Wolfram Language code: Graphics[Polygon[Table[{Cos[2π k / 6], Sin[2π k / 6]}, {k, 0, 5}]]]

Wolfram Language code: Graphics3D[Polygon[Table[{Cos[2π k / 6], Sin[2π k / 6], 0}, {k, 0, 5}]]]

Polygons with holes:

Wolfram Language code:

Graphics[Polygon[{{0, 0}, {2, 0}, {1, Sqrt[3]}} -> {{{(1/2), (1/2 Sqrt[3])}, {(3/2), (1/2 Sqrt[3])}, {1, (2/Sqrt[3])}}}]]

Wolfram Language code:

Graphics3D[Polygon[{{0, 0, 0}, {2, 0, 0}, {1, Sqrt[3], 0}} -> {{{(1/2), (1/2 Sqrt[3]), 0}, {(3/2), (1/2 Sqrt[3]), 0}, {1, (2/Sqrt[3]), 0}}}]]

Styling (6)

Color directives specify the face colors of polygons:

Wolfram Language code: Table[Graphics[{c, Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}]}], {c, {Red, Green, Blue, Yellow}}]

Wolfram Language code: Table[Graphics3D[{c, Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

Texture can be used to specify a texture to be used on the faces of polygons:

Wolfram Language code:

{Graphics[{Texture[ExampleData[{"TestImage", "JellyBeans2"}]], Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexTextureCoordinates -> {{1, 0}, {0.5, 1}, {0, 0}}]}], Graphics3D[{Texture[ExampleData[{"TestImage", "JellyBeans2"}]], Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {0.5, 1}}]}, Lighting -> "Neutral"]}

Texture can work together with different Opacity:

Wolfram Language code:

Table[Graphics[{Opacity[o], Texture[ExampleData[{"TestImage", "House"}]], Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexTextureCoordinates -> {{1, 0}, {0.5, 1}, {0, 0}}]}], {o, {0.25, 0.5, 0.75, 1}}]

Texture can work together with different Lighting:

Wolfram Language code:

Table[Graphics3D[{Texture[ExampleData[{"TestImage", "Sailboat"}]], Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {0.5, 1}}]}, Lighting -> {{"Directional", c, {4, -4, 4}}}], {c, {Red, Green, Yellow, White}}]

FaceForm and EdgeForm can be used to specify the styles of the interiors and boundaries:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Polygon[{{0, 0}, {0, 1}, {1, 1}, {1, 0}}]}]

Wolfram Language code:

Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Polygon[{{0, 0, 0}, {1, 1, 0}, {1, 1, 1}, {0, 0, 1}}]}]

In 3D, different properties can be specified for the front and back of faces using FaceForm:

Wolfram Language code: p = {FaceForm[Yellow, Blue], Polygon[{{1, 0, 0}, {0, Sqrt[3], 0}, {-1, 0, 0}}]};

Wolfram Language code: {Graphics3D[p, ViewPoint -> Top], Graphics3D[p, ViewPoint -> Bottom]}

Use FaceForm to set front and back textures differently in 3D:

Wolfram Language code:

vtc = {{0, 0}, {1, 0}, {1, 1}, {0, 1}};
coords = {{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}}, {{0, 0, 0}, {1, 0, 0}, {1, 0, 1}, {0, 0, 1}}, {{1, 0, 0}, {1, 1, 0}, {1, 1, 1}, {1, 0, 1}}, {{1, 1, 0}, {0, 1, 0}, {0, 1, 1}, {1, 1, 1}}, {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}, {0, 1, 1}}};

Wolfram Language code:

Graphics3D[{FaceForm[Texture[[image]], Texture[[image]]], Polygon[coords, VertexTextureCoordinates -> Table[vtc, {6}]]}, Lighting -> "Neutral"]

Colors can be specified at vertices using VertexColors:

Wolfram Language code: Graphics[Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexColors -> {Red, Green, Blue}]]

Wolfram Language code: Graphics3D[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

Normals can be specified at vertices using VertexNormals for 3D polygons:

Wolfram Language code: n = {1, -1, 1};

Wolfram Language code: Graphics3D[{Yellow, Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexNormals -> {-n, n, n}]}]

Coordinates (3)

Use Scaled coordinates:

Wolfram Language code: Graphics[Polygon[{Scaled[{0, 0}], Scaled[{.5, 1}], Scaled[{1, 0}]}], Frame -> True]

Wolfram Language code: Graphics3D[Polygon[{Scaled[{0, 0, .2}], Scaled[{.5, 1, .8}], Scaled[{1, 0, .2}]}], Axes -> True]

Use ImageScaled coordinates in 2D:

Wolfram Language code: Graphics[Polygon[{ImageScaled[{0, 0}], ImageScaled[{.5, 1}], ImageScaled[{1, 0}]}], Frame -> True]

Use Offset coordinates in 2D:

Wolfram Language code: Graphics[Polygon[{Offset[{10, 10}, {0, 0}], Offset[{0, -20}, {.5, 1}], Offset[{-10, 10}, {1, 0}]}], Frame -> True]

Regions (10)

Embedding dimension:

Wolfram Language code: RegionEmbeddingDimension[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

Geometric dimension:

Wolfram Language code: RegionDimension[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

Point membership test:

Wolfram Language code: ℛ = Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}];

Wolfram Language code: {RegionMember[ℛ, {2 / 3, 1 / 3, 2 / 3}], RegionMember[ℛ, {0, 0, 0}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

Area:

Wolfram Language code: ℛ = Polygon[{{1, 0}, {1, 1}, {0, 0}}];

Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: {RegionDistance[ℛ, {3, 4}], RegionDistance[ℛ, {1, 1}]}

Plot it:

Wolfram Language code:

{Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -4, 4}, {y, -4, 4}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: {SignedRegionDistance[ℛ, {3, 4}], SignedRegionDistance[ℛ, {1, 1}]}

Plot it:

Wolfram Language code:

Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point in the region:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: RegionNearest[ℛ, {3, 4}]

Nearest points:

Wolfram Language code:

pts = Table[4{Cos[k 2 π / 25], Sin[k 2π / 25]}, {k, 0., 24}];
nst = RegionNearest[ℛ, #]& /@ pts;

Wolfram Language code:

Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A polygon is bounded:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: BoundedRegionQ[ℛ]

Get its range:

Wolfram Language code: rr = RegionBounds[ℛ]

Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

Integrate over a polygon:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: Integrate[x ^ 2 + y ^ 2, {x, y}∈ℛ]

Optimize over a polygon:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]

Solve equations in a polygon:

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];

Wolfram Language code: Solve[x^2 + y^2 == 4 && {x, y}∈ℛ, {x, y}]

Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[{0, 0}, 2]}, {Red, PointSize[Medium], Point[{x, y} /. %]}}]

Options (7)

VertexColors (2)

Polygon with vertex colors:

Wolfram Language code: Graphics[Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexColors -> {Red, Green, Blue}]]

Specify vertex colors for 3D polygons:

Wolfram Language code: Graphics3D[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

VertexNormals (1)

Compute normal vectors using the cross product of edge vectors:

Wolfram Language code: {p1, p2, p3} = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};

Wolfram Language code: n = Cross[p2 - p1, p3 - p1]

A triangle with normals pointing in the direction {1,-1,1}:

Wolfram Language code: Graphics3D[{Yellow, Polygon[{p1, p2, p3}, VertexNormals -> {n, n, n}]}]

Using different normals will affect shading:

Wolfram Language code: Graphics3D[{Yellow, Polygon[{p1, p2, p3}, VertexNormals -> {-n, n, n}]}]

VertexTextureCoordinates (4)

Texture-mapped polygon:

Wolfram Language code:

Graphics[{Texture[ExampleData[{"TestImage", "Flower"}]], Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexTextureCoordinates -> {{1, 0}, {0.5, 1}, {0, 0}}]}]

Texture mapping with 2D polygons:

Wolfram Language code:

Graphics[{Texture[ExampleData[{"TestImage", "Airplane2"}]], Polygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}]

Texture mapping with 3D polygons:

Wolfram Language code:

Graphics3D[{Texture[ExampleData[{"TestImage", "Airplane2"}]], Polygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, Lighting -> "Neutral"]

Repeat a texture by using non-unified texture coordinate values:

Wolfram Language code:

{Graphics[{Texture[ExampleData[{"TestImage", "Mandrill"}]], Polygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}], Graphics3D[{Texture[ExampleData[{"TestImage", "Mandrill"}]], Polygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}, Lighting -> "Neutral"]}

Texture mapping is preceded by VertexColors:

Wolfram Language code:

Graphics3D[{Texture[[image]], Polygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}, 
	VertexColors -> {Red, Green, Blue, Purple}]}, Lighting -> "Neutral"]

Applications (3)

Define a polygon with vertices:

Wolfram Language code: ngon[p_, q_] := Polygon[Table[{Cos[2Pi k q / p], Sin[2Pi k q / p]}, {k, p}]]

Regular polygons:

Wolfram Language code: Row[Table[Graphics[{EdgeForm[Red], LightRed, ngon[n, 1]}, ImageSize -> 70], {n, 3, 14}]]

Star polygons:

Wolfram Language code:

Row[Reap[Table[Table[If[CoprimeQ[p, q], Sow[Graphics[{EdgeForm[Green], LightGreen, ngon[p, q]}, ImageSize -> 70]]], {q, 2, p / 2}], {p, 5, 12}]][[2, 1]]]

Define the regular hexagon:

Wolfram Language code: h[x_, y_] := Polygon[Table[{Cos[2Pi k / 6] + x, Sin[2Pi k / 6] + y}, {k, 6}]]

Regular hexagonal tiling:

Wolfram Language code: Graphics[{EdgeForm[Opacity[.7]], StandardBlue, Table[h[3i + 3((-1) ^ j + 1) / 4, Sqrt[3] / 2j], {i, 5}, {j, 10}]}]

Get face polygons from PolyhedronData:

Wolfram Language code: p = N[PolyhedronData["TruncatedIcosahedron", "Faces", "Polygon"]];

Shrink each face with respect to the centroid:

Wolfram Language code: shrink[t_, Polygon[x_List, opts___]] := Module[{c = Plus@@x / Length[x]}, Polygon[Map[(c + (1 - t)(# - c))&, x], opts]]

Wolfram Language code:

Animate[Graphics3D[{FaceForm[Yellow, Green], p /. y_Polygon :> shrink[s, y]}, PlotRange -> 2.5], {s, 0, .8}, SaveDefinitions -> True, AnimationRunning -> False, AnimationDirection -> ForwardBackward, DefaultDuration -> 1]

Properties & Relations (4)

GraphicsComplex offers an efficient way to generate a polygon with many shared vertices:

Wolfram Language code: v = {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}};

Wolfram Language code: i = {{1, 2, 5}, {2, 3, 5}, {3, 4, 5}, {4, 1, 5}};

Wolfram Language code: {Graphics3D[{Opacity[.7], GraphicsComplex[v, Polygon[i]]}], Graphics3D[{GraphicsComplex[v, Line[i]]}]}

Applying Normal to the graphics complex produces ordinary polygons:

Wolfram Language code: Normal[GraphicsComplex[v, Polygon[i]]]

Polygon is a generalization of Triangle:

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}}];
Subscript[ℛ, 2] = Triangle[{{0, 0}, {1, 0}, {1, 1}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Polygon is a generalization of Rectangle:

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}];
Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A Simplex with three vertices is a special case of Polygon:

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}}];
Subscript[ℛ, 2] = Simplex[{{0, 0}, {1, 0}, {1, 1}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

In any number of dimensions starting from 2:

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}}];
Subscript[ℛ, 2] = Simplex[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Possible Issues (3)

In 3D, if the vertices are not in a plane, the polygon triangulation can be unpredictable:

Wolfram Language code: Graphics3D[Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}]]

Wolfram Language code: Graphics3D[Polygon[RandomReal[1, {10, 3}]]]

Degenerate polygons are not valid geometric regions:

Wolfram Language code: Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}]

Wolfram Language code: RegionQ[%]

Seams can sometimes appear between individual polygons as a result of antialiasing:

Wolfram Language code: Graphics[{Gray, Table[Polygon[{{x, 0}, {x + 1, 0}, {x + 1, 1}, {x, 1}}], {x, 0, 2}]}]

Using a single polygon object avoids any seams:

Wolfram Language code: Graphics[{Gray, Polygon[Table[{{x, 0}, {x + 1, 0}, {x + 1, 1}, {x, 1}}, {x, 0, 2}]]}]

Neat Examples (3)

Random triangle collections:

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Polygon[RandomReal[1, {3, 2}]]}, {30}]]

Wolfram Language code:

Graphics3D[Table[{EdgeForm[Black], Opacity[.7], Hue[RandomReal[]], Polygon[RandomReal[1, {3, 3}]]}, {30}], Lighting -> "Neutral"]

Digital petals:

Wolfram Language code:

With[{d = 2Pi / 12}, Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], Polygon[{(8 - r){Cos[d(q - 1)], Sin[d(q - 1)]}, (8 - r){Cos[d(q + 1)], Sin[d(q + 1)]}, (10 - r){Cos[d q], Sin[d q]}}]}, {r, 6}, {q, 12}]]]

A rotating star:

Wolfram Language code:

Animate[Graphics[Rotate[Polygon[Table[{Cos[t], Sin[t]}, {t, 0, 4Pi, 4Pi / 5}]], θ, {0, 0}], PlotRange -> 1.2], {θ, 0, 2π}, AnimationRunning -> False]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Polygon

Details and Options

Examples

Basic Examples (2)

Scope (22)

Graphics (12)

Specification (3)

Styling (6)

Coordinates (3)

Regions (10)

Options (7)

VertexColors (2)

VertexNormals (1)

VertexTextureCoordinates (4)

Applications (3)

Properties & Relations (4)

Possible Issues (3)

Neat Examples (3)

Text

CMS

APA

BibTeX

BibLaTeX

Polygon

Details and Options

Examples

Basic Examples (2)

Scope (22)

Graphics (12)

Specification (3)

Styling (6)

Coordinates (3)

Regions (10)

Options (7)

VertexColors (2)

VertexNormals (1)

VertexTextureCoordinates (4)

Applications (3)

Properties & Relations (4)

Possible Issues (3)

Neat Examples (3)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX