WOLFRAM

Wolfram Language & System Documentation Center

AugmentedPolyhedron[poly]

gives the augmented polyhedron poly by replacing each face by a pyramid.

AugmentedPolyhedron[poly,h]

gives the augmented polyhedron with a pyramid of height h.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Polyhedron Operations  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

AugmentedPolyhedron

AugmentedPolyhedron[poly]

gives the augmented polyhedron poly by replacing each face by a pyramid.

AugmentedPolyhedron[poly,h]

gives the augmented polyhedron with a pyramid of height h.

Details and Options

Examples

open all close all

Basic Examples  (2)

Augmented polyhedron of a dodecahedron:

Wolfram Language code: AugmentedPolyhedron[Dodecahedron[]]
Wolfram Language code: Graphics3D[%]

Find the augmented polyhedron of the space shuttle:

Wolfram Language code: 𝒫 = AugmentedPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]];

Visualization:

Wolfram Language code: Graphics3D[𝒫, Boxed -> False]

Scope  (4)

AugmentedPolyhedron works on polyhedra:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: AugmentedPolyhedron[𝒫]
Wolfram Language code: Graphics3D[%]

AugmentedPolyhedron of Platonic solids includes Tetrahedron:

Wolfram Language code: AugmentedPolyhedron[Tetrahedron[1]]

Cube:

Wolfram Language code: AugmentedPolyhedron[Cube[1]]

Dodecahedron:

Wolfram Language code: AugmentedPolyhedron[Dodecahedron[1]]
Wolfram Language code: Graphics3D[%]

Octahedron:

Wolfram Language code: AugmentedPolyhedron[Octahedron[1]]

Icosahedron:

Wolfram Language code: AugmentedPolyhedron[Icosahedron[1]]

Support polyhedron meshes:

Wolfram Language code: 𝒫 = ExampleData[{"Geometry3D", "SpaceShuttle"}, "BoundaryMeshRegion"]
Wolfram Language code: AugmentedPolyhedron[𝒫]
Wolfram Language code: Graphics3D[%]

Augment the polyhedron by different heights:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: Table[Graphics3D[AugmentedPolyhedron[𝒫, h]], {h, {0.1, 0.2, 0.3, 0.4}}]

Applications  (4)

Basic Applications  (3)

Gallery of Platonic solids and their augmented polyhedra:

Wolfram Language code: Grid[Table[{Graphics3D[f[1], Boxed -> False], [image], Graphics3D[AugmentedPolyhedron[f[1]], Boxed -> False]}, {f, {Tetrahedron, Cube, Octahedron, Dodecahedron, Icosahedron}}]]

Gallery of Archimedean solids and their augmented polyhedra:

Wolfram Language code: Multicolumn[Table[Row[{Graphics3D[f, Boxed -> False, ImageSize -> 50], [image], Graphics3D[AugmentedPolyhedron[f], Boxed -> False, ImageSize -> 50]}], {f, PolyhedronData["Archimedean", "Polyhedron"]}], 2, Spacings -> 3]

Augmented compounds of Platonic solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], AugmentedPolyhedron[f[1]], f[1]}, Boxed -> False], {f, {Tetrahedron, Cube, Dodecahedron}}]

Archimedean solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], f, AugmentedPolyhedron[f]}, Boxed -> False], {f, PolyhedronData["Archimedean", "Polyhedron"]}]

Polyhedron Operations  (1)

Use AugmentedPolyhedron to compute the polyhedron operations such as zip operation:

Wolfram Language code: zip[poly_] := DualPolyhedron[AugmentedPolyhedron[poly]]
Wolfram Language code: zip[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Properties & Relations  (1)

The augmented simple polyhedron is simple:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: SimplePolyhedronQ[#]& /@ {𝒫, AugmentedPolyhedron[𝒫]}

Possible Issues  (2)

AugmentedPolyhedron only supports simple polyhedra:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 0}, {2, 0, 0}, {1, 1, 0}, {1, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}, {5, 6, 7}, {5, 6, 8}, {6, 7, 8}, {5, 7, 8}}];
Wolfram Language code: SimplePolyhedronQ[𝒫]
Wolfram Language code: AugmentedPolyhedron[𝒫]

AugmentedPolyhedron can return degenerate polyhedra:

Wolfram Language code: AugmentedPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]]
Wolfram Language code: RegionQ[%]
Wolfram Research (2019), AugmentedPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/AugmentedPolyhedron.html.

Text

Wolfram Research (2019), AugmentedPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/AugmentedPolyhedron.html.

CMS

Wolfram Language. 2019. "AugmentedPolyhedron." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AugmentedPolyhedron.html.

APA

Wolfram Language. (2019). AugmentedPolyhedron. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AugmentedPolyhedron.html

BibTeX

@misc{reference.wolfram_2026_augmentedpolyhedron, author="Wolfram Research", title="{AugmentedPolyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/AugmentedPolyhedron.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_augmentedpolyhedron, organization={Wolfram Research}, title={AugmentedPolyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/AugmentedPolyhedron.html}, note=[Accessed: 12-June-2026]}