WOLFRAM

Wolfram Language & System Documentation Center

RegionResize[reg,l]

resize the region reg to have the first side length l preserving side length ratios.

RegionResize[reg,{lmax}]

resize into a box with maximum side length lmax preserving side length ratios.

RegionResize[reg,{l1,l2,…}]

resize into a box with side lengths li.

RegionResize[reg,{{x1,min,x1,max},{x2,min,x2,max},…}]

resize into a box with corners {x1,min,x2,min,…} and {x1,max,x2,max,…}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Special Regions  
Formula Regions  
Mesh Regions  
Derived Regions  
Subdivision Regions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

RegionResize

RegionResize[reg,l]

resize the region reg to have the first side length l preserving side length ratios.

RegionResize[reg,{lmax}]

resize into a box with maximum side length lmax preserving side length ratios.

RegionResize[reg,{l1,l2,…}]

resize into a box with side lengths li.

RegionResize[reg,{{x1,min,x1,max},{x2,min,x2,max},…}]

resize into a box with corners {x1,min,x2,min,…} and {x1,max,x2,max,…}.

Details

  • RegionResize is used to resize a region in ways that either preserve the shape or distort the shape.
  • The side lengths li can be any of:
  • Automaticautomatically determined side length
    Allthe original side length
    Scaled[s]fraction s of the original side length
    numnum side length
    {num}at most num side length
  • RegionResize[reg,l] is equivalent to RegionResize[reg,{l,Automatic,…}].
  • RegionResize[reg,{l}] is equivalent to RegionResize[reg,{{l},{l},…}].

Examples

open all close all

Basic Examples  (2)

Resize a triangle:

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, 1 / 2]

Visualize the regions:

Wolfram Language code: Graphics[{Red, ℛ, StandardGray, 𝒯}]

Resize a 3D mesh region:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {100, 3}]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 3}, {-2, 2}, {1, 4}}];

Visualize the regions:

Wolfram Language code: Show[ℛ, 𝒯]

Scope  (26)

Basic Uses  (7)

RegionResize works for any constant region:

Wolfram Language code: RegionResize[Disk[], {{-1, 2}, {-1, 2}}]

Non-constant regions:

Wolfram Language code: RegionResize[Disk[{x, y}, 2], {{-1, 2}, {-1, 2}}]

Finite regions:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 4 - x y + y ^ 4 ≤ 1., {x, y}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{-1, 2}, {-1, 1}}]

Visualize the regions:

Wolfram Language code: RegionPlot[{ℛ, 𝒯}]

RegionResize works on any geometric dimension:

Wolfram Language code: RegionResize[Ball[{1, 2, 3, 4, 5, 7}, 8], {{0, 1}, {0, 2}, {0, 3}, {1, 4}, {5, 10}, {2, 3}}]

Resize the region to have the first side length 2 and preserve side length ratios:

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {1, 2}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, 2];
Wolfram Language code: RegionBounds[𝒯]
Wolfram Language code: Graphics[{Red, 𝒯, StandardGray, ℛ}]

Resize into a box with maximum side length 3 and preserve side length ratios:

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {1, 2}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {3}];
Wolfram Language code: RegionBounds[𝒯]
Wolfram Language code: Graphics[{Red, 𝒯, StandardGray, ℛ}]

Resize into a box with side lengths:

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {1, 2}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {1, 4}];
Wolfram Language code: RegionBounds[𝒯]
Wolfram Language code: Graphics[{StandardGray, 𝒯, Red, ℛ}]

Resize into a box with corners:

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {1, 2}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{-1, 1}, {2, 3}}];
Wolfram Language code: RegionBounds[𝒯]
Wolfram Language code: Graphics[{StandardGray, 𝒯, Red, ℛ}]

The side lengths li can be automatically determined:

Wolfram Language code: ℛ = Triangle[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {Automatic, 3, Automatic}];
Wolfram Language code: RegionBounds[𝒯]

Original side length:

Wolfram Language code: 𝒯 = RegionResize[ℛ, {All, 3, 4}];
Wolfram Language code: RegionBounds[𝒯]

A fraction of the original side length:

Wolfram Language code: 𝒯 = RegionResize[ℛ, {Scaled[1 / 2], 3, 4}];
Wolfram Language code: RegionBounds[𝒯]
Wolfram Language code: Graphics3D[{StandardGray, 𝒯, Red, ℛ}]

Number:

Wolfram Language code: 𝒯 = RegionResize[ℛ, {1, 3, 4}];
Wolfram Language code: RegionBounds[𝒯]

Upper bounds:

Wolfram Language code: 𝒯 = RegionResize[ℛ, {2, {3}, 4}];
Wolfram Language code: RegionBounds[𝒯]

