Perimeter
Perimeter[reg]
gives the perimeter of the two-dimensional region reg.
Perimeter[{x1,x2},{s,smin,smax},{t,tmin,tmax}]
gives the perimeter of the parametrized region whose Cartesian coordinates xi are functions of s and t.
Perimeter[{x1,x2},{s,smin,smax},{t,tmin,tmax},chart]
interprets the xi as coordinates in the specified coordinate chart.
Details and Options
- Perimeter is also known as circumference.
- Coordinate charts in the fourth argument of Perimeter can be specified as triples {coordsys,metric,dim} in the same way as in the first argument of CoordinateChartData. The short form in which dim is omitted may be used.
- The following options can be given:
-
AccuracyGoal Infinity digits of absolute accurary sought Assumptions $Assumptions assumptions to make about parameters GenerateConditions Automatic whether to generate conditions on parameters PerformanceGoal $PerformanceGoal aspects of performance to try to optimize PrecisionGoal Automatic digits of precision sought WorkingPrecision Automatic the precision used in internal computations - Perimeter can be used with symbolic regions in GeometricScene.
Examples
open all close allBasic Examples (4)
Perimeter[Disk[]]The perimeter of a 3-4-5 triangle:
Perimeter[SSSTriangle[3, 4, 5]]The perimeter of an annulus with inner radius 1 and outer radius 2:
Perimeter[{r Sin[θ], r Cos[θ]}, {r, 1, 2}, {θ, 0, 2π}]The perimeter of a sector expressed in polar coordinates:
Perimeter[{r, θ}, {r, 0, 1}, {θ, 0, π / 3}, "Polar"]Scope (17)
Special Regions (4)
Perimeter[Rectangle[{Subscript[l, x], Subscript[l, y]}, {Subscript[u, x], Subscript[u, y]}]]Region[Rectangle[{0, 0}, {2, 1}]]Perimeter[Parallelogram[{Subscript[p, x], Subscript[p, y]}, {{Subscript[u, x], Subscript[u, y]}, {Subscript[v, x], Subscript[v, y]}}]]Region[Parallelogram[{0, 0}, {{2, 0}, {1, 2}}]]Perimeter[Simplex[2]]Region[Simplex[2]]The perimeter of a Polygon:
ℛ = Polygon[{{0, 0}, {2, -1}, {1, 0}, {2, 1}}];Region[ℛ]Perimeter[ℛ]Disk:
Perimeter[Disk[{Subscript[c, x], Subscript[c, y]}, r]]Region[Disk[{0, 0}, 1]]Disk can be used as an ellipse:
Perimeter[Disk[{Subscript[c, x], Subscript[c, y]}, {Subscript[r, x], Subscript[r, y]}]]Region[Disk[{0, 0}, {3, 2}]]Formula Regions (4)
The perimeter of a disk represented as an ImplicitRegion:
Perimeter[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]]The perimeter of a disk represented as a ParametricRegion:
Perimeter[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}]]Using a rational parametrization of a disk:
Perimeter[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}]]The perimeter of an ImplicitRegion:
ℛ = ImplicitRegion[x^4 + 3x^2y + 2x^2y^2 - y^3 + y^4 ≤ 0, {x, y}];Perimeter[ℛ]BoundaryDiscretizeRegion[ℛ]Perimeter[%]The perimeter of a ParametricRegion:
ℛ = ParametricRegion[{r Cos[θ]^3, r Sin[θ]^3}, {{r, 0, 1}, {θ, 0, 4π}}];Perimeter[ℛ]BoundaryDiscretizeRegion[ℛ]Perimeter[%]Mesh Regions (3)
The perimeter of a BoundaryMeshRegion:
ConvexHullMesh[RandomReal[1, {10, 2}]]Perimeter[%]The perimeter of a MeshRegion:
DelaunayMesh[RandomReal[1, {10, 2}]]Perimeter[%]The perimeter of a MeshRegion with mixed dimensions:
DiscretizeGraphics[Graphics[{Rectangle[], Circle[], Point[{-1, 1}]}]]Perimeter[%]Derived Regions (2)
The perimeter of a RegionIntersection:
ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];Region[ℛ]Perimeter[ℛ]The perimeter of a TransformedRegion:
ℛ = TransformedRegion[Disk[], ScalingTransform[{a, b}]];Region[ℛ /. {a -> 3, b -> 2}]Perimeter[ℛ]Parametric Formulas (1)
The perimeter of an ellipse with semimajor axes 2 and 1:
Perimeter[{2r Sin[θ], r Cos[θ]}, {r, 0, 1}, {θ, 0, 2Pi}]ParametricPlot[{2r Sin[θ], r Cos[θ]}, {r, 0, 1}, {θ, 0, 2Pi}]The same ellipse in elliptic coordinates:
Perimeter[{r, v}, {r, 0, ArcSech[Sqrt[3] / 2]}, {v, 0, 2Pi}, {{"Elliptic", Sqrt[3]}}]CSG Regions (1)
The perimeter of a linear CSGRegion:
ℛ = CSGRegion["Difference", {Rectangle[{-1, -1}, {1, 1}], Rectangle[{-1 / 2, -1 / 2}]}]Perimeter[ℛ]ℛ = CSGRegion["Difference", {Disk[], Disk[{0, 0}, 1 / 2]}]Perimeter[ℛ]Subdivision Regions (2)
The perimeter of SubdivisionRegion:
ℛ = SubdivisionRegion[Rectangle[]]Perimeter[ℛ]The perimeter of successive subdivision levels converges to that of the limit region:
levels = Table[SubdivisionRegion[Rectangle[], i], {i, 0, 4}]ListPlot[Perimeter /@ levels, ...]Options (2)
Assumptions (1)
WorkingPrecision (1)
Compute the Perimeter using machine arithmetic:
Perimeter[ImplicitRegion[x ^ 6 + y ^ 6 - x y ≤ 1, {x, y}], WorkingPrecision -> MachinePrecision]In some cases, the exact answer cannot be computed:
Perimeter[ImplicitRegion[x ^ 6 + y ^ 6 - x y ≤ 1, {x, y}]]Applications (4)
A farmer has a 40.5-acre plot of land in the shape of a regular pentagon. How much fence is needed to enclose the plot?
Model the plot as a RegularPolygon of unknown radius:
plot = RegularPolygon[r, 5];Determine the radius given the area:
Area[plot]First[Solve[% == Quantity[40.5, "Acres"] && r > 0, r]]Perimeter[plot] /. %Find the perimeter of a MengerMesh in [0,1]×[0,1]:
MengerMesh[3]Perimeter[%]Find the general formula for the perimeter of a MengerMesh of order n:
Table[Perimeter[MengerMesh[n]], {n, 1, 5}]FindSequenceFunction[Rationalize[%], n]The perimeter tends to infinity even though the regions stay bounded inside [0,1]×[0,1]:
Limit[%, n -> ∞]Compute the orbital circumference of Mars:
{Subscript[r, min], Subscript[r, max]} = Entity["Planet", "Mars"][{"SemiminorAxis", "SemimajorAxis"}]Perimeter[Ellipsoid[{0, 0}, {Subscript[r, min], Subscript[r, max]}]]UnitConvert[Entity["Planet", "Mars"]["OrbitCircumference"], "AstronomicalUnit"]The coastline paradox states a country's border is fractal in nature and hence its perimeter is unbounded [more info].
Obtain the polygon representing the United Kingdom:
poly = Entity["Country", "UnitedKingdom"]["Polygon"] /. GeoPosition -> Identity;
pts = Reverse /@ poly[[1, 1]];The perimeter of the United Kingdom with various amounts of sampling points along its border:
Table[
With[{reg = Polygon[pts[[1 ;; -1 ;; n]]]},
Column[{
Graphics[reg],
Row[{"Perimeter: ", Perimeter[reg]}],
Row[{"VertexCount: ", Length[First[reg]]}]
}, Alignment -> Center]
],
{n, {10, 5, 1}}
]Properties & Relations (3)
For regions with only full-dimensional components, the perimeter is the ArcLength of its boundary:
ℛ = Disk[];Perimeter[ℛ]ArcLength[RegionBoundary[ℛ]]Regions with nonzero perimeter will have nonzero Area:
ℛ = Disk[];Perimeter[ℛ]Area[ℛ]Find the perimeter of lamina entities:
reg = Entity["Lamina", "Salinon"];EntityValue[reg, "Image"]Use EntityValue to find the perimeter of a salinon with outer radius 5 and inner radius 1:
EntityValue[reg, "Perimeter"][5, 1]Find the perimeter through the region's implicit representation:
EntityValue[reg, "ImplicitRegion"][5, 1]Perimeter[%]Possible Issues (1)
Neat Examples (3)
Create a gallery of perimeters of special regions:
regs = {Disk[{x, y}, r], Ellipsoid[{0, 0}, {Subscript[r, x], Subscript[r, y]}], Rectangle[{0, 0}, {l, w}], RegularPolygon[r, n], Parallelogram[{0, 0}, {{Subscript[u, 1], Subscript[u, 2]}, {Subscript[v, 1], Subscript[v, 2]}}], Simplex[{{0, 0}, {Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}], StadiumShape[{{0, 0}, {x, y}}, r]};Grid[Join[{Text /@ {"Region", "Perimeter"}}, Transpose[{Inactivate[#, List]& /@ regs, Perimeter /@ regs}]], Background -> {None, {{None, GrayLevel[.9]}}, {{1, 1} -> Hue[.6, .4, 1], {1, 2} -> Hue[.6, .4, 1]}}, BaseStyle -> {FontFamily -> Times, FontSize -> 12}, Dividers -> All, FrameStyle -> Hue[.6, .4, .8], Spacings -> {2, 1}]//TraditionalFormThe perimeter of an implicitly described smiley:
ℛ = ImplicitRegion[(((x^2 == 2 y && -3 ≤ x ≤ 3) || (x^2 + y^2 ≤ 16 && (16 x^2/49) + (1/4) (y + 1)^2 > 1) || x^2 + (y + (1/2))^2 ≤ 4) && (x + (3/2))^2 + (y - 1)^2 > (9/16) && (x - (3/2))^2 + (y - 1)^2 > (9/16)) || (x + (7/5))^2 + (y - (11/10))^2 ≤ (1/16) || (x - (8/5))^2 + (y - (11/10))^2 ≤ (1/16) || 28323 + 60 x (92 + 15 x) + 900 y^2 == 8464 y || 28323 + 60 x (-92 + 15 x) + 900 y^2 == 8464 y, {x, y}];Region[ℛ]Perimeter[ℛ]The perimeter of a self-intersecting polygon:
pts = RandomReal[{-1, 1}, {50, 2}];Region[Polygon[pts]]Perimeter[Polygon[pts]]Text
Wolfram Research (2017), Perimeter, Wolfram Language function, https://reference.wolfram.com/language/ref/Perimeter.html (updated 2019).
CMS
Wolfram Language. 2017. "Perimeter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Perimeter.html.
APA
Wolfram Language. (2017). Perimeter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Perimeter.html