WOLFRAM

Wolfram Language & System Documentation Center

QuartileSkewness[data]

gives the coefficient of quartile skewness for the elements in list.

QuartileSkewness[data,{{a,b},{c,d}}]

uses the quantile definition specified by parameters a, b, c, d.

QuartileSkewness[dist]

gives the coefficient of quartile skewness for the distribution dist.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Array Data  
Image and Audio Data  
Date and Time  
Distributions and Processes  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

QuartileSkewness

QuartileSkewness[data]

gives the coefficient of quartile skewness for the elements in list.

QuartileSkewness[data,{{a,b},{c,d}}]

uses the quantile definition specified by parameters a, b, c, d.

QuartileSkewness[dist]

gives the coefficient of quartile skewness for the distribution dist.

Details

  • QuartileSkewness[data] is given by , where is given by Quartiles[data].
  • A positive value of quartile skewness indicates the median is closer to the lower quartile than the upper quartile .
  • A negative value of quartile skewness indicates the median is closer to the upper quartile .
  • QuartileSkewness[data,{{a,b},{c,d}}] uses computed as Quartiles[data, {{a,b},{c,d}}]. »
  • Common choices of parameters {{a,b},{c,d}} include:
  • {{0, 0}, {1, 0}}inverse empirical CDF
    {{0, 0}, {0, 1}}linear interpolation (California method)
    {{1/2, 0}, {0, 0}}element numbered closest to p n
    {{1/2, 0}, {0, 1}}linear interpolation (hydrologist method; default)
    {{0, 1}, {0, 1}}mean‐based estimate (Weibull method)
    {{1, -1}, {0, 1}}mode‐based estimate
    {{1/3, 1/3}, {0, 1}}median‐based estimate
    {{3/8, 1/4}, {0, 1}}normal distribution estimate
  • The default choice of parameters is {{1/2,0},{0,1}}. »
  • The data can have the following additional forms and interpretations:
  • Associationthe values (the keys are ignored) »
    SparseArrayas an array, equivalent to Normal[data] »
    QuantityArrayquantities as an array »
    WeightedDatabased on the underlying EmpiricalDistribution »
    EventDatabased on the underlying SurvivalDistribution »
    TimeSeries, TemporalData, …vector or array of values (the time stamps ignored) »
    Image,Image3DRGB channels values or grayscale intensity value »
    Audioamplitude values of all channels »
    DateObject, TimeObjectlist of dates or list of times »

Examples

open all close all

Basic Examples  (3)

Quartile skewness for a list of exact numbers:

Wolfram Language code: QuartileSkewness[{1, 3, 3, 2, 5, 6}]

Quartile skewness of a list of dates:

Wolfram Language code: QuartileSkewness[{Yesterday, Today, Tomorrow}]
Wolfram Language code: QuartileSkewness[{Yesterday, Today, Today + Quantity[2, "Days"]}]

Quartile skewness of a parametric distribution:

Wolfram Language code: QuartileSkewness[ExponentialDistribution[λ]]

Scope  (23)

Basic Uses  (8)

Exact input yields exact output:

Wolfram Language code: QuartileSkewness[{1, 3, 2, 7}]
Wolfram Language code: QuartileSkewness[{π, E, 2}]//Together

Approximate input yields approximate output:

Wolfram Language code: QuartileSkewness[{1., 3., 2., 7.}]
Wolfram Language code: QuartileSkewness[N[{1, 3, 2, 7}, 30]]

Compute results using other parametrizations:

Wolfram Language code: QuartileSkewness[{-1, 5, 10, 4, 25, 2, 1}]
Wolfram Language code: QuartileSkewness[{-1, 5, 10, 4, 25, 2, 1}, {{0, 0}, {1, 0}}]

Find the quartile skewness for WeightedData:

Wolfram Language code: data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3}; weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};
Wolfram Language code: QuartileSkewness[WeightedData[data, weights]]

Find the quartile skewness for EventData:

Wolfram Language code: e = {1.0, 2.1, 3.2, 4.5, 5.7}; ci = {0, 0, 0, 1, 0};
Wolfram Language code: QuartileSkewness[EventData[e, ci]]

Find the quartile skewness for TemporalData:

Wolfram Language code: s1 = {2, 1, 6, 5, 7, 4}; s2 = {4, 7, 5, 6, 1, 2}; t = {1, 2, 5, 10, 12, 15};
Wolfram Language code: td = TemporalData[{s1, s2}, {t}];
Wolfram Language code: QuartileSkewness[td[10]]

Find the quartile skewness of TimeSeries:

Wolfram Language code: QuartileSkewness[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {}}, False, 10.]]

The quartile skewness depends only on the values:

Wolfram Language code: QuartileSkewness[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {}}, False, 10.]["Values"]]

Find the quartile skewness for data involving quantities:

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]
Wolfram Language code: QuartileSkewness[data]

Array Data  (5)

QuartileSkewness for a matrix gives columnwise ranges:

Wolfram Language code: QuartileSkewness[{{3, 5}, {1, 8}, {5, 6}, {7, 8}, {2, 4}}]

QuartileSkewness for a tensor gives columnwise medians at the first level:

Wolfram Language code: QuartileSkewness[{{{3, 4}, {8, 1}}, {{1, 19}, {1, 4}}, {{1, 20}, {1, 4}}}]

Works with large arrays:

Wolfram Language code: QuartileSkewness[RandomReal[1, 10 ^ 7]]
Wolfram Language code: QuartileSkewness[RandomReal[1, {10 ^ 6, 5}]]

When the input is an Association, QuartileSkewness works on its values:

Wolfram Language code: mat = RandomReal[1, {3, 2}];
Wolfram Language code: assoc = AssociationThread[Range[3], mat] QuartileSkewness[assoc]

SparseArray data can be used just like dense arrays:

Wolfram Language code: sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j < i :> (i + j) ^ 2}, {100, 10}]
Wolfram Language code: QuartileSkewness[sp]

Find quartile skewness of a QuantityArray:

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]
Wolfram Language code: QuartileSkewness[data]

Image and Audio Data  (2)

Channel-wise quartile skewness value of an RGB image:

Wolfram Language code: QuartileSkewness[[image]]
Wolfram Language code: RGBColor[%]

Quartile skewness intensity value of a grayscale image:

Wolfram Language code: QuartileSkewness[[image]]

Quartile skewness amplitude of all amplitude values of all channels:

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]
Wolfram Language code: QuartileSkewness[a]

Date and Time  (5)

Compute quartile skewness of dates:

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];
Wolfram Language code: DateHistogram[dates]
Wolfram Language code: QuartileSkewness[dates]

Compute the weighted quartile skewness of dates:

Wolfram Language code: dates = RandomDate[4]
Wolfram Language code: weights = {1, 1, 1, 3};
Wolfram Language code: QuartileSkewness[WeightedData[dates, weights]]

Compare with simple quartile skewness:

Wolfram Language code: QuartileSkewness[dates]

Compute the quartile skewness of dates given in different calendars:

Wolfram Language code: dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}
Wolfram Language code: QuartileSkewness[dates]

Compute the quartile skewness of times:

Wolfram Language code: times = RandomTime[3]
Wolfram Language code: QuartileSkewness[times]

Compute the quartile skewness of times with different time zone specifications:

Wolfram Language code: times = {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}
Wolfram Language code: QuartileSkewness[times]

Distributions and Processes  (3)

Find the quartile skewness for a parametric distribution:

Wolfram Language code: QuartileSkewness[ExponentialDistribution[μ]]

Quartile skewness for a derived distribution:

Wolfram Language code: QuartileSkewness[TransformedDistribution[x^2, xNormalDistribution[]]]

Data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];
Wolfram Language code: QuartileSkewness[HistogramDistribution[data]]

Quartile skewness for a time slice of a random process:

Wolfram Language code: QuartileSkewness[GeometricBrownianMotionProcess[0, 1, 2][1 / 7]]

Applications  (6)

Zero QuartileSkewness indicates the median is equally distant from the remaining quartiles:

Wolfram Language code: 𝒟 = NormalDistribution[];
Wolfram Language code: QuartileSkewness[𝒟]
Wolfram Language code: Differences[Quartiles[𝒟]]//N
Wolfram Language code: {m1, m2, m3} = Quartiles[𝒟]; Plot[PDF[𝒟, x], {x, -3, 3}, Filling -> Axis, Ticks -> {Automatic, None}, Epilog -> {Green, Line[{{m2, 0}, {m2, PDF[𝒟, m2]}}], Directive[Red, Dashed], Line[{{m1, 0}, {m1, PDF[𝒟, m1]}}], Line[{{m3, 0}, {m3, PDF[𝒟, m3]}}]}]

Positive QuartileSkewness indicates that the median is closer to the lower quartile:

Wolfram Language code: 𝒟 = ChiSquareDistribution[2.5];
Wolfram Language code: QuartileSkewness[𝒟]//N
Wolfram Language code: Differences[Quartiles[𝒟]]//N
Wolfram Language code: {m1, m2, m3} = Quartiles[𝒟];Plot[PDF[𝒟, x], {x, 0, 12}, Filling -> Axis, Ticks -> {Automatic, None}, Epilog -> {Green, Line[{{m2, 0}, {m2, PDF[𝒟, m2]}}], Directive[Red, Dashed], Line[{{m1, 0}, {m1, PDF[𝒟, m1]}}], Line[{{m3, 0}, {m3, PDF[𝒟, m3]}}]}]

Negative QuartileSkewness indicates that the median is closer to the upper quartile:

Wolfram Language code: 𝒟 = GumbelDistribution[5, 3];
Wolfram Language code: QuartileSkewness[𝒟]//N
Wolfram Language code: Differences[Quartiles[𝒟]]//N
Wolfram Language code: {m1, m2, m3} = Quartiles[𝒟];Plot[PDF[𝒟, x], {x, 0, 9}, Filling -> Axis, Ticks -> {Automatic, None}, Epilog -> {Green, Line[{{m2, 0}, {m2, PDF[𝒟, m2]}}], Directive[Red, Dashed], Line[{{m1, 0}, {m1, PDF[𝒟, m1]}}], Line[{{m3, 0}, {m3, PDF[𝒟, m3]}}]}]

Obtain a robust estimate of asymmetry when extreme values are present:

Wolfram Language code: QuartileSkewness[{5, 3, 10 ^ 6, 2, 1, 4, 8}]//N

Measures based on the Mean are heavily influenced by extreme values:

Wolfram Language code: Skewness[{5, 3, 10 ^ 6, 2, 1, 4, 8}]//N

This time series contains the number of steps taken daily by a person during a period of five months:

Wolfram Language code: stepdata = TemporalData[TimeSeries, {{{10785, 11753, 7092, 5290, 5022, 7438, 13386, 11195, 12499, 12495, 12004, 11833, 4097, 14270, 10280, 11947, 12699, 15634, 12332, 8399, 4680, 10034, 9173, 5309, 9552, 5605, 13294, 7600, 2417, 0, 1315, 9066, 11624 ... 1, 9618, 21243, 22273, 15869, 17687, 9263, 21162, 14724, 6386}}, {TemporalData`DateSpecification[{2013, 4, 1, 0, 0, 0.}, {2013, 9, 1, 0, 0, 0.}, {1, "Day"}]}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1}}, True, 10.];
Wolfram Language code: DateListPlot[stepdata, Joined -> False, Filling -> 0]

Median number of steps:

Wolfram Language code: Median[stepdata]//Floor

Analyze whether the step distribution is skewed toward the lower or the upper quartile:

Wolfram Language code: QuartileSkewness[stepdata]//N

The histogram of the frequency of daily counts shows that the median is closer to the upper quartile:

Wolfram Language code: highlightbar[{{x0_, x1_}, {y0_, y1_}}, d_, meta___] := {If[x0 ≤ First[meta] < x1, Red, {}], Rectangle[{x0, y0}, {x1, y1}]}
Wolfram Language code: {q1, q2, q3} = Quartiles[stepdata]
Wolfram Language code: Histogram[stepdata -> q2, 25, ChartElementFunction -> highlightbar, Ticks -> {{{q1, "q1", {0, .1}}, {q2, "q2", {0, .1}}, {q3, "q3", {0, .1}}}}]

Find the quartile skewness for the heights of children in a class:

Wolfram Language code: heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];
Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]

Negative quartile skewness indicates that the median is closer to the lower quartile:

Wolfram Language code: QuartileSkewness[heights]//N

Properties & Relations  (3)

QuartileSkewness is a function of linearly interpolated Quantile values:

Wolfram Language code: data = RandomReal[10, 20];
Wolfram Language code: QuartileSkewness[data]
Wolfram Language code: {q1, q2, q3} = Quantile[data, {1 / 4, 1 / 2, 3 / 4}, {{1 / 2, 0}, {0, 1}}]
Wolfram Language code: (q1 - 2q2 + q3) / (q3 - q1)

QuartileSkewness is a function of quartiles:

Wolfram Language code: data = RandomReal[10, 20];
Wolfram Language code: QuartileSkewness[data]
Wolfram Language code: {q1, q2, q3} = Quartiles[data]
Wolfram Language code: (q1 - 2q2 + q3) / (q3 - q1)

QuartileSkewness is a function of the median, first quartile and a dispersion measure:

Wolfram Language code: data = RandomReal[10, 20];
Wolfram Language code: QuartileSkewness[data]
Wolfram Language code: 1 - 2(Median[data] - First[Quartiles[data]]) / InterquartileRange[data]
Wolfram Language code: 1 - (Median[data] - First[Quartiles[data]]) / QuartileDeviation[data]

Possible Issues  (1)

QuartileSkewness requires numeric values:

Wolfram Language code: QuartileSkewness[{a, b, c}]

Neat Examples  (1)

The distribution of QuartileSkewness estimates for 50, 100 and 300 samples:

Wolfram Language code: QuartileSkewness[ChiSquareDistribution[0.65]]
Wolfram Language code: SmoothHistogram[Table[QuartileSkewness[RandomVariate[ChiSquareDistribution[0.65], {s, 1000}]], {s, {50, 100, 300}}], Filling -> Axis, PlotLegends -> {50, 100, 300}, PlotRange -> {{0, 1}, Automatic}]
Wolfram Research (2007), QuartileSkewness, Wolfram Language function, https://reference.wolfram.com/language/ref/QuartileSkewness.html (updated 2024).

Text

Wolfram Research (2007), QuartileSkewness, Wolfram Language function, https://reference.wolfram.com/language/ref/QuartileSkewness.html (updated 2024).

CMS

Wolfram Language. 2007. "QuartileSkewness." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/QuartileSkewness.html.

APA

Wolfram Language. (2007). QuartileSkewness. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QuartileSkewness.html

BibTeX

@misc{reference.wolfram_2026_quartileskewness, author="Wolfram Research", title="{QuartileSkewness}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/QuartileSkewness.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_quartileskewness, organization={Wolfram Research}, title={QuartileSkewness}, year={2024}, url={https://reference.wolfram.com/language/ref/QuartileSkewness.html}, note=[Accessed: 13-June-2026]}