Special Regions  (6)

Regions in :

Wolfram Language code: RegionResize[Point[{{1}, {2}, {3}}], {{1, 4}}]

Regions in :

Wolfram Language code: RegionResize[Point[{{1, 1}, {2, 3}, {3, 5}}], {{1, 5}, {1, 3}}]
Wolfram Language code: RegionResize[Circle[{0, 0}, 3], {{1, 3}, {0, 3}}]
Wolfram Language code: RegionResize[Disk[{0, 0}, {3, 5}], {{0, 3}, {-5, 5}}]

Visualize the regions in :

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{0, 2}, {0, 1}}]
Wolfram Language code: Graphics[{Red, ℛ, StandardGray, 𝒯}]

Regions in :

Wolfram Language code: RegionResize[Point[{{1, 1, 1}, {2, 3, 4}, {3, 5, 8}}], {{1, 2}, {1, 3}, {2, 5}}]
Wolfram Language code: RegionResize[Line[{{1, 2, 3}, {4, 5, 6}}], {{1, 2}, {1, 3}, {2, 5}}]
Wolfram Language code: RegionResize[Polygon[{{1, 0, 0}, {0, 2, 0}, {0, 0, 3}}], {{1, 2}, {1, 3}, {2, 5}}]

Visualize the regions in :

Wolfram Language code: ℛ = Cuboid[{1, 1, 1}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {2, 2, 2 / 3}]
Wolfram Language code: Graphics3D[{StandardGray, 𝒯, Red, ℛ}]

Regions in :

Wolfram Language code: RegionResize[Simplex[{{1, 0, 0, 0}, {0, 2, 0, 0}, {0, 0, 3, 0}, {0, 0, 0, 4}}], {{0, 1}, {0, 2}, {0, 3}, {1, 4}}]
Wolfram Language code: RegionResize[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}], {{0, 1}, {0, 2}, {0, 3}, {1, 4}, {5, 10}}]
Wolfram Language code: RegionResize[Ball[{1, 2, 3, 4, 5, 7}, 8], {{0, 1}, {0, 2}, {0, 3}, {1, 4}, {5, 10}, {2, 3}}]

Formula Regions  (3)

A union of two disks as an ImplicitRegion:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 4∨(x - 3)^2 + y^2 ≤ 3, {x, y}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{0, 3}, {-2, 2}}]

Visualize the regions:

Wolfram Language code: RegionPlot[{ℛ, 𝒯}]

A union of two cylinders as an ImplicitRegion:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 2∨(x - 2)^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{0, 3}, {-2, 2}, {3, 4}}]

Visualize regions:

Wolfram Language code: RegionPlot3D[{ℛ, 𝒯}]

A rational parametrization of a disk represented as a ParametricRegion:

Wolfram Language code: ℛ = ParametricRegion[{(1 - t ^ 2) / (1 + t ^ 2), 2t / (1 + t ^ 2)}, {t}];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 2}, {0, 1}}]

Visualize regions:

Wolfram Language code: RegionPlot[{ℛ, 𝒯}]

Mesh Regions  (4)

MeshRegion in 2D:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {50, 2}]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 3}, {0, 2}}];

Visualize regions:

Wolfram Language code: Show[ℛ, 𝒯]

MeshRegion in 3D:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {100, 3}]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 3}, {-2, 2}, {1, 4}}];

Visualize regions:

Wolfram Language code: Show[ℛ, 𝒯]

BoundaryMeshRegion in 2D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {50, 2}]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 4}, {-1, 2}}];

Visualize bounds:

Wolfram Language code: Show[ℛ, 𝒯]

BoundaryMeshRegion in 3D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {100, 3}]]; 𝒯 = RegionResize[ℛ, {{1, 5}, {1, 5}, {1, 6}}];

Visualize regions:

Wolfram Language code: Show[ℛ, 𝒯]

Derived Regions  (4)

RegionIntersection of two regions:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 5}, {0, 3}}];

Visualize regions:

Wolfram Language code: Show[DiscretizeRegion[ℛ], DiscretizeRegion[𝒯]]

RegionUnion of mixed-dimensional regions:

Wolfram Language code: ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 5}, {0, 3}}];

Visualize bounds:

Wolfram Language code: Show[DiscretizeRegion[ℛ], DiscretizeRegion[𝒯]]

TransformedRegion:

Wolfram Language code: ℛ = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{3, 2}]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 4}, {0, 3}}];

Visualize bounds:

Wolfram Language code: Show[DiscretizeRegion[ℛ], DiscretizeRegion[𝒯]]

RegionBoundary:

Wolfram Language code: ℛ = RegionBoundary[Disk[{0, 0}, 1]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 4}, {0, 3}}]

Visualize bounds:

Wolfram Language code: Show[DiscretizeRegion[ℛ], DiscretizeRegion[𝒯]]

Subdivision Regions  (2)

SubdivisionRegion in 2D:

Wolfram Language code: ℛ = SubdivisionRegion[Rectangle[]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1.2, 4}, {0, 2}}];

Visualize regions:

Wolfram Language code: Show[ℛ, 𝒯]

SubdivisionRegion in 3D:

Wolfram Language code: ℛ = SubdivisionRegion[Cube[]];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{0, 4}, {0, 1}, {0, 2}}];

Visualize regions:

Wolfram Language code: Show[ℛ, 𝒯]

Applications  (4)

Resize a rectangle:

Wolfram Language code: Graphics[{Red, ℛ = Rectangle[], StandardGray, RegionResize[ℛ, 1 / 2]}]

Triangle:

Wolfram Language code: Graphics[{Red, ℛ = Triangle[], StandardGray, RegionResize[ℛ, 1 / 2]}]

Cuboid:

Wolfram Language code: Graphics3D[{Red, ℛ = Cuboid[], StandardGray, RegionResize[ℛ, {1 / 2, 3, 1 / 1}]}]

Pyramid:

Wolfram Language code: ℛ = Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}];
Wolfram Language code: Graphics3D[{Red, ℛ, StandardGray, RegionResize[ℛ, {1 / 2, 3, 1 / 1}]}]

Resize a 3D model before printing:

Wolfram Language code: ℛ = ExampleData[{"Geometry3D", "Beethoven"}, "MeshRegion"]
Wolfram Language code: Abs[Subtract @@@ RegionBounds[ℛ]]

A smaller model:

Wolfram Language code: 𝒯 = RegionResize[ℛ, Scaled[1 / 2]];
Wolfram Language code: Abs[Subtract @@@ RegionBounds[𝒯]]

Reduce the cost of the 3D printed model:

Wolfram Language code: Printout3D[ℛ, "Sculpteo"]["Price"]
Wolfram Language code: Printout3D[𝒯, "Sculpteo"]["Price"]

Resize a graphics scene:

Wolfram Language code: g = Graphics3D[{Blue, Cylinder[], Red, Sphere[{0, 0, 2}]}]
Wolfram Language code: Show[{g, RegionResize[DiscretizeGraphics[g], {{1, 4}, {1, 3}, {1, 4}}]}]

Modify a plot:

Wolfram Language code: g = Plot3D[Sin[x + y ^ 2], {x, -2, 2}, {y, -2, 2}]
Wolfram Language code: Show[{g, RegionResize[DiscretizeGraphics[g], Scaled[2 / 3]]}]

Properties & Relations  (3)

RegionResize can preserve the box ratios by resizing the region to have the first side length:

Wolfram Language code: ℛ = RegionResize[DelaunayMesh[RandomReal[1, {100, 2}]], 1];
Wolfram Language code: 𝒯 = RegionResize[ℛ, 3];
Wolfram Language code: Ratios[Subtract@@@RegionBounds[#]]& /@ {ℛ, 𝒯}

Use RegionBounds to get bounds of a region:

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];
Wolfram Language code: RegionBounds[ℛ]

Rescale the region and get the new bounds:

Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 4}, {1, 2}}];
Wolfram Language code: RegionBounds[𝒯]

RescalingTransform can be used to resize the region:

Wolfram Language code: ℛ = ArrayMesh[{{1, 0}, {1, 1}}, Frame -> True];
Wolfram Language code: 𝒯 = RegionResize[ℛ, {{1, 5}, {1, 3}}]

Use RescalingTransform:

Wolfram Language code: TransformedRegion[ℛ, RescalingTransform[RegionBounds[ℛ], RegionBounds[𝒯]]]

Possible Issues  (1)

An infinite region cannot be resized to fit in a finite box:

Wolfram Language code: reg = InfiniteLine[{0, 0}, {1, 1}];
Wolfram Language code: BoundedRegionQ[reg]
Wolfram Language code: RegionResize[reg, {{1, 2}, {0, 1}}]
Wolfram Research (2016), RegionResize, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionResize.html.

Text

Wolfram Research (2016), RegionResize, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionResize.html.

CMS

Wolfram Language. 2016. "RegionResize." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RegionResize.html.

APA

Wolfram Language. (2016). RegionResize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionResize.html

BibTeX

@misc{reference.wolfram_2026_regionresize, author="Wolfram Research", title="{RegionResize}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/RegionResize.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_regionresize, organization={Wolfram Research}, title={RegionResize}, year={2016}, url={https://reference.wolfram.com/language/ref/RegionResize.html}, note=[Accessed: 13-June-2026]}