WOLFRAM

Wolfram Language & System Documentation Center

TruncatedPolyhedron[poly]

gives the truncated polyhedron of poly by truncating all vertices.

TruncatedPolyhedron[poly,l]

truncates the polyhedron poly by a length ratio l at its vertices.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Polyhedron Operations  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

TruncatedPolyhedron

TruncatedPolyhedron[poly]

gives the truncated polyhedron of poly by truncating all vertices.

TruncatedPolyhedron[poly,l]

truncates the polyhedron poly by a length ratio l at its vertices.

Details and Options

Examples

open all close all

Basic Examples  (2)

Truncated polyhedron of a dodecahedron:

Wolfram Language code: TruncatedPolyhedron[Dodecahedron[]]
Wolfram Language code: Graphics3D[%]

Find the truncated polyhedron of the Space Shuttle:

Wolfram Language code: 𝒫 = TruncatedPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]];

Visualization:

Wolfram Language code: Graphics3D[𝒫, Boxed -> False]

Scope  (4)

TruncatedPolyhedron works on polyhedra:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: TruncatedPolyhedron[𝒫]
Wolfram Language code: Graphics3D[%]

TruncatedPolyhedron of Platonic solids includes Tetrahedron:

Wolfram Language code: TruncatedPolyhedron[Tetrahedron[1]]

Cube:

Wolfram Language code: TruncatedPolyhedron[Cube[1]]
Wolfram Language code: Graphics3D[%]

Dodecahedron:

Wolfram Language code: TruncatedPolyhedron[Dodecahedron[1]]

Octahedron:

Wolfram Language code: TruncatedPolyhedron[Octahedron[1]]

Icosahedron:

Wolfram Language code: TruncatedPolyhedron[Icosahedron[1]]

Support polyhedron meshes:

Wolfram Language code: 𝒫 = ExampleData[{"Geometry3D", "SpaceShuttle"}, "BoundaryMeshRegion"]
Wolfram Language code: TruncatedPolyhedron[𝒫]
Wolfram Language code: Graphics3D[%]

Truncate the polyhedron by different length ratios:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: Table[Graphics3D[TruncatedPolyhedron[𝒫, ratio]], {ratio, {0.1, 0.2, 0.3, 0.4}}]

Applications  (9)

Basic Applications  (3)

Gallery of Platonic solids and their truncated polyhedra:

Wolfram Language code: Grid[Table[{Graphics3D[f[1], Boxed -> False], [image], Graphics3D[TruncatedPolyhedron[f[1]], Boxed -> False]}, {f, {Tetrahedron, Cube, Octahedron, Dodecahedron, Icosahedron}}]]

Gallery of Archimedean solids and their truncated polyhedra:

Wolfram Language code: Multicolumn[Table[Row[{Graphics3D[f, Boxed -> False, ImageSize -> 50], [image], Graphics3D[TruncatedPolyhedron[f], Boxed -> False, ImageSize -> 50]}], {f, PolyhedronData["Archimedean", "Polyhedron"]}], 2, Spacings -> 3]

Truncated compounds of Platonic solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], TruncatedPolyhedron[f[1]], f[1]}, Boxed -> False], {f, {Tetrahedron, Cube, Dodecahedron}}]

Archimedean solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], f, TruncatedPolyhedron[f]}, Boxed -> False], {f, PolyhedronData["Archimedean", "Polyhedron"]}]

Polyhedron Operations  (6)

Use TruncatedPolyhedron to compute the polyhedron operations, such as ambo operation:

Wolfram Language code: ambo[poly_] := TruncatedPolyhedron[poly, 0.5]
Wolfram Language code: ambo[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Needle operation:

Wolfram Language code: needle[poly_] := DualPolyhedron[TruncatedPolyhedron[poly]]
Wolfram Language code: needle[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Join operation:

Wolfram Language code: join[poly_] := DualPolyhedron[TruncatedPolyhedron[poly, 0.5]]
Wolfram Language code: join[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Bevel operation:

Wolfram Language code: bevel[poly_] := TruncatedPolyhedron[TruncatedPolyhedron[poly, 0.5]]
Wolfram Language code: bevel[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Expand operation:

Wolfram Language code: expand[poly_] := TruncatedPolyhedron[TruncatedPolyhedron[poly, 0.5], 0.5]
Wolfram Language code: expand[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Ortho operation:

Wolfram Language code: ortho[poly_] := DualPolyhedron[TruncatedPolyhedron[TruncatedPolyhedron[poly, 0.5], 0.5]]
Wolfram Language code: ortho[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Properties & Relations  (2)

The truncated simple polyhedron is simple:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: SimplePolyhedronQ[#]& /@ {𝒫, TruncatedPolyhedron[𝒫]}

The truncated convex polyhedron is convex:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: ConvexPolyhedronQ[#]& /@ {𝒫, TruncatedPolyhedron[𝒫]}

Possible Issues  (2)

TruncatedPolyhedron only supports simple polyhedra:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 0}, {2, 0, 0}, {1, 1, 0}, {1, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}, {5, 6, 7}, {5, 6, 8}, {6, 7, 8}, {5, 7, 8}}];
Wolfram Language code: SimplePolyhedronQ[𝒫]
Wolfram Language code: TruncatedPolyhedron[𝒫]

TruncatedPolyhedron can return degenerate polyhedra:

Wolfram Language code: TruncatedPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]]
Wolfram Language code: RegionQ[%]

Neat Examples  (1)

Truncate a tetrahedron:

Wolfram Language code: Graphics3D /@ NestList[TruncatedPolyhedron[#, 1 / 2]&, Tetrahedron[], 4]
Wolfram Research (2019), TruncatedPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/TruncatedPolyhedron.html.

Text

Wolfram Research (2019), TruncatedPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/TruncatedPolyhedron.html.

CMS

Wolfram Language. 2019. "TruncatedPolyhedron." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TruncatedPolyhedron.html.

APA

Wolfram Language. (2019). TruncatedPolyhedron. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TruncatedPolyhedron.html

BibTeX

@misc{reference.wolfram_2026_truncatedpolyhedron, author="Wolfram Research", title="{TruncatedPolyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/TruncatedPolyhedron.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_truncatedpolyhedron, organization={Wolfram Research}, title={TruncatedPolyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/TruncatedPolyhedron.html}, note=[Accessed: 13-June-2026]}