Wolfram Language & System Documentation Center

QuartileDeviation

QuartileDeviation[data]

gives the quartile deviation or semi-interquartile range of the elements in data.

QuartileDeviation[data,{{a,b},{c,d}}]

uses the quantile definition specified by parameters a, b, c, d.

QuartileDeviation[dist]

gives the quartile deviation or semi-interquartile range of the distribution dist.

Details

QuartileDeviation is a robust measure of dispersion, which means it is not very sensitive to outliers.
QuartileDeviation[data] is given by , where is given by Quartiles[data]. »

For MatrixQ data, quartile deviation is computed for each column vector with QuartileDeviation[{{x₁,y₁,…},{x₂,y₂,…},…}] equivalent to {QuartileDeviation[{x₁,x₂,…}],QuartileDeviation[{y₁,y₂,…}]}. »

For ArrayQ data, quartile deviation is equivalent to ArrayReduce[QuartileDeviation,data,1]. »

QuartileDeviation[data,{{a,b},{c,d}}] uses computed as Quartiles[data, {{a,b},{c,d}}]. »
Common choices of parameters {{a,b},{c,d}} include:

	{{0,0},{1,0}}	inverse empirical CDF
	{{0,0},{0,1}}	linear interpolation (California method)
	{{1/2,0},{0,0}}	element numbered closest to p n
	{{1/2,0},{0,1}}	linear interpolation (hydrologist method; default)
	{{0,1},{0,1}}	mean‐based estimate (Weibull method)
	{{1,-1},{0,1}}	mode‐based estimate
	{{1/3,1/3},{0,1}}	median‐based estimate
	{{3/8,1/4},{0,1}}	normal distribution estimate

The default choice of parameters is {{1/2,0},{0,1}}. »
The data can have the following additional forms and interpretations:

	Association	the values (the keys are ignored) »
	SparseArray	as an array, equivalent to Normal[data] »
	QuantityArray	quantities as an array »
	WeightedData	based on the underlying EmpiricalDistribution »
	EventData	based on the underlying SurvivalDistribution »
	TimeSeries, TemporalData, …	vector or array of values (the time stamps ignored) »
	Image,Image3D	RGB channel's values or grayscale intensity value »
	Audio	amplitude values of all channels »
	DateObject, TimeObject	list of dates or list of times »

QuartileDeviation[dist] is given by InterquartileRange[dist]/2. »

For a random process proc, the quartile deviation function can be computed for slice distribution at time t, SliceDistribution[proc,t], as [t]=QuartileDeviation[SliceDistribution[proc,t]]. »

Examples

open all close all

Basic Examples (3)

Quartile deviation for a list of exact numbers:

Wolfram Language code: QuartileDeviation[{1, 3, 4, 2, 5, 6}]

Quartile deviation of a list of dates:

Wolfram Language code: QuartileDeviation[{Yesterday, Today, Tomorrow}]

Quartile deviation of a parametric distribution:

Wolfram Language code: QuartileDeviation[ExponentialDistribution[λ]]

Scope (23)

Basic Uses (8)

Exact input yields exact output:

Wolfram Language code: QuartileDeviation[{1, 3, 2, 7}]

Wolfram Language code: QuartileDeviation[{π, E, 2}]//Together

Approximate input yields approximate output:

Wolfram Language code: QuartileDeviation[{1., 3., 2., 7.}]

Wolfram Language code: QuartileDeviation[N[{1, 3, 2, 7}, 30]]

Compute results using other parametrizations:

Wolfram Language code: QuartileDeviation[{-1, 5, 10, 4, 25, 2, 1}]

Wolfram Language code: QuartileDeviation[{-1, 5, 10, 4, 25, 2, 1}, {{0, 0}, {1, 0}}]

Find the quartile deviation for WeightedData:

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: QuartileDeviation[WeightedData[data, weights]]

Find the quartile deviation for EventData:

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: QuartileDeviation[EventData[e, ci]]

Find the quartile deviation for TemporalData:

Wolfram Language code:

s1 = {2, 1, 6, 5, 7, 4};
s2 = {4, 7, 5, 6, 1, 2};
t = {1, 2, 5, 10, 12, 15};

Wolfram Language code: td = TemporalData[{s1, s2}, {t}];

Wolfram Language code: QuartileDeviation[td[10]]

Find the quartile deviation for TimeSeries:

Wolfram Language code:

QuartileDeviation[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]]

The quartile deviation depends only on the values:

Wolfram Language code:

QuartileDeviation[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"]]

Find the quartile deviation for data involving quantities:

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: QuartileDeviation[data]

Array Data (5)

QuartileDeviation for a matrix gives columnwise ranges:

Wolfram Language code: QuartileDeviation[{{3, 5}, {1, 8}, {5, 6}, {7, 8}, {2, 4}}]

Quartile deviation for a tensor works across the first index:

Wolfram Language code: QuartileDeviation[RandomReal[1, {2, 2, 2}]]

Works with large arrays:

Wolfram Language code: QuartileDeviation[RandomReal[1, 10 ^ 7]]

Wolfram Language code: QuartileDeviation[RandomReal[1, {10 ^ 6, 5}]]

When the input is an Association, QuartileDeviation works on its values:

Wolfram Language code:

mat = RandomReal[1, {3, 2}];
assoc = AssociationThread[Range[3], mat]

Wolfram Language code: QuartileDeviation[assoc]

SparseArray data can be used just like dense arrays:

Wolfram Language code: sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j < i :> (i + j) ^ 2}, {100, 10}]

Wolfram Language code: QuartileDeviation[sp]

Find the quartile deviation of a QuantityArray:

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]

Wolfram Language code: QuartileDeviation[data]

Image and Audio Data (2)

Channelwise quartile deviation value of an RGB image:

Wolfram Language code: QuartileDeviation[[image]]

Wolfram Language code: RGBColor[%]

Quartile deviation intensity value of a grayscale image:

Wolfram Language code: QuartileDeviation[[image]]

Quartile deviation amplitude of all amplitude values of all channels:

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: QuartileDeviation[a]

Date and Time (5)

Compute quartile deviation of dates:

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];

Wolfram Language code: DateHistogram[dates]

Wolfram Language code: QuartileDeviation[dates]

Wolfram Language code: UnitConvert[%, "Years"]

Compute the weighted quartile deviation of dates:

Wolfram Language code: dates = RandomDate[4]

Wolfram Language code: weights = {1, 1, 1, 3};

Wolfram Language code: QuartileDeviation[WeightedData[dates, weights]]

Compare to unweighted quartile deviation:

Wolfram Language code: UnitConvert[QuartileDeviation[dates], "Days"]

Compute the quartile deviation of dates given in different calendars:

Wolfram Language code:

dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}

Wolfram Language code: QuartileDeviation[dates]

Wolfram Language code: UnitConvert[%, "Years"]

Compute the quartile deviation of times:

Wolfram Language code: times = RandomTime[3]

Wolfram Language code: QuartileDeviation[times]

Compute the quartile deviation of times with different time zone specifications:

Wolfram Language code: times = {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}

Wolfram Language code: QuartileDeviation[times]

Distributions and Processes (3)

Find the quartile deviation for a parametric distribution:

Wolfram Language code: QuartileDeviation[ExponentialDistribution[μ]]

Quartile deviation for a derived distribution:

Wolfram Language code: QuartileDeviation[TransformedDistribution[x^2, xNormalDistribution[]]]

Data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: QuartileDeviation[HistogramDistribution[data]]

Quartile deviation for a time slice of a random process:

Wolfram Language code: QuartileDeviation[GeometricBrownianMotionProcess[0, 1, 2][1 / 7]]

Applications (4)

Obtain a robust estimate of dispersion when extreme values are present:

Wolfram Language code: QuartileDeviation[{5, 3, 10 ^ 6, 20, 15, 6}]//N

Measures based on the Mean are heavily influenced by extreme values:

Wolfram Language code: StandardDeviation[{5, 3, 10 ^ 6, 20, 15, 6}]//N

Wolfram Language code: MeanDeviation[{5, 3, 10 ^ 6, 20, 15, 6}]//N

Identify periods of high volatility in stock data using a five-year moving quartile deviation:

Wolfram Language code: data = TemporalData[«4»];

Wolfram Language code: smooth = MovingMap[QuartileDeviation, data, {Quantity[5 * 365, "Day"]}];

Wolfram Language code: DateListPlot[smooth]

Compute QuartileDeviation for slices of a collection of paths of a random process:

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

Choose a few slice times:

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: qdev = Map[{#, QuartileDeviation[data[#]]}&, times];

Plot of the quartile deviations for the selected times:

Wolfram Language code: ListPlot[qdev]

Find the quartile deviation of the heights for the children in a class:

Wolfram Language code:

heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 
	        150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];

Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]

Wolfram Language code: (qd = QuartileDeviation[heights])//N

Plot the quartile deviation respective of the median:

Wolfram Language code:

m = Median[heights];
n = Length[heights];
ListPlot[{heights, {{0, m}, {n, m}}, {{0, m - qd}, {n, m - qd}}, {{0, m + qd}, {n, m + qd}}}, Filling -> {1 -> 0, 3 -> {4}}, Joined -> {False, True, True, True}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, PlotLegends -> {"heights", "median", "quartile deviation bands"}, AxesLabel -> Automatic]

Properties & Relations (3)

QuartileDeviation is half the difference of linearly interpolated Quantile values:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: Apply[Subtract, Quantile[data, {3 / 4, 1 / 4}, {{1 / 2, 0}, {0, 1}}]] / 2

Wolfram Language code: QuartileDeviation[data]

QuartileDeviation is half the difference between the first and third quartiles:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code:

qrs = Quartiles[data];
(qrs[[3]] - qrs[[1]]) / 2

Wolfram Language code: QuartileDeviation[data]

InterquartileRange is twice QuartileDeviation:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: InterquartileRange[data]

Wolfram Language code: 2QuartileDeviation[data]

Also true for a distribution:

Wolfram Language code: With[{dist = ChiSquareDistribution[3]}, 2QuartileDeviation[dist] == InterquartileRange[dist]//Simplify]

Possible Issues (2)

QuartileDeviation requires numeric values in data:

Wolfram Language code: QuartileDeviation[{a, b, c}]

The symbolic closed form may exist for some distributions:

Wolfram Language code: QuartileDeviation[NormalDistribution[μ, σ]]

QuartileDeviation is not the difference between the median and the first or the third quantiles:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: qs = Quartiles[data]

Wolfram Language code: qs[[1]] + QuartileDeviation[data] == qs[[2]]

Wolfram Language code: qs[[2]] + QuartileDeviation[data] == qs[[3]]

The difference between the third and the first quantiles is given by InterquartileRange:

Wolfram Language code: qs[[1]] + InterquartileRange[data] == qs[[3]]

Neat Examples (1)

The distribution of QuartileDeviation estimates for 20, 100 and 300 samples:

Wolfram Language code: QuartileDeviation[ExponentialDistribution[0.9]]

Wolfram Language code:

SmoothHistogram[Table[QuartileDeviation[RandomVariate[ExponentialDistribution[0.9], {s, 1000}]], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 1.5}, Automatic}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

QuartileDeviation

Details

Examples

Basic Examples (3)

Scope (23)

Basic Uses (8)

Array Data (5)

Image and Audio Data (2)

Date and Time (5)

Distributions and Processes (3)

Applications (4)

Properties & Relations (3)

Possible Issues (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

QuartileDeviation

Details

Examples

Basic Examples (3)

Scope (23)

Basic Uses (8)

Array Data (5)

Image and Audio Data (2)

Date and Time (5)

Distributions and Processes (3)

Applications (4)

Properties & Relations (3)

Possible Issues (2)

Neat Examples (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX