WOLFRAM

Wolfram Language & System Documentation Center

BeveledPolyhedron[poly]

gives the beveled polyhedron of poly, by beveling each edge.

BeveledPolyhedron[poly,l]

bevels the polyhedron poly by a length ratio l at its edges.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Polyhedron Operations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

BeveledPolyhedron

BeveledPolyhedron[poly]

gives the beveled polyhedron of poly, by beveling each edge.

BeveledPolyhedron[poly,l]

bevels the polyhedron poly by a length ratio l at its edges.

Details and Options

Examples

open all close all

Basic Examples  (2)

Beveled polyhedron of a dodecahedron:

Wolfram Language code: BeveledPolyhedron[Dodecahedron[]]
Wolfram Language code: Graphics3D[%]

Find the beveled polyhedron of the space shuttle:

Wolfram Language code: 𝒫 = BeveledPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]];

Visualization:

Wolfram Language code: Graphics3D[𝒫, Boxed -> False]

Scope  (4)

BeveledPolyhedron works on polyhedrons:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: BeveledPolyhedron[𝒫]
Wolfram Language code: Graphics3D[%]

BeveledPolyhedron of Platonic solids includes Tetrahedron:

Wolfram Language code: BeveledPolyhedron[Tetrahedron[1]]

Cube:

Wolfram Language code: BeveledPolyhedron[Cube[1]]
Wolfram Language code: Graphics3D[%]

Dodecahedron:

Wolfram Language code: BeveledPolyhedron[Dodecahedron[1]]

Octahedron:

Wolfram Language code: TruncatedPolyhedron[Octahedron[1]]

Icosahedron:

Wolfram Language code: BeveledPolyhedron[Icosahedron[1]]

Support polyhedron meshes:

Wolfram Language code: 𝒫 = ExampleData[{"Geometry3D", "SpaceShuttle"}, "BoundaryMeshRegion"]
Wolfram Language code: BeveledPolyhedron[𝒫]
Wolfram Language code: Graphics3D[%]

Bevel the polyhedron by different length ratios:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: Table[Graphics3D[BeveledPolyhedron[𝒫, ratio]], {ratio, {0.1, 0.2, 0.3, 0.4}}]

Applications  (5)

Basic Applications  (3)

Gallery of Platonic solids and their beveled polyhedrons:

Wolfram Language code: Grid[Table[{Graphics3D[f[1], Boxed -> False], [image], Graphics3D[BeveledPolyhedron[f[1]], Boxed -> False]}, {f, {Tetrahedron, Cube, Octahedron, Dodecahedron, Icosahedron}}]]

Gallery of Archimedean solids and their beveled polyhedrons:

Wolfram Language code: Multicolumn[Table[Row[{Graphics3D[f, Boxed -> False, ImageSize -> 50], [image], Graphics3D[BeveledPolyhedron[f], Boxed -> False, ImageSize -> 50]}], {f, PolyhedronData["Archimedean", "Polyhedron"]}], 2, Spacings -> 3]

Beveled compounds of Platonic solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], BeveledPolyhedron[f[1]], f[1]}, Boxed -> False], {f, {Tetrahedron, Cube, Dodecahedron}}]

Archimedean solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], f, BeveledPolyhedron[f]}, Boxed -> False], {f, PolyhedronData["Archimedean", "Polyhedron"]}]

Polyhedron Operations  (2)

Use BeveledPolyhedron to compute the polyhedron operations, such as meta-operation:

Wolfram Language code: meta[poly_] := DualPolyhedron[BeveledPolyhedron[poly]]
Wolfram Language code: meta[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

BeveledPolyhedron can be computed by TruncatedPolyhedron:

Wolfram Language code: bevel[poly_] := TruncatedPolyhedron[TruncatedPolyhedron[poly, 0.5]]
Wolfram Language code: bevel[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Possible Issues  (2)

BeveledPolyhedron only supports simple polyhedrons:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 0}, {2, 0, 0}, {1, 1, 0}, {1, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}, {5, 6, 7}, {5, 6, 8}, {6, 7, 8}, {5, 7, 8}}];
Wolfram Language code: SimplePolyhedronQ[𝒫]
Wolfram Language code: BeveledPolyhedron[𝒫]

BeveledPolyhedron can return degenerate polyhedra:

Wolfram Language code: BeveledPolyhedron[Polyhedron[{{-1, 0, 0}, {-1/2, -1/2, -(1/Sqrt[2])}, {-1/2, -1/2, 1/Sqrt[2]}, {-1/2, 1/2, -(1/Sqrt[2])}, {-1/2, 1/2, 1/Sqrt[2]}, {0, -1, 0}, {0, 1, 0}, {1/2, -1/2, -(1/Sqrt[2])}, {1/2, -1/2, 1/Sqrt[2]}, {1/2, 1/2, -(1/Sqrt[2])}, {1/2, 1/2, 1/Sqrt[2]}, {1, 0, 0}}, {{4, 10, 8, 2}, {3, 9, 11, 5}, {9, 6, 8, 12}, {3, 1, 2, 6}, {5, 7, 4, 1}, {11, 12, 10, 7}, {12, 11, 9}, {3, 5, 1}, {6, 9, 3}, {5, 11, 7}, {8, 10, 12}, {1, 4, 2}, {2, 8, 6}, {7, 10, 4}}]]
Wolfram Language code: RegionQ[%]
Wolfram Research (2019), BeveledPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/BeveledPolyhedron.html.

Text

Wolfram Research (2019), BeveledPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/BeveledPolyhedron.html.

CMS

Wolfram Language. 2019. "BeveledPolyhedron." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BeveledPolyhedron.html.

APA

Wolfram Language. (2019). BeveledPolyhedron. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BeveledPolyhedron.html

BibTeX

@misc{reference.wolfram_2026_beveledpolyhedron, author="Wolfram Research", title="{BeveledPolyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/BeveledPolyhedron.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_beveledpolyhedron, organization={Wolfram Research}, title={BeveledPolyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/BeveledPolyhedron.html}, note=[Accessed: 13-June-2026]}