WOLFRAM

Wolfram Language & System Documentation Center

DualPolyhedron[poly]

gives the dual polyhedron of the polyhedron poly.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Polyhedron Operations  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

DualPolyhedron

DualPolyhedron[poly]

gives the dual polyhedron of the polyhedron poly.

Details and Options

Examples

open all close all

Basic Examples  (2)

Dual polyhedron of a dodecahedron:

Wolfram Language code: DualPolyhedron[Dodecahedron[]]
Wolfram Language code: Graphics3D[%]

Find the dual of the space shuttle:

Wolfram Language code: 𝒫 = DualPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]];

Visualization:

Wolfram Language code: Graphics3D[𝒫, Boxed -> False]

Scope  (3)

DualPolyhedron works on polyhedrons:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: DualPolyhedron[𝒫]
Wolfram Language code: Graphics3D[{Opacity[0.2], 𝒫, %}]

DualPolyhedron of Platonic solids includes Tetrahedron:

Wolfram Language code: DualPolyhedron[Tetrahedron[1]]

Cube:

Wolfram Language code: DualPolyhedron[Cube[1]]
Wolfram Language code: Graphics3D[%]

Dodecahedron:

Wolfram Language code: DualPolyhedron[Dodecahedron[1]]

Octahedron:

Wolfram Language code: DualPolyhedron[Octahedron[1]]

Icosahedron:

Wolfram Language code: DualPolyhedron[Icosahedron[1]]

Special polyhedron representations:

Wolfram Language code: 𝒫 = ExampleData[{"Geometry3D", "SpaceShuttle"}, "BoundaryMeshRegion"]
Wolfram Language code: DualPolyhedron[𝒫]
Wolfram Language code: Graphics3D[{Opacity[0.2], 𝒫, %}]

Applications  (9)

Basic Applications  (3)

Create a gallery of Platonic solids and their duals:

Wolfram Language code: Grid[Table[{Graphics3D[f[1], Boxed -> False], [image], Graphics3D[DualPolyhedron[f[1]], Boxed -> False]}, {f, {Tetrahedron, Cube, Octahedron, Dodecahedron, Icosahedron}}]]

Create a gallery of Archimedean solids and their duals:

Wolfram Language code: Multicolumn[Table[Row[{Graphics3D[f, Boxed -> False, ImageSize -> 50], [image], Graphics3D[DualPolyhedron[f], Boxed -> False, ImageSize -> 50]}], {f, PolyhedronData["Archimedean", "Polyhedron"]}], 2, Spacings -> 3]

Dual compounds of Platonic solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], DualPolyhedron[f[1]], f[1]}, Boxed -> False], {f, {Tetrahedron, Cube, Dodecahedron}}]

Archimedean solids:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], f, DualPolyhedron[f]}, Boxed -> False], {f, PolyhedronData["Archimedean", "Polyhedron"]}]

Polyhedron Operations  (6)

Use DualPolyhedron to compute the polyhedron operations, such as needle operation:

Wolfram Language code: needle[poly_] := DualPolyhedron[TruncatedPolyhedron[poly]]
Wolfram Language code: needle[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Meta-operation:

Wolfram Language code: meta[poly_] := DualPolyhedron[BeveledPolyhedron[poly]]
Wolfram Language code: meta[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Join operation:

Wolfram Language code: join[poly_] := DualPolyhedron[TruncatedPolyhedron[poly]]
Wolfram Language code: join[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Zip operation:

Wolfram Language code: zip[poly_] := DualPolyhedron[AugmentedPolyhedron[poly]]
Wolfram Language code: zip[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Ortho operation:

Wolfram Language code: ortho[poly_] := DualPolyhedron[TruncatedPolyhedron[TruncatedPolyhedron[poly]]]
Wolfram Language code: ortho[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Expand operation:

Wolfram Language code: expand[poly_] := DualPolyhedron[TruncatedPolyhedron[TruncatedPolyhedron[poly, 0.5]]]
Wolfram Language code: expand[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Properties & Relations  (4)

The dual of a simple polyhedron is simple:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: SimplePolyhedronQ[#]& /@ {𝒫, DualPolyhedron[𝒫]}

The dual of a Platonic solid polyhedron is Platonic solid:

Wolfram Language code: 𝒫 = Cube[1];
Wolfram Language code: DualPolyhedron[𝒫]
Wolfram Language code: {Graphics3D[𝒫], Graphics3D[%]}

The dual of its dual is the original polyhedron:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: DualPolyhedron[DualPolyhedron[𝒫]];
Wolfram Language code: {Graphics3D[𝒫], Graphics3D[%]}

Pyramids are self-dual polyhedrons:

Wolfram Language code: DualPolyhedron[Pyramid[]]
Wolfram Language code: Graphics3D[%]

Possible Issues  (3)

DualPolyhedron only supports simple polyhedra:

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 0}, {2, 0, 0}, {1, 1, 0}, {1, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}, {5, 6, 7}, {5, 6, 8}, {6, 7, 8}, {5, 7, 8}}];
Wolfram Language code: SimplePolyhedronQ[𝒫]
Wolfram Language code: DualPolyhedron[𝒫]

The dual of a polyhedron is topologically dual:

Wolfram Language code: dual = DualPolyhedron[Tetrahedron[1]]

The dual of a dual:

Wolfram Language code: DualPolyhedron[dual]

DualPolyhedron can return degenerate polyhedra:

Wolfram Language code: DualPolyhedron[Polyhedron[{{-1, 0, 0}, {-1/2, -1/2, -(1/Sqrt[2])}, {-1/2, -1/2, 1/Sqrt[2]}, {-1/2, 1/2, -(1/Sqrt[2])}, {-1/2, 1/2, 1/Sqrt[2]}, {0, -1, 0}, {0, 1, 0}, {1/2, -1/2, -(1/Sqrt[2])}, {1/2, -1/2, 1/Sqrt[2]}, {1/2, 1/2, -(1/Sqrt[2])}, {1/2, 1/2, 1/Sqrt[2]}, {1, 0, 0}}, {{4, 10, 8, 2}, {3, 9, 11, 5}, {9, 6, 8, 12}, {3, 1, 2, 6}, {5, 7, 4, 1}, {11, 12, 10, 7}, {12, 11, 9}, {3, 5, 1}, {6, 9, 3}, {5, 11, 7}, {8, 10, 12}, {1, 4, 2}, {2, 8, 6}, {7, 10, 4}}]]
Wolfram Language code: RegionQ[%]
Wolfram Research (2019), DualPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/DualPolyhedron.html.

Text

Wolfram Research (2019), DualPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/DualPolyhedron.html.

CMS

Wolfram Language. 2019. "DualPolyhedron." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DualPolyhedron.html.

APA

Wolfram Language. (2019). DualPolyhedron. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DualPolyhedron.html

BibTeX

@misc{reference.wolfram_2026_dualpolyhedron, author="Wolfram Research", title="{DualPolyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DualPolyhedron.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dualpolyhedron, organization={Wolfram Research}, title={DualPolyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/DualPolyhedron.html}, note=[Accessed: 13-June-2026]}