Wolfram Language & System Documentation Center

TransformedRegion

TransformedRegion[reg,f]

represents the transformed region , where reg is a region and f is a function.

Details and Options

TransformedRegion is also known as the image of a region.

Examples

open all close all

Basic Examples (2)

A rotated rectangle:

Wolfram Language code: ℛ = TransformedRegion[Rectangle[], RotationTransform[π / 4]]

Wolfram Language code: Region[ℛ]

Wolfram Language code: Area[ℛ]

A disk transformed by :

Wolfram Language code: ℛ = TransformedRegion[Disk[{1, 1}, 4], {Indexed[#, 1] Indexed[#, 2], Indexed[#, 1] + Indexed[#, 2]}&];

Wolfram Language code: Region[ℛ]

Wolfram Language code: RegionMeasure[ℛ]

Scope (26)

Special Regions (10)

Some transformed regions are computed explicitly:

Wolfram Language code:

Subscript[ℛ, 1] = Rectangle[];
Subscript[ℛ, 2] = TransformedRegion[Subscript[ℛ, 1], ShearingTransform[Pi / 4, {1, 0}, {0, 1}]]

Visualize the transformation:

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

A linear-fractional transformation of the unit ball:

Wolfram Language code:

Subscript[ℛ, 1] = Ball[];
𝒯 = TransformationFunction[{{7, 5, -2, -4}, {3, -8, 9, 4}, {-8, 3, 1, -6}, {1, 0, 0, 2}}];
Subscript[ℛ, 2] = TransformedRegion[Subscript[ℛ, 1], 𝒯]

Visualize the transformation:

Wolfram Language code: Graphics3D[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Translate a unit Disk:

Wolfram Language code: ℛ = TransformedRegion[Disk[], TranslationTransform[{2, 3}]];

Point membership test:

Wolfram Language code: {RegionMember[ℛ, {0, 0}], RegionMember[ℛ, {2, 3}]}

Conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Wolfram Language code: Region[ℛ]

Shear a unit Rectangle:

Wolfram Language code: ℛ = TransformedRegion[Rectangle[], ShearingTransform[30Degree, {1, 0}, {0, 1}]];

Compute the RegionBounds:

Wolfram Language code: RegionBounds[ℛ]

Wolfram Language code: Region[ℛ]

Rotate a standard Triangle:

Wolfram Language code:

r = Triangle[];
Region[r]

Wolfram Language code: ℛ = TransformedRegion[Triangle[], RotationTransform[π / 3]];

Wolfram Language code: Region[ℛ]

Region remains constant and bounded:

Wolfram Language code: {ConstantRegionQ[r], ConstantRegionQ[ℛ]}

Wolfram Language code: {BoundedRegionQ[r], BoundedRegionQ[ℛ]}

Scale a Circle:

Wolfram Language code:

r = Circle[];
Region[r]

Wolfram Language code: ℛ = TransformedRegion[r, ScalingTransform[2., {1, 1}]];

Wolfram Language code: Region[ℛ]

Compute the ArcLength:

Wolfram Language code: {ArcLength[r], ArcLength[ℛ]}

A disk transformed by a nonlinear transformation :

Wolfram Language code: r1 = TransformedRegion[Disk[{1, 1}, 4], Function[p, {p[[1]] p[[2]], p[[1]] + p[[2]]}]];

Wolfram Language code: Region[r1]

Express the same point mapping using Indexed:

Wolfram Language code: r2 = TransformedRegion[Disk[{1, 1}, 4], {Indexed[#, 1] Indexed[#, 2], Indexed[#, 1] + Indexed[#, 2]}&];

Wolfram Language code: Region[r2]

Compute the RegionMeasure:

Wolfram Language code: RegionMeasure[r2]

Map points from a 3D Cuboid into 2D by a nonlinear transformation :

Wolfram Language code: ℛ = TransformedRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], {Indexed[#, 1] + Indexed[#, 2], Indexed[#, 1] + Indexed[#, 3]}&];

Geometric and embedding dimension:

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

Compute the RegionCentroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Visualize:

Wolfram Language code: RegionPlot[ℛ, Epilog -> {Red, Point[c]}]

Signed distance from a point:

Wolfram Language code: SignedRegionDistance[ℛ, {1, 1}]

Wolfram Language code: SignedRegionDistance[ℛ, {0, 2}]

Rotate a 3D Cuboid:

Wolfram Language code: ℛ = TransformedRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], RotationTransform[Pi / 3, {1, 1, 1}]];

Distance from a point:

Wolfram Language code: RegionDistance[ℛ, {0, 0, 0}]

Wolfram Language code: RegionDistance[ℛ, {2, 1, 0}]

Nearest point in the region:

Wolfram Language code: RegionNearest[ℛ, {1, 1, 1}]

Wolfram Language code: RegionNearest[ℛ, {2, 1, 0}]

Nearest points:

Wolfram Language code:

pts = Flatten[Table[{1 / 2, 1 / 2, 1 / 2} + {Cos[k 2π / 10]Sin[l π / 5], Sin[k 2π / 10]Sin[l π / 5], Cos[l π / 5]}, {k, 0., 9}, {l, 0., 4}], 1];
nst = RegionNearest[ℛ, #]& /@ pts;

Wolfram Language code:

Graphics3D[{GeometricTransformation[Cuboid[], RotationTransform[Pi / 3, {1, 1, 1}]], {Dashed, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}]

Integrate over a rotated unit cube:

Wolfram Language code: ℛ = TransformedRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], RotationTransform[Pi / 3, {1, 1, 1}]];

Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

Optimize:

Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations:

Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 3 / 2 && z^2 == x y && {x, y, z}∈ℛ, {x, y, z}]

Formula Regions (6)

Shear a ParametricRegion:

Wolfram Language code: pr = ParametricRegion[{Sin[θ], Sin[2θ]}, {{θ, 0, 2π}}];

Wolfram Language code: Region[pr]

Wolfram Language code: ℛ = TransformedRegion[pr, ShearingTransform[30Degree, {1., 0}, {0, 1}]];

Compute the ArcLength:

Wolfram Language code: ArcLength[ℛ]

Nearest point on the region from a given point:

Wolfram Language code:

pt = {1.2, -0.75};
npt = RegionNearest[ℛ, pt]

Wolfram Language code: RegionPlot[ℛ, Epilog -> {PointSize[Large], {Red, Point[pt]}, {Blue, Point[npt]}, {Dashed, Line[{pt, npt}]}}]

A rotated ParametricRegion:

Wolfram Language code: pr = ParametricRegion[{{s, (1 + t) s ^ 2 - t}, -1 ≤ s ≤ 1 && 0 ≤ t ≤ 1}, {s, t}];

Wolfram Language code: Region[pr]

Wolfram Language code: ℛ = TransformedRegion[pr, RotationTransform[Pi / 4, {1, 1}]];

Wolfram Language code: Region[ℛ]

Compute the Area:

Wolfram Language code: Area[ℛ]

Compute the RegionBounds:

Wolfram Language code: RegionBounds[ℛ]

RegionDistance:

Wolfram Language code: RegionDistance[ℛ, {1, -1}]

Wolfram Language code: RegionDistance[ℛ, {2., 0}]

Shear an ImplicitRegion:

Wolfram Language code: ir = ImplicitRegion[x ^ 2 - y ^ 2 ≤ 1, {x, y}];

Wolfram Language code: DiscretizeRegion[ir, {{-2, 2}, {-2, 2}}]

Wolfram Language code: ℛ = TransformedRegion[ir, ShearingTransform[30Degree, {1, 0}, {0, 1}]];

Wolfram Language code: DiscretizeRegion[ℛ, {{-3, 3}, {-2, 2}}]

Region remains unbounded:

Wolfram Language code: {BoundedRegionQ[ir], BoundedRegionQ[ℛ]}

Point membership test:

Wolfram Language code: {RegionMember[ℛ, {0, 0}], RegionMember[ℛ, {2, 0}]}

Conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Scale an ImplicitRegion:

Wolfram Language code: ir = ImplicitRegion[x^2 + y^2 + z^2 < 1 || (x + 1)^2 + y^2 + z^2 < 1, {x, y, z}];

Wolfram Language code: Region[ir]

Wolfram Language code: ℛ = TransformedRegion[ir, ScalingTransform[{1, 2, 2}]];

Wolfram Language code: Region[ℛ]

Compute the Volume:

Wolfram Language code: Volume[ℛ]

Integrate over the region:

Wolfram Language code: Integrate[x + y z, {x, y, z}∈ℛ]

Optimize:

Wolfram Language code: MinValue[{x + y z, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations:

Wolfram Language code: Reduce[x + y z == 3 / 2 && y == x z && {x, y, z}∈ℛ, {x, y, z}]

An ImplicitRegion transformed by a nonlinear transformation :

Wolfram Language code: ir = ImplicitRegion[0 ≤ x ≤ 2 && 0 ≤ y ≤ 2 && x y ≤ 1, {x, y}];

Wolfram Language code: RegionPlot[ir]

Wolfram Language code: r1 = TransformedRegion[ir, Function[p, {p[[1]] p[[2]], p[[1]] + p[[2]]}]];

Wolfram Language code: RegionPlot[r1]

Express the same point mapping using Indexed:

Wolfram Language code: r2 = TransformedRegion[ir, {Indexed[#, 1] Indexed[#, 2], Indexed[#, 1] + Indexed[#, 2]}&];

Wolfram Language code: RegionPlot[r2]

Compute the RegionMeasure:

Wolfram Language code: RegionMeasure[r2]

Map points from a 3D ball into 2D by a nonlinear transformation :

Wolfram Language code: ir = ImplicitRegion[x^2 + y^2 + z^2 < 1, {x, y, z}];

Wolfram Language code: Region[ir]

Wolfram Language code: ℛ = TransformedRegion[ir, {Indexed[#, 1] + Indexed[#, 2], Indexed[#, 1] + Indexed[#, 3]}&];

Geometric and embedding dimension:

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

Compute the RegionCentroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Visualize:

Wolfram Language code: RegionPlot[ℛ, Epilog -> {Red, Point[c]}]

Mesh Regions (3)

Rotate a BoundaryMeshRegion:

Wolfram Language code: br = BoundaryMeshRegion[{{2, 1}, {6, -1}, {4, 1}, {6, 3}}, Line[{1, 2, 3, 4, 1}]]

Wolfram Language code: ℛ = TransformedRegion[br, RotationTransform[Pi / 3, {1, 1}]];

Transformed region is still BoundaryMeshRegionQ:

Wolfram Language code: {BoundaryMeshRegionQ[br], BoundaryMeshRegionQ[ℛ]}

Point membership test:

Wolfram Language code: {RegionMember[ℛ, {2, 3}], RegionMember[ℛ, {1, 3}]}

Compute the RegionCentroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Visualize it:

Wolfram Language code: RegionPlot[ℛ, Epilog -> {Red, Point[c]}]

Compute the Area:

Wolfram Language code: Area[ℛ]

Integrate over the region:

Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

Shear a MeshRegion:

Wolfram Language code:

mr = MeshRegion[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 1}, {1, 1, 1}, {0, 1, 1}, {0.5, 0.5, 1.5}, {1.5, 0, 0}, {1.5, 1, 0}, {1, -0.5, 0}}, Hexahedron[{1, 2, 3, 4, 5, 6, 7, 8}]]

Wolfram Language code: ℛ = TransformedRegion[mr, ShearingTransform[30Degree, {1, 0, 0}, {0, 1, 0}]]

Transformed region is still MeshRegionQ:

Wolfram Language code: {MeshRegionQ[mr], MeshRegionQ[ℛ]}

Compute the Volume:

Wolfram Language code: Volume[ℛ]

Compute the RegionBounds:

Wolfram Language code: RegionBounds[ℛ]

RegionDistance from a point:

Wolfram Language code: RegionDistance[ℛ, {1, -1, 1}]

Wolfram Language code: RegionDistance[ℛ, {1, 1, 1}]

Integrate over the region:

Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

Scale a lower-dimensional MeshRegion:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {2, 1 / 2}, {2, -1 / 2}}, {Line[{1, 2}], Line[{2, 3}], Line[{3, 4}], Line[{4, 2}]}]

Wolfram Language code: ℛ = TransformedRegion[mr, ScalingTransform[2, {1, 1}]]

Compute the ArcLength:

Wolfram Language code: {ArcLength[mr], ArcLength[ℛ]}

Nearest point on the region from a given point:

Wolfram Language code:

pt = {1.5, 1.5};
npt = RegionNearest[ℛ, pt]

Wolfram Language code: RegionPlot[ℛ, Epilog -> {PointSize[Large], {Red, Point[pt]}, {Blue, Point[npt]}, {Dashed, Line[{pt, npt}]}}]

Derived Regions (5)

Transform a TransformedRegion:

Wolfram Language code: tr = TransformedRegion[Cuboid[], ShearingTransform[30Degree, {1, 0, 0}, {0, 1, 1}]];

Wolfram Language code: Region[tr]

Wolfram Language code: ℛ = TransformedRegion[tr, ReflectionTransform[{0, 1, 1}]];

Wolfram Language code: Region[ℛ]

Compute the Volume:

Wolfram Language code: Volume[ℛ]

Integrate over the region:

Wolfram Language code: Integrate[x + y z, {x, y, z}∈ℛ]

Optimize:

Wolfram Language code: MinValue[{x + y z, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations:

Wolfram Language code: Reduce[x + y z == 3 / 2 && y == x z && {x, y, z}∈ℛ, {x, y, z}]

Transform a RegionDifference:

Wolfram Language code: rd = RegionDifference[Rectangle[{0, 0}], Disk[{1, 0}, 1 / 2]];

Wolfram Language code: Region[rd]

Wolfram Language code: ℛ = TransformedRegion[rd, RotationTransform[π / 4]];

Wolfram Language code: Region[ℛ]

Compute the Area:

Wolfram Language code: Area[ℛ]

Compute the RegionBounds:

Wolfram Language code: RegionBounds[ℛ]

SignedRegionDistance from a given point:

Wolfram Language code: SignedRegionDistance[ℛ, {-1 / 4, 1}]

Wolfram Language code: SignedRegionDistance[ℛ, {2, -3}]

Transform a RegionBoundary:

Wolfram Language code: rb = RegionBoundary[Polygon[{{0, 0}, {3, -1}, {2, 0}, {3, 1}}]];

Wolfram Language code: Region[rb]

Wolfram Language code: ℛ = TransformedRegion[rb, ScalingTransform[2, {1, 1}]];

Compute the ArcLength:

Wolfram Language code: ArcLength[ℛ]

Nearest point on the region from a given point:

Wolfram Language code:

pt = {3 / 2, 2};
npt = RegionNearest[ℛ, pt]

Wolfram Language code: RegionPlot[ℛ, Epilog -> {PointSize[Large], {Red, Point[pt]}, {Blue, Point[npt]}, {Dashed, Line[{pt, npt}]}}]

Transform a RegionProduct:

Wolfram Language code: rp = RegionProduct[Disk[{0, 0}, 1], Line[{{0}, {1}}]];

Wolfram Language code: Region[rp]

Wolfram Language code: ℛ = TransformedRegion[rp, ReflectionTransform[{1, 0, 1}]];

Wolfram Language code: Region[ℛ]

Compute the Volume:

Wolfram Language code: Volume[ℛ]

Compute the RegionBounds:

Wolfram Language code: RegionBounds[ℛ]

RegionDistance from a point:

Wolfram Language code: RegionDistance[ℛ, {0, 0, 0}]

Wolfram Language code: RegionDistance[ℛ, {1, 1, 1}]

Transform a RegionUnion by a nonlinear transformation :

Wolfram Language code: ru = RegionUnion[Disk[{0, 0}, 2], Disk[{3, 0}, 2]];

Wolfram Language code: Region[ru]

Wolfram Language code: r1 = TransformedRegion[ru, Function[p, {p[[1]] p[[2]], p[[1]] + p[[2]]}]];

Wolfram Language code: Region[r1]

Express the same point mapping using Indexed:

Wolfram Language code: r2 = TransformedRegion[ru, {Indexed[#, 1] Indexed[#, 2], Indexed[#, 1] + Indexed[#, 2]}&];

Wolfram Language code: Region[r2]

Compute the RegionBounds:

Wolfram Language code: RegionBounds[r2]

CSG Regions (1)

Transform a CSGRegion in 2D:

Wolfram Language code: TransformedRegion[CSGRegion["Difference", {Disk[], Disk[{0, 0}, 1 / 2]}], ScalingTransform[{3, 1}]]

3D:

Wolfram Language code: TransformedRegion[CSGRegion["Difference", {Ball[], Cuboid[{-2, -2, 0}, {2, 2, -2}]}], ScalingTransform[{3, 1, 1}]]

Subdivision Regions (1)

Transform a SubdivisionRegion in 2D:

Wolfram Language code: TransformedRegion[SubdivisionRegion[Rectangle[]], ScalingTransform[{3, 1}]]

3D:

Wolfram Language code: TransformedRegion[SubdivisionRegion[Cube[]], ScalingTransform[{3, 1, 1}]]

Applications (2)

Any triangle is an affine transformation of the standard triangle:

Wolfram Language code: {p0, p1, p2} = {{1, 1}, {2, 2}, {3, 1}};

The transformation is given by , where $A=TemplateBox[{{{, {{{p, _, 1}, -, {p, _, 0}}, ,, ..., ,, {{p, _, 3}, -, {p, _, 0}}}, }}}, Transpose]$ :

Wolfram Language code: A = {p1 - p0, p2 - p0};

Wolfram Language code: t = AffineTransform[{A, p0}];

Compare original and transformed unit triangle:

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{p0, p1, p2}];
Subscript[ℛ, 2] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];

Wolfram Language code:

{Region[Subscript[ℛ, 1], Frame -> True], 
	Region[TransformedRegion[Subscript[ℛ, 2], t], Frame -> True]}

Find the perspective transformation of a unit Cuboid with center :

Wolfram Language code: tr = LinearFractionalTransform[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {-(1/2), 0, 0, 1}}];

Wolfram Language code: ℛ = TransformedRegion[Cuboid[], tr]

Visualize the region:

Wolfram Language code:

RegionPlot3D[Evaluate@RegionMember[ℛ, {x, y, z}], {x, -2, 2}, {y, -0.5, 2.5}, {z, -0.5, 2.5}, Mesh -> None, PlotPoints -> 100, PlotStyle  -> Opacity[0.3, Yellow]]

Compute the Volume:

Wolfram Language code: Volume[ℛ]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

TransformedRegion

Details and Options

Examples

Basic Examples (2)

Scope (26)

Special Regions (10)

Formula Regions (6)

Mesh Regions (3)

Derived Regions (5)

CSG Regions (1)

Subdivision Regions (1)

Applications (2)

Text

CMS

APA

BibTeX

BibLaTeX

TransformedRegion

Details and Options

Examples

Basic Examples (2)

Scope (26)

Special Regions (10)

Formula Regions (6)

Mesh Regions (3)

Derived Regions (5)

CSG Regions (1)

Subdivision Regions (1)

Applications (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX