Wolfram Language & System Documentation Center

AnatomyPlot3D

AnatomyPlot3D[primitives,options]

represents a three-dimensional graphical image that works with anatomical entities as well as standard 3D graphics primitives and directives.

Details and Options

Using AnatomyPlot3D requires internet connectivity.
AnatomyPlot3D allows standalone anatomical entities to represent annotated 3D primitives, substituting the "Graphics3D" property of the entity.
Entities that appear inside of primitives act as coordinate specifiers, substituting the "RegionCentroid" of the entity.
AnatomyPlot3D is displayed in StandardForm as a graphical image.
PlotRange can be specified using anatomical entities, substituting the "RegionBounds" of the entity.
Coordinate values of the human and animal anatomical entities correspond to an average adult human male and average adult animal, respectively, measured in millimeters.
AnatomyPlot3D uses the same directives as Graphics3D, with the following addition:
AnatomyStyling[directives] anatomical entities are to be drawn using the specified graphics directives
AnatomyPlot3D has the same options as Graphics3D, with the following additions and changes: [List of all options]

Boxed	False	whether to draw the bounding box
Lighting	"Neutral"	simulated light sources to use
PlotTheme	$PlotTheme	overall theme for the plot
AnatomySkinStyle	None	style to be applied to automatically included nearest skin subparts
ViewPoint	{0,-1.9,0}	viewing position

Anatomy base themes include:

		"Business"	a bold, modern design
		"Detailed"	identify size using labeled axes and grid lines
		"Marketing"	elegant design suitable for marketing needs
		"Minimal"	flat shading with minimal detail
		"Monochrome"	single-color design
		"Scientific"	individually colored parts identified by tooltip
		"Web"	bright shading and color suitable for web
		"Classic"	historical dark coloring

Anatomy feature themes include:

		"Transparent"	gray transparency
		{"Transparent",color}	color transparency
		"Vintage"	sepia-toned illustrative design
		"XRay"	gray transparency with bone emphasis

Anatomy color feature themes include individually colored parts identified by tooltip:

		"BoldColor"	12 bold colors
		"CoolColor"	8 cool colors
		"DarkColor"	8 dark colors
		"NeonColor"	8 neon colors
		"PastelColor"	8 pastel colors
		"RoyalColor"	8 royal colors
		"VibrantColor"	10 vibrant colors
		"WarmColor"	8 warm colors

List of all options

AlignmentPoint	Center	the default point in the graphic to align with
AnatomySkinStyle	None	style to be applied to automatically included nearest skin subparts
AspectRatio	Automatic	ratio of height to width
Axes	False	whether to draw axes
AxesEdge	Automatic	on which edges to put axes
AxesLabel	None	axes labels
AxesOrigin	Automatic	where axes should cross
AxesStyle	{}	graphics directives to specify the style for axes
Background	None	background color for the plot
BaselinePosition	Automatic	how to align with a surrounding text baseline
BaseStyle	{}	base style specifications for the graphic
Boxed	False	whether to draw the bounding box
BoxRatios	Automatic	bounding 3D box ratios
BoxStyle	{}	style specifications for the box
ClipPlanes	None	clipping planes
ClipPlanesStyle	Automatic	style specifications for clipping planes
ContentSelectable	Automatic	whether to allow contents to be selected
ControllerLinking	False	when to link to external rotation controllers
ControllerPath	Automatic	what external controllers to try to use
Epilog	{}	2D graphics primitives to be rendered after the main plot
FaceGrids	None	grid lines to draw on the bounding box
FaceGridsStyle	{}	style specifications for face grids
FormatType	TraditionalForm	default format type for text
ImageMargins	0.	the margins to leave around the graphic
ImagePadding	All	what extra padding to allow for labels, etc.
ImageSize	Automatic	absolute size at which to render the graphic
LabelStyle	{}	style specifications for labels
Lighting	"Neutral"	simulated light sources to use
Method	Automatic	details of 3D graphics methods to use
PlotLabel	None	a label for the plot
PlotRange	All	range of values to include
PlotRangePadding	Automatic	how much to pad the range of values
PlotRegion	Automatic	final display region to be filled
PlotTheme	$PlotTheme	overall theme for the plot
PreserveImageOptions	Automatic	whether to preserve image options when displaying new versions of the same graphic
Prolog	{}	2D graphics primitives to be rendered before the main plot
RotationAction	"Fit"	how to render after interactive rotation
SphericalRegion	Automatic	whether to make the circumscribing sphere fit in the final display area
Ticks	Automatic	specification for ticks
TicksStyle	{}	style specification for ticks
TouchscreenAutoZoom	False	whether to zoom to fullscreen when activated on a touchscreen
ViewAngle	Automatic	angle of the field of view
ViewCenter	Automatic	point to display at the center
ViewMatrix	Automatic	explicit transformation matrix
ViewPoint	{0,-1.9,0}	viewing position
ViewProjection	Automatic	projection method for rendering objects distant from the viewer
ViewRange	All	range of viewing distances to include
ViewVector	Automatic	position and direction of a simulated camera
ViewVertical	{0,0,1}	direction to make vertical

Examples

open all close all

Basic Examples (5)

Display basic entities:

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftFemur"]]

Wolfram Language code: AnatomyPlot3D[Entity["AnimalAnatomicalStructure", "LeftFemur::CanisLupusFamiliaris::4t62p"]]

Display complex entities:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "RightHand"]}]

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}]

Coloring and styling of entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftClavicle"], StandardRed, Entity["AnatomicalStructure", "LeftScapula"]}]

Use a theme for stylized effects:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "RightHand"]}, PlotTheme -> "Business"]

Use entities in arbitrary graphics primitives:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"], AbsoluteThickness[2], StandardBlue, Arrow[{Entity["AnatomicalStructure", "DistalPhalanxOfLeftThumb"], Entity["AnatomicalStructure", "DistalPhalanxOfLeftIndexFinger"]}]}]

Scope (11)

Coloring and Styling (3)

You can color all entities one style:

Wolfram Language code: AnatomyPlot3D[{StandardBlue, Entity["AnatomicalStructure", "LeftArm"]}]

The following example shows that “intermediate” structures like biceps brachii can be handled, even though they are made of smaller atomic components:

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> StandardGreen|>], Entity["AnatomicalStructure", "LeftArm"]}]

The following example shows that you can also style the lower-level atomic structures separately:

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "LongHeadOfLeftBicepsBrachii"] -> StandardGreen, Entity["AnatomicalStructure", "ShortHeadOfLeftBicepsBrachii"] -> StandardBlue|>], Entity["AnatomicalStructure", "LeftArm"]}]

The following example shows that you can color all objects one color, with the exception of muscles (or any other entity), which are a different color:

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|_ -> StandardRed, Entity["AnatomicalStructure", "Muscle"] -> StandardBlue|>], Entity["AnatomicalStructure", "LeftArm"]}]

With no arguments, AnatomyStyling behaves like FaceForm[]:

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[], EdgeForm[StandardBlue], Entity["AnatomicalStructure", "SeventhCervicalVertebra"]}]

AnatomyStyling["Natural"] restores styles to their original state, ignoring earlier directives:

Wolfram Language code:

AnatomyPlot3D[{StandardRed, Entity["AnatomicalStructure", "SeventhCervicalVertebra"], AnatomyStyling["Natural"], Entity["AnatomicalStructure", "FirstThoracicVertebra"]}]

Primitives (6)

Drawing a line involving entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"], Entity["AnatomicalStructure", "RightHand"], StandardRed, Line[{Entity["AnatomicalStructure", "LeftHand"], Entity["AnatomicalStructure", "RightHand"]}]}]

Drawing an arrow involving entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "SkeletonOfRightHand"], StandardRed, Arrow[{{-175, -130, 758}, Entity["AnatomicalStructure", "RightFifthMetacarpalBone"]}, 5], Text["5th metacarpal", {-175, -130, 758}, {0, -1}]}]

Drawing a cuboid involving entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "HipBone"], Entity["AnatomicalStructure", "Scapula"], Opacity[.5, StandardRed], Cuboid[Entity["AnatomicalStructure", "LeftHipBone"], Entity["AnatomicalStructure", "RightScapula"]]}]

Drawing a sphere involving entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "SkeletonOfLeftUpperLimb"], Opacity[.5], Sphere[Entity["AnatomicalStructure", "LeftElbow"], 50]}]

Drawing a cylinder involving entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHumerus"], Entity["AnatomicalStructure", "LeftHand"], Opacity[.3], Cylinder[{Entity["AnatomicalStructure", "LeftElbow"], Entity["AnatomicalStructure", "LeftWrist"]}, 20]}]

Drawing a tube involving entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftClavicle"], Entity["AnatomicalStructure", "LeftScapula"], Entity["AnatomicalStructure", "LeftHand"], StandardRed, Tube[{Entity["AnatomicalStructure", "LeftShoulder"], Entity["AnatomicalStructure", "LeftElbow"], Entity["AnatomicalStructure", "LeftWrist"]}, 10]}]

Labeling Subparts (1)

Label subparts using text:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "SetOfCervicalVertebrae"]}] /. Annotation[x_, y_] :> {x, LightDarkSwitched[Black, White], Text[y["Name"], y["Entity"]["RegionCentroid"] + {45, 0, 0}, {-1, 0}]}

Cutting Layers (1)

Apply a clipping plane to an anatomical structure:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "Aorta"], ClipPlanes -> {InfinitePlane[{{-3, -123, 1226}, {17, -143, 1226}, {-3, -143, 1206}}]}, Entity["AnatomicalStructure", "Heart"]}, PlotRange -> Entity["AnatomicalStructure", "Heart"]]

Apply multiple clipping planes to an anatomical structure:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"], ClipPlanesStyle -> {Directive[Opacity[.3], StandardRed], Directive[Opacity[.3], StandardBlue]}, ClipPlanes -> {InfinitePlane[{{273 - 20, -146, 725}, {273 - 20, -146 - 20, 725}, {273, -146 - 20, 725}}], InfinitePlane[{{273 + 20, -146 - 20, 735}, {273 + 20, -146, 735 - 20}, {273, -146 - 20, 735 - 20}}]}, Entity["AnatomicalStructure", "SkinOfLeftHand"]}, Boxed -> True, Axes -> True]

Options (29)

AnatomySkinStyle (3)

Automatically include the nearest skin subpart for anatomical structure entities:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftFemur"], Entity["AnatomicalStructure", "RightFemur"]}, AnatomySkinStyle -> Automatic]

The default styling can be overridden:

Wolfram Language code:

AnatomyPlot3D[{StandardRed, Entity["AnatomicalStructure", "PituitaryGland"]}, AnatomySkinStyle -> Directive[StandardBlue, Opacity[.3]], ViewPoint -> Left]

The default behavior is to not include any skin subparts:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftFemur"]}, AnatomySkinStyle -> None]

Axes (3)

By default, Axes is not drawn for AnatomyPlot3D:

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}]

Use AxesTrue to draw axes:

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True]

Turn each axis on individually:

Wolfram Language code:

{AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, PlotLabel -> "X axis", Axes -> {True, False, False}], AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, PlotLabel -> "Y axis", Axes -> {False, True, False}], AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, PlotLabel -> "Z axis", Axes -> {False, False, True}]}

AxesLabel (3)

No axis labels are drawn by default:

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True]

Place a label on the axis:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True, AxesLabel -> z]

Specify axis labels:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True, AxesLabel -> {x, y, z}]

AxesOrigin (2)

The position of the axes is determined automatically:

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True]

Specify an explicit origin for the axes:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True, AxesOrigin -> {0, 0, -100}]

AxesStyle (4)

Change the style for the axes:

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> StandardRed]

Specify the style of each axis:

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> {Directive[Thick, StandardRed], Directive[Thick, StandardBlue], Directive[Thick, StandardGreen]}]

Use different styles for the ticks and the axes:

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> StandardBlue, TicksStyle -> StandardRed]

Use different styles for the labels and the axes:

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> StandardPurple, LabelStyle -> StandardRed]

Method (2)

Tooltips are enabled by default, but they can be disabled by using "Tooltips":

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftIndexFinger"], Method -> {"Tooltips" -> False}]

Tooltips are disabled by default for some PlotTheme settings, but they can be enabled using "Tooltips":

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftIndexFinger"], PlotTheme -> "Minimal", Method -> {"Tooltips" -> True}]

By default, some structures may have white space around them:

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftFoot"]]

White space around these 3D structures can be minimized using "ShrinkWrap":

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftFoot"], Method -> {"ShrinkWrap" -> True}]

PlotRange (1)

Restrict the PlotRange to a specific entity with a padding of 50 mm:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftFemur"], Entity["AnatomicalStructure", "LeftTibia"], Entity["AnatomicalStructure", "LeftFibula"], Entity["AnatomicalStructure", "LeftPatella"]}, PlotRange -> Entity["AnatomicalStructure", "LeftPatella"], PlotRangePadding -> 50]

PlotTheme (2)

Classic textbook illustration:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic"]

Identify subparts by tooltip and individual color:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Scientific"]

Illustrate with flat shading and minimal detail:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Minimal"]

Historical sepia-toned illustration:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Vintage"]

Transparent appearance with emphasis on the bones similar to an x‐ray:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "XRay"]

Highlight bones by combining the default bone color with the transparent theme:

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|EntityClass["AnatomicalStructure", "Bones"] -> "Natural"|>], Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> {"Transparent", Hue[.58]}]

SphericalRegion (1)

By default, the rendered scene is centered at the center of the bounding box:

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "RightFoot"]]

SphericalRegion can be used to recenter the scene around a specific scene element and constrain the view to the element's bounding sphere:

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "RightFoot"], SphericalRegion -> Entity["AnatomicalStructure", "RightThirdMetatarsalBone"]]

Ticks (4)

Ticks are placed automatically in each plot:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True]

Use TicksNone to not draw any tick marks:

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> None]

Place tick marks at specific positions:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{220, 250, 300}, {-100, -120, -150}, {650, 700, 800}}]

Draw tick marks at the specified positions with the specified labels:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{{220, a}, {250, b}, {300, c}}, {{-100, d}, {-120, e}, {-150, f}}, {{650, g}, {700, h}, {800, i}}}]

TicksStyle (4)

Specify overall ticks style, including the tick labels:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, TicksStyle -> Directive[Bold, StandardRed]]

Specify tick style for each of the axes:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, TicksStyle -> {Directive[StandardPurple, Bold], Directive[Bold, StandardRed], Directive[Bold, StandardBlue]}]

Specify tick marks with scaled lengths:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{{220, a, .1}, {250, b, .1}, {300, c, .1}}, {{-100, d, .2}, {-120, e, .2}, {-150, f, .2}}, {{650, g, .15}, {700, h, .15}, {800, i, .15}}}]

Customize each tick with position, length, labeling and styling:

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{{220, a, .1, Directive[StandardRed]}, {250, b, .1, Directive[StandardRed]}, {300, c, .1, Directive[StandardRed]}}, {{-100, d, .2, Directive[StandardBlue, Thick]}, {-120, e, .2, Directive[StandardBlue, Thick]}, {-150, f, .2, Directive[StandardBlue, Thick]}}, {{650, g, .15, Directive[StandardBlue]}, {700, h, .15, Directive[StandardBlue]}, {800, i, .15, Directive[StandardBlue]}}}]

Applications (1)

A more automated approach to labeling subparts can be obtained by making use of region properties of the anatomical structures:

Wolfram Language code:

anatomyCallouts[entities_, callouts_List] := Module[{scene, pr, sc, sr, cr}, 
	pr = PlotRange /. AbsoluteOptions[scene = AnatomyPlot3D[{entities}], PlotRange];{sc, sr} = {Mean /@ pr, Norm[Subtract@@@pr] / 2};
	cr = Rule@@@AnatomyData[callouts, {"Name", "RegionCentroid"}];
	Show[scene, Graphics3D[{AbsoluteThickness[2], StandardRed, Line[{#[[2]], sr Normalize[(#[[2]] - sc)] + sc}]& /@ cr, Black, Inset[Style[#[[1]], Bold, 16], 1.1sr Normalize[(#[[2]] - sc)] + sc, Background -> GrayLevel[.95]]& /@ cr}], ImageSize -> {500, 400}]]

Wolfram Language code:

anatomyCallouts[{Entity["AnatomicalStructure", "Skull"]}, {Entity["AnatomicalStructure", "FrontalBone"], Entity["AnatomicalStructure", "OccipitalBone"], Entity["AnatomicalStructure", "RightTemporalBone"], Entity["AnatomicalStructure", "RightParietalBone"], Entity["AnatomicalStructure", "LeftParietalBone"], Entity["AnatomicalStructure", "LeftTemporalBone"]}]

Properties & Relations (1)

The models used with AnatomyPlot3D are the same ones obtained from the "Graphics3D" property used in EntityValue:

Wolfram Language code: model = Entity["AnatomicalStructure", "HipBone"]["Graphics3D"]

The structure of the models includes an Annotation for each subpart that can be useful for labeling and other reference keeping:

Wolfram Language code: Cases[model, _Annotation, ∞] /. Annotation[body_, ann_] :> Inactive[Annotation][Graphics3D[body], ann]

Neat Examples (4)

Use Overlay to place anatomical structures over a skin silhouette:

Wolfram Language code:

Block[{opts = {PlotRange -> Entity["AnatomicalStructure", "Skin"], ViewAngle -> 14°, ViewCenter -> {.5, 0, .7}}}, Overlay[{AnatomyPlot3D[{AnatomyStyling[{Directive[Lighting -> {{"Ambient", White}}, GrayLevel[.3]]}], Entity["AnatomicalStructure", "Skin"]}, Background -> GrayLevel[.2], opts], AnatomyPlot3D[{Entity["AnatomicalStructure", "AlimentarySystem"]}, opts]}]]

Control Opacity when locating subparts within a transparent structure:

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|_ -> Opacity[.15], Entity["AnatomicalStructure", "TricuspidValve"] -> White|>], Entity["AnatomicalStructure", "Heart"]}, PlotTheme -> {"Transparent", StandardRed}]

Apply Rotate to anatomical structures:

Wolfram Language code:

Manipulate[AnatomyPlot3D[{Entity["AnatomicalStructure", "Neurocranium"], Entity["AnatomicalStructure", "ZygomaticBone"], Entity["AnatomicalStructure", "SphenoidBone"], Entity["AnatomicalStructure", "NasalBone"], Entity["AnatomicalStructure", "Maxilla"], Entity["AnatomicalStructure", "MaxillaryDentition"], Rotate[{Entity["AnatomicalStructure", "Mandible"], Entity["AnatomicalStructure", "MandibularDentition"]}, Dynamic[t Degree], {1, 0, 0}, {0.33, -106., 1470.}]}, SphericalRegion -> True, PlotRange -> Entity["AnatomicalStructure", "Skull"], PlotRangePadding -> 20], {t, 0, 20}, SynchronousUpdating -> False]

Apply ClipPlanes to specific objects in the scene:

Wolfram Language code:

Manipulate[
	AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftUpperLimb"], ClipPlanes -> Dynamic[{InfinitePlane[{{0, -300, z}, {300, -300, z + 200}, {200, 0, z}}]}], Entity["AnatomicalStructure", "SkinOfLeftUpperLimb"]}], 
	{z, 400, 1400}, SynchronousUpdating -> False
	]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

AnatomyPlot3D

Details and Options

List of all options

Examples

Basic Examples (5)

Scope (11)

Coloring and Styling (3)

Primitives (6)

Labeling Subparts (1)

Cutting Layers (1)

Options (29)

AnatomySkinStyle (3)

Axes (3)

AxesLabel (3)

AxesOrigin (2)

AxesStyle (4)

Method (2)

PlotRange (1)

PlotTheme (2)

SphericalRegion (1)

Ticks (4)

TicksStyle (4)

Applications (1)

Properties & Relations (1)

Neat Examples (4)

Text

CMS

APA

BibTeX

BibLaTeX

AnatomyPlot3D

Details and Options

List of all options

Examples

Basic Examples (5)

Scope (11)

Coloring and Styling (3)

Primitives (6)

Labeling Subparts (1)

Cutting Layers (1)

Options (29)

AnatomySkinStyle (3)

Axes (3)

AxesLabel (3)

AxesOrigin (2)

AxesStyle (4)

Method (2)

PlotRange (1)

PlotTheme (2)

SphericalRegion (1)

Ticks (4)

TicksStyle (4)

Applications (1)

Properties & Relations (1)

Neat Examples (4)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX