WOLFRAM

Wolfram Language & System Documentation Center

ReconstructionMesh[{pt1,pt2,…}]

reconstructs a mesh from a set of points pt1,pt2,….

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Specifications  
Options  
Method  
ProgressReporting  
VertexNormals  
Applications  
Curve Reconstruction  
Surface Reconstruction  
Solid Reconstruction  
Properties & Relations  
Interactive Examples  
See Also
Related Guides
History
Cite this Page

ReconstructionMesh

ReconstructionMesh[{pt1,pt2,…}]

reconstructs a mesh from a set of points pt1,pt2,….

Details and Options

Examples

open all close all

Basic Examples  (3)

Reconstruct a curve in 2D:

Wolfram Language code: ReconstructionMesh[CirclePoints[16]]

Reconstruct a solid in 2D:

Wolfram Language code: pts = RandomPoint[Annulus[], 500];
Wolfram Language code: ReconstructionMesh[pts]

Reconstruct a surface in 3D:

Wolfram Language code: pts = RandomPoint[ResourceData["Stanford Bunny"], 10000];
Wolfram Language code: ReconstructionMesh[pts]

Scope  (7)

Basic Uses  (5)

Reconstruct a curve in 2D:

Wolfram Language code: pts = Table[(2 + 2 / 3.5Sin[3 t]) * RotationMatrix[t].{1, 0}, {t, 0, 2 Pi, 0.15}];
Wolfram Language code: ReconstructionMesh[pts]

Reconstruct a solid in 2D:

Wolfram Language code: pts = RandomPoint[Annulus[], 500];
Wolfram Language code: ReconstructionMesh[pts]

Reconstruct a curve in 3D:

Wolfram Language code: pts = Table[{t, Cos[t], Sin[t]}, {t, 0, 8Pi, Pi / 20}];
Wolfram Language code: ReconstructionMesh[pts]

Reconstruct a surface in 3D:

Wolfram Language code: pts = RandomPoint[DiscretizeRegion[Torus[]], 1000];
Wolfram Language code: ReconstructionMesh[pts]
Wolfram Language code: RegionDimension[%]

Reconstruct a solid in 3D:

Wolfram Language code: pts = RandomPoint[CapsuleShape[], 1000];
Wolfram Language code: ReconstructionMesh[pts]
Wolfram Language code: RegionDimension[%]

Specifications  (2)

ReconstructionMesh works on coordinates:

Wolfram Language code: coords = RandomPoint[ResourceData["Cow"], 10000];
Wolfram Language code: ReconstructionMesh[coords]

It is equivalent to points without normals:

Wolfram Language code: ReconstructionMesh[Point[coords]]

ReconstructionMesh works on oriented points:

Wolfram Language code: coords = ExampleData[{"Geometry3D", "Cow"}, "VertexData"]; normals = ExampleData[{"Geometry3D", "Cow"}, "VertexNormals"];
Wolfram Language code: ReconstructionMesh[Point[coords, VertexNormals -> normals]]

Options  (5)

Method  (3)

Use the "Crust" method to reconstruct curves:

Wolfram Language code: pts = Table[{t, Cos[t]}, {t, 0, 4Pi, Pi / 10}]; ReconstructionMesh[pts, Method -> "Crust"]
Wolfram Language code: pts = Table[{t, Cos[t], Sin[t]}, {t, 0, 4Pi, Pi / 20}]; ReconstructionMesh[pts, Method -> "Crust"]

Use the "AlphaShape" method to reconstruct curves:

Wolfram Language code: pts = Table[{t, Cos[t], Sin[t]}, {t, 0, 4Pi, Pi / 20}]; ReconstructionMesh[pts, Method -> "AlphaShape"]

Surfaces:

Wolfram Language code: pts = SpherePoints[80]; ReconstructionMesh[pts, Method -> "AlphaShape"]

Solids:

Wolfram Language code: pts = RandomPoint[Ball[], 1000]; ReconstructionMesh[pts, Method -> "AlphaShape"]

Set an explicit value for :

Wolfram Language code: ReconstructionMesh[pts, Method -> {"AlphaShape", "Alpha" -> 1.0}]

Use the "Poisson" method to reconstruct surfaces in 3D when the normals for the points are known:

Wolfram Language code: pts = ExampleData[{"Geometry3D", "Beethoven"}, "VertexData"]; nls = ExampleData[{"Geometry3D", "Beethoven"}, "VertexNormals"]; ReconstructionMesh[Point[pts, VertexNormals -> nls], Method -> "Poisson"]

If no normals are provided, ReconstructionMesh will estimate them before reconstruction:

Wolfram Language code: ReconstructionMesh[pts, Method -> "Poisson"]

ProgressReporting  (1)

By default, ReconstructionMesh does report progress:

Wolfram Language code: pts = RandomPoint[ResourceData["Cow"], 10000]; ReconstructionMesh[pts]
Wolfram Language code: [image]

With the setting ProgressReporting False, ReconstructionMesh does not show the progress of the computation:

Wolfram Language code: ReconstructionMesh[pts, ProgressReporting -> False]

VertexNormals  (1)

Specify coordinate orientations using VertexNormals:

Wolfram Language code: coords = ExampleData[{"Geometry3D", "Beethoven"}, "VertexData"]; normals = ExampleData[{"Geometry3D", "Beethoven"}, "VertexNormals"]; ReconstructionMesh[coords, VertexNormals -> normals]

This is equivalent to passing oriented points:

Wolfram Language code: ReconstructionMesh[Point[coords, VertexNormals -> normals]]
Wolfram Language code: RegionEqual[%, %%]

Applications  (4)

Curve Reconstruction  (1)

ReconstructionMesh can reconstruct 1D curves in 2D:

Wolfram Language code: pts = Table[{t, Cos[t]}, {t, 0, 4Pi, Pi / 20}]; ReconstructionMesh[pts]

3D:

Wolfram Language code: pts = Table[{t, Cos[t], Sin[t]}, {t, 0, 8Pi, Pi / 20}]; ReconstructionMesh[pts]

Surface Reconstruction  (2)

ReconstructionMesh can reconstruct surfaces in 1D:

Wolfram Language code: pts = RandomPoint[RegionUnion[Ball[{-2}], Ball[{2}]], 30]; ReconstructionMesh[pts]
Wolfram Language code: RegionMeasure[%]

2D:

Wolfram Language code: pts = RandomPoint[RegionBoundary[Annulus[]], 500]; ReconstructionMesh[pts]
Wolfram Language code: ArcLength[%]

3D:

Wolfram Language code: pts = RandomPoint[RegionBoundary[DiscretizeRegion[Torus[]]], 1000]; ReconstructionMesh[pts]
Wolfram Language code: Area[%]

ReconstructionMesh can reconstruct 3D models:

Wolfram Language code: ReconstructionMesh[RandomPoint[ResourceData[#], 10000]]& /@ {"Stanford Bunny", "Cow", "Horse"}

Solid Reconstruction  (1)

ReconstructionMesh can reconstruct solids in 2D:

Wolfram Language code: pts = RandomPoint[Annulus[], 500]; ReconstructionMesh[pts]
Wolfram Language code: Area[%]

3D:

Wolfram Language code: pts = RandomPoint[CapsuleShape[], 1000]; ReconstructionMesh[pts]
Wolfram Language code: Volume[%]

Properties & Relations  (7)

ConcaveHullMesh reconstructs meshes using alpha shapes:

Wolfram Language code: coords = RandomPoint[Annulus[], 500];
Wolfram Language code: ConcaveHullMesh[coords]

This is similar to calling ReconstructionMesh with the Method set to "AlphaShape":

Wolfram Language code: ReconstructionMesh[coords, Method -> "AlphaShape"]

GradientFittedMesh reconstructs meshes using Poisson surface reconstruction:

Wolfram Language code: coords = RandomPoint[DiscretizeRegion[Torus[]], 1000];
Wolfram Language code: GradientFittedMesh[coords]

This is similar to calling ReconstructionMesh with the Method set to "Poisson":

Wolfram Language code: ReconstructionMesh[coords, Method -> "Poisson"]

FindCurvePath can be used to reconstruct curves from points:

Wolfram Language code: coords = RandomPoint[Circle[], 30];
Wolfram Language code: path = FindCurvePath[coords]; MeshRegion[coords, Line[path]]

This is similar to calling ReconstructionMesh with the Method set to "Crust":

Wolfram Language code: ReconstructionMesh[coords, Method -> "Crust"]

ListSurfacePlot3D can also be used to reconstruct 3D surfaces from points:

Wolfram Language code: coords = MeshCoordinates[ResourceData["Stanford Bunny"]];
Wolfram Language code: ListSurfacePlot3D[coords, MaxPlotPoints -> 50]

ConvexHullMesh can reconstruct convex meshes:

Wolfram Language code: coords = CirclePoints[100];
Wolfram Language code: ConvexHullMesh[coords]

Use DelaunayMesh to include the interior simplices:

Wolfram Language code: DelaunayMesh[coords]

RegionFit fits a geometric model to a set of points:

Wolfram Language code: coords = RandomPoint[Circle[{1, 2}, 3], 5];
Wolfram Language code: RegionFit[coords, "Circle"]

EstimatedPointNormals can estimate normals for use in reconstruction:

Wolfram Language code: coords = RandomPoint[ResourceData["Cow"], 10000];
Wolfram Language code: normals = EstimatedPointNormals[coords]//Shallow
Wolfram Language code: ReconstructionMesh[Point[coords, VertexNormals -> %]]

Interactive Examples  (1)

Create an interactive example with draggable points to view the reconstructed mesh in real time:

Wolfram Language code: DynamicModule[{p = CirclePoints[10]}, LocatorPane[Dynamic[p], Graphics[{FaceForm[LightGray], EdgeForm[Black], Dynamic[ReconstructionMesh[p] /. _EmptyRegion -> {}]}, PlotRange -> 1.2]]]
Wolfram Research (2022), ReconstructionMesh, Wolfram Language function, https://reference.wolfram.com/language/ref/ReconstructionMesh.html.

Text

Wolfram Research (2022), ReconstructionMesh, Wolfram Language function, https://reference.wolfram.com/language/ref/ReconstructionMesh.html.

CMS

Wolfram Language. 2022. "ReconstructionMesh." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ReconstructionMesh.html.

APA

Wolfram Language. (2022). ReconstructionMesh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ReconstructionMesh.html

BibTeX

@misc{reference.wolfram_2026_reconstructionmesh, author="Wolfram Research", title="{ReconstructionMesh}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ReconstructionMesh.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_reconstructionmesh, organization={Wolfram Research}, title={ReconstructionMesh}, year={2022}, url={https://reference.wolfram.com/language/ref/ReconstructionMesh.html}, note=[Accessed: 12-June-2026]}