Wolfram Language & System Documentation Center

MaterialShading

is a three-dimensional graphics directive specifying that surfaces that follow are to be drawn with the material "material" appearance.

MaterialShading[{"material",col}]

uses the specified color col as the base color.

MaterialShading[parm₁val₁,parm₂val₂,…]

uses the specified parameters parms.

Details

MaterialShading is also known as physically based shading or PBR shader.
MaterialShading is typically used to render surfaces in a way that models some key aspect of light and material interaction in the real world.
MaterialShading["material"] specifies that reflectance on the surface should well approximate optical properties of the material "material".
Possible materials include:

MaterialShading[{"material",col}] specifies the base color for the material "material".

MaterialShading[<|parm₁val₁,…|>] specifies that reflectance on the surface should approximate the reflectance equation based on physical, geometric and lighting properties parm_i.

Possible color parameters parm_i of the material include:

	"BaseColor"	base color of the material
	"EmissionColor"	color of the light emitted accross the surface
	"SpecularColor"	color of the light of a specular reflection

Values val_i for color parameters parm_i can be given in the following forms:
col a color

Texture[image] a 2D texture based on an image

{…,s} fraction of the color contribution to the final color
Possible physical parameters parm_i include:
"MetallicCoefficient" metallic coefficient of the materal surface

"RoughnessCoefficient" roughness coefficient of the materal surface
Values val_i for physical parameters parm_i can be given in the following forms:
s fraction of the property on the surface

Texture[image] a 2D texture based on an image

Possible geometric parameters parm_i include:
"SurfaceNormals" normal vectors of the surface
Values val_i for geometric parameters parm_i can be given in the following forms:
Texture[image] a 2D texture based on an image

{…,s} fraction of surface normals

Possible parameters parm_i of the clear coat covering of the material include:
"CoatColor" color of the coat covering

"CoatRoughnessCoefficient" roughness cooefficient of the coat covering

Possible anisotropy parameters parm_i include:
"SpecularAnisotropyCoefficient" anisotropy coefficient of specular reflection

"CoatAnisotropyCofficient" anisotropy coefficient of coat reflection
Values val_i for anisotropy parameters parm_i can be given in the following forms:
s fraction of the reflection with respect to the view angle

{s,θ} rotation of the reflection

Possible parameters parm_i of the material at grazing angles include:
"SheenColor" color of the light of reflections

"SheenRoughnessCoefficient" roughness coefficient

Possible light parameters parm_i include:
"AmbientExposureFraction" fraction of the ambient light on the surface
Values val_i for light parameters parm_i can be given in the following forms:
s fraction of the ambient light on the surface

Texture[image] a 2D texture based on an image

MaterialShading[] is effectively equivalent to MaterialShading[<|"BaseColor"White|>].
MaterialShading will override any color, Opacity, Texture, Glow or Specularity settings.

Examples

open all close all

Basic Examples (4)

Apply material shading to the unit sphere:

Wolfram Language code: Graphics3D[{MaterialShading["Iron"], Sphere[]}, Lighting -> "ThreePoint"]

Show a knot made of bronze:

Wolfram Language code: Graphics3D[{MaterialShading["Bronze"], KnotData["SolomonSeal", "ImageData"]}, Lighting -> "ThreePoint"]

Style a surface in a plot:

Wolfram Language code:

Plot3D[Sin[x + y ^ 2], {x, -3, 3}, {y, -2, 2}, PlotPoints -> 80, PlotStyle -> MaterialShading["Copper"], Mesh -> None, Lighting -> "ThreePoint"]

Show a gold Beethoven bust:

Wolfram Language code:

Graphics3D[{MaterialShading["Gold"], ExampleData[{"Geometry3D", "Beethoven"}, "GraphicsComplex"]}, Boxed -> False, Lighting -> "ThreePoint"]

Scope (15)

Basic Uses (6)

Apply material shading to a graphics primitive:

Wolfram Language code: Graphics3D[{MaterialShading["Iron"], #}, Lighting -> "ThreePoint"]& /@ {Sphere[], CapsuleShape[], Cone[]}

Apply material shading to a plot:

Wolfram Language code:

SphericalPlot3D[1 + Sin[5ϕ] / 5, {θ, 0, Pi}, {ϕ, 0, 2Pi}, Axes -> False, PlotStyle -> MaterialShading["Gold"], PlotPoints -> 40, Lighting -> "ThreePoint"]

Apply material shading to a chart:

Wolfram Language code: BarChart3D[Range[5], ChartElements -> [image], ChartStyle -> MaterialShading["Copper"], Lighting -> "ThreePoint"]

Style a geometric region:

Wolfram Language code: Region[Style[MengerMesh[2, 3], MaterialShading["Clay"]], Lighting -> "Accent"]

Apply material shading to a 3D object:

Wolfram Language code:

Graphics3D[{MaterialShading["Aluminum"], ExampleData[{"Geometry3D", "Galleon"}, "GraphicsComplex"]}, Lighting -> "ThreePoint", Boxed -> False]

Summary box:

Wolfram Language code: MaterialShading["Gold"]

Specification (6)

Specify a named material preset:

Wolfram Language code: Graphics3D[{MaterialShading["Electrum"], Sphere[]}, Lighting -> "ThreePoint"]

Use a material Entity:

Wolfram Language code: Graphics3D[{MaterialShading[Entity["Element", "Copper"]], Sphere[]}, Lighting -> "ThreePoint"]

Use a custom base color for a named material:

Wolfram Language code: Graphics3D[{MaterialShading[{"Electrum", Cyan}], Sphere[]}, Lighting -> "ThreePoint"]

Specify the material parameters directly:

Wolfram Language code:

Graphics3D[{MaterialShading[<|"BaseColor" -> Red, "MetallicCoefficient" -> 1.0, "RoughnessCoefficient" -> 0.8 |>], Sphere[]}, Lighting -> "ThreePoint"]

Use LightDarkSwitched to specify different colors for light and dark modes:

Wolfram Language code:

graphic = Graphics3D[{MaterialShading[<|"BaseColor" -> LightDarkSwitched[Red, Cyan]|>], Sphere[]}, Lighting -> "ThreePoint"];

Wolfram Language code: {LightModePane[graphic], DarkModePane[graphic]}

MaterialShading[] with no arguments uses a White base color:

Wolfram Language code: Graphics3D[{MaterialShading[], Sphere[]}, Lighting -> "ThreePoint"]

Lighting (3)

MaterialShading works with all types of lights:

Wolfram Language code:

lights = {{"Ambient", LightGray}, {"Point", White, ImageScaled[{1, 1, 2}]}, {"Directional", White, ImageScaled[{1, 1, 2}]}, {"Spot", White, {{1, -1, 1}, {0, 0, 0}}, Pi / 4}};
Graphics3D[{MaterialShading["Iron"], Sphere[]}, Lighting -> {#}]& /@ lights

Use colored lights:

Wolfram Language code:

Graphics3D[{MaterialShading["Iron"], Sphere[]}, Lighting -> {{"Directional", Red, ImageScaled[{1, -0.5, 1}]}, {"Directional", Green, ImageScaled[{-1, -0.5, 1}]}, {"Directional", Blue, ImageScaled[{0, 1, 1}]}, {"Ambient", GrayLevel[0.2]}}]

Use "ThreePoint" or "Accent" lighting to faithfully reproduce colors on the surface:

Wolfram Language code: Graphics3D[{MaterialShading["Iron"], Sphere[]}, Lighting -> #] & /@ { "ThreePoint", "Accent", Automatic}

Applications (14)

Basic Applications (10)

Show the named materials:

Wolfram Language code:

knot = IconizedObject[«[image]»];
materials = {"Aluminum", "Brass", "Bronze", "Copper", "Electrum", "Gold", "Iron", "Pewter", "Silver", "Clay", "Foil", "Glazed", "Plastic", "Rubber", "Satin", "Velvet"};

Wolfram Language code:

Grid[Partition[Labeled[Graphics3D[{MaterialShading[#], knot}, Lighting -> "ThreePoint", Boxed -> False, ImageSize -> 72, Method -> {"ShrinkWrap" -> True}], #]& /@ materials, 4, 4, 1, {}], Spacings -> {1, 1}]

Use the "BaseColor" parameter to set the base color of the material:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"BaseColor" -> c|>], Sphere[]}, Lighting -> "ThreePoint"], {c, {RGBColor[0.34398, 0.49112, 0.89936], RGBColor[0.97, 0.606, 0.081], RGBColor[0.91, 0.318, 0.243]}}]

Use the "RoughnessCoefficient" parameter to set the shininess of the material:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"RoughnessCoefficient" -> r|>], Sphere[]}, Lighting -> "ThreePoint"], {r, {0.15, 0.4, 1.0}}]

Use the "SpecularColor" parameter to set the color of the specular highlight on shiny materials:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"SpecularColor" -> s, "RoughnessCoefficient" -> 0.3|>], Sphere[]}, Lighting -> "ThreePoint"], {s, {RGBColor[0.34398, 0.49112, 0.89936], RGBColor[0.97, 0.606, 0.081], RGBColor[0.91, 0.318, 0.243]}}]

