WOLFRAM

Wolfram Language & System Documentation Center

TimeSeriesResample[tseries]

uniformly resamples the time series tseries according to its minimum time increment.

TimeSeriesResample[tseries,rspec]

resamples tseries according to the resampling specification rspec.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Data Types  
Sampling  
Options  
ResamplingMethod  
HolidayCalendar  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

TimeSeriesResample

TimeSeriesResample[tseries]

uniformly resamples the time series tseries according to its minimum time increment.

TimeSeriesResample[tseries,rspec]

resamples tseries according to the resampling specification rspec.

Details and Options

  • TimeSeriesResample is typically used to convert an irregular time series to regular one so that algorithms for regular time series can be used, such as filtering operations. It can also be used to align several time series.
  • Given a time series with timestamps , a resampled time series with timestamps can be generated with values tseries[τi].
  • Possible forms of time series tseries include:
  • TimeSeries[…]continuous time-ordered sampled data
    TemporalData[…]one or more paths composed of time-value pairs
    {{t1,x1},{t2,x2},…}list of time-value pairs
    {x1,x2,…}list of values with implied integer times starting at 0
  • Some basic settings for rspec include:
  • dtuniform times with spacing dt
    {t_(min),t_(max),dt}times t_(min) to t_(max) with spacing dt
    {{t1,t2,…}}explicit times {t1,t2,…}
    daytypeday type specification
  • Possible daytype values include "Weekday", "Weekend", Monday through Sunday, "BeginningOfMonth", "EndOfMonth", "BusinessDay" and "Holiday".
  • If dt is set to Automatic, the minimum time increment in tseries is used.
  • The following settings for rspec are useful if tseries contains multiple paths:
  • "Union"use all times present in tseries
    "Intersection"use times common to all paths
    {"Times",p}use times from path p
  • TimeSeriesResample takes the following options:
  • ResamplingMethod Automaticmethod to use for resampling
    CalendarTypeAutomaticcalendar system to interpret the dates
    HolidayCalendar Automaticholiday calendar schedule for business days
    TimeZoneAutomatictime zone specification for dates

Examples

open all close all

Basic Examples  (2)

Resample a TimeSeries:

Wolfram Language code: ts = TimeSeries[{1.2, 1.8, 1.3, .4, 1.5}, {{1, 2, 3, 4, 7}}]
Wolfram Language code: TimeSeriesResample[ts, .5]
Wolfram Language code: ListPlot[#, Filling -> {2 -> 0}]& /@ {ts, %}

Resample a multi-path TemporalData:

Wolfram Language code: data = RandomFunction[PoissonProcess[.3], {1, 50}, 3]

This data is not uniformly sampled:

Wolfram Language code: ListPlot[data]

Resample using uniform times:

Wolfram Language code: rdata = TimeSeriesResample[data, 1];
Wolfram Language code: ListPlot[rdata]

Scope  (14)

Basic Uses  (3)

Downsample a time series:

Wolfram Language code: data = RandomFunction[PoissonProcess[30], {1, 5}]
Wolfram Language code: ListPlot[data]

Resample with a step of 0.25:

Wolfram Language code: ds = TimeSeriesResample[data, .25]
Wolfram Language code: ListPlot[ds]

Sample multiple paths at the same time:

Wolfram Language code: data = RandomFunction[PoissonProcess[10], {1, 5}, 20]
Wolfram Language code: ListPlot[data]

Resample at a step of 0.1:

Wolfram Language code: ds = TimeSeriesResample[data, 0.01]
Wolfram Language code: ListPlot[ds]

Take a time series of stock prices in March 2023:

Wolfram Language code: ts = FinancialData["SBUX", {"March 2023"}];

Resample at a daily resolution, interpolating holidays and weekends:

Wolfram Language code: tsR = TimeSeriesResample[ts, "Day"]
Wolfram Language code: DateListPlot[#, Joined -> False, Filling -> 0]& /@ {ts, tsR}

Data Types  (6)

Resample a time series in the form of a vector:

Wolfram Language code: data = {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]};

Upsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 1 / 2]//Simplify

Downsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 2]

A time series given as time-value pairs:

Wolfram Language code: data = {{1, Subscript[x, 1]}, {2, Subscript[x, 2]}, {3, Subscript[x, 3]}, {4, Subscript[x, 4]}, {5, Subscript[x, 5]}};

Upsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 1 / 2]//Simplify

Downsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 2]

Resample a TimeSeries:

Wolfram Language code: data = TimeSeries[{{1, Subscript[x, 1]}, {2, Subscript[x, 2]}, {3, Subscript[x, 3]}, {4, Subscript[x, 4]}, {5, Subscript[x, 5]}}]

Upsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 1 / 2]//Normal//Simplify

Downsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 2]//Normal//Simplify

By default, an EventSeries is not interpolated:

Wolfram Language code: data = EventSeries[{{1, Subscript[x, 1]}, {2, Subscript[x, 2]}, {4, Subscript[x, 4]}}]
Wolfram Language code: TimeSeriesResample[data, 1]//Normal

Setting the ResamplingMethod overrides this:

Wolfram Language code: TimeSeriesResample[data, 1, ResamplingMethod -> {"Constant", c}]//Normal

A single path given as TemporalData:

Wolfram Language code: data = TemporalData[{{1, Subscript[x, 1]}, {2, Subscript[x, 2]}, {3, Subscript[x, 3]}, {4, Subscript[x, 4]}, {5, Subscript[x, 5]}}]

Upsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 1 / 2]["Path"]

Downsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 2]["Path"]

Multiple paths given as TemporalData:

Wolfram Language code: data = TemporalData[{{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, {Subscript[y, 1], Subscript[y, 2], Subscript[y, 3], Subscript[y, 4], Subscript[y, 5]}}, {1}]

Upsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, .5]["Paths"]

Downsample by a factor of 2:

Wolfram Language code: TimeSeriesResample[data, 2]["Paths"]

Sampling  (5)

Resample according to the smallest time increment in a TemporalData:

Wolfram Language code: data = RandomFunction[PoissonProcess[3], {1, 100}]
Wolfram Language code: rdata = TimeSeriesResample[data]

The original data was irregular, while the resampled data is regular:

Wolfram Language code: RegularlySampledQ /@ {data, rdata}

Larger step values dt give coarser sampling:

Wolfram Language code: data = RandomFunction[PoissonProcess[3], {1, 100}]
Wolfram Language code: Table[ListPlot[TimeSeriesResample[data, dt], PlotLabel -> dt], {dt, {1, 5, 10}}]

Use a time quantity as a sampling increment for calendar timestamps:

Wolfram Language code: data = FinancialData["APP", "2022"]
Wolfram Language code: TimeSeriesResample[data, Quantity[2, "Months"]]
Wolfram Language code: DateListPlot[{data, %}]

Resample time series with dates:

Wolfram Language code: ts = TimeSeries[Range[20], {DateObject[{2026, 1, 30}], Automatic, "Day"}]

Select business days:

Wolfram Language code: TimeSeriesResample[ts, "BusinessDay"]
Wolfram Language code: DateListPlot[{ts, %}, Joined -> {True, False}, Filling -> {2 -> 0}]

Select weekends:

Wolfram Language code: TimeSeriesResample[ts, "Weekend"]
Wolfram Language code: DayName /@ %["Timestamps"]

Select Wednesdays:

Wolfram Language code: TimeSeriesResample[ts, Wednesday]
Wolfram Language code: %//Normal

Resample multiple paths:

Wolfram Language code: td = TemporalData[{{{1, x1}, {2, x2}, {2.1, x3}, {3, x4}, {4, x5}}, {{1, y1}, {1.5, y2}, {2, y3}, {2.5, y4}, {3, y5}, {3.5, y6}, {5, y7}}}]

Use the union of times:

Wolfram Language code: TimeSeriesResample[td, "Union"]
Wolfram Language code: %["Times"]

The intersection:

Wolfram Language code: TimeSeriesResample[td, "Intersection"]
Wolfram Language code: %["Times"]

Use times from the first path:

Wolfram Language code: TimeSeriesResample[td, {"Times", 1}]
Wolfram Language code: %["Times"]

Options  (4)

ResamplingMethod  (3)

Specify the interpolation order in resampling:

Wolfram Language code: data = TimeSeries[{1, 2, 3, 4}, {{1, 3, 4, 7}}]
Wolfram Language code: TimeSeriesResample[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 2}]//Normal

By default, the method setting for the data is used:

Wolfram Language code: TimeSeriesResample[data]//Normal
Wolfram Language code: data["ResamplingType"]

Setting ResamplingMethod to None gives missing resampled values:

Wolfram Language code: data = TimeSeries[{1, 2, 3, 4}, {{0, 3, 4, 6}}]
Wolfram Language code: TimeSeriesResample[data, 1, ResamplingMethod -> None]//Normal

Resample using a constant value:

Wolfram Language code: data = TimeSeries[{10, 20, 40, 70}, {{.1, .5, .7, .9}}]
Wolfram Language code: TimeSeriesResample[data, ResamplingMethod -> {"Constant", Mean[data]}]//Normal

HolidayCalendar  (1)

Take a time series with calendar timestamps:

Wolfram Language code: data = TemporalData[Range[8], {DateObject[{2025, 4, 17}]}]

Resample on US business days:

Wolfram Language code: TimeSeriesResample[data, "BusinessDay", HolidayCalendar -> "UnitedStates"]
Wolfram Language code: Normal[%]

Resample on business days in Germany:

Wolfram Language code: TimeSeriesResample[data, "BusinessDay", HolidayCalendar -> "Germany"]
Wolfram Language code: Normal[%]

Applications  (5)

Take a time series of daily step counts:

Wolfram Language code: stepdata = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 154, "Endpoints" -> TabularColumn[Association[ "Data" -> {2, {{NumericArray[{15796, 15949}, "Integer32"], {}, None}}, None}, "ElementType" ... {}, None}, "ElementType" -> "Integer64"]], Association["ResamplingMethod" -> "LinearInterpolation", "TimeObservationWindow" -> DateInterval[{{{2013, 4, 1, 0, 0, 0.}, {2013, 9, 1, 0, 0, 0.}}}, "Day", "Gregorian", -6., "UT", Automatic]]];

Select the values for each day of the week:

Wolfram Language code: weekdays = {Monday, Tuesday, Wednesday, Thursday, Friday, Saturday, Sunday}; wk = Map[TimeSeriesResample[stepdata, #]&, weekdays];

Compute the mean number of steps for each day of the week:

Wolfram Language code: avg = Map[Floor[Mean[#]]&, wk];

Visualize the mean steps per day:

Wolfram Language code: BarChart[avg, ...]

Financial information is generated only for business days:

Wolfram Language code: data = FinancialData["SBUX", "Close", {{2013, 12, 1}, {2013, 12, 31}}]

The automatically created time series is not regularly sampled with respect to calendar days:

Wolfram Language code: RegularlySampledQ[data]

Resample according to "BusinessDay" to create a uniformly sampled time series:

Wolfram Language code: ts = TimeSeriesResample[data, "BusinessDay"]
Wolfram Language code: RegularlySampledQ[ts]

The paths are the same:

Wolfram Language code: data["Path"] == ts["Path"]

Financial information is generated only for business days:

Wolfram Language code: data = FinancialData["SBUX", "Close", {{2025, 11, 20}, {2026, 1, 5}}]

There are no changes on the non-business days, hence it can be resampled by day by keeping the value from the left:

Wolfram Language code: TimeSeriesResample[data, ResamplingMethod -> "PreviousElement"]

The plot is flat over the weekends and holidays:

Wolfram Language code: DateListPlot[%]

Use AirPressureData to examine pressure changes due to Hurricane Sandy at Long Island MacArthur Airport:

Wolfram Language code: pressure = AirPressureData["KISP", {DateObject[{2012, 10, 27}], DateObject[{2012, 10, 30}]}]
Wolfram Language code: DateListPlot[pressure, FrameLabel -> Automatic]

The data is not regularly sampled:

Wolfram Language code: RegularlySampledQ[pressure]

To analyze the rate of change, data needs to be resampled into a regularly sampled time series:

Wolfram Language code: res = TimeSeriesResample[pressure, {DateObject[{2012, 10, 27}], Automatic, "Hour"}]
Wolfram Language code: RegularlySampledQ[res]

Plotting each observation disjointly shows the rate of change of the pressure, with larger spacing indicating faster changes:

Wolfram Language code: DateListPlot[res, Joined -> False]

Analyze the monthly temperatures in Champaign during 2014:

Wolfram Language code: ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 365, "Endpoints" -> TabularColumn[Association[ "Data" -> {2, {{{1388534400000, 1419984000000}, {}, None}}, None}, "ElementType" -> "Date"[" ... 7.78, 6.83, -1.39, -3.89, -4.06, -3.17, -0.72, -0.89, 7.78, 6.22, 2.28, 3.28, 8.17, 0.11, -4.44, -2, -10.28}, {}, None}}, None}, "ElementType" -> TypeSpecifier["Quantity"]["NumberExpression", "DegreesCelsius"]]], Association[]];

The raw data comes in one-day increments:

Wolfram Language code: ts["MinimumTimeIncrement"]

Resample by a month:

Wolfram Language code: monthlyTemps = TimeSeriesResample[ts, "Month"]
Wolfram Language code: monthlyTemps["MinimumTimeIncrement"]

Basic descriptive statistics:

Wolfram Language code: Comap[{Min, Mean, Max}, monthlyTemps]

Compare to the original data:

Wolfram Language code: Comap[{Min, Mean, Max}, ts]
Wolfram Language code: DateListPlot[{ts, monthlyTemps}, PlotLegends -> {"daily temperatures", "resampled monthly"}, FrameLabel -> Automatic]

Properties & Relations  (2)

Take a time series:

Wolfram Language code: ts = TimeSeries[{1, -1.4, -0.5, 2.2, 0.6, 3.5}, {0}]

Resampling with spacing smaller than the minimum time increment will add timestamps:

Wolfram Language code: TimeSeriesResample[ts, .5]

Resample with spacing larger than the minimum time increment:

Wolfram Language code: TimeSeriesResample[ts, 1.3]

Specifying the resampling range outside the time domain will extrapolate the time series:

Wolfram Language code: ts = TimeSeries[{1.2, 1.8, -.3, .4, 1.5}, {{1, 2, 3, 4, 7}}]
Wolfram Language code: TimeSeriesResample[ts, {0, 10, .5}]
Wolfram Language code: ListLinePlot[{ts, %}, Filling -> {1 -> 0}]

Possible Issues  (1)

The original timestamps may not be preserved after resampling:

Wolfram Language code: v = {1, 3, 9, 3, 2}; t = {0, .3, 1, 1.3, 2}; ts = TimeSeries[v, {t}]
Wolfram Language code: TimeSeriesResample[ts]["Timestamps"]//Normal
Wolfram Language code: Complement[%, t]
Wolfram Research (2014), TimeSeriesResample, Wolfram Language function, https://reference.wolfram.com/language/ref/TimeSeriesResample.html (updated 2026).

Text

Wolfram Research (2014), TimeSeriesResample, Wolfram Language function, https://reference.wolfram.com/language/ref/TimeSeriesResample.html (updated 2026).

CMS

Wolfram Language. 2014. "TimeSeriesResample." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/TimeSeriesResample.html.

APA

Wolfram Language. (2014). TimeSeriesResample. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TimeSeriesResample.html

BibTeX

@misc{reference.wolfram_2026_timeseriesresample, author="Wolfram Research", title="{TimeSeriesResample}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSeriesResample.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_timeseriesresample, organization={Wolfram Research}, title={TimeSeriesResample}, year={2026}, url={https://reference.wolfram.com/language/ref/TimeSeriesResample.html}, note=[Accessed: 13-June-2026]}