Specular highlights with the base color set to Black:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"SpecularColor" -> s, "RoughnessCoefficient" -> 0.3, "BaseColor" -> Black|>], Sphere[]}, Lighting -> "ThreePoint"], {s, {RGBColor[0.34398, 0.49112, 0.89936], RGBColor[0.97, 0.606, 0.081], RGBColor[0.91, 0.318, 0.243]}}]

Use the "MetallicCoefficient" parameter to create metallic materials:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"MetallicCoefficient" -> m, "RoughnessCoefficient" -> 0.7|>], Sphere[]}, Lighting -> "ThreePoint"], {m, {0, 1}}]

Set the base color:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"BaseColor" -> c, "MetallicCoefficient" -> 1, "RoughnessCoefficient" -> 0.7|>], Sphere[]}, Lighting -> "ThreePoint"], {c, {RGBColor[0.34398, 0.49112, 0.89936], RGBColor[0.97, 0.606, 0.081], RGBColor[0.91, 0.318, 0.243]}}]

Use the "SpecularAnisotropyCoefficient" parameter to set the material's preference to reflect light along its tangent direction:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"MetallicCoefficient" -> 1, "RoughnessCoefficient" -> 0.7, "SpecularAnisotropyCoefficient" -> a|>], Sphere[]}, Lighting -> "Accent"], {a, {0, 0.5, 1.0}}]

Set a custom angle for the tangent direction:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"MetallicCoefficient" -> 1, "RoughnessCoefficient" -> 0.7, "SpecularAnisotropyCoefficient" -> {1.0, θ}|>], Sphere[]}, Lighting -> "Accent"], {θ, {0, Pi / 4, Pi / 2}}]

Use the "EmissionColor" parameter to set the light emitted by the material itself:

Wolfram Language code: Table[Graphics3D[{MaterialShading[<|"EmissionColor" -> c|>], Sphere[]}, Lighting -> "Accent"], {c, {Red, Green, Blue}}]

The emitted color does not require scene lighting:

Wolfram Language code: Graphics3D[{MaterialShading[<|"EmissionColor" -> Red|>], Sphere[]}, Lighting -> None]

Use the "SheenColor" parameter to add highlights on the edges of materials:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"SheenColor" -> c|>], Sphere[]}, Lighting -> "Accent"], {c, {RGBColor[0.34398, 0.49112, 0.89936], RGBColor[0.97, 0.606, 0.081], RGBColor[0.91, 0.318, 0.243]}}]

The "SheenRoughnessCoefficient" parameter sets the concentration of the sheen lighting:

Wolfram Language code:

Table[Graphics3D[{MaterialShading[<|"SheenColor" -> RGBColor[0.34398, 0.49112, 0.89936], "SheenRoughnessCoefficient" -> r|>], Sphere[]}, Lighting -> "Accent"], {r, {0.1, 0.9}}]

Metallic materials do not have diffuse lighting and appear dark when perfectly smooth:

Wolfram Language code: Graphics3D[{MaterialShading[<|"MetallicCoefficient" -> 1|>], Sphere[]}, Lighting -> "Accent"]

Use the "RoughnessCoefficient" parameter to increase the roughness of the metal:

Wolfram Language code:

Graphics3D[{MaterialShading[<|"MetallicCoefficient" -> 1, "RoughnessCoefficient" -> #|>], Sphere[]}, Lighting -> "Accent"]& /@ {1 / 3, 2 / 3, 1}

The "AmbientExposureFraction" parameter has no effect with directional, point or spot lights:

Wolfram Language code:

lights = {{"Directional", White, ImageScaled[{1, 1, 4}]}, {"Point", White, ImageScaled[{1, 1, 2}]}, {"Spot", White, {ImageScaled[{1, 1, 2}], {0, 0, 0}}, Pi / 4}};
Graphics3D[{MaterialShading[<|"AmbientExposureFraction" -> Texture[[image]]|>], Sphere[]}, Lighting -> {#}]& /@ lights

Use an ambient light to view the effect of the "AmbientExposureFraction" parameter:

Wolfram Language code:

Graphics3D[{MaterialShading[<|"AmbientExposureFraction" -> Texture[[image]]|>], Sphere[]}, Lighting -> {{"Directional", Gray, ImageScaled[{1, 1, 4}]}, {"Ambient", Gray}}]

Photorealistic Materials (4)

Create a nonmetallic matte material:

Wolfram Language code: Graphics3D[{MaterialShading[], Sphere[]}, Lighting -> "ThreePoint"]

Use combinations of PBR textures to create semi-realistic materials:

Wolfram Language code: Graphics3D[{MaterialShading[<|"BaseColor" -> Texture[[image]], "SurfaceNormals" -> Texture[[image]]|>], Sphere[]}, ...]

Use metallic textures to create metal materials with wear and tear:

Wolfram Language code:

Graphics3D[{MaterialShading[<|"BaseColor" -> Texture[[image]], "SurfaceNormals" -> Texture[[image]], "RoughnessCoefficient" -> 0.65, "MetallicCoefficient" -> Texture[[image]] |>], Sphere[]}, Lighting -> "ThreePoint", Boxed -> False, ViewPoint -> Front]

Use emission textures to create glowing-hot materials:

Wolfram Language code:

Graphics3D[{MaterialShading[<|"BaseColor" -> GrayLevel[0.15], "SurfaceNormals" -> Texture[[image]], "RoughnessCoefficient" -> 0.6, "EmissionColor" -> Texture[[image]] , "SpecularColor" -> GrayLevel[1]|>], Sphere[]}, Lighting -> "Accent", Boxed -> False, ViewPoint -> Right]

Properties & Relations (3)

MaterialShading with no arguments approximates the default system appearance:

Wolfram Language code: {Graphics3D[{MaterialShading[], Sphere[]}], Graphics3D[{Sphere[]}]}

Apply a texture to a cuboid:

Wolfram Language code: Graphics3D[{MaterialShading[<|"BaseColor" -> Texture[[image]] |>], Cuboid[]}, Lighting -> "Neutral"]

Use VertexTextureCoordinates to specify vertex texture coordinates for a 2D texture:

Wolfram Language code:

Graphics3D[{MaterialShading[<|"BaseColor" -> Texture[[image]]|>], Polygon[{{-2, -1, 0}, {2, -1, 0}, {2, 1, 0}, {-2, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 1}, {0, 1}}]}]

Possible Issues (1)

The default light scheme uses several colored light sources:

Wolfram Language code: Graphics3D[{MaterialShading["Iron"], Sphere[]}]

Use "ThreePoint" lighting to get the standard material shading effect:

Wolfram Language code: Graphics3D[{MaterialShading["Iron"], Sphere[]}, Lighting -> "ThreePoint"]

Neat Examples (1)

A red, glazed deco-cube:

Wolfram Language code:

With[{c = 0.8}, ContourPlot3D[((x ^ 2 + y ^ 2 - c ^ 2) ^ 2 + (z ^ 2 - 1) ^ 2) ((y ^ 2 + z ^ 2 - c ^ 2) ^ 2 + (x ^ 2 - 1) ^ 2) ((z ^ 2 + x ^ 2 - c ^ 2) ^ 2 + (y ^ 2 - 1) ^ 2), {x, -1.5, 1.5}, {y, -1.5, 1.5}, {z, -1.5, 1.5}, Contours -> {0.1}, ContourStyle -> {MaterialShading[{"Glazed", Red}]}, Boxed -> False, Axes -> False, Background -> GrayLevel[.1], Lighting -> "ThreePoint", Mesh -> False, ViewAngle -> Pi / 10, ViewVertical -> {0, 1, 0}, PlotPoints -> 50]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

MaterialShading

Details

Examples

Basic Examples (4)

Scope (15)

Basic Uses (6)

Specification (6)

Lighting (3)

Applications (14)

Basic Applications (10)

Photorealistic Materials (4)

Properties & Relations (3)

Possible Issues (1)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

	col	a color
	Texture[image]	a 2D texture based on an image
	{…,s}	fraction of the color contribution to the final color

	s	fraction of the property on the surface
	Texture[image]	a 2D texture based on an image

	Texture[image]	a 2D texture based on an image
	{…,s}	fraction of surface normals

	"CoatColor"	color of the coat covering
	"CoatRoughnessCoefficient"	roughness cooefficient of the coat covering

MaterialShading

Details

Examples

Basic Examples (4)

Scope (15)

Basic Uses (6)

Specification (6)

Lighting (3)

Applications (14)

Basic Applications (10)

Photorealistic Materials (4)

Properties & Relations (3)

Possible Issues (1)

Neat Examples (